[PATCH 1/3] nasm: fix COMPATIBLE_HOST to match any vendor

[PATCH 1/3] nasm: fix COMPATIBLE_HOST to match any vendor

[Michael Smith]

On x86_64, it was looking for x86_64-linux, not x86_64-blah-linux;
it broke the build for syslinux if a BUILD_VENDOR was set.

Signed-off-by: Michael Smith <msmith@cbnco.com>
---
 recipes/nasm/nasm_0.98.38.bb |    3 ++-
 1 files changed, 2 insertions(+), 1 deletions(-)

diff --git a/recipes/nasm/nasm_0.98.38.bb b/recipes/nasm/nasm_0.98.38.bb
index 86e7f2b..abe47fe 100644
--- a/recipes/nasm/nasm_0.98.38.bb
+++ b/recipes/nasm/nasm_0.98.38.bb
@@ -1,7 +1,8 @@
 DESCRIPTION = "General-purpose x86 assembler"
 SECTION = "devel"
 LICENSE = "GPL"
-COMPATIBLE_HOST = '(x86_64|i.86.*)-(linux|freebsd.*)'
+COMPATIBLE_HOST = '(x86_64|i.86).*-(linux|freebsd.*)'
+PR = "r1"
 
 SRC_URI = "${SOURCEFORGE_MIRROR}/nasm/nasm-${PV}.tar.bz2"
 
-- 
1.6.3

[PATCH 2/3] mtools: don't install-info; fixes build on non-Debian hosts

[Michael Smith]

The install-info installed into staging by dpkg-native looks for
/var/backups/infodir.bak and /usr/share/base-files/info.dir on
the build system. On Debian/Ubuntu this is benign, but on other
distros these files don't exist and the install fails.

The info file is still installed, we just don't try to rebuild the
nonexistent directory.

There are cleaner ways to solve this in the long run:

http://dev.openbossa.org/trac/mamona/ticket/139

Signed-off-by: Michael Smith <msmith@cbnco.com>
---
 recipes/mtools/mtools_4.0.10.bb |    5 ++++-
 1 files changed, 4 insertions(+), 1 deletions(-)

diff --git a/recipes/mtools/mtools_4.0.10.bb b/recipes/mtools/mtools_4.0.10.bb
index b53306a..18fbb7d 100644
--- a/recipes/mtools/mtools_4.0.10.bb
+++ b/recipes/mtools/mtools_4.0.10.bb
@@ -13,12 +13,15 @@ SRC_URI="http://ftp.gnu.org/gnu/mtools/mtools-${PV}.tar.bz2 \
 	file://plainio.patch;patch=1 \
 	file://use-sg_io.patch;patch=1"
 
-S = "${WORKDIR}/mtools-${PV}"
+PR = "r1"
 
 inherit autotools
 
 EXTRA_OECONF = "--without-x"
 
+# Don't try to run install-info -- it'll fail on non-Debian build systems.
+EXTRA_OEMAKE = "INSTALL_INFO="
+
 do_fix_perms() {
 	chmod 644 ${S}/*.c ${S}/*.h
 }
-- 
1.6.3

[PATCH 3/3] syslinux: upgrade to 3.82 and split into a few packages

[Michael Smith]

3.63 is no longer available.

Signed-off-by: Michael Smith <msmith@cbnco.com>
---

I guess I changed a few too many lines for
git format-patch -M -C --find-copies-harder to recognize it as a pair
of renames (syslinux, syslinux-native 3.63 -> 3.82).


 conf/checksums.ini                       |    4 +++
 recipes/syslinux/syslinux-native_3.63.bb |   23 ----------------
 recipes/syslinux/syslinux-native_3.82.bb |   24 +++++++++++++++++
 recipes/syslinux/syslinux_3.63.bb        |   32 -----------------------
 recipes/syslinux/syslinux_3.82.bb        |   41 ++++++++++++++++++++++++++++++
 5 files changed, 69 insertions(+), 55 deletions(-)
 delete mode 100644 recipes/syslinux/syslinux-native_3.63.bb
 create mode 100644 recipes/syslinux/syslinux-native_3.82.bb
 delete mode 100644 recipes/syslinux/syslinux_3.63.bb
 create mode 100644 recipes/syslinux/syslinux_3.82.bb

diff --git a/conf/checksums.ini b/conf/checksums.ini
index b50f7f7..eb7c56b 100644
--- a/conf/checksums.ini
+++ b/conf/checksums.ini
@@ -23278,6 +23278,10 @@ sha256=c087b112da0afd1c50ba8a8a2727c4cabfb1e5a57f43701c5abdc05865072649
 md5=ee6b84cc7b598b4e1a00a4a8c6676d4e
 sha256=d4d17102e014d3183a11719896061dc464c3d9a836caaf47b3b57da4ac23b52d
 
+[http://kernel.org/pub/linux/utils/boot/syslinux/syslinux-3.82.tar.bz2]
+md5=c9f4e73e385c86b3a8faf9b615a04836
+sha256=1dbbf8cfd10fc07187fa8bfede23639fc95314976730f3474cb349e8bf6c6f61
+
 [http://www.balabit.com/downloads/files/syslog-ng/sources/1.6/src/syslog-ng-1.6.11.tar.gz]
 md5=8f9ca6140f428dc9adec9fa1c270a2dd
 sha256=dd37f1e280bd6c2d66c9a15aa3ee9e209a1b649e3b79e70fee58aea1cb0ea093
diff --git a/recipes/syslinux/syslinux-native_3.63.bb b/recipes/syslinux/syslinux-native_3.63.bb
deleted file mode 100644
index 3cd1ff8..0000000
--- a/recipes/syslinux/syslinux-native_3.63.bb
+++ /dev/null
@@ -1,23 +0,0 @@
-# syslinux-native OE build file
-# Copyright (C) 2004-2006, Advanced Micro Devices, Inc.  All Rights Reserved
-# Copyright (C) 2009, O.S. Systems Software Ltda.  All Rights Reserved
-# Released under the MIT license (see packages/COPYING)
-
-require syslinux_${PV}.bb
-inherit native
-
-STAGE_TEMP="${WORKDIR}/stage_temp"
-
-do_stage() {
-	install -d ${STAGE_TEMP}
-	oe_runmake install INSTALLROOT="${STAGE_TEMP}"
-
-	install -d ${STAGING_BINDIR}
-	install -m 755 ${STAGE_TEMP}/usr/bin/syslinux ${STAGING_BINDIR}
-	install -m 755 ${STAGE_TEMP}/sbin/extlinux ${STAGING_BINDIR}
-
-	install -d ${STAGING_DATADIR}/syslinux
-	install -m 0644 ${STAGE_TEMP}/usr/lib/syslinux/isolinux.bin ${STAGING_DATADIR}/syslinux/isolinux.bin
-	install -m 644 ${S}/ldlinux.sys ${STAGING_DATADIR}/syslinux/ldlinux.sys
-	install -m 644 ${S}/ldlinux.bss ${STAGING_DATADIR}/syslinux/ldlinux.bss
-}
diff --git a/recipes/syslinux/syslinux-native_3.82.bb b/recipes/syslinux/syslinux-native_3.82.bb
new file mode 100644
index 0000000..69ab9c1
--- /dev/null
+++ b/recipes/syslinux/syslinux-native_3.82.bb
@@ -0,0 +1,24 @@
+# syslinux-native OE build file
+# Copyright (C) 2004-2006, Advanced Micro Devices, Inc.  All Rights Reserved
+# Copyright (C) 2009, O.S. Systems Software Ltda.  All Rights Reserved
+# Released under the MIT license (see packages/COPYING)
+
+require syslinux_${PV}.bb
+inherit native
+
+STAGE_TEMP="${WORKDIR}/stage_temp"
+
+do_stage() {
+	install -d ${STAGE_TEMP}
+	oe_runmake install INSTALLROOT="${STAGE_TEMP}"
+
+	install -d ${STAGING_BINDIR}
+	install -m 755 ${STAGE_TEMP}/${bindir}/syslinux ${STAGING_BINDIR}
+	install -m 755 ${STAGE_TEMP}/${base_sbindir}/extlinux ${STAGING_BINDIR}
+
+	install -d ${STAGING_DATADIR}/syslinux
+	install -m 0644 ${STAGE_TEMP}/${datadir}/syslinux/isolinux.bin ${STAGING_DATADIR}/syslinux/isolinux.bin
+	install -m 0644 ${STAGE_TEMP}/${datadir}/syslinux/mbr.bin ${STAGING_DATADIR}/syslinux/mbr.bin
+	install -m 0644 ${S}/core/ldlinux.sys ${STAGING_DATADIR}/syslinux/ldlinux.sys
+	install -m 0644 ${S}/core/ldlinux.bss ${STAGING_DATADIR}/syslinux/ldlinux.bss
+}
diff --git a/recipes/syslinux/syslinux_3.63.bb b/recipes/syslinux/syslinux_3.63.bb
deleted file mode 100644
index 95fb557..0000000
--- a/recipes/syslinux/syslinux_3.63.bb
+++ /dev/null
@@ -1,32 +0,0 @@
-# syslinux OE build file
-# Copyright (C) 2009, O.S. Systems Software Ltda.  All Rights Reserved
-# Released under the MIT license (see packages/COPYING)
-
-DESCRIPTION="A multi-purpose linux bootloader"
-HOMEPAGE="http://syslinux.zytor.com/"
-LICENSE="GPL"
-DEPENDS="nasm-native"
-RDEPENDS="mtools"
-PR="r2"
-
-SRC_URI = "${KERNELORG_MIRROR}/pub/linux/utils/boot/syslinux/syslinux-${PV}.tar.bz2 "
-
-S="${WORKDIR}/syslinux-${PV}"
-
-inherit autotools
-
-do_configure_prepend() {
-	# drop win32 targets or build fails
-	sed -i 's,win32/\S*,,g' -i Makefile
-}
-
-do_compile() {
-	oe_runmake CC="${CC}"
-}
-
-do_install() {
-	oe_runmake install INSTALLROOT="${D}"
-
-	# we don't use com32, drop it
-	rm -r "${D}/${libdir}/syslinux/com32"
-}
diff --git a/recipes/syslinux/syslinux_3.82.bb b/recipes/syslinux/syslinux_3.82.bb
new file mode 100644
index 0000000..4c4102e
--- /dev/null
+++ b/recipes/syslinux/syslinux_3.82.bb
@@ -0,0 +1,41 @@
+# syslinux OE build file
+# Copyright (C) 2009, O.S. Systems Software Ltda.  All Rights Reserved
+# Released under the MIT license (see packages/COPYING)
+
+DESCRIPTION = "A multi-purpose linux bootloader"
+HOMEPAGE = "http://syslinux.zytor.com/"
+LICENSE = "GPL"
+DEPENDS = "nasm-native"
+RRECOMMENDS_${PN} = "mtools"
+PR = "r0"
+
+SRC_URI = "${KERNELORG_MIRROR}/pub/linux/utils/boot/syslinux/syslinux-${PV}.tar.bz2 "
+
+EXTRA_OEMAKE = " \
+	BINDIR=${bindir} SBINDIR=${base_sbindir} LIBDIR=${libdir} \
+	DATADIR=${datadir} MANDIR=${mandir} INCDIR=${includedir} \
+"
+
+do_configure() {
+	# drop win32 targets or build fails
+	sed -e 's,win32/\S*,,g' -i Makefile
+
+	# clean installer executables included in source tarball
+	oe_runmake clean
+}
+
+do_compile() {
+	# Rebuild only the installer; keep precompiled bootloaders
+	# as per author's request (doc/distrib.txt)
+	oe_runmake CC="${CC}" installer
+}
+
+do_install() {
+	oe_runmake install INSTALLROOT="${D}"
+}
+
+PACKAGES =+ "${PN}-extlinux ${PN}-mbr"
+FILES_${PN} = "${bindir}/syslinux"
+FILES_${PN}-extlinux = "${base_sbindir}/extlinux"
+FILES_${PN}-mbr = "${datadir}/${PN}/mbr.bin"
+FILES_${PN}-dev += "${datadir}/${PN}/com32"
-- 
1.6.3

Re: [PATCH 3/3] syslinux: upgrade to 3.82 and split into a few packages

[Holger Hans Peter Freyther]

On Monday 17 August 2009 15:29:03 Michael Smith wrote:
> 3.63 is no longer available.
>
> Signed-off-by: Michael Smith <msmith@cbnco.com>

Haha, this might sound weird... Could you write a section for our usermanual 
on how to use syslinux?

z.

Re: [PATCH 3/3] syslinux: upgrade to 3.82 and split into a few packages

[Michael Smith]

Holger Hans Peter Freyther wrote:
> On Monday 17 August 2009 15:29:03 Michael Smith wrote:
>> 3.63 is no longer available.

> Haha, this might sound weird... Could you write a section for our usermanual 
> on how to use syslinux?

Sure, I can take a look at that later. I'm really only using extlinux 
for USB sticks; for everything else I still like GRUB best.

Mike

Re: [PATCH 3/3] syslinux: upgrade to 3.82 and split into a few packages

[Roman I Khimov]

В сообщении от Понедельник 17 августа 2009 19:35:41 автор Michael Smith написал:
> Sure, I can take a look at that later. I'm really only using extlinux
> for USB sticks; for everything else I still like GRUB best.

You can also do bootable USB drive images with GRUB (not GRUB2, unfortunately)
with something like this added to standard ext2 image for drive FS:

============================
HDDIMG = "${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.img"
IMAGE_POSTPROCESS_COMMAND = " \
        dd if=/dev/zero of=${HDDIMG} bs=512 count=63; \
        dd if="${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.ext2" of=${HDDIMG} bs=512 seek=63; \
        head -c 8388608 /dev/zero >> ${HDDIMG}; \
        cat ${WORKDIR}/sfdisk.one_partition | /sbin/sfdisk ${HDDIMG}; \
        echo -e "device (hd0) ${HDDIMG} \n root (hd0,0) \n setup (hd0)" | qemu-i386 ${IMAGE_ROOTFS}/usr/sbin/grub --device-map=/dev/null --batch ; \
        rm "${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.ext2" "${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2"; \
        "
============================

where "sfdisk.one_partition" is

==========================
# partition table of test
unit: sectors

    test1 : start=       63, size=         , Id=83
    test2 : start=        0, size=        0, Id= 0
    test3 : start=        0, size=        0, Id= 0
    test4 : start=        0, size=        0, Id= 0
==========================

A bit hacky-whacky may be, but works good here for USB installer images.

Re: [PATCH 3/3] syslinux: upgrade to 3.82 and split into a few packages

[Michael Smith]

Roman I Khimov wrote:
> В сообщении от Понедельник 17 августа 2009 19:35:41 автор Michael Smith написал:

> You can also do bootable USB drive images with GRUB (not GRUB2, unfortunately)
> with something like this added to standard ext2 image for drive FS:

I've been running into some odd behaviour with GRUB and a lot of newer 
(read: cheaper) USB sticks on HP servers. For some reason GRUB can only 
access some tiny portion of the device (e.g. first 100 MB out of 2000).

That alone probably wouldn't have stopped me (SanDisk Cruzers always 
work :) but it's not really possible to build GRUB for x86_64, and GRUB2 
will only build with a fight.

extlinux definitely lacks all the command-line troubleshooting features 
that make me like GRUB... but so far it hasn't needed any 
troubleshooting, it just works :)

Mike

Re: [PATCH 3/3] syslinux: upgrade to 3.82 and split into a few packages

[Roman I Khimov]

В сообщении от Понедельник 17 августа 2009 22:45:40 автор Michael Smith 
написал:
> Roman I Khimov wrote:
> > В сообщении от Понедельник 17 августа 2009 19:35:41 автор Michael Smith
> > написал:
> >
> > You can also do bootable USB drive images with GRUB (not GRUB2,
> > unfortunately) with something like this added to standard ext2 image for
> > drive FS:
>
> .....
> That alone probably wouldn't have stopped me (SanDisk Cruzers always
> work :) but it's not really possible to build GRUB for x86_64, and GRUB2
> will only build with a fight.

Well, for x86_64 we build GRUB like this:

========
LDFLAGS += "-static"
CFLAGS += "${CFLAGS_MULTILIB}"
========

where

==========
CFLAGS_MULTILIB = "-march=i686 -m32"
==========

Re: x86_64 multilib

[Michael Smith]

Roman I Khimov wrote:
> Well, for x86_64 we build GRUB like this:
> 
> ========
> LDFLAGS += "-static"
> CFLAGS += "${CFLAGS_MULTILIB}"
> ========
> 
> where
> 
> ==========
> CFLAGS_MULTILIB = "-march=i686 -m32"
> ==========

Hi Roman,

I had to build my gcc-cross with --disable-multilib because my glibc is 
not multilib. In April you posted a patch series to add multilib support 
for x86_64, but I'm not sure how much of it made it into the tree:

http://thread.gmane.org/gmane.comp.handhelds.openembedded/22737

Are you still using that patchset to get working gcc -m32?

Thanks,
Mike

Re: x86_64 multilib

[Roman I Khimov]

В сообщении от Вторник 18 августа 2009 22:15:58 автор Michael Smith написал:
> Roman I Khimov wrote:
> I had to build my gcc-cross with --disable-multilib because my glibc is
> not multilib. In April you posted a patch series to add multilib support
> for x86_64, but I'm not sure how much of it made it into the tree:
> 
> http://thread.gmane.org/gmane.comp.handhelds.openembedded/22737

Just the binutils patch, as far as I remember.

> Are you still using that patchset to get working gcc -m32?

Evolved a bit, but most of it should be correct.

OK, I've rebased what I'd had in OE branch and if I've not messed up something 
it should be currently in "rik/amd64" branch. Will check if there is anything 
interesting left in overlay of x86_64 project which from this patchset 
originated (project itself was released in May and almost not touched since, 
so I had little incentive to continue pushing this changes, unfortunately). 

Feel free to try/test/enhance with new glibc/gcc versions/corrections, etc. 
I'll probably try to add some new glibc versions on weekend, if time permits. 
I think the first 4 patches are ready for review/push (although need to test 
after rebase), and others mostly need porting to other versions.

Re: [PATCH 3/3] syslinux: upgrade to 3.82 and split into a fewPackages

[marcin]

Dnia Mon, 17 Aug 2009 16:12:13 +0200 napisano:

> Haha, this might sound weird... Could you
> write a section for our usermanual 
> on how to use syslinux?

Check classes/bootimg.bbclass for code. It was imported from Poky some time ago.

Re: [PATCH 2/3] mtools: don't install-info; fixes build on non-Debian hosts

[Holger Hans Peter Freyther]

On Monday 17 August 2009 15:29:02 Michael Smith wrote:
> The install-info installed into staging by dpkg-native looks for
> /var/backups/infodir.bak and /usr/share/base-files/info.dir on
> the build system. On Debian/Ubuntu this is benign, but on other
> distros these files don't exist and the install fails.
>
> The info file is still installed, we just don't try to rebuild the
> nonexistent directory.
>
> There are cleaner ways to solve this in the long run:
>
> http://dev.openbossa.org/trac/mamona/ticket/139
>
> Signed-off-by: Michael Smith <msmith@cbnco.com>


Signed-off-by: Holger Freyther <zecke@selfish.org>

again, no need to bump the PR.



> ---
>  recipes/mtools/mtools_4.0.10.bb |    5 ++++-
>  1 files changed, 4 insertions(+), 1 deletions(-)
>
> diff --git a/recipes/mtools/mtools_4.0.10.bb
> b/recipes/mtools/mtools_4.0.10.bb index b53306a..18fbb7d 100644
> --- a/recipes/mtools/mtools_4.0.10.bb
> +++ b/recipes/mtools/mtools_4.0.10.bb
> @@ -13,12 +13,15 @@
> SRC_URI="http://ftp.gnu.org/gnu/mtools/mtools-${PV}.tar.bz2 \
> file://plainio.patch;patch=1 \
>  	file://use-sg_io.patch;patch=1"
>
> -S = "${WORKDIR}/mtools-${PV}"
> +PR = "r1"
>
>  inherit autotools
>
>  EXTRA_OECONF = "--without-x"
>
> +# Don't try to run install-info -- it'll fail on non-Debian build systems.
> +EXTRA_OEMAKE = "INSTALL_INFO="
> +
>  do_fix_perms() {
>  	chmod 644 ${S}/*.c ${S}/*.h
>  }

Re: [PATCH 2/3] mtools: don't install-info; fixes build on non-Debian hosts

[Otavio Salvador]

Hello Holger,

On Mon, Aug 17, 2009 at 11:11 AM, Holger Hans Peter
Freyther<holger+oe@freyther.de> wrote:
> again, no need to bump the PR.

I completely disagree with changes landing without PR bump.

Not bumping them can cause a change, that breaks something, to not be
noticed for long time.

In my opinion we ought to _always_ bump PR when changing the recipe.
This ensure it is widely tested and deployed.

-- 
Otavio Salvador                  O.S. Systems
E-mail: otavio@ossystems.com.br  http://www.ossystems.com.br
Mobile: +55 53 9981-7854         http://projetos.ossystems.com.br

Re: [PATCH 2/3] mtools: don't install-info; fixes build on non-Debian hosts

[Koen Kooi]

On 18-08-09 11:02, Otavio Salvador wrote:
> Hello Holger,
>
> On Mon, Aug 17, 2009 at 11:11 AM, Holger Hans Peter
> Freyther<holger+oe@freyther.de>  wrote:
>> again, no need to bump the PR.
>
> I completely disagree with changes landing without PR bump.
>
> Not bumping them can cause a change, that breaks something, to not be
> noticed for long time.
>
> In my opinion we ought to _always_ bump PR when changing the recipe.
> This ensure it is widely tested and deployed.

It also makes it easier to spot patterns in tinderbox.

regards,

Koen

Re: [PATCH 2/3] mtools: don't install-info; fixes build on non-Debian hosts

[Michael Smith]

Otavio Salvador wrote:

> Not bumping them can cause a change, that breaks something, to not be
> noticed for long time.
> 
> In my opinion we ought to _always_ bump PR when changing the recipe.
> This ensure it is widely tested and deployed.

OK, I think that's 2 for bumping PR and 1 for not, so I will bump it. I 
guess there is a website called youtube now, you can go watch it while 
glibc recompiles itself. :P

Mike

Re: [PATCH 1/3] nasm: fix COMPATIBLE_HOST to match any vendor

[Holger Hans Peter Freyther]

On Monday 17 August 2009 15:29:01 Michael Smith wrote:
> On x86_64, it was looking for x86_64-linux, not x86_64-blah-linux;
> it broke the build for syslinux if a BUILD_VENDOR was set.
>
> Signed-off-by: Michael Smith <msmith@cbnco.com>
> ---
>  recipes/nasm/nasm_0.98.38.bb |    3 ++-
>  1 files changed, 2 insertions(+), 1 deletions(-)
>
> diff --git a/recipes/nasm/nasm_0.98.38.bb b/recipes/nasm/nasm_0.98.38.bb
> index 86e7f2b..abe47fe 100644
> --- a/recipes/nasm/nasm_0.98.38.bb
> +++ b/recipes/nasm/nasm_0.98.38.bb
> @@ -1,7 +1,8 @@
>  DESCRIPTION = "General-purpose x86 assembler"
>  SECTION = "devel"
>  LICENSE = "GPL"
> -COMPATIBLE_HOST = '(x86_64|i.86.*)-(linux|freebsd.*)'
> +COMPATIBLE_HOST = '(x86_64|i.86).*-(linux|freebsd.*)'
> +PR = "r1"

Signed-off-by: Holger Hans Peter Freyther <zecke@selfish.org>

No need to bump the PR here. Whoever is landing it, please remove.