Re: [PATCH 3/3] prusw-fw: Package the firmware images from ti-linux-firmware

["Denys Dmytriyenko" <denys@ti.com>]

On Sun, Aug 23, 2020 at 03:24:29PM +0530, Lokesh Vutla wrote:
> 
> 
> On 22/08/20 12:24 am, Denys Dmytriyenko wrote:
> > On Fri, Aug 21, 2020 at 01:02:38PM +0530, Lokesh Vutla wrote:
> >> Directly take the images from ti-linux-firmware instead of using pdk
> >>
> >> Signed-off-by: Lokesh Vutla <lokeshvutla@ti.com>
> >> ---
> >>  recipes-bsp/prusw-fw/prusw-fw_3.0.0.bb | 38 ++++++++++++++++++++++++
> >>  recipes-bsp/prusw-fw/prusw-fw_git.bb   | 40 --------------------------
> >>  2 files changed, 38 insertions(+), 40 deletions(-)
> >>  create mode 100644 recipes-bsp/prusw-fw/prusw-fw_3.0.0.bb
> >>  delete mode 100644 recipes-bsp/prusw-fw/prusw-fw_git.bb
> >>
> >> diff --git a/recipes-bsp/prusw-fw/prusw-fw_3.0.0.bb b/recipes-bsp/prusw-fw/prusw-fw_3.0.0.bb
> >> new file mode 100644
> >> index 00000000..514237eb
> >> --- /dev/null
> >> +++ b/recipes-bsp/prusw-fw/prusw-fw_3.0.0.bb
> >> @@ -0,0 +1,38 @@
> >> +DESCRIPTION = "PRU Switch firmware for AM57xx, AM437x and AM335x"
> > 
> > Use SUMMARY here
> 
> Sure
> 
> > 
> > 
> >> +LICENSE = "TI-TFL"
> >> +LIC_FILES_CHKSUM = "file://LICENSE.ti;md5=b5aebf0668bdf95621259288c4a46d76"
> >> +
> >> +PV = "3.0.3"
> > 
> > So, the filename sets PV to 3.0.0, but here it's 3.0.3?
> 
> 3.0.3 will fix the file name.
> 
> > 
> > 
> >> +PR = "r1"
> > 
> > Drop PR
> 
> If PR is not added, the below error occurs. What could be wrong?

Right, you are keeping the same PV as before, so you can't remove PR (or 
reset it to "r0"). I got confused and thought it was an upgrade (i.e. 3.0.0 
vs. 3.0.3 above).


> ERROR: prusw-fw-3.0.3-r0 do_packagedata: QA Issue: Package version for package prusw-fw-src went backwards which would break package feeds (from 0:3.0.3-r1.0 to 0:3.0.3-r0.1) [version-going-backwards]
> ERROR: prusw-fw-3.0.3-r0 do_packagedata: QA Issue: Package version for package prusw-fw-dbg went backwards which would break package feeds (from 0:3.0.3-r1.0 to 0:3.0.3-r0.1) [version-going-backwards]
> 
> Thanks and regards,
> Lokesh
> 
> > 
> > 
> >> +CLEANBROKEN = "1"
> >> +
> >> +COMPATIBLE_MACHINE = "ti33x|ti43x|am57xx-evm|am57xx-hs-evm"
> >> +
> >> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> >> +
> >> +SRCREV = "7ba9722b74608ad4472790972917e1205eb3c049"
> >> +BRANCH ?= "ti-linux-firmware"
> >> +
> >> +SRC_URI = "git://git.ti.com/processor-firmware/ti-linux-firmware.git;protocol=git;branch=${BRANCH}"
> >> +
> >> +S = "${WORKDIR}/git"
> >> +
> >> +TARGET = ""
> >> +TARGET_ti33x = "am335x-pru0-prusw-fw.elf am335x-pru1-prusw-fw.elf"
> >> +TARGET_ti43x = "am437x-pru0-prusw-fw.elf am437x-pru1-prusw-fw.elf"
> >> +TARGET_am57xx-evm = "am57xx-pru0-prusw-fw.elf am57xx-pru1-prusw-fw.elf"
> >> +TARGET_am57xx-hs-evm = "am57xx-pru0-prusw-fw.elf am57xx-pru1-prusw-fw.elf"
> >> +
> >> +do_install() {
> >> +	install -d ${D}${base_libdir}/firmware/ti-pruss
> >> +	for f in ${TARGET}; do
> >> +		install -m 0644 ${S}/ti-pruss/$f ${D}${base_libdir}/firmware/ti-pruss/$f
> >> +	done
> >> +}
> >> +
> >> +
> >> +FILES_${PN} = "${base_libdir}/firmware"
> >> +
> >> +INSANE_SKIP_${PN} = "arch"
> >> diff --git a/recipes-bsp/prusw-fw/prusw-fw_git.bb b/recipes-bsp/prusw-fw/prusw-fw_git.bb
> >> deleted file mode 100644
> >> index 2921fb1d..00000000
> >> --- a/recipes-bsp/prusw-fw/prusw-fw_git.bb
> >> +++ /dev/null
> >> @@ -1,40 +0,0 @@
> >> -DESCRIPTION = "PRU Switch firmware for AM57xx"
> >> -
> >> -require recipes-ti/includes/ti-paths.inc
> >> -require recipes-bsp/icss-emac-lld/icss-emac-lld.inc
> >> -
> >> -LICENSE = "TI-TFL"
> >> -LIC_FILES_CHKSUM = "file://icss_dualemac/src/firmware_version.h;beginline=6;endline=53;md5=1f0a640a261059cdcbbcf01e6a739ff3"
> >> -
> >> -PR = "${INC_PR}.0"
> >> -
> >> -TI_PDK_COMP = "ti.drv.icss_emac.firmware"
> >> -
> >> -B = "${S}/icss_switch"
> >> -
> >> -COMPATIBLE_MACHINE = "dra7xx"
> >> -
> >> -PACKAGE_ARCH = "${MACHINE_ARCH}"
> >> -
> >> -DEPENDS = "ti-cgt-pru-native"
> >> -
> >> -PRU_VERSION = ""
> >> -PRU_VERSION_dra7xx = "REV2"
> >> -
> >> -FW_PREFIX = ""
> >> -FW_PREFIX_dra7xx = "am57xx"
> >> -
> >> -
> >> -EXTRA_OEMAKE += "CL_PRU_INSTALL_PATH="${TI_CGT_PRU_INSTALL_DIR}" PRU_VERSION_LIST="${PRU_VERSION}""
> >> -
> >> -do_install() {
> >> -	install -d ${D}${base_libdir}/firmware/ti-pruss
> >> -	install -m 0644 ./elf/${PRU_VERSION}/icss_stp_switch_PRU0.elf \
> >> -		${D}${base_libdir}/firmware/ti-pruss/${FW_PREFIX}-pru0-prusw-fw.elf
> >> -	install -m 0644 ./elf/${PRU_VERSION}/icss_stp_switch_PRU1.elf \
> >> -		${D}${base_libdir}/firmware/ti-pruss/${FW_PREFIX}-pru1-prusw-fw.elf
> >> -}
> >> -
> >> -FILES_${PN} = "${base_libdir}/firmware"
> >> -
> >> -INSANE_SKIP_${PN} = "arch"
> >> -- 
> >> 2.23.0
> >>