[meta-oe][PATCH 1/2] uthash: update to v2.0.2

[meta-oe][PATCH 1/2] uthash: update to v2.0.2

[André Draszik]

From: André Draszik <andre.draszik@jci.com>

- the license has changed to BSD-1-Clause
- the main package is empty (as this only provides
  header files), so the -dev package must not depend
  on the main package

Signed-off-by: André Draszik <andre.draszik@jci.com>
---
 meta-oe/recipes-support/uthash/uthash_1.9.7.bb | 16 --------------
 meta-oe/recipes-support/uthash/uthash_2.0.2.bb | 30 ++++++++++++++++++++++++++
 2 files changed, 30 insertions(+), 16 deletions(-)
 delete mode 100644 meta-oe/recipes-support/uthash/uthash_1.9.7.bb
 create mode 100644 meta-oe/recipes-support/uthash/uthash_2.0.2.bb

diff --git a/meta-oe/recipes-support/uthash/uthash_1.9.7.bb b/meta-oe/recipes-support/uthash/uthash_1.9.7.bb
deleted file mode 100644
index 82a9f2a6a..000000000
--- a/meta-oe/recipes-support/uthash/uthash_1.9.7.bb
+++ /dev/null
@@ -1,16 +0,0 @@
-SUMMARY = "Hash table for C structures"
-SECTION = "base"
-LICENSE = "GPLv2"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=564f9c44927f6247dc810bf557e2b240"
-
-SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${BP}.tar.bz2"
-
-SRC_URI[md5sum] = "1f14bbee7ee73ed0ceb3549f8cf378b4"
-SRC_URI[sha256sum] = "956f5c99798349c413275fe4c9ff128d72e280655dadbe4365f8e9fbda91393f"
-
-do_install () {
-    install -dm755 ${D}${includedir}
-    install -m 0644 ${S}/src/*.h ${D}${includedir}
-}
-
-BBCLASSEXTEND = "native"
diff --git a/meta-oe/recipes-support/uthash/uthash_2.0.2.bb b/meta-oe/recipes-support/uthash/uthash_2.0.2.bb
new file mode 100644
index 000000000..8a6887ef0
--- /dev/null
+++ b/meta-oe/recipes-support/uthash/uthash_2.0.2.bb
@@ -0,0 +1,30 @@
+SUMMARY = "Hash table and linked list for C structures"
+DESCRIPTION = " uthash-dev provides a hash table implementation using C preprocessor macros.\n\
+ This package also includes:\n\
+  * utlist.h provides linked list macros for C structures\n\
+  * utarray.h implements dynamic arrays using macros\n\
+  * utstring.h implements a basic dynamic string\n\
+"
+HOMEPAGE = "https://troydhanson.github.io/uthash/"
+SECTION = "base"
+LICENSE = "BSD-1-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=5cc1f1e4c71f19f580458586756c02b4"
+
+SRC_URI = "https://github.com/troydhanson/${BPN}/archive/v${PV}.tar.gz;downloadfilename=${BP}.tar.gz"
+UPSTREAM_CHECK_URI = "https://github.com/troydhanson/${BPN}/releases"
+
+SRC_URI[md5sum] = "d08632a58674274c9cd87e2930f5696a"
+SRC_URI[sha256sum] = "34a31d51dd7a839819cecd6f46049b4ffe031d7f3147d9a042f5504fdb1348d1"
+
+do_compile[noexec] = "1"
+
+do_install () {
+    install -dm755 ${D}${includedir}
+    install -m0644 src/*.h ${D}${includedir}
+}
+
+# The main package is empty and non-existent, so -dev
+# should not depend on it...
+RDEPENDS_${PN}-dev = ""
+
+BBCLASSEXTEND = "native"
-- 
2.15.1

[meta-oe][PATCH 2/2] uthash: add ptest support

[André Draszik]

From: André Draszik <andre.draszik@jci.com>

Signed-off-by: André Draszik <andre.draszik@jci.com>
---
 meta-oe/recipes-support/uthash/uthash/run-ptest | 10 ++++++++++
 meta-oe/recipes-support/uthash/uthash_2.0.2.bb  | 18 +++++++++++++++++-
 2 files changed, 27 insertions(+), 1 deletion(-)
 create mode 100755 meta-oe/recipes-support/uthash/uthash/run-ptest

diff --git a/meta-oe/recipes-support/uthash/uthash/run-ptest b/meta-oe/recipes-support/uthash/uthash/run-ptest
new file mode 100755
index 000000000..14071a649
--- /dev/null
+++ b/meta-oe/recipes-support/uthash/uthash/run-ptest
@@ -0,0 +1,10 @@
+#!/bin/sh
+
+cd tests
+for i in test*[0-9] ; do
+    if ./${i} | cmp -s "${i}.ans" - ; then
+        echo "PASS: ${i}"
+    else
+        echo "FAIL: ${i}"
+    fi
+done
diff --git a/meta-oe/recipes-support/uthash/uthash_2.0.2.bb b/meta-oe/recipes-support/uthash/uthash_2.0.2.bb
index 8a6887ef0..ccdd13b32 100644
--- a/meta-oe/recipes-support/uthash/uthash_2.0.2.bb
+++ b/meta-oe/recipes-support/uthash/uthash_2.0.2.bb
@@ -10,19 +10,35 @@ SECTION = "base"
 LICENSE = "BSD-1-Clause"
 LIC_FILES_CHKSUM = "file://LICENSE;md5=5cc1f1e4c71f19f580458586756c02b4"
 
-SRC_URI = "https://github.com/troydhanson/${BPN}/archive/v${PV}.tar.gz;downloadfilename=${BP}.tar.gz"
+SRC_URI = "\
+    https://github.com/troydhanson/${BPN}/archive/v${PV}.tar.gz;downloadfilename=${BP}.tar.gz \
+    file://run-ptest \
+"
 UPSTREAM_CHECK_URI = "https://github.com/troydhanson/${BPN}/releases"
 
 SRC_URI[md5sum] = "d08632a58674274c9cd87e2930f5696a"
 SRC_URI[sha256sum] = "34a31d51dd7a839819cecd6f46049b4ffe031d7f3147d9a042f5504fdb1348d1"
 
+inherit ptest
+
 do_compile[noexec] = "1"
 
+do_compile_ptest() {
+    oe_runmake -C tests tests_only TEST_TARGET=
+}
+
 do_install () {
     install -dm755 ${D}${includedir}
     install -m0644 src/*.h ${D}${includedir}
 }
 
+do_install_ptest() {
+    install -dm755 ${D}${PTEST_PATH}/tests
+    install -m0755 tests/test*[0-9] ${D}${PTEST_PATH}/tests
+    install -m0644 tests/test*[0-9].ans ${D}${PTEST_PATH}/tests
+    install -m0644 tests/test*[0-9].dat ${D}${PTEST_PATH}/tests
+}
+
 # The main package is empty and non-existent, so -dev
 # should not depend on it...
 RDEPENDS_${PN}-dev = ""
-- 
2.15.1

Re: [meta-oe][PATCH 1/2] uthash: update to v2.0.2

[André Draszik]

On Fri, 2018-01-12 at 12:29 +0000, André Draszik wrote:
> 
[...]
> +HOMEPAGE = "https://troydhanson.github.io/uthash/"
> +SECTION = "base"
> +LICENSE = "BSD-1-Clause"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=5cc1f1e4c71f19f580458586756c02b4"

Note that there is no common license file for BSD-1-Clause in OE-core, which
causes this warning:

WARNING: <image> do_rootfs: The license listed BSD-1-Clause was not in the licenses collected for recipe uthash

Is this really the first recipe using BSD-1-Clause?
Should a license file be added to OE-core, or is there a different approach
taken normally?


Cheers,
Andre'

Re: [meta-oe][PATCH 1/2] uthash: update to v2.0.2

[akuster808]

On 01/12/2018 04:33 AM, André Draszik wrote:
> On Fri, 2018-01-12 at 12:29 +0000, André Draszik wrote:
> [...]
>> +HOMEPAGE = "https://troydhanson.github.io/uthash/"
>> +SECTION = "base"
>> +LICENSE = "BSD-1-Clause"
>> +LIC_FILES_CHKSUM = "file://LICENSE;md5=5cc1f1e4c71f19f580458586756c02b4"
> Note that there is no common license file for BSD-1-Clause in OE-core, which
> causes this warning:
>
> WARNING: <image> do_rootfs: The license listed BSD-1-Clause was not in the licenses collected for recipe uthash
>
> Is this really the first recipe using BSD-1-Clause?

Does the standalone "BSD" license over Clause 1?

> Should a license file be added to OE-core, or is there a different approach
> taken normally?
>
>
> Cheers,
> Andre'
>

Re: [meta-oe][PATCH 1/2] uthash: update to v2.0.2

[André Draszik]

On Tue, 2018-01-16 at 22:20 -0800, akuster808 wrote:
> 
> On 01/12/2018 04:33 AM, André Draszik wrote:
> > On Fri, 2018-01-12 at 12:29 +0000, André Draszik wrote:
> > [...]
> > > +HOMEPAGE = "https://troydhanson.github.io/uthash/"
> > > +SECTION = "base"
> > > +LICENSE = "BSD-1-Clause"
> > > +LIC_FILES_CHKSUM =
> > > "file://LICENSE;md5=5cc1f1e4c71f19f580458586756c02b4"
> > 
> > Note that there is no common license file for BSD-1-Clause in OE-core,
> > which
> > causes this warning:
> > 
> > WARNING: <image> do_rootfs: The license listed BSD-1-Clause was not in
> > the licenses collected for recipe uthash
> > 
> > Is this really the first recipe using BSD-1-Clause?
> 
> Does the standalone "BSD" license over Clause 1?

Well, the stand-alone BSD license is effectively BSD-3-Clause, so it's of
course more restrictive than the 1-Clause version.


Cheers,
Andre'