* [meta-rockchip][PATCH v3] enable stored U-Boot environment
@ 2024-04-24 17:44 Trevor Woerner
2024-04-25 13:07 ` [yocto-patches] " Quentin Schulz
0 siblings, 1 reply; 2+ messages in thread
From: Trevor Woerner @ 2024-04-24 17:44 UTC (permalink / raw)
To: yocto-patches
U-Boot has the ability to store its environment variables to a permanent
storage device. Whether or not it does so for any one specific device
depends on whatever settings are enabled in that specific device's
defconfig. In order to definitively configure U-Boot to be able to store
its environment into the device from which it boots, for any device
supported in this BSP, simply add the following to MACHINE_FEATURES:
rk-u-boot-env
If enabled, there is now a second choice to make: should the build also
include the U-Boot environment in the image or not? The default environment,
as generated by U-Boot, can be included in the generated wic image. If it
is included, then flashing the image will also flash the default U-Boot
environment variables and settings, wiping out anything that might have been
there already. If it is not included then your device will either continue
using whatever environment happens to be there (if valid), or will not use any
stored environment if the stored environment has not been set or is invalid.
The variable which governs this behaviour is:
RK_IMAGE_INCLUDES_UBOOT_ENV
By default this is set to "0", meaning that by default the image does not
contain the U-Boot environment. To enable this behaviour, enable this
variable. This variable only takes effect if rk-u-boot-env is listed in
MACHINE_FEATURES, and has no effect otherwise.
The script:
scripts/dump-uboot-env-from-yocto-image.sh
can be used on a rockchip wic image to see the contents of the U-Boot
environment partition at build time.
Tested by booting the same image on both eMMC and SDcard with the following
devices, verifying the ability to read and write the U-Boot environment in
both U-Boot and Linux user-space, and that changes made in one are seen in the
other:
rock-3a
rock-5a
rock-5b
rock-pi-4b
rock-pi-e
rock64
Signed-off-by: Trevor Woerner <twoerner@gmail.com>
---
v3 changes:
- switch from using a bbclass so the `rk-u-boot-env` override can be used
directly
- add SPDX header to script
- drop `inherit deploy` in U-Boot bbappend
v2 changes:
- re-word the commit message and README for clarity
- use bash's built-in math handling instead of depending on `bc`
- in anticipation of the upcoming feature in U-Boot whereby rockchip
devices can automatically select the environment storage device to be
the same as the boot device, use a more recent SRCREV for builds that do
environment handling, instead of hardcoding the environment storage device
by SoC family
- handle RK_IMAGE_INCLUDES_UBOOT_ENV as a boolean
---
README | 20 +++++++++++++
conf/machine/include/rockchip-wic.inc | 11 +++++++
.../rockchip-enable-environment-mmc.cfg | 6 ++++
recipes-bsp/u-boot/u-boot_%.bbappend | 19 ++++++++++++
scripts/dump-uboot-env-from-yocto-image.sh | 29 +++++++++++++++++++
wic/rockchip.wks | 2 +-
6 files changed, 86 insertions(+), 1 deletion(-)
create mode 100644 recipes-bsp/u-boot/files/rk-u-boot-env/rockchip-enable-environment-mmc.cfg
create mode 100755 scripts/dump-uboot-env-from-yocto-image.sh
diff --git a/README b/README
index c76fc9131276..605773d4ecd3 100644
--- a/README
+++ b/README
@@ -67,6 +67,26 @@ Notes:
in the configuration (e.g. conf/local.conf).
+U-Boot Environment:
+------------------
+ In order to configure U-Boot to be able to store its environment into the
+ device from which it was booted, for any device supported in this BSP,
+ simply add the following to MACHINE_FEATURES:
+
+ rk-u-boot-env
+
+ If enabled, to additionally have the U-Boot environment generated and
+ stored in the image, also enable the following variable (default: off):
+
+ RK_IMAGE_INCLUDES_UBOOT_ENV
+
+ The script:
+
+ scripts/dump-uboot-env-from-yocto-image.sh
+
+ can be used on a rockchip wic image to see the contents of the U-Boot
+ environment partition at build time.
+
Maintenance:
-----------
Please send pull requests, patches, comments, or questions to the
diff --git a/conf/machine/include/rockchip-wic.inc b/conf/machine/include/rockchip-wic.inc
index 147a36685d7d..18b75a2de945 100644
--- a/conf/machine/include/rockchip-wic.inc
+++ b/conf/machine/include/rockchip-wic.inc
@@ -2,6 +2,11 @@
require conf/machine/include/rockchip-extlinux.inc
+# 'rk-u-boot-env' indicates the user wants to be able to save their U-Boot
+# environment back to the drive from which the device was booted
+MACHINEOVERRIDES .= "${@bb.utils.contains('MACHINE_FEATURES', 'rk-u-boot-env', ':rk-u-boot-env', '', d)}"
+IMAGE_INSTALL:append:rk-u-boot-env = " u-boot-fw-utils u-boot-env"
+
SPL_BINARY ?= "idbloader.img"
IMAGE_FSTYPES += "wic wic.bmap"
@@ -11,7 +16,13 @@ WKS_FILE_DEPENDS ?= " \
virtual/bootloader \
"
+RK_IMAGE_INCLUDES_UBOOT_ENV ?= "no"
+RK_UBOOT_ENV = " "
+RK_UBOOT_ENV:rk-u-boot-env = "${@ '--source rawcopy --sourceparams=file=u-boot.env' if \
+ bb.utils.to_boolean(d.getVar('RK_IMAGE_INCLUDES_UBOOT_ENV'), False) else ' '}"
+
WICVARS:append = " \
SPL_BINARY \
UBOOT_SUFFIX \
+ RK_UBOOT_ENV \
"
diff --git a/recipes-bsp/u-boot/files/rk-u-boot-env/rockchip-enable-environment-mmc.cfg b/recipes-bsp/u-boot/files/rk-u-boot-env/rockchip-enable-environment-mmc.cfg
new file mode 100644
index 000000000000..778772d27767
--- /dev/null
+++ b/recipes-bsp/u-boot/files/rk-u-boot-env/rockchip-enable-environment-mmc.cfg
@@ -0,0 +1,6 @@
+CONFIG_ENV_SIZE=0x8000
+CONFIG_ENV_OFFSET=0x3f8000
+# CONFIG_ENV_IS_NOWHERE is not set
+CONFIG_ENV_IS_IN_MMC=y
+CONFIG_DM_SEQ_ALIAS=y
+CONFIG_SPL_DM_SEQ_ALIAS=y
diff --git a/recipes-bsp/u-boot/u-boot_%.bbappend b/recipes-bsp/u-boot/u-boot_%.bbappend
index a83179a9f007..d63042b9be41 100644
--- a/recipes-bsp/u-boot/u-boot_%.bbappend
+++ b/recipes-bsp/u-boot/u-boot_%.bbappend
@@ -1,7 +1,13 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+SRC_URI:append:rk-u-boot-env = " file://rockchip-enable-environment-mmc.cfg"
+SRCREV:rk-u-boot-env = "cdfcc37428e06f4730ab9a17cc084eeb7676ea1a"
+
# various machines require the pyelftools library for parsing dtb files
DEPENDS:append = " python3-pyelftools-native"
DEPENDS:append:rk3308 = " u-boot-tools-native"
DEPENDS:append:rock-pi-4 = " gnutls-native"
+DEPENDS:append:rk-u-boot-env = " u-boot-mkenvimage-native"
EXTRA_OEMAKE:append:px30 = " BL31=${DEPLOY_DIR_IMAGE}/bl31-px30.elf"
EXTRA_OEMAKE:append:rk3308 = " \
@@ -34,3 +40,16 @@ do_compile:append:rock2-square () {
cp ${B}/spl/${SPL_BINARY} ${B}
fi
}
+
+do_compile:append:rk-u-boot-env() {
+ UBOOT_ENV_SIZE="$(cat ${B}/.config | grep "^CONFIG_ENV_SIZE=" | cut -d'=' -f2)"
+ echo "/dev/disk/by-partlabel/uboot_env 0x0000 ${UBOOT_ENV_SIZE}" > ${WORKDIR}/fw_env.config
+}
+
+do_deploy:append:rk-u-boot-env() {
+ UBOOT_ENV_SIZE="$(cat ${B}/.config | grep "^CONFIG_ENV_SIZE=" | cut -d'=' -f2)"
+ mkenvimage -s ${UBOOT_ENV_SIZE} ${B}/u-boot-initial-env -o ${WORKDIR}/u-boot.env
+
+ install -d ${DEPLOYDIR}
+ install -m 0644 ${WORKDIR}/u-boot.env ${DEPLOYDIR}
+}
diff --git a/scripts/dump-uboot-env-from-yocto-image.sh b/scripts/dump-uboot-env-from-yocto-image.sh
new file mode 100755
index 000000000000..9386c1d29213
--- /dev/null
+++ b/scripts/dump-uboot-env-from-yocto-image.sh
@@ -0,0 +1,29 @@
+#/bin/bash
+# SPDX-License-Identifier: OSL-3.0
+#
+# a program that can take a wic file and dump out the contents
+# of the U-Boot environment in canonical hex+ascii format
+# (assuming the "rockchip" layout specified in this layer's wic file)
+
+# check for programs
+check_pgm() {
+ $1 --help > /dev/null 2>&1
+ if [ $? -ne 0 ]; then
+ echo "required program \"$1\" not found"
+ exit 1
+ fi
+}
+check_pgm dd
+check_pgm hexdump
+
+if [ $# -ne 1 ]; then
+ echo "required param missing: yocto wic image"
+ exit 1
+fi
+if [ ! -e "$1" ]; then
+ echo "specified file \"$1\" not found"
+ exit 1
+fi
+
+SKIP=$(( 8128 * 512 ))
+dd if="$1" ibs=1 skip=$SKIP count=32k 2> /dev/null | hexdump -C
diff --git a/wic/rockchip.wks b/wic/rockchip.wks
index 9ba3352b51bb..bc65f73b0cf3 100644
--- a/wic/rockchip.wks
+++ b/wic/rockchip.wks
@@ -22,7 +22,7 @@ part loader1 --offset 64s --fixed-size 3552K --fstype=none --part-name load
part v_storage --offset 7168s --fixed-size 256K --fstype=none --part-name v_storage
part reserved --offset 7680s --fixed-size 192K --fstype=none --part-name reserved
part reserved1 --offset 8064s --fixed-size 32K --fstype=none --part-name reserved1
-part uboot_env --offset 8128s --fixed-size 32K --fstype=none --part-name uboot_env
+part uboot_env --offset 8128s --fixed-size 32K --fstype=none --part-name uboot_env ${RK_UBOOT_ENV}
part reserved2 --offset 8192s --fixed-size 4096K --fstype=none --part-name reserved2
part loader2 --offset 16384s --fixed-size 4096K --fstype=none --part-name loader2 --source rawcopy --sourceparams="file=u-boot.${UBOOT_SUFFIX}"
part atf --offset 24576s --fixed-size 4096K --fstype=none --part-name atf
--
2.44.0.478.g7774cfed6261
^ permalink raw reply related [flat|nested] 2+ messages in thread* Re: [yocto-patches] [meta-rockchip][PATCH v3] enable stored U-Boot environment
2024-04-24 17:44 [meta-rockchip][PATCH v3] enable stored U-Boot environment Trevor Woerner
@ 2024-04-25 13:07 ` Quentin Schulz
0 siblings, 0 replies; 2+ messages in thread
From: Quentin Schulz @ 2024-04-25 13:07 UTC (permalink / raw)
To: yocto-patches
Hi Trevor,
On 4/24/24 19:44, Trevor Woerner via lists.yoctoproject.org wrote:
> U-Boot has the ability to store its environment variables to a permanent
> storage device. Whether or not it does so for any one specific device
> depends on whatever settings are enabled in that specific device's
> defconfig. In order to definitively configure U-Boot to be able to store
> its environment into the device from which it boots, for any device
> supported in this BSP, simply add the following to MACHINE_FEATURES:
>
> rk-u-boot-env
>
> If enabled, there is now a second choice to make: should the build also
> include the U-Boot environment in the image or not? The default environment,
> as generated by U-Boot, can be included in the generated wic image. If it
> is included, then flashing the image will also flash the default U-Boot
> environment variables and settings, wiping out anything that might have been
> there already. If it is not included then your device will either continue
> using whatever environment happens to be there (if valid), or will not use any
> stored environment if the stored environment has not been set or is invalid.
> The variable which governs this behaviour is:
>
> RK_IMAGE_INCLUDES_UBOOT_ENV
>
> By default this is set to "0", meaning that by default the image does not
> contain the U-Boot environment. To enable this behaviour, enable this
> variable. This variable only takes effect if rk-u-boot-env is listed in
> MACHINE_FEATURES, and has no effect otherwise.
>
> The script:
>
> scripts/dump-uboot-env-from-yocto-image.sh
>
> can be used on a rockchip wic image to see the contents of the U-Boot
> environment partition at build time.
>
> Tested by booting the same image on both eMMC and SDcard with the following
> devices, verifying the ability to read and write the U-Boot environment in
> both U-Boot and Linux user-space, and that changes made in one are seen in the
> other:
> rock-3a
> rock-5a
> rock-5b
> rock-pi-4b
> rock-pi-e
> rock64
>
> Signed-off-by: Trevor Woerner <twoerner@gmail.com>
> ---
> v3 changes:
> - switch from using a bbclass so the `rk-u-boot-env` override can be used
> directly
> - add SPDX header to script
> - drop `inherit deploy` in U-Boot bbappend
>
> v2 changes:
> - re-word the commit message and README for clarity
> - use bash's built-in math handling instead of depending on `bc`
> - in anticipation of the upcoming feature in U-Boot whereby rockchip
> devices can automatically select the environment storage device to be
> the same as the boot device, use a more recent SRCREV for builds that do
> environment handling, instead of hardcoding the environment storage device
> by SoC family
> - handle RK_IMAGE_INCLUDES_UBOOT_ENV as a boolean
> ---
> README | 20 +++++++++++++
> conf/machine/include/rockchip-wic.inc | 11 +++++++
> .../rockchip-enable-environment-mmc.cfg | 6 ++++
> recipes-bsp/u-boot/u-boot_%.bbappend | 19 ++++++++++++
> scripts/dump-uboot-env-from-yocto-image.sh | 29 +++++++++++++++++++
> wic/rockchip.wks | 2 +-
> 6 files changed, 86 insertions(+), 1 deletion(-)
> create mode 100644 recipes-bsp/u-boot/files/rk-u-boot-env/rockchip-enable-environment-mmc.cfg
> create mode 100755 scripts/dump-uboot-env-from-yocto-image.sh
>
> diff --git a/README b/README
> index c76fc9131276..605773d4ecd3 100644
> --- a/README
> +++ b/README
> @@ -67,6 +67,26 @@ Notes:
>
> in the configuration (e.g. conf/local.conf).
>
> +U-Boot Environment:
> +------------------
> + In order to configure U-Boot to be able to store its environment into the
> + device from which it was booted, for any device supported in this BSP,
> + simply add the following to MACHINE_FEATURES:
> +
> + rk-u-boot-env
> +
> + If enabled, to additionally have the U-Boot environment generated and
> + stored in the image, also enable the following variable (default: off):
> +
> + RK_IMAGE_INCLUDES_UBOOT_ENV
> +
> + The script:
> +
> + scripts/dump-uboot-env-from-yocto-image.sh
> +
> + can be used on a rockchip wic image to see the contents of the U-Boot
> + environment partition at build time.
> +
> Maintenance:
> -----------
> Please send pull requests, patches, comments, or questions to the
> diff --git a/conf/machine/include/rockchip-wic.inc b/conf/machine/include/rockchip-wic.inc
> index 147a36685d7d..18b75a2de945 100644
> --- a/conf/machine/include/rockchip-wic.inc
> +++ b/conf/machine/include/rockchip-wic.inc
> @@ -2,6 +2,11 @@
>
> require conf/machine/include/rockchip-extlinux.inc
>
> +# 'rk-u-boot-env' indicates the user wants to be able to save their U-Boot
> +# environment back to the drive from which the device was booted
> +MACHINEOVERRIDES .= "${@bb.utils.contains('MACHINE_FEATURES', 'rk-u-boot-env', ':rk-u-boot-env', '', d)}"
FYI, this results in:
MACHINEOVERRIDES="aarch64:cortexa76-cortexa55:rk3588s:rk3588:rock-5b:rk-u-boot-env"
which means rk-u-boot-env is "stronger" than rock-5b as an OVERRIDES.
Considering that they are likely going to be used in different contexts
where we wouldn't have both VAR:rock-5b AND VAR:rk-u-boot-env, I guess
it's fine?
> +IMAGE_INSTALL:append:rk-u-boot-env = " u-boot-fw-utils u-boot-env"
> +
> SPL_BINARY ?= "idbloader.img"
>
> IMAGE_FSTYPES += "wic wic.bmap"
> @@ -11,7 +16,13 @@ WKS_FILE_DEPENDS ?= " \
> virtual/bootloader \
> "
>
> +RK_IMAGE_INCLUDES_UBOOT_ENV ?= "no"
> +RK_UBOOT_ENV = " "
> +RK_UBOOT_ENV:rk-u-boot-env = "${@ '--source rawcopy --sourceparams=file=u-boot.env' if \
I could recommend to put u-boot.env in a variable so that we can change
it if we want and it's easier to keep track of things that go together.
(e.g. do_deploy:append:rk-u-boot-env() would be using it too).
> + bb.utils.to_boolean(d.getVar('RK_IMAGE_INCLUDES_UBOOT_ENV'), False) else ' '}"
> +
> WICVARS:append = " \
> SPL_BINARY \
> UBOOT_SUFFIX \
> + RK_UBOOT_ENV \
Wondering if we want to alphabetically order this list?
> "
> diff --git a/recipes-bsp/u-boot/files/rk-u-boot-env/rockchip-enable-environment-mmc.cfg b/recipes-bsp/u-boot/files/rk-u-boot-env/rockchip-enable-environment-mmc.cfg
> new file mode 100644
> index 000000000000..778772d27767
> --- /dev/null
> +++ b/recipes-bsp/u-boot/files/rk-u-boot-env/rockchip-enable-environment-mmc.cfg
> @@ -0,0 +1,6 @@
> +CONFIG_ENV_SIZE=0x8000
> +CONFIG_ENV_OFFSET=0x3f8000
> +# CONFIG_ENV_IS_NOWHERE is not set
> +CONFIG_ENV_IS_IN_MMC=y
> +CONFIG_DM_SEQ_ALIAS=y
> +CONFIG_SPL_DM_SEQ_ALIAS=y
> diff --git a/recipes-bsp/u-boot/u-boot_%.bbappend b/recipes-bsp/u-boot/u-boot_%.bbappend
> index a83179a9f007..d63042b9be41 100644
> --- a/recipes-bsp/u-boot/u-boot_%.bbappend
> +++ b/recipes-bsp/u-boot/u-boot_%.bbappend
> @@ -1,7 +1,13 @@
> +FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
> +
> +SRC_URI:append:rk-u-boot-env = " file://rockchip-enable-environment-mmc.cfg"
> +SRCREV:rk-u-boot-env = "cdfcc37428e06f4730ab9a17cc084eeb7676ea1a"
> +
> # various machines require the pyelftools library for parsing dtb files
> DEPENDS:append = " python3-pyelftools-native"
Unrelated, but this is not required anymore since
ab37ae5bdd46ba61e4b2c0de2a61b9473264f714 where it is now in the upstream
recipe.
> DEPENDS:append:rk3308 = " u-boot-tools-native"
> DEPENDS:append:rock-pi-4 = " gnutls-native"
> +DEPENDS:append:rk-u-boot-env = " u-boot-mkenvimage-native"
>
> EXTRA_OEMAKE:append:px30 = " BL31=${DEPLOY_DIR_IMAGE}/bl31-px30.elf"
> EXTRA_OEMAKE:append:rk3308 = " \
> @@ -34,3 +40,16 @@ do_compile:append:rock2-square () {
> cp ${B}/spl/${SPL_BINARY} ${B}
> fi
> }
Unrelated, but I'm wondering whether the above is still necessary for
rock2-square? I think we should have migrated all Rockchip SoCs to binman?
> +
> +do_compile:append:rk-u-boot-env() {
> + UBOOT_ENV_SIZE="$(cat ${B}/.config | grep "^CONFIG_ENV_SIZE=" | cut -d'=' -f2)"
> + echo "/dev/disk/by-partlabel/uboot_env 0x0000 ${UBOOT_ENV_SIZE}" > ${WORKDIR}/fw_env.config
> +}
> +
> +do_deploy:append:rk-u-boot-env() {
> + UBOOT_ENV_SIZE="$(cat ${B}/.config | grep "^CONFIG_ENV_SIZE=" | cut -d'=' -f2)"
> + mkenvimage -s ${UBOOT_ENV_SIZE} ${B}/u-boot-initial-env -o ${WORKDIR}/u-boot.env
Better make sure this file is created first by guarding it with
if [ -n "${UBOOT_INITIAL_ENV}" ];
to match the upstream recipe?
I see this as the last obvious blocker. I raised a few other points, the
"blockiness" part of those depending on what you want to do/what you
will answer :) But I think we're almos there :)
> +
> + install -d ${DEPLOYDIR}
> + install -m 0644 ${WORKDIR}/u-boot.env ${DEPLOYDIR}
> +}
> diff --git a/scripts/dump-uboot-env-from-yocto-image.sh b/scripts/dump-uboot-env-from-yocto-image.sh
> new file mode 100755
> index 000000000000..9386c1d29213
> --- /dev/null
> +++ b/scripts/dump-uboot-env-from-yocto-image.sh
> @@ -0,0 +1,29 @@
> +#/bin/bash
> +# SPDX-License-Identifier: OSL-3.0
> +#
> +# a program that can take a wic file and dump out the contents
> +# of the U-Boot environment in canonical hex+ascii format
> +# (assuming the "rockchip" layout specified in this layer's wic file)
> +
> +# check for programs
> +check_pgm() {
> + $1 --help > /dev/null 2>&1
> + if [ $? -ne 0 ]; then
> + echo "required program \"$1\" not found"
> + exit 1
> + fi
> +}
> +check_pgm dd
> +check_pgm hexdump
> +
> +if [ $# -ne 1 ]; then
> + echo "required param missing: yocto wic image"
> + exit 1
> +fi
> +if [ ! -e "$1" ]; then
This could match a directory, maybe you want ! -f here?
> + echo "specified file \"$1\" not found"
> + exit 1
> +fi
> +
> +SKIP=$(( 8128 * 512 ))
> +dd if="$1" ibs=1 skip=$SKIP count=32k 2> /dev/null | hexdump -C
Just because I was curious, this could also be
xxd -s $SKIP -l $(( 32 * 1024 )) "$1"
though it doesn't "collapse" regions with the same values like dd does.
Cheers,
Quentin
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2024-04-25 13:07 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2024-04-24 17:44 [meta-rockchip][PATCH v3] enable stored U-Boot environment Trevor Woerner
2024-04-25 13:07 ` [yocto-patches] " Quentin Schulz
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.