* RFC: Task-base rewrite
@ 2007-03-04 21:28 Marcin Juszkiewicz
2007-03-04 22:55 ` Koen Kooi
2007-04-12 18:35 ` Marcin Juszkiewicz
0 siblings, 2 replies; 12+ messages in thread
From: Marcin Juszkiewicz @ 2007-03-04 21:28 UTC (permalink / raw)
To: openembedded-devel
[-- Attachment #1: Type: text/plain, Size: 1003 bytes --]
During last two months I was working on new version of task-base. It was
done from time to time without too much testing as I had many other
things on my todo list.
The main problem of task-base is that it give one package as result so if
you want to create smaller rootfs for only few features you need to
create own-task-base and base image on it.
My version create several task-base-*, task-distro-* packages which cover
several features one by one. Some features contain extra stuff only if
other features are available (for example Bluetooth on USB bus only if
distro supports BT and device support USB Host).
Code needs cleanup, changes here and there but it should be better then
current implementation. Recent changes made to task-base in .dev are not
in my version yet.
Opinions? Ideas? Patches? Suggestions?
--
JID: hrw-jabber.org
OpenEmbedded developer/consultant
Try not! Do, or do not! There is no try!
-- Yoda
[-- Attachment #2: task-base-new.bb --]
[-- Type: text/plain, Size: 11040 bytes --]
DESCRIPTION = "Merge machine and distro options to create a basic machine task/package"
PR = "r17.6"
PACKAGES = "\
task-base-minimal \
task-base-core-default \
\
task-base \
${@base_contains("MACHINE_FEATURES","acpi","task-base-acpi","", d)} \
${@base_contains("MACHINE_FEATURES","alsa","task-base-alsa","", d)} \
${@base_contains("MACHINE_FEATURES","apm","task-base-apm","", d)} \
${@base_contains("MACHINE_FEATURES","bluetooth","task-base-bluetooth","", d)} \
${@base_contains("MACHINE_FEATURES","ext2","task-base-ext2","", d)} \
${@base_contains("MACHINE_FEATURES","irda","task-base-irda","", d)} \
${@base_contains("MACHINE_FEATURES","keyboard","task-base-keyboard","", d)} \
${@base_contains("MACHINE_FEATURES","nfs","task-base-nfs","", d)} \
${@base_contains("MACHINE_FEATURES","pci","task-base-pci","", d)} \
${@base_contains("MACHINE_FEATURES","pcmcia","task-base-pcmcia","", d)} \
${@base_contains("MACHINE_FEATURES","phone","task-base-phone","", d)} \
${@base_contains("MACHINE_FEATURES","screen","task-base-screen","", d)} \
${@base_contains("MACHINE_FEATURES","smbfs","task-base-smbfs","", d)} \
${@base_contains("MACHINE_FEATURES","touchscreen","task-base-touchscreen","", d)} \
${@base_contains("MACHINE_FEATURES","usbgadget","task-base-usbgadget","", d)} \
${@base_contains("MACHINE_FEATURES","usbhost","task-base-usbhost","", d)} \
${@base_contains("MACHINE_FEATURES","wifi","task-base-wifi","", d)} \
${@base_contains("MACHINE_FEATURES","kernel26","task-base-kernel26","task-base-kernel24",d)} \
\
${@base_contains("DISTRO_FEATURES","cramfs","task-distro-cramfs","", d)} \
${@base_contains("DISTRO_FEATURES","ipsec","task-distro-ipsec","", d)} \
${@base_contains("DISTRO_FEATURES","ipv6","task-distro-ipv6","", d)} \
${@base_contains("DISTRO_FEATURES","nfs","task-distro-nfs","", d)} \
${@base_contains("DISTRO_FEATURES","ppp","task-distro-ppp","", d)} \
${@base_contains("DISTRO_FEATURES","smbfs","task-distro-smbfs","", d)} \
${@base_contains("DISTRO_FEATURES","wifi","task-distro-wifi","", d)} \
\
task-distro-base \
task-distro-extras \
task-base-machine \
task-base-machine-extras \
"
ALLOW_EMPTY = "1"
PACKAGE_ARCH = "${MACHINE_ARCH}"
# Valid only in MACHINE_FEATURES:
#
# kernel24
# kernel26
# apm
# keyboard
# touchscreen
# screen
# pci
# acpi
# phone
# Valid only in DISTRO_FEATURES:
#
# nfs
# smbfs
# ipsec
# wifi
# ppp
# Valid COMBINED_FEATURES:
# (These features need to be supported by both the machine and the distro)
#
# alsa
# bluetooth
# ext2
# irda
# pci
# pcmcia
# usbgadget
# usbhost
DISTRO_CORE_PACKAGE ?= "task-base-core-default"
#
# task-base
#
#
# task-base-oh-minimal
# An example of a small cut down machine configuration
#
RDEPENDS_task-base-minimal = "\
kernel \
${@base_contains("MACHINE_FEATURES","kernel26","task-base-kernel26","task-base-kernel24",d)} \
${@base_contains("MACHINE_FEATURES","apm","task-base-apm","",d)} \
${@base_contains("COMBINED_FEATURES","pcmcia","${PCMCIA_MANAGER}","",d)} \
${MACHINE_ESSENTIAL_EXTRA_RDEPENDS}"
RRECOMMENDS_task-base-minimal = "\
${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS}"
RDEPENDS_task-base-core-default = "\
base-files \
base-passwd \
busybox \
initscripts \
netbase \
sysvinit \
sysvinit-pidof \
tinylogin \
modutils-initscripts"
RRECOMMENDS_task-base-core-default = "\
dropbear \
fuser \
setserial"
RDEPENDS_task-base = "\
${DISTRO_CORE_PACKAGE} \
kernel \
${@base_contains("MACHINE_FEATURES", "kernel24", "task-base-kernel24","",d)} \
${@base_contains("MACHINE_FEATURES", "kernel26", "task-base-kernel26","",d)} \
${@base_contains("MACHINE_FEATURES", "apm", "task-base-apm","",d)} \
${@base_contains("MACHINE_FEATURES", "acpi", "task-base-acpi","",d)} \
${@base_contains("MACHINE_FEATURES", "keyboard", "task-base-keyboard","",d)} \
${@base_contains("COMBINED_FEATURES","alsa", "task-base-alsa","",d)} \
${@base_contains("COMBINED_FEATURES","ext2", "task-base-ext2","",d)} \
${@base_contains("COMBINED_FEATURES","irda", "task-base-irda","",d)} \
${@base_contains("COMBINED_FEATURES","pci", "task-base-pci","",d)} \
${@base_contains("COMBINED_FEATURES","pcmcia", "task-base-pcmcia","",d)} \
${@base_contains("COMBINED_FEATURES","usbhost", "task-base-usbhost","",d)} \
${@base_contains("COMBINED_FEATURES","bluetooth","task-base-bluetooth","",d)} \
${@base_contains("COMBINED_FEATURES","wifi", "task-base-wifi","",d)} \
${@base_contains("DISTRO_FEATURES", "nfs", "task-distro-nfs","",d)} \
${@base_contains("DISTRO_FEATURES", "ipsec", "task-distro-ipsec","",d)} \
${@base_contains("DISTRO_FEATURES", "ppp", "task-distro-ppp","",d)} \
task-base-machine \
task-distro-base"
RRECOMMENDS_task-base = "\
${@base_contains("MACHINE_FEATURES", "kernel26", "task-base-kernel26-extras","",d)} \
task-base-machine-extras \
task-distro-extras"
RDEPENDS_task-distro-base = "${DISTRO_EXTRA_RDEPENDS}"
RRECOMMENDS_task-distro-extras = "${DISTRO_EXTRA_RRECOMMENDS}"
RDEPENDS_task-base-machine = "${MACHINE_EXTRA_RDEPENDS} ${MACHINE_ESSENTIAL_EXTRA_RDEPENDS}"
RRECOMMENDS_task-base-machine-extras = "\
${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS} \
${MACHINE_EXTRA_RRECOMMENDS}"
RDEPENDS_task-base-kernel24 = "\
modutils-depmod \
linux-hotplug"
RDEPENDS_task-base-kernel26 = "\
udev \
sysfsutils \
module-init-tools"
RRECOMMENDS_task-base-kernel24-extras = "\
kernel-module-input \
kernel-module-uinput"
RRECOMMENDS_task-base-kernel26-extras = "\
kernel-module-input \
kernel-module-uinput"
RDEPENDS_task-base-keyboard = "\
keymaps"
RDEPENDS_task-base-pci = "\
pciutils"
RDEPENDS_task-base-acpi = "\
acpid"
RDEPENDS_task-base-apm = "\
apm \
apmd \
${@base_contains("MACHINE_FEATURES", "kernel24", "network-suspend-scripts","",d)}"
RDEPENDS_task-base-ext2 = "\
e2fsprogs \
e2fsprogs-e2fsck \
e2fsprogs-mke2fs"
RRECOMMENDS_task-base-ext2 = "\
hdparm"
RDEPENDS_task-base-alsa = "\
alsa-utils-alsactl \
alsa-utils-alsamixer"
RRECOMMENDS_task-base-alsa = "\
kernel-module-snd-mixer-oss \
kernel-module-snd-pcm-oss"
RDEPENDS_task-base-pcmcia = "\
${PCMCIA_MANAGER}"
RRECOMMENDS_task-base-pcmcia = "\
${@base_contains("DISTRO_FEATURES","wifi","task-base-pcmcia-wifi","", d)} \
${@base_contains("DISTRO_FEATURES","bluetooth","task-base-pcmcia-bluetooth","", d)} \
kernel-module-pcmcia \
kernel-module-airo-cs \
kernel-module-pcnet-cs \
kernel-module-serial-cs \
kernel-module-ide-cs"
RDEPENDS_task-base-pcmcia-wifi = "\
prism3-firmware \
prism3-support \
spectrum-fw \
hostap-conf \
orinoco-conf \
${@base_contains("MACHINE_FEATURES","kernel26","kernel-module-hostap-cs kernel-module-orinoco-cs kernel-module-spectrum-cs","hostap-modules-cs orinoco-modules-cs",d)}"
RRECOMMENDS_task-base-pcmcia-wifi = "\
hostap-utils"
RDEPENDS_task-base-bluetooth = "\
bluez-utils"
RRECOMMENDS_task-base-bluetooth = "\
blueprobe \
kernel-module-bluetooth \
kernel-module-l2cap \
kernel-module-rfcomm \
kernel-module-hci-vhci \
kernel-module-bnep \
kernel-module-hidp \
kernel-module-hci-uart \
kernel-module-sco"
RRECOMMENDS_task-base-usbhost-bluetooth = "\
kernel-module-hci-usb"
RRECOMMENDS_task-base-pcmcia-bluetooth = "\
kernel-module-bluetooth3c-cs \
kernel-module-bluecard-cs \
kernel-module-bluetoothuart-cs \
kernel-module-dtl1-cs \
kernel-module-serial-cs"
RDEPENDS_task-base-irda = "\
irda-utils"
RRECOMMENDS_task-base-irda = "\
${@base_contains("DISTRO_FEATURES","ppp","task-base-irda-ppp","", d)} \
kernel-module-pxaficp-ir \
kernel-module-irda \
kernel-module-ircomm \
kernel-module-ircomm-tty \
kernel-module-irlan \
kernel-module-irport \
kernel-module-irtty"
RRECOMMENDS_task-base-irda-ppp = "\
kernel-module-irnet"
RRECOMMENDS_task-base-usbhost-irda = "\
kernel-module-ir-usb"
RRECOMMENDS_task-base-usbgadget = "\
kernel-module-pxa27x_udc \
kernel-module-gadgetfs \
kernel-module-g-file-storage \
kernel-module-g-serial \
kernel-module-g-ether"
RDEPENDS_task-base-usbhost = "\
usbutils"
RRECOMMENDS_task-base-usbhost = "\
${@base_contains("DISTRO_FEATURES","bluetooth","task-base-usbhost-bluetooth","", d)} \
${@base_contains("DISTRO_FEATURES","irda","task-base-usbhost-irda","", d)} \
kernel-module-ohci-hcd \
kernel-module-usbcore \
kernel-module-usbhid \
kernel-module-usbnet \
kernel-module-sd-mod \
kernel-module-scsi-mod \
kernel-module-usbmouse \
kernel-module-mousedev \
kernel-module-usbserial \
kernel-module-usb-storage"
RRECOMMENDS_task-base-pci-wifi = "\
hostap-utils"
RDEPENDS_task-distro-ppp = "\
ppp \
ppp-dialin"
RRECOMMENDS_task-distro-ppp = "\
kernel-module-ppp-async \
kernel-module-ppp-deflate \
kernel-module-ppp-mppe"
RDEPENDS_task-distro-ipsec = "\
openswan"
RRECOMMENDS_task-distro-ipsec = "\
kernel-module-ipsec"
RDEPENDS_task-distro-wifi = "\
wireless-tools"
RRECOMMENDS_task-distro-wifi = "\
kernel-module-ieee80211-crypt \
kernel-module-ieee80211-crypt-ccmp \
kernel-module-ieee80211-crypt-tkip \
kernel-module-ieee80211-crypt-wep \
kernel-module-arc4 \
kernel-module-michael-mic \
kernel-module-aes \
wpa-supplicant"
RRECOMMENDS_task-distro-smbfs = "\
kernel-module-cifs \
kernel-module-smbfs"
RRECOMMENDS_task-distro-cramfs = "\
kernel-module-cramfs"
RDEPENDS_task-distro-nfs = "\
portmap"
RRECOMMENDS_task-distro-nfs = "\
kernel-module-nfs \
kernel-module-lockd \
kernel-module-sunrpc"
RRECOMMENDS_task-distro-ipv6 = "\
kernel-module-ipv6"
# Tosort
# kernel-module-nvrd
# kernel-module-mip6-mn
# kernel-module-tun
# kernel-module-ide-disk
# kernel-module-ide-probe-mo
# kernel-module-loop
# kernel-module-vfat
# kernel-module-ext2
# kernel-module-sco
# kernel-module-af_packet
# kernel-module-ip-gre
# kernel-module-ip-tables
# kernel-module-ipip
# kernel-module-des
# kernel-module-md5
# kernel-module-8250
# Should be DISTRO_EXTRA_RRECOMMENDS: lrzsz
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-03-04 21:28 RFC: Task-base rewrite Marcin Juszkiewicz
@ 2007-03-04 22:55 ` Koen Kooi
2007-03-05 8:04 ` Marcin Juszkiewicz
2007-04-12 18:35 ` Marcin Juszkiewicz
1 sibling, 1 reply; 12+ messages in thread
From: Koen Kooi @ 2007-03-04 22:55 UTC (permalink / raw)
To: openembedded-devel
-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1
Marcin Juszkiewicz schreef:
> During last two months I was working on new version of task-base. It was
> done from time to time without too much testing as I had many other
> things on my todo list.
>
> The main problem of task-base is that it give one package as result so if
> you want to create smaller rootfs for only few features you need to
> create own-task-base and base image on it.
>
> My version create several task-base-*, task-distro-* packages which cover
> several features one by one. Some features contain extra stuff only if
> other features are available (for example Bluetooth on USB bus only if
> distro supports BT and device support USB Host).
>
> Code needs cleanup, changes here and there but it should be better then
> current implementation. Recent changes made to task-base in .dev are not
> in my version yet.
>
> Opinions? Ideas? Patches? Suggestions?
>
>
>
> ------------------------------------------------------------------------
>
> DESCRIPTION = "Merge machine and distro options to create a basic machine task/package"
> PR = "r17.6"
PRs are cheap, no need to go beyond the decimal point :)
regards,
Koen
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
iD8DBQFF605SMkyGM64RGpERAsK+AKCc2AbDLqBzKq4jMBiJKzak2lB7igCdGOrE
DWvfAAh7vZW+MTAhveI+iTM=
=ROC0
-----END PGP SIGNATURE-----
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-03-04 22:55 ` Koen Kooi
@ 2007-03-05 8:04 ` Marcin Juszkiewicz
2007-03-07 17:09 ` Koen Kooi
0 siblings, 1 reply; 12+ messages in thread
From: Marcin Juszkiewicz @ 2007-03-05 8:04 UTC (permalink / raw)
To: openembedded-devel
Dnia niedziela, 4 marca 2007, Koen Kooi napisał:
> Marcin Juszkiewicz schreef:
> > PR = "r17.6"
> PRs are cheap, no need to go beyond the decimal point :)
I usually bump PR after decimal point during tests.
--
JID: hrw-jabber.org
OpenEmbedded developer/consultant
Five is a sufficiently close approximation to infinity. [Robert Firth]
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-03-05 8:04 ` Marcin Juszkiewicz
@ 2007-03-07 17:09 ` Koen Kooi
2007-03-08 13:57 ` Marcin Juszkiewicz
0 siblings, 1 reply; 12+ messages in thread
From: Koen Kooi @ 2007-03-07 17:09 UTC (permalink / raw)
To: openembedded-devel
-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1
Marcin Juszkiewicz schreef:
> Dnia niedziela, 4 marca 2007, Koen Kooi napisał:
>> Marcin Juszkiewicz schreef:
>
>>> PR = "r17.6"
>
>> PRs are cheap, no need to go beyond the decimal point :)
>
> I usually bump PR after decimal point during tests.
OK, I see no objections from people, commit it tonight?
regards,
Koen
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
iD8DBQFF7vHDMkyGM64RGpERApb9AJwIUwen+wv2lsws2TZN+rqf809bZACfSmGf
UIlWJfcLNTcSrunmCCXfhuo=
=hWeU
-----END PGP SIGNATURE-----
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-03-07 17:09 ` Koen Kooi
@ 2007-03-08 13:57 ` Marcin Juszkiewicz
0 siblings, 0 replies; 12+ messages in thread
From: Marcin Juszkiewicz @ 2007-03-08 13:57 UTC (permalink / raw)
To: openembedded-devel
Dnia środa, 7 marca 2007, Koen Kooi napisał:
> OK, I see no objections from people, commit it tonight?
It is not ready for commit. It need testing, improving and then commiting.
Now it does not even work fully:
ERROR: No providers of runtime build target task-base-usbhost-bluetooth
(for
['/home/hrw/devel/oe/org.openembedded/packages/tasks/task-base-new.bb'])
NOTE: Removing failed runtime build target task-base-usbhost-bluetooth
NOTE: Removing failed runtime build target task-base-machine
NOTE: Removing failed runtime build target task-base-bluetooth
NOTE: Removing failed runtime build target task-distro-base
NOTE: Removing failed runtime build target task-base-kernel26
NOTE: Removing failed runtime build target task-distro-nfs
NOTE: Removing failed runtime build target task-base-usbhost
NOTE: Removing failed runtime build target task-base-apm
NOTE: Removing failed runtime build target task-distro-ppp
NOTE: Removing failed runtime build target task-base-alsa
ERROR: No providers of runtime build target task-base-usbhost-irda (for
['/home/hrw/devel/oe/org.openembedded/packages/tasks/task-base-new.bb'])
NOTE: Removing failed runtime build target task-base-usbhost-irda
ERROR: No providers of runtime build target task-base-kernel26-extras (for
['/home/hrw/devel/oe/org.openembedded/packages/tasks/task-base-new.bb'])
NOTE: Removing failed runtime build target task-base-kernel26-extras
ERROR: No providers of runtime build target task-distro-extras after
filtering (for
['/home/hrw/devel/oe/org.openembedded/packages/tasks/task-base-new.bb'])
NOTE: Removing failed runtime build target task-distro-extras
ERROR: No providers of runtime build target task-base-machine-extras after
filtering (for
['/home/hrw/devel/oe/org.openembedded/packages/tasks/task-base-new.bb'])
NOTE: Removing failed runtime build target task-base-machine-extras
--
JID: hrw-jabber.org
OpenEmbedded developer/consultant
It might look like I'm doing nothing,
but at the cellular level I'm really quite busy!
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-03-04 21:28 RFC: Task-base rewrite Marcin Juszkiewicz
2007-03-04 22:55 ` Koen Kooi
@ 2007-04-12 18:35 ` Marcin Juszkiewicz
2007-04-12 19:19 ` Koen Kooi
` (2 more replies)
1 sibling, 3 replies; 12+ messages in thread
From: Marcin Juszkiewicz @ 2007-04-12 18:35 UTC (permalink / raw)
To: openembedded-devel; +Cc: Michael 'Mickey' Lauer, Koen Kooi
[-- Attachment #1: Type: text/plain, Size: 1776 bytes --]
Dnia niedziela, 4 marca 2007, Marcin Juszkiewicz napisał:
> During last two months I was working on new version of task-base. It
> was done from time to time without too much testing as I had many other
> things on my todo list.
>
> The main problem of task-base is that it give one package as result so
> if you want to create smaller rootfs for only few features you need to
> create own-task-base and base image on it.
>
> My version create several task-base-*, task-distro-* packages which
> cover several features one by one. Some features contain extra stuff
> only if other features are available (for example Bluetooth on USB bus
> only if distro supports BT and device support USB Host).
New version attached is based on task-base r23.
Packages.small is result of build for progear/angstrom combination (with
some changes to both configs - added some features).
What this version gives:
- each feature gets own package,
- task-boot contain ONLY stuff needed to boot
- task-distro-base contain distro addons
- task-machine-base contain machine specific addons
- task-base depend on all needed task-* packages
- ability to choose SSH daemon (dropbear, openssh, none) by distro
- ability to choose /dev/ manager (udev, devfsd, mdev) by distro
- ability to choose getty provider (tinylogin by default) by distro
With this version it is easier to create smaller rootfs - for example
image with ONLY bluetooth support is "task-boot + task-base-bluetooth".
Do some tests, post opinions - I think that this will be nice improvement
of task-base.
--
JID: hrw-jabber.org
OpenEmbedded developer/consultant
I used to think the brain is the most wonderfull organ in my body,
till I realised what was telling me that
[-- Attachment #2: task-base.bb --]
[-- Type: text/plain, Size: 11307 bytes --]
DESCRIPTION = "Merge machine and distro options to create a basic machine task/package"
PR = "r24"
PACKAGES = 'task-boot \
task-base \
task-distro-base \
task-machine-base \
${@base_contains("MACHINE_FEATURES","acpi","task-base-acpi","", d)} \
${@base_contains("MACHINE_FEATURES","alsa","task-base-alsa","", d)} \
${@base_contains("MACHINE_FEATURES","apm","task-base-apm","", d)} \
${@base_contains("MACHINE_FEATURES","bluetooth","task-base-bluetooth","", d)} \
${@base_contains("MACHINE_FEATURES","ext2","task-base-ext2","", d)} \
${@base_contains("MACHINE_FEATURES","irda","task-base-irda","", d)} \
${@base_contains("MACHINE_FEATURES","keyboard","task-base-keyboard","", d)} \
${@base_contains("MACHINE_FEATURES","nfs","task-base-nfs","", d)} \
${@base_contains("MACHINE_FEATURES","pci","task-base-pci","", d)} \
${@base_contains("MACHINE_FEATURES","pcmcia","task-base-pcmcia","", d)} \
${@base_contains("MACHINE_FEATURES","phone","task-base-phone","", d)} \
${@base_contains("MACHINE_FEATURES","screen","task-base-screen","", d)} \
${@base_contains("MACHINE_FEATURES","smbfs","task-base-smbfs","", d)} \
${@base_contains("MACHINE_FEATURES","touchscreen","task-base-touchscreen","", d)} \
${@base_contains("MACHINE_FEATURES","usbgadget","task-base-usbgadget","", d)} \
${@base_contains("MACHINE_FEATURES","usbhost","task-base-usbhost","", d)} \
${@base_contains("MACHINE_FEATURES","wifi","task-base-wifi","", d)} \
${@base_contains("MACHINE_FEATURES","kernel26","task-base-kernel26","task-base-kernel24",d)} \
\
${@base_contains("DISTRO_FEATURES","cramfs","task-base-cramfs","", d)} \
${@base_contains("DISTRO_FEATURES","ipsec","task-base-ipsec","", d)} \
${@base_contains("DISTRO_FEATURES","ipv6","task-base-ipv6","", d)} \
${@base_contains("DISTRO_FEATURES","nfs","task-base-nfs","", d)} \
${@base_contains("DISTRO_FEATURES","ppp","task-base-ppp","", d)} \
${@base_contains("DISTRO_FEATURES","smbfs","task-base-smbfs","", d)} \
${@base_contains("DISTRO_FEATURES","wifi","task-base-wifi","", d)} \
'
ALLOW_EMPTY = "1"
PACKAGE_ARCH = "${MACHINE_ARCH}"
#
# udev, devfsd, mdev (from busybox) or none
#
DISTRO_DEV_MANAGER ?= "${@base_contains("MACHINE_FEATURES", "kernel26", "udev","",d)} "
#
# sysvinit, upstart
#
DISTRO_INIT_MANAGER ?= "sysvinit"
#
# tinylogin, getty
#
DISTRO_LOGIN_MANAGER ?= "tinylogin"
#
# linux-hotplug or none
#
HOTPLUG ?= "${@base_contains("MACHINE_FEATURES", "kernel24", "linux-hotplug","",d)} "
#
# dropbear, openssh or none
#
DISTRO_SSH_DAEMON ?= "dropbear"
#
# pcmciautils for >= 2.6.13-rc1, pcmcia-cs for others
#
PCMCIA_MANAGER ?= "${@base_contains('MACHINE_FEATURES', 'kernel26','pcmciautils','pcmcia-cs',d)} "
MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
#
# task-base
#
RDEPENDS_task-base = "\
task-boot \
task-distro-base \
task-machine-base \
${DISTRO_SSH_DAEMON} \
${HOTPLUG} \
\
${@base_contains('MACHINE_FEATURES', 'kernel26','task-base-kernel26','task-base-kernel24',d)} \
${@base_contains('MACHINE_FEATURES', 'apm', 'task-base-apm', '',d)} \
${@base_contains('MACHINE_FEATURES', 'acpi', 'task-base-acpi', '',d)} \
${@base_contains('MACHINE_FEATURES', 'keyboard', 'task-base-keyboard', '',d)} \
\
${@base_contains('COMBINED_FEATURES', 'alsa', 'task-base-alsa', '',d)} \
${@base_contains('COMBINED_FEATURES', 'ext2', 'task-base-ext2', '',d)} \
${@base_contains('COMBINED_FEATURES', 'irda', 'task-base-irda', '',d)} \
${@base_contains('COMBINED_FEATURES', 'pci', 'task-base-pci', '',d)} \
${@base_contains('COMBINED_FEATURES', 'pcmcia', 'task-base-pcmcia', '',d)} \
${@base_contains('COMBINED_FEATURES', 'usbhost', 'task-base-usbhost', '',d)} \
${@base_contains('COMBINED_FEATURES', 'bluetooth', 'task-base-bluetooth', '',d)} \
${@base_contains('COMBINED_FEATURES', 'wifi', 'task-base-wifi', '',d)} \
${@base_contains('COMBINED_FEATURES', 'uboot', 'task-base-uboot', '',d)} \
${@base_contains('COMBINED_FEATURES', 'redboot', 'task-base-redboot', '',d)} \
\
${@base_contains('DISTRO_FEATURES', 'nfs', 'task-base-nfs', '',d)} \
${@base_contains('DISTRO_FEATURES', 'ipsec', 'task-base-ipsec', '',d)} \
${@base_contains('DISTRO_FEATURES', 'ppp', 'task-base-ppp', '',d)} \
${@base_contains('DISTRO_FEATURES', 'raid', 'task-base-raid', '',d)} \
"
RDEPENDS_task-distro-base = "${DISTRO_EXTRA_RDEPENDS}"
RRECOMMENDS_task-distro-base = "${DISTRO_EXTRA_RRECOMMENDS}"
RDEPENDS_task-machine-base = "${MACHINE_EXTRA_RDEPENDS}"
RRECOMMENDS_task-machine-base = "${MACHINE_EXTRA_RRECOMMENDS}"
#
# task-boot
# Minimal set of packages - needed to boot
#
RDEPENDS_task-boot = "\
kernel \
base-files \
base-passwd \
busybox \
initscripts \
modutils-initscripts \
netbase \
${DISTRO_DEV_MANAGER} \
${DISTRO_INIT_MANAGER} \
${DISTRO_LOGIN_MANAGER} \
${MACHINE_ESSENTIAL_EXTRA_RDEPENDS}"
RRECOMMENDS_task-boot = "\
${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS}"
RDEPENDS_task-base-kernel24 = "\
modutils-depmod"
RDEPENDS_task-base-kernel26 = "\
sysfsutils \
module-init-tools"
RDEPENDS_task-base-keyboard = "\
keymaps"
RDEPENDS_task-base-pci = "\
pciutils"
RRECOMMENDS_task-base-kernel26 = "\
kernel-module-input \
kernel-module-uinput"
RDEPENDS_task-base-acpi = "\
acpid"
RDEPENDS_task-base-apm = "\
apm \
apmd \
${@base_contains('MACHINE_FEATURES', 'kernel24', 'network-suspend-scripts', '',d)}"
RDEPENDS_task-base-ext2 = "\
hdparm \
e2fsprogs \
e2fsprogs-e2fsck \
e2fsprogs-mke2fs"
RDEPENDS_task-base-alsa = "\
alsa-utils-alsactl \
alsa-utils-alsamixer"
RRECOMMENDS_task-base-alsa = "\
alsa-state \
kernel-module-snd-mixer-oss \
kernel-module-snd-pcm-oss"
RDEPENDS_task-base-pcmcia = "\
${PCMCIA_MANAGER} \
${@base_contains('DISTRO_FEATURES', 'wifi', 'prism3-firmware', '',d)} \
${@base_contains('DISTRO_FEATURES', 'wifi', 'prism3-support', '',d)} \
${@base_contains('DISTRO_FEATURES', 'wifi', 'spectrum-fw', '',d)} \
${@base_contains('DISTRO_FEATURES', 'wifi', 'hostap-conf', '',d)} \
${@base_contains('DISTRO_FEATURES', 'wifi', 'orinoco-conf', '',d)}"
RRECOMMENDS_task-base-pcmcia = "\
${@base_contains('MACHINE_FEATURES', 'kernel26', '${task-base-pcmcia26}', '${task-base-pcmcia24}',d)} \
kernel-module-pcmcia \
kernel-module-airo-cs \
kernel-module-pcnet-cs \
kernel-module-serial-cs \
kernel-module-ide-cs \
kernel-module-ide-disk \
"
task-base-pcmcia24 = "\
${@base_contains('DISTRO_FEATURES', 'wifi', 'hostap-modules-cs', '',d)} \
${@base_contains('DISTRO_FEATURES', 'wifi', 'orinoco-modules-cs', '',d)}"
task-base-pcmcia26 = "\
${@base_contains('DISTRO_FEATURES', 'wifi', 'kernel-module-hostap-cs', '',d)} \
${@base_contains('DISTRO_FEATURES', 'wifi', 'kernel-module-orinoco-cs', '',d)} \
${@base_contains('DISTRO_FEATURES', 'wifi', 'kernel-module-spectrum-cs', '',d)}"
RDEPENDS_task-base-bluetooth = "\
blueprobe \
bluez-utils"
RRECOMMENDS_task-base-bluetooth = "\
kernel-module-bluetooth \
kernel-module-l2cap \
kernel-module-rfcomm \
kernel-module-hci-vhci \
kernel-module-bnep \
kernel-module-hidp \
kernel-module-hci-uart \
kernel-module-sco \
${@base_contains('COMBINED_FEATURES', 'usbhost', 'kernel-module-hci-usb', '',d)} \
${@base_contains('COMBINED_FEATURES', 'pcmcia', 'kernel-module-bluetooth3c-cs', '',d)} \
${@base_contains('COMBINED_FEATURES', 'pcmcia', 'kernel-module-bluecard-cs', '',d)} \
${@base_contains('COMBINED_FEATURES', 'pcmcia', 'kernel-module-bluetoothuart-cs', '',d)} \
${@base_contains('COMBINED_FEATURES', 'pcmcia', 'kernel-module-dtl1-cs', '',d)}"
RDEPENDS_task-base-irda = "\
irda-utils"
RRECOMMENDS_task-base-irda = "\
kernel-module-pxaficp-ir \
kernel-module-irda \
kernel-module-ircomm \
kernel-module-ircomm-tty \
kernel-module-irlan \
${@base_contains('DISTRO_FEATURES', 'ppp', 'kernel-module-irnet', '',d)} \
kernel-module-irport \
kernel-module-irtty \
kernel-module-irtty-sir \
kernel-module-sir-dev \
${@base_contains('COMBINED_FEATURES', 'usbhost', 'kernel-module-ir-usb', '',d)} "
RRECOMMENDS_task-base-usbgadget = "\
kernel-module-pxa27x_udc \
kernel-module-gadgetfs \
kernel-module-g-file-storage \
kernel-module-g-serial \
kernel-module-g-ether"
RDEPENDS_task-base-usbhost = "\
usbutils "
RRECOMMENDS_task-base-usbhost = "\
kernel-module-uhci-hcd \
kernel-module-ohci-hcd \
kernel-module-ehci-hcd \
kernel-module-usbcore \
kernel-module-usbhid \
kernel-module-usbnet \
kernel-module-sd-mod \
kernel-module-scsi-mod \
kernel-module-usbmouse \
kernel-module-mousedev \
kernel-module-usbserial \
kernel-module-usb-storage "
RDEPENDS_task-base-uboot = "\
uboot-utils"
RDEPENDS_task-base-redboot = "\
fis"
RDEPENDS_task-base-ppp = "\
ppp \
ppp-dialin"
RRECOMMENDS_task-base-ppp = "\
kernel-module-ppp-async \
kernel-module-ppp-deflate \
kernel-module-ppp-mppe"
RDEPENDS_task-base-ipsec = "\
openswan"
RRECOMMENDS_task-base-ipsec = "\
kernel-module-ipsec"
RDEPENDS_task-base-wifi = "\
wireless-tools \
${@base_contains('COMBINED_FEATURES', 'pcmcia', 'hostap-utils', '',d)} \
${@base_contains('COMBINED_FEATURES', 'pci', 'hostap-utils', '',d)} \
wpa-supplicant"
RRECOMMENDS_task-base-wifi = "\
kernel-module-ieee80211-crypt \
kernel-module-ieee80211-crypt-ccmp \
kernel-module-ieee80211-crypt-tkip \
kernel-module-ieee80211-crypt-wep \
kernel-module-ecb \
kernel-module-arc4 \
kernel-module-michael-mic \
kernel-module-aes"
RRECOMMENDS_task-base-smbfs = "\
kernel-module-cifs \
kernel-module-smbfs"
RRECOMMENDS_task-base-cramfs = "\
kernel-module-cramfs"
RDEPENDS_task-base-nfs = "\
portmap"
RRECOMMENDS_task-base-nfs = "\
kernel-module-nfs "
RDEPENDS_task-base-raid = "\
"
RDEPENDS_task-base-screen = "\
"
RDEPENDS_task-base-touchscreen = "\
tslib-tests \
tslib-calibrate "
RDEPENDS_task-base-ipv6 = "\
"
RRECOMMENDS_task-base-ipv6 = "\
kernel-module-ipv6 "
# Tosort
# kernel-module-nvrd
# kernel-module-mip6-mn
# kernel-module-tun
# kernel-module-ide-disk
# kernel-module-ide-probe-mo
# kernel-module-loop
# kernel-module-vfat
# kernel-module-ext2
# kernel-module-sco
# kernel-module-af_packet
# kernel-module-ip-gre
# kernel-module-ip-tables
# kernel-module-ipip
# kernel-module-des
# kernel-module-md5
# kernel-module-8250
# Should be DISTRO_EXTRA_RRECOMMENDS: lrzsz
[-- Attachment #3: Packages.small --]
[-- Type: text/plain, Size: 3308 bytes --]
Package: task-base-acpi
Depends: acpid
Package: task-base-alsa
Depends: alsa-utils-alsactl, alsa-utils-alsamixer
Recommends: alsa-state, kernel-module-snd-mixer-oss, kernel-module-snd-pcm-oss
Package: task-base-ext2
Depends: hdparm, e2fsprogs, e2fsprogs-e2fsck, e2fsprogs-mke2fs
Package: task-base-ipsec
Depends: openswan
Recommends: kernel-module-ipsec
Package: task-base-ipv6
Recommends: kernel-module-ipv6
Package: task-base-irda
Depends: irda-utils
Recommends: kernel-module-pxaficp-ir, kernel-module-irda, kernel-module-ircomm, kernel-module-ircomm-tty, kernel-module-irlan, kernel-module-irnet, kernel-module-irport, kernel-module-irtty, kernel-module-irtty-sir, kernel-module-sir-dev, kernel-module-ir-usb
Package: task-base-kernel26
Depends: sysfsutils, module-init-tools
Recommends: kernel-module-input, kernel-module-uinput
Package: task-base-nfs
Depends: portmap
Recommends: kernel-module-nfs
Package: task-base-pci
Depends: pciutils
Package: task-base-pcmcia
Depends: pcmciautils, prism3-firmware, prism3-support, spectrum-fw, hostap-conf, orinoco-conf
Recommends: kernel-module-hostap-cs, kernel-module-orinoco-cs, kernel-module-spectrum-cs, kernel-module-pcmcia, kernel-module-airo-cs, kernel-module-pcnet-cs, kernel-module-serial-cs, kernel-module-ide-cs, kernel-module-ide-disk
Package: task-base-ppp
Depends: ppp, ppp-dialin
Recommends: kernel-module-ppp-async, kernel-module-ppp-deflate, kernel-module-ppp-mppe
Package: task-base-screen
Package: task-base-smbfs
Recommends: kernel-module-cifs, kernel-module-smbfs
Package: task-base-touchscreen
Depends: tslib-tests, tslib-calibrate
Package: task-base-usbhost
Depends: usbutils
Recommends: kernel-module-uhci-hcd, kernel-module-ohci-hcd, kernel-module-ehci-hcd, kernel-module-usbcore, kernel-module-usbhid, kernel-module-usbnet, kernel-module-sd-mod, kernel-module-scsi-mod, kernel-module-usbmouse, kernel-module-mousedev, kernel-module-usbserial, kernel-module-usb-storage
Package: task-base-wifi
Depends: wireless-tools, hostap-utils, hostap-utils, wpa-supplicant
Recommends: kernel-module-ieee80211-crypt, kernel-module-ieee80211-crypt-ccmp, kernel-module-ieee80211-crypt-tkip, kernel-module-ieee80211-crypt-wep, kernel-module-ecb, kernel-module-arc4, kernel-module-michael-mic, kernel-module-aes
Package: task-base
Depends: task-boot, task-distro-base, task-machine-base, dropbear, task-base-kernel26, task-base-acpi, task-base-alsa, task-base-ext2, task-base-irda, task-base-pci, task-base-pcmcia, task-base-usbhost, task-base-nfs, task-base-ipsec, task-base-ppp
Package: task-boot
Depends: kernel, base-files, base-passwd, busybox, initscripts, modutils-initscripts, netbase, udev, sysvinit, tinylogin
Package: task-distro-base
Depends: update-modules, module-init-tools, modutils-initscripts, sysvinit, initscripts, sysvinit-pidof, psplash, netbase, dropbear, angstrom-version, ipkg, ipkg-collateral, util-linux-mount, util-linux-umount, avahi-daemon, avahi-autoipd, tslib-tests, tslib-calibrate, gdb, strace, procps
Recommends: kernel-module-vfat, kernel-module-ext2
Package: task-machine-base
Recommends: progear-ac, progear-battery, kernel-module-snd-ali5451, kernel-module-i2c-ali1535, kernel-module-i2c-ali15x3, kernel-module-yenta-socket
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-04-12 18:35 ` Marcin Juszkiewicz
@ 2007-04-12 19:19 ` Koen Kooi
2007-04-12 22:26 ` Richard Purdie
2007-04-12 22:31 ` Rod Whitby
2 siblings, 0 replies; 12+ messages in thread
From: Koen Kooi @ 2007-04-12 19:19 UTC (permalink / raw)
To: openembedded-devel
-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1
Marcin Juszkiewicz schreef:
> What this version gives:
>
> - each feature gets own package,
> - task-boot contain ONLY stuff needed to boot
> - task-distro-base contain distro addons
> - task-machine-base contain machine specific addons
> - task-base depend on all needed task-* packages
> - ability to choose SSH daemon (dropbear, openssh, none) by distro
> - ability to choose /dev/ manager (udev, devfsd, mdev) by distro
> - ability to choose getty provider (tinylogin by default) by distro
>
> With this version it is easier to create smaller rootfs - for example
> image with ONLY bluetooth support is "task-boot + task-base-bluetooth".
>
> Do some tests, post opinions - I think that this will be nice improvement
> of task-base.
I think this would make things like moko-slug possible at image-level instead of distro level.
regards,
Koen
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
iD8DBQFGHoZSMkyGM64RGpERAqARAJ0Xo0xWJG3F3J70kYOKPBBOky8QIwCfeCO9
4kqtpGWYED9Ict0YQd3wcoA=
=0WnC
-----END PGP SIGNATURE-----
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-04-12 18:35 ` Marcin Juszkiewicz
2007-04-12 19:19 ` Koen Kooi
@ 2007-04-12 22:26 ` Richard Purdie
2007-04-12 22:31 ` Rod Whitby
2 siblings, 0 replies; 12+ messages in thread
From: Richard Purdie @ 2007-04-12 22:26 UTC (permalink / raw)
To: Marcin Juszkiewicz
Cc: openembedded-devel, Michael 'Mickey' Lauer, Koen Kooi
On Thu, 2007-04-12 at 20:35 +0200, Marcin Juszkiewicz wrote:
> New version attached is based on task-base r23.
>
> Packages.small is result of build for progear/angstrom combination (with
> some changes to both configs - added some features).
>
> What this version gives:
>
> - each feature gets own package,
> - task-boot contain ONLY stuff needed to boot
> - task-distro-base contain distro addons
> - task-machine-base contain machine specific addons
> - task-base depend on all needed task-* packages
> - ability to choose SSH daemon (dropbear, openssh, none) by distro
> - ability to choose /dev/ manager (udev, devfsd, mdev) by distro
> - ability to choose getty provider (tinylogin by default) by distro
>
> With this version it is easier to create smaller rootfs - for example
> image with ONLY bluetooth support is "task-boot + task-base-bluetooth".
>
> Do some tests, post opinions - I think that this will be nice improvement
> of task-base.
I agree with it and it gets my approval FWIW :)
Cheers,
Richard
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-04-12 18:35 ` Marcin Juszkiewicz
2007-04-12 19:19 ` Koen Kooi
2007-04-12 22:26 ` Richard Purdie
@ 2007-04-12 22:31 ` Rod Whitby
2007-04-13 6:19 ` Marcin Juszkiewicz
2 siblings, 1 reply; 12+ messages in thread
From: Rod Whitby @ 2007-04-12 22:31 UTC (permalink / raw)
To: Marcin Juszkiewicz; +Cc: openembedded-devel
Marcin Juszkiewicz wrote:
>> My version create several task-base-*, task-distro-* packages which
>> cover several features one by one. Some features contain extra stuff
>> only if other features are available (for example Bluetooth on USB bus
>> only if distro supports BT and device support USB Host).
>
> What this version gives:
>
> - each feature gets own package,
> - task-boot contain ONLY stuff needed to boot
> - task-distro-base contain distro addons
> - task-machine-base contain machine specific addons
> - task-base depend on all needed task-* packages
> - ability to choose SSH daemon (dropbear, openssh, none) by distro
> - ability to choose /dev/ manager (udev, devfsd, mdev) by distro
> - ability to choose getty provider (tinylogin by default) by distro
>
> With this version it is easier to create smaller rootfs - for example
> image with ONLY bluetooth support is "task-boot + task-base-bluetooth".
>
> Do some tests, post opinions - I think that this will be nice improvement
> of task-base.
No tests yet, but it has the support of nslu2-linux distros.
I especially like the dropbear/openssh selection capability.
-- Rod
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-04-12 22:31 ` Rod Whitby
@ 2007-04-13 6:19 ` Marcin Juszkiewicz
2007-04-13 8:47 ` Marcin Juszkiewicz
2007-04-17 3:22 ` Cliff Brake
0 siblings, 2 replies; 12+ messages in thread
From: Marcin Juszkiewicz @ 2007-04-13 6:19 UTC (permalink / raw)
To: openembedded-devel
Dnia piątek, 13 kwietnia 2007, Rod Whitby napisał:
> No tests yet, but it has the support of nslu2-linux distros.
;)
Idea of splitting into separate packages comes from my discussions with
Richard about differencies between Poky task-base and OE task-base.
During last Easter I had more time to think about correct implementation
and wanted to make small rootfs creation easier then it was before.
And nslu2 rootfs is big - Cliff Brake created 1.7M rootfs for his Compulab
board.
Cliff: can you look at task-boot contents and tell does it need something
removed/added to create minimal image?
> I especially like the dropbear/openssh selection capability.
Too many people complain about having dropbear in their rootfs ;)
--
JID: hrw-jabber.org
OpenEmbedded developer/consultant
I don't know. I don't care. And it doesn't make any difference.
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-04-13 6:19 ` Marcin Juszkiewicz
@ 2007-04-13 8:47 ` Marcin Juszkiewicz
2007-04-17 3:22 ` Cliff Brake
1 sibling, 0 replies; 12+ messages in thread
From: Marcin Juszkiewicz @ 2007-04-13 8:47 UTC (permalink / raw)
To: openembedded-devel
After discussion on #oe and making extra changes I pushed new task-base
into repository.
--
JID: hrw-jabber.org
OpenEmbedded developer/consultant
chaos, panic, packet loss - my work here is done!
^ permalink raw reply [flat|nested] 12+ messages in thread
* Re: RFC: Task-base rewrite
2007-04-13 6:19 ` Marcin Juszkiewicz
2007-04-13 8:47 ` Marcin Juszkiewicz
@ 2007-04-17 3:22 ` Cliff Brake
1 sibling, 0 replies; 12+ messages in thread
From: Cliff Brake @ 2007-04-17 3:22 UTC (permalink / raw)
To: Marcin Juszkiewicz, openembedded-devel
On 4/13/07, Marcin Juszkiewicz <openembedded@hrw.one.pl> wrote:
> Idea of splitting into separate packages comes from my discussions with
> Richard about differencies between Poky task-base and OE task-base.
> During last Easter I had more time to think about correct implementation
> and wanted to make small rootfs creation easier then it was before.
>
> And nslu2 rootfs is big - Cliff Brake created 1.7M rootfs for his Compulab
> board.
>
> Cliff: can you look at task-boot contents and tell does it need something
> removed/added to create minimal image?
Hi Marcin,
Looks great. I'm hoping to merge my updater project into OE in the
next couple weeks so that we have a complete solution for JFFS2 on the
compulab module. The new task base should be ideal for that. I'll
let you know how it works out.
Thanks,
Cliff
--
=======================
Cliff Brake
http://bec-systems.com
^ permalink raw reply [flat|nested] 12+ messages in thread
end of thread, other threads:[~2007-04-17 3:22 UTC | newest]
Thread overview: 12+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2007-03-04 21:28 RFC: Task-base rewrite Marcin Juszkiewicz
2007-03-04 22:55 ` Koen Kooi
2007-03-05 8:04 ` Marcin Juszkiewicz
2007-03-07 17:09 ` Koen Kooi
2007-03-08 13:57 ` Marcin Juszkiewicz
2007-04-12 18:35 ` Marcin Juszkiewicz
2007-04-12 19:19 ` Koen Kooi
2007-04-12 22:26 ` Richard Purdie
2007-04-12 22:31 ` Rod Whitby
2007-04-13 6:19 ` Marcin Juszkiewicz
2007-04-13 8:47 ` Marcin Juszkiewicz
2007-04-17 3:22 ` Cliff Brake
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.