[thud/master][PATCH 0/2] Adding ti-cgt7x-1.1.0*

[thud/master][PATCH 0/2] Adding ti-cgt7x-1.1.0*

[Mahesh Radhakrishnan]

The ti-cgt7x is not external yet, hence the SRC_URI has a dummy link.
Also, the ti-paths have been updated to install the same.

Mahesh Radhakrishnan (2):
  ti-cgt-7x: Initial version of TI-CGT-C7000 recipe
  ti-paths.inc: Adding install directory for ti-cgt-7x

 recipes-ti/devtools/ti-cgt7x_1.1.0.bb | 65 +++++++++++++++++++++++++++++++++++
 recipes-ti/includes/ti-paths.inc      |  3 ++
 2 files changed, 68 insertions(+)
 create mode 100644 recipes-ti/devtools/ti-cgt7x_1.1.0.bb

-- 
1.9.1

[thud/master][PATCH 1/2] ti-cgt-7x: Initial version of TI-CGT-C7000 recipe

[Mahesh Radhakrishnan]

The tools are not available externally yet, hence the
SRC_URI link
"http://install.source.dir.local/${BINFILE};name=${BINFILE_NAME}"
---
 recipes-ti/devtools/ti-cgt7x_1.1.0.bb | 65 +++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 recipes-ti/devtools/ti-cgt7x_1.1.0.bb

diff --git a/recipes-ti/devtools/ti-cgt7x_1.1.0.bb b/recipes-ti/devtools/ti-cgt7x_1.1.0.bb
new file mode 100644
index 0000000..19da698
--- /dev/null
+++ b/recipes-ti/devtools/ti-cgt7x_1.1.0.bb
@@ -0,0 +1,65 @@
+DESCRIPTION = "TI DSP Code Generation Tools"
+HOMEPAGE = "https://www-a.ti.com/downloads/sds_support/TICodegenerationTools/download.htm"
+LICENSE = "(TI-TSPA & Thai-Open-Source-Software-Center) & BSD-3-Clause & BSL-1.0 & Patrick-Powell & AFL-3.0 & MIT & BSD-2-Clause & PD"
+
+LIC_FILES_CHKSUM_class-target = "file://usr/share/doc/ti/cgt-c7x/C7000_1.0.x_CodeGenerationTools_Manifest.htm;md5=3074e433c5d52657076d1d138dfbdaf8"
+
+require recipes-ti/includes/ti-unpack.inc
+
+# only x86_64 is supported
+COMPATIBLE_HOST = "x86_64.*-linux"
+COMPATIBLE_HOST_class-target = "null"
+
+# For now we only have hardfp version for target class
+python __anonymous() {
+    c = d.getVar("CLASSOVERRIDE")
+
+    if c == "class-target":
+        tunes = d.getVar("TUNE_FEATURES")
+        if not tunes:
+            return
+        pkgn = d.getVar("PN")
+        pkgv = d.getVar("PV")
+        if "callconvention-hard" not in tunes:
+            bb.warn("%s-%s ONLY supports hardfp mode for now" % (pkgn, pkgv))
+            raise bb.parse.SkipPackage("%s-%s ONLY supports hardfp mode for now" % (pkgn, pkgv))
+}
+
+BINFILE = "ti_cgt_c7000_${PV}_linux_installer_x86.bin"
+BINFILE_NAME = "cgt7x_x86_installer"
+
+# Please note, "install.source.dir.local" is not a real URL, below files need to be pre-downloaded
+SRC_URI = "http://install.source.dir.local/${BINFILE};name=${BINFILE_NAME}"
+
+TI_BIN_UNPK_ARGS = "--prefix ${S}"
+TI_BIN_UNPK_CMDS = ""
+
+BINFILE = "ti_cgt_c7000_${PV}_linux_installer_x86.bin"
+
+BINFILE_MD5 = "feb668b4213403c661909adcf65d2ba8"
+BINFILE_SHA256 = "4a3954c973622c00a9b91fa90473cf921f4b763300b0e7c32735304867856ab8"
+
+SRC_URI[cgt7x_x86_installer.md5sum]    = "feb668b4213403c661909adcf65d2ba8"
+SRC_URI[cgt7x_x86_installer.sha256sum] = "4a3954c973622c00a9b91fa90473cf921f4b763300b0e7c32735304867856ab8"
+
+S = "${WORKDIR}/c7000_${PV}"
+
+do_install() {
+    install -d ${D}/${TI_CGT7X_INSTALL_DIR_RECIPE}
+    cp -rP --preserve=mode,links,timestamps --no-preserve=ownership ${WORKDIR}/c7000_${PV}/. ${D}/${TI_CGT7X_INSTALL_DIR_RECIPE}
+}
+
+do_install_class-target() {
+    ${WORKDIR}/${BINFILE} --prefix ${D}
+}
+
+
+FILES_${PN} += "${TI_CGT7X_INSTALL_DIR_RECIPE}"
+
+INSANE_SKIP_${PN} += "arch staticdev textrel"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+
+BBCLASSEXTEND = "native nativesdk"
-- 
1.9.1

[thud/master][PATCH 2/2] ti-paths.inc: Adding install directory for ti-cgt-7x

[Mahesh Radhakrishnan]

Signed-off-by: Mahesh Radhakrishnan <m-radhakrishnan2@ti.com>
---
 recipes-ti/includes/ti-paths.inc | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/recipes-ti/includes/ti-paths.inc b/recipes-ti/includes/ti-paths.inc
index 250074b..52a93cf 100644
--- a/recipes-ti/includes/ti-paths.inc
+++ b/recipes-ti/includes/ti-paths.inc
@@ -60,6 +60,8 @@ export MPM_INSTALL_DIR_RECIPE        = "${installdir}/ti-mpm-tree"
 export TI_CGT6X_7_INSTALL_DIR_RECIPE   = "${installdir}/cgt6x-7"
 export GCC_LINARO_BAREMETAL_TOOLCHAIN_RECIPE          = "${installdir}/gcc-linaro-baremetal"
 export GCC_LINARO_BAREMETAL_AARCH64_TOOLCHAIN_RECIPE  = "${installdir}/gcc-linaro-baremetal-aarch64"
+export TI_CGT7X_INSTALL_DIR_RECIPE        = "${installdir}/cgt-c7x"
+
 
 # This is where the tools will end up in sysroot
 export BIOS_INSTALL_DIR       = "${STAGING_DIR_TARGET}${BIOS_INSTALL_DIR_RECIPE}"
@@ -113,6 +115,7 @@ export MPM_INSTALL_DIR        = "${STAGING_DIR_TARGET}${MPM_INSTALL_DIR_RECIPE}"
 export TI_CGT6X_7_INSTALL_DIR   = "${STAGING_DIR_NATIVE}${TI_CGT6X_7_INSTALL_DIR_RECIPE}"
 export GCC_LINARO_BAREMETAL_TOOLCHAIN         =  "${STAGING_DIR_NATIVE}${GCC_LINARO_BAREMETAL_TOOLCHAIN_RECIPE}"
 export GCC_LINARO_BAREMETAL_AARCH64_TOOLCHAIN =  "${STAGING_DIR_NATIVE}${GCC_LINARO_BAREMETAL_AARCH64_TOOLCHAIN_RECIPE}"
+export TI_CGT7X_INSTALL_DIR        = "${STAGING_DIR_NATIVE}${TI_CGT7X_INSTALL_DIR_RECIPE}"
 
 
 DSPSUFFIX_omapl137 = "x674"
-- 
1.9.1

Re: [thud/master][PATCH 1/2] ti-cgt-7x: Initial version of TI-CGT-C7000 recipe

[Denys Dmytriyenko]

On Tue, Aug 13, 2019 at 03:48:58PM -0400, Mahesh Radhakrishnan wrote:
> The tools are not available externally yet, hence the
> SRC_URI link
> "http://install.source.dir.local/${BINFILE};name=${BINFILE_NAME}"

Please don't phrase it like this! There's no such thing as internal or 
external at this level. Better say that it's not publicly fetchable yet 
and requires pre-downloading.


> ---
>  recipes-ti/devtools/ti-cgt7x_1.1.0.bb | 65 +++++++++++++++++++++++++++++++++++
>  1 file changed, 65 insertions(+)
>  create mode 100644 recipes-ti/devtools/ti-cgt7x_1.1.0.bb
> 
> diff --git a/recipes-ti/devtools/ti-cgt7x_1.1.0.bb b/recipes-ti/devtools/ti-cgt7x_1.1.0.bb
> new file mode 100644
> index 0000000..19da698
> --- /dev/null
> +++ b/recipes-ti/devtools/ti-cgt7x_1.1.0.bb
> @@ -0,0 +1,65 @@
> +DESCRIPTION = "TI DSP Code Generation Tools"
> +HOMEPAGE = "https://www-a.ti.com/downloads/sds_support/TICodegenerationTools/download.htm"
> +LICENSE = "(TI-TSPA & Thai-Open-Source-Software-Center) & BSD-3-Clause & BSL-1.0 & Patrick-Powell & AFL-3.0 & MIT & BSD-2-Clause & PD"
> +
> +LIC_FILES_CHKSUM_class-target = "file://usr/share/doc/ti/cgt-c7x/C7000_1.0.x_CodeGenerationTools_Manifest.htm;md5=3074e433c5d52657076d1d138dfbdaf8"
> +
> +require recipes-ti/includes/ti-unpack.inc
> +
> +# only x86_64 is supported
> +COMPATIBLE_HOST = "x86_64.*-linux"
> +COMPATIBLE_HOST_class-target = "null"

So, target is not supported, but LIC_FILES_CHKSUM is only set for the target.


> +# For now we only have hardfp version for target class
> +python __anonymous() {
> +    c = d.getVar("CLASSOVERRIDE")
> +
> +    if c == "class-target":
> +        tunes = d.getVar("TUNE_FEATURES")
> +        if not tunes:
> +            return
> +        pkgn = d.getVar("PN")
> +        pkgv = d.getVar("PV")
> +        if "callconvention-hard" not in tunes:
> +            bb.warn("%s-%s ONLY supports hardfp mode for now" % (pkgn, pkgv))
> +            raise bb.parse.SkipPackage("%s-%s ONLY supports hardfp mode for now" % (pkgn, pkgv))

Again, this check is also only valid for the target.


> +}
> +
> +BINFILE = "ti_cgt_c7000_${PV}_linux_installer_x86.bin"
> +BINFILE_NAME = "cgt7x_x86_installer"
> +
> +# Please note, "install.source.dir.local" is not a real URL, below files need to be pre-downloaded
> +SRC_URI = "http://install.source.dir.local/${BINFILE};name=${BINFILE_NAME}"
> +
> +TI_BIN_UNPK_ARGS = "--prefix ${S}"
> +TI_BIN_UNPK_CMDS = ""
> +
> +BINFILE = "ti_cgt_c7000_${PV}_linux_installer_x86.bin"
> +
> +BINFILE_MD5 = "feb668b4213403c661909adcf65d2ba8"
> +BINFILE_SHA256 = "4a3954c973622c00a9b91fa90473cf921f4b763300b0e7c32735304867856ab8"
> +
> +SRC_URI[cgt7x_x86_installer.md5sum]    = "feb668b4213403c661909adcf65d2ba8"
> +SRC_URI[cgt7x_x86_installer.sha256sum] = "4a3954c973622c00a9b91fa90473cf921f4b763300b0e7c32735304867856ab8"
> +
> +S = "${WORKDIR}/c7000_${PV}"
> +
> +do_install() {
> +    install -d ${D}/${TI_CGT7X_INSTALL_DIR_RECIPE}
> +    cp -rP --preserve=mode,links,timestamps --no-preserve=ownership ${WORKDIR}/c7000_${PV}/. ${D}/${TI_CGT7X_INSTALL_DIR_RECIPE}
> +}
> +
> +do_install_class-target() {
> +    ${WORKDIR}/${BINFILE} --prefix ${D}
> +}
> +
> +
> +FILES_${PN} += "${TI_CGT7X_INSTALL_DIR_RECIPE}"
> +
> +INSANE_SKIP_${PN} += "arch staticdev textrel"
> +
> +INHIBIT_PACKAGE_STRIP = "1"
> +INHIBIT_SYSROOT_STRIP = "1"
> +INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
> +
> +BBCLASSEXTEND = "native nativesdk"

How are native and nativesdk would work, if LIC_FILES_CHKSUM is only provided 
for target?


> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> meta-ti mailing list
> meta-ti@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/meta-ti