All of lore.kernel.org
 help / color / mirror / Atom feed
* [PATCH 1/3] arm/fvp: Update FVP Base to 11.32.19
@ 2026-08-10 17:48 Jon Mason
  2026-08-10 17:48 ` [PATCH 2/3] arm/fvps: remove unused files Jon Mason
  2026-08-10 17:48 ` [PATCH 3/3] arm/fvps: change COMPATIBLE_HOST default Jon Mason
  0 siblings, 2 replies; 3+ messages in thread
From: Jon Mason @ 2026-08-10 17:48 UTC (permalink / raw)
  To: meta-arm

Update the fvp-base model recipe to version 11.32.19.

The new release changes the package layout and installation process,
requiring updates to the license checksums, source checksums, install
procedure, and FVP binary linking.

Signed-off-by: Jon Mason <jon.mason@arm.com>
---
 .../fvp/fvp-base-a-aem_11.31.28.bb            | 20 -------
 .../fvp/fvp-base-a-aem_11.32.19.bb            | 59 +++++++++++++++++++
 2 files changed, 59 insertions(+), 20 deletions(-)
 delete mode 100644 meta-arm/recipes-devtools/fvp/fvp-base-a-aem_11.31.28.bb
 create mode 100644 meta-arm/recipes-devtools/fvp/fvp-base-a-aem_11.32.19.bb

diff --git a/meta-arm/recipes-devtools/fvp/fvp-base-a-aem_11.31.28.bb b/meta-arm/recipes-devtools/fvp/fvp-base-a-aem_11.31.28.bb
deleted file mode 100644
index 3a4789c57f4e..000000000000
--- a/meta-arm/recipes-devtools/fvp/fvp-base-a-aem_11.31.28.bb
+++ /dev/null
@@ -1,20 +0,0 @@
-require fvp-envelope.inc
-
-LICENSE:append = " AND Artistic-2.0 AND BSL-1.0 AND BSD-2-Clause AND Unlicense"
-
-SUMMARY = "Arm Fixed Virtual Platform - Armv-A Base RevC Architecture Envelope Model FVP"
-LIC_FILES_CHKSUM = "file://license_terms/license_agreement.txt;md5=1a33828e132ba71861c11688dbb0bd16 \
-                    file://license_terms/third_party_licenses/third_party_licenses.txt;md5=5e3a194978d88188b5a0eebd263f2ca8 \
-                    file://license_terms/third_party_licenses/arm_license_management_utilities/third_party_licenses.txt;md5=4f61d2f0d834d5c29d53d828572fb6fc"
-
-SRC_URI[fvp-aarch64.sha256sum] = "38cfb5244fe898bed5c3ba46ec6e3654638e29085ef597b9ed92f36be08adf1d"
-SRC_URI[fvp-x86_64.sha256sum] = "527920d1873472de045c844fa6f5b8679511ad4f9996058eb9e075b0f0eada10"
-
-# The CSS used in the FVP homepage make it too difficult to query with the tooling currently in Yocto
-UPSTREAM_VERSION_UNKNOWN = "1"
-
-MODEL_CODE = "FVP_Base_RevC_AEMvA"
-
-COMPATIBLE_HOST = "(aarch64|x86_64).*-linux"
-
-INSANE_SKIP:${PN} += "dev-so"
diff --git a/meta-arm/recipes-devtools/fvp/fvp-base-a-aem_11.32.19.bb b/meta-arm/recipes-devtools/fvp/fvp-base-a-aem_11.32.19.bb
new file mode 100644
index 000000000000..26557769a577
--- /dev/null
+++ b/meta-arm/recipes-devtools/fvp/fvp-base-a-aem_11.32.19.bb
@@ -0,0 +1,59 @@
+require fvp-ecosystem.inc
+
+LICENSE:append = " AND Artistic-2.0 AND BSL-1.0 AND BSD-2-Clause AND Unlicense"
+
+FVP_ARCH:aarch64 = "Linux_armv8"
+FVP_ARCH:x86-64 = "Linux_x86"
+
+SUMMARY = "Arm Fixed Virtual Platform - Armv-A Base RevC Architecture Envelope Model FVP"
+SRC_URI = "https://developer.arm.com/-/cdn-downloads/permalink/FVPs-Architecture/${PV_URL_SHORT}/${MODEL_CODE}_${PV_URL}_${FVP_ARCH}.tar.gz;subdir=${BP};name=fvp-${HOST_ARCH}"
+
+LIC_FILES_CHKSUM = "file://license_terms/license_agreement.txt;md5=ac2215fd2c35830a4a52f9f910c6a552 \
+                    file://license_terms/third_party_licenses/third_party_licenses.txt;md5=da95c9d79488fe4b6115bb7f9900b505 \
+                    file://license_terms/third_party_licenses/arm_license_management_utilities/third_party_licenses.txt;md5=4f61d2f0d834d5c29d53d828572fb6fc"
+
+SRC_URI[fvp-aarch64.sha256sum] = "c01a1450ee2adee499183026b01f4c31f760081ffdefd5c9a9788ae58d8542ce"
+SRC_URI[fvp-x86_64.sha256sum] = "b6835fd07cb390c7a32f84fe1cead84bde992813b49679137b3a7a0a026e92de"
+
+# The CSS used in the FVP homepage make it too difficult to query with the tooling currently in Yocto
+UPSTREAM_VERSION_UNKNOWN = "1"
+
+MODEL_CODE = "FVP_Base_RevC_AEMvA"
+SHELL_SCRIPT_NAME = "${MODEL_CODE}_11.32_19_${FVP_ARCH}.sh"
+
+COMPATIBLE_HOST = "(aarch64|x86_64).*-linux"
+
+INSANE_SKIP:${PN} += "dev-so"
+
+do_install() {
+    mkdir --parents ${D}${FVPDIR}/models/${FVP_ARCH} ${D}${bindir}
+
+    ${S}/${SHELL_SCRIPT_NAME} \
+        --i-agree-to-the-contained-eula \
+        --no-interactive \
+        --allow-existing-dir \
+        --skip-platform-check \
+        --destination ${D}${FVPDIR}
+
+    fvp_link_binaries
+}
+# The new version no longer has any files expect the README and install
+# script.  So, we have to run install before checking the license files
+# for them to be present.
+do_populate_lic[depends] += "${PN}:do_install"
+
+# The files are located in a different directory that expected in
+# fvp-common.inc.  So, doing it uniquely in here
+fvp_link_binaries() {
+    DIR="${D}${FVPDIR}/bin/"
+
+    stat $DIR/FVP_* >/dev/null 2>&1 || bbfatal Cannot find FVP binaries in $DIR
+
+    for FVP in $DIR/FVP_*; do
+        ln -rs $FVP ${D}${bindir}/$(basename $FVP)
+    done
+    # But not the .so files too
+    rm -f ${D}${bindir}/*.so
+
+    cp -r ${D}${FVPDIR}/license_terms ${S}
+}
-- 
2.50.1 (Apple Git-155)



^ permalink raw reply related	[flat|nested] 3+ messages in thread
end of thread, other threads:[~2026-08-10 17:48 UTC | newest]

Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2026-08-10 17:48 [PATCH 1/3] arm/fvp: Update FVP Base to 11.32.19 Jon Mason
2026-08-10 17:48 ` [PATCH 2/3] arm/fvps: remove unused files Jon Mason
2026-08-10 17:48 ` [PATCH 3/3] arm/fvps: change COMPATIBLE_HOST default Jon Mason

This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.