Re: [thud/zeus/master][PATCH] recipes-graphics: Add recipe for DevIL

[Denys Dmytriyenko <denys@ti.com>]

On Wed, Jan 22, 2020 at 11:36:26AM -0600, Gowtham Tammana wrote:
> Developers Image Library (DevIL) is a cross-platfor image utility
> library with simple syntax (openil.sourceforge.net). Adding recipe to
> build from sources.

Where is it coming from? I see there are many copies in other layers - is it 
based on something or completely done from scratch?


> Signed-off-by: Gowtham Tammana <g-tammana@ti.com>
> ---
>  .../recipes-graphics/devil/devil_1.8.0.bb     | 30 +++++++++++++++++++
>  .../devil/files/Remove-ILUT-dependency.patch  | 13 ++++++++
>  2 files changed, 43 insertions(+)
>  create mode 100644 meta-arago-extras/recipes-graphics/devil/devil_1.8.0.bb
>  create mode 100644 meta-arago-extras/recipes-graphics/devil/files/Remove-ILUT-dependency.patch
> 
> diff --git a/meta-arago-extras/recipes-graphics/devil/devil_1.8.0.bb b/meta-arago-extras/recipes-graphics/devil/devil_1.8.0.bb
> new file mode 100644
> index 00000000..6ba7f34b
> --- /dev/null
> +++ b/meta-arago-extras/recipes-graphics/devil/devil_1.8.0.bb
> @@ -0,0 +1,30 @@
> +DESCRIPTION = "Developer's Image Library (DevIL) is a cross-platform image \
> +               library utilizing simple syntax to load, save, convert, \
> +               manipulate, filter and display a variety of images."

Would also need a short SUMMARY set.


> +HOMEPAGE = "https://github.com/DentonW/DevIL"
> +LICENSE = "LGPLv2"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=fc178bcd425090939a8b634d1d6a9594"
> +
> +SRC_URI = "git://github.com/dentonw/devil.git;protocol=git;branch=master \
> +           file://Remove-ILUT-dependency.patch"
> +
> +SRCREV = "e34284a7e07763769f671a74b4fec718174ad862"
> +
> +COMPATIBLE_MACHINE = "j7-evm"

Is it really compatible with j7 only? Looks to me as rather generic...


> +
> +PR = "r1"
> +S = "${WORKDIR}/git"
> +
> +# Build only DevIL
> +OECMAKE_SOURCEPATH = "${S}/DevIL"
> +
> +PACKAGECONFIG ??= "png"
> +PACKAGECONFIG[png] = "-DIL_NO_PNG=0,-DIL_NO_PNG=1,libpng,"
> +
> +DEPENDS += "libpng"

Dependency on libpng should be taken care by the PACKAGECONFIG above.


> +inherit pkgconfig cmake
> +
> +INSANE_SKIP_${PN} += "file-rdeps dev-so"
> +FILES_${PN} += "${libdir}/lib*${SOLIBSDEV}"
> +FILES_SOLIBSDEV = ""

Any way to package the libraries properly and not suppress QA checks?


> diff --git a/meta-arago-extras/recipes-graphics/devil/files/Remove-ILUT-dependency.patch b/meta-arago-extras/recipes-graphics/devil/files/Remove-ILUT-dependency.patch
> new file mode 100644
> index 00000000..4f0f9dfa
> --- /dev/null
> +++ b/meta-arago-extras/recipes-graphics/devil/files/Remove-ILUT-dependency.patch
> @@ -0,0 +1,13 @@
> +diff --git a/DevIL/CMakeLists.txt b/DevIL/CMakeLists.txt
> +index e342f93d..fae40167 100644
> +--- a/DevIL/CMakeLists.txt
> ++++ b/DevIL/CMakeLists.txt
> +@@ -6,7 +6,7 @@ set (CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules")
> + 
> + add_subdirectory(src-IL)
> + add_subdirectory(src-ILU)
> +-add_subdirectory(src-ILUT)
> ++# add_subdirectory(src-ILUT)
> + option(IL_TESTS "build DevIL tests" ON)
> + if (IL_TESTS)
> +     ENABLE_TESTING()
> -- 
> 2.25.0
>