libnetfilter_queue: build system cleanups

libnetfilter_queue: build system cleanups

[Jan Engelhardt]

The following changes since commit 9ae213ed891556bde865b81b959e76c36461bc9e:

  nfq: fix redundant LIBVERSION definition (2010-07-15 11:12:30 +0200)

are available in the git repository at:
  git://dev.medozas.de/libnetfilter_queue master

Jan Engelhardt (10):
      build: build: use autoconf-suggested naming of files
      build: use modern call syntax for AC_INIT, AM_INIT_AUTOMAKE
      build: avoid use of deprecated INCLUDES
      build: use simpler autoreconf in autogen
      build: run AC_CANONICAL_HOST only
      build: no need for error message in PKG_CHECK_MODULES
      build: set Libs.private for pkgconfig file
      build: remove statements without effect
      build: remove -fPIC flag
      Update .gitignore

 .gitignore                   |   33 ++++++++++++++++++---------------
 Makefile.am                  |    6 ------
 autogen.sh                   |   20 +++-----------------
 configure.in => configure.ac |   18 +++++-------------
 libnetfilter_queue.pc.in     |    1 +
 src/Makefile.am              |    6 +++---
 utils/.gitignore             |    1 +
 utils/Makefile.am            |    2 +-
 8 files changed, 32 insertions(+), 55 deletions(-)
 rename configure.in => configure.ac (52%)
 create mode 100644 utils/.gitignore

[PATCH 01/10] build: build: use autoconf-suggested naming of files

[Jan Engelhardt]

Signed-off-by: Jan Engelhardt <jengelh@medozas.de>
---
 configure.ac |   33 +++++++++++++++++++++++++++++++++
 configure.in |   33 ---------------------------------
 2 files changed, 33 insertions(+), 33 deletions(-)
 create mode 100644 configure.ac
 delete mode 100644 configure.in

diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..a82c9f1
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,33 @@
+dnl Process this file with autoconf to create configure.
+
+AC_INIT
+AC_CANONICAL_SYSTEM
+AC_CONFIG_MACRO_DIR([m4])
+
+AM_INIT_AUTOMAKE(libnetfilter_queue, 1.0.0)
+
+AC_PROG_CC
+AC_EXEEXT
+AM_PROG_LIBTOOL
+AC_PROG_INSTALL
+
+AC_SUBST(LIBTOOL_DEPS)
+
+case $target in 
+*-*-linux*) ;;
+*) AC_MSG_ERROR([Linux only, dude!]);;
+esac
+
+dnl Dependencies
+LIBNFNETLINK_REQUIRED=0.0.41
+ 
+PKG_CHECK_MODULES(LIBNFNETLINK, libnfnetlink >= $LIBNFNETLINK_REQUIRED,,
+	AC_MSG_ERROR(Cannot find libnfnetlink >= $LIBNFNETLINK_REQUIRED))
+ 
+CFLAGS="$CFLAGS $LIBNFNETLINK_CFLAGS"
+LIBNFQUEUE_LIBS="$LIBNFNETLINK_LIBS"
+ 
+AC_SUBST(LIBNFQUEUE_LIBS)
+
+dnl Output the makefiles
+AC_OUTPUT(Makefile include/Makefile include/libnetfilter_queue/Makefile src/Makefile utils/Makefile libnetfilter_queue.pc doxygen.cfg)
diff --git a/configure.in b/configure.in
deleted file mode 100644
index a82c9f1..0000000
--- a/configure.in
+++ /dev/null
@@ -1,33 +0,0 @@
-dnl Process this file with autoconf to create configure.
-
-AC_INIT
-AC_CANONICAL_SYSTEM
-AC_CONFIG_MACRO_DIR([m4])
-
-AM_INIT_AUTOMAKE(libnetfilter_queue, 1.0.0)
-
-AC_PROG_CC
-AC_EXEEXT
-AM_PROG_LIBTOOL
-AC_PROG_INSTALL
-
-AC_SUBST(LIBTOOL_DEPS)
-
-case $target in 
-*-*-linux*) ;;
-*) AC_MSG_ERROR([Linux only, dude!]);;
-esac
-
-dnl Dependencies
-LIBNFNETLINK_REQUIRED=0.0.41
- 
-PKG_CHECK_MODULES(LIBNFNETLINK, libnfnetlink >= $LIBNFNETLINK_REQUIRED,,
-	AC_MSG_ERROR(Cannot find libnfnetlink >= $LIBNFNETLINK_REQUIRED))
- 
-CFLAGS="$CFLAGS $LIBNFNETLINK_CFLAGS"
-LIBNFQUEUE_LIBS="$LIBNFNETLINK_LIBS"
- 
-AC_SUBST(LIBNFQUEUE_LIBS)
-
-dnl Output the makefiles
-AC_OUTPUT(Makefile include/Makefile include/libnetfilter_queue/Makefile src/Makefile utils/Makefile libnetfilter_queue.pc doxygen.cfg)
-- 
1.7.1

[PATCH 02/10] build: use modern call syntax for AC_INIT, AM_INIT_AUTOMAKE

[Jan Engelhardt]

automake options also need to definitely go into configure.ac, otherwise
they only apply to a single directory.

Signed-off-by: Jan Engelhardt <jengelh@medozas.de>
---
 Makefile.am  |    2 --
 configure.ac |    4 ++--
 2 files changed, 2 insertions(+), 4 deletions(-)

diff --git a/Makefile.am b/Makefile.am
index 28641f8..b4e604b 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -1,5 +1,3 @@
-AUTOMAKE_OPTIONS = foreign dist-bzip2 1.6
-
 ACLOCAL_AMFLAGS = -I m4
 
 EXTRA_DIST = $(man_MANS) 
diff --git a/configure.ac b/configure.ac
index a82c9f1..3bd3e1c 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1,10 +1,10 @@
 dnl Process this file with autoconf to create configure.
 
-AC_INIT
+AC_INIT([libnetfilter_queue], [1.0.0])
 AC_CANONICAL_SYSTEM
 AC_CONFIG_MACRO_DIR([m4])
 
-AM_INIT_AUTOMAKE(libnetfilter_queue, 1.0.0)
+AM_INIT_AUTOMAKE([-Wall foreign subdir-objects dist-bzip2 1.6])
 
 AC_PROG_CC
 AC_EXEEXT
-- 
1.7.1

[PATCH 03/10] build: avoid use of deprecated INCLUDES

[Jan Engelhardt]

Makefile.am: "INCLUDES" is the old name for "AM_CPPFLAGS" (or "*_CPPFLAGS")

And remove unused $(all_includes)

Signed-off-by: Jan Engelhardt <jengelh@medozas.de>
---
 src/Makefile.am   |    2 +-
 utils/Makefile.am |    2 +-
 2 files changed, 2 insertions(+), 2 deletions(-)

diff --git a/src/Makefile.am b/src/Makefile.am
index 63d5bc8..c408961 100644
--- a/src/Makefile.am
+++ b/src/Makefile.am
@@ -20,7 +20,7 @@
 #
 LIBVERSION=2:0:1
 
-INCLUDES = $(all_includes) -I$(top_srcdir)/include -I${KERNELDIR}
+AM_CPPFLAGS = -I$(top_srcdir)/include -I${KERNELDIR}
 AM_CFLAGS = -fPIC -Wall
 LIBS = @LIBNFQUEUE_LIBS@
 
diff --git a/utils/Makefile.am b/utils/Makefile.am
index 9a5e9d6..1f52864 100644
--- a/utils/Makefile.am
+++ b/utils/Makefile.am
@@ -1,5 +1,5 @@
 
-INCLUDES = $(all_includes) -I$(top_srcdir)/include -I${KERNELDIR} 
+AM_CPPFLAGS = -I$(top_srcdir)/include -I${KERNELDIR}
 
 check_PROGRAMS = nfqnl_test
 
-- 
1.7.1

[PATCH 04/10] build: use simpler autoreconf in autogen

[Jan Engelhardt]

Note: the use of -i seems required, otherwise autoreconf barfs about
missing tools (depcomp, etc.). Since they are provided in the tarballs
as files anyway rather than like previously as symlinks, I do not see
a problem using -i.

Signed-off-by: Jan Engelhardt <jengelh@medozas.de>
---
 autogen.sh |   20 +++-----------------
 1 files changed, 3 insertions(+), 17 deletions(-)

diff --git a/autogen.sh b/autogen.sh
index cf697c6..57c3532 100755
--- a/autogen.sh
+++ b/autogen.sh
@@ -1,4 +1,4 @@
-#!/bin/sh
+#!/bin/sh -e
 
 include ()
 {
@@ -34,20 +34,6 @@ include ()
     fi
 }
 
-run ()
-{
-    echo "running: $*"
-    eval $*
-
-    if test $? != 0 ; then
-	echo "error: while running '$*'"
-	exit 1
-    fi
-}
-
 [ "x$1" = "xdistrib" ] && include
-run libtoolize
-run aclocal
-#run autoheader
-run automake -a
-run autoconf
+autoreconf -fi
+rm -Rf autom4te.cache
-- 
1.7.1

[PATCH 05/10] build: run AC_CANONICAL_HOST only

[Jan Engelhardt]

There is no need to call AC_CANONICAL_SYSTEM when only
AC_CANONICAL_HOST is needed. Also, checking for $target is factually
incorrect, since we do not produce object code like a compiler. Use
$host, which specifies the triple/quadrople where the compiled program
is supposed to run.

Signed-off-by: Jan Engelhardt <jengelh@medozas.de>
---
 configure.ac |    4 ++--
 1 files changed, 2 insertions(+), 2 deletions(-)

diff --git a/configure.ac b/configure.ac
index 3bd3e1c..7c3468b 100644
--- a/configure.ac
+++ b/configure.ac
@@ -1,7 +1,7 @@
 dnl Process this file with autoconf to create configure.
 
 AC_INIT([libnetfilter_queue], [1.0.0])
-AC_CANONICAL_SYSTEM
+AC_CANONICAL_HOST
 AC_CONFIG_MACRO_DIR([m4])
 
 AM_INIT_AUTOMAKE([-Wall foreign subdir-objects dist-bzip2 1.6])
@@ -13,7 +13,7 @@ AC_PROG_INSTALL
 
 AC_SUBST(LIBTOOL_DEPS)
 
-case $target in 
+case "$host" in
 *-*-linux*) ;;
 *) AC_MSG_ERROR([Linux only, dude!]);;
 esac
-- 
1.7.1

[PATCH 06/10] build: no need for error message in PKG_CHECK_MODULES

[Jan Engelhardt]

PKG_CHECK_MODULES already produces its own (and more verbose) messsage
when a module cannot be found.

Mucking around with CFLAGS and LIBS is also not needed since pkgconfig
takes care of providing variables, so let's use them in Makefile.am.

Signed-off-by: Jan Engelhardt <jengelh@medozas.de>
---
 configure.ac    |   10 +---------
 src/Makefile.am |    4 ++--
 2 files changed, 3 insertions(+), 11 deletions(-)

diff --git a/configure.ac b/configure.ac
index 7c3468b..c4cc36e 100644
--- a/configure.ac
+++ b/configure.ac
@@ -19,15 +19,7 @@ case "$host" in
 esac
 
 dnl Dependencies
-LIBNFNETLINK_REQUIRED=0.0.41
- 
-PKG_CHECK_MODULES(LIBNFNETLINK, libnfnetlink >= $LIBNFNETLINK_REQUIRED,,
-	AC_MSG_ERROR(Cannot find libnfnetlink >= $LIBNFNETLINK_REQUIRED))
- 
-CFLAGS="$CFLAGS $LIBNFNETLINK_CFLAGS"
-LIBNFQUEUE_LIBS="$LIBNFNETLINK_LIBS"
- 
-AC_SUBST(LIBNFQUEUE_LIBS)
+PKG_CHECK_MODULES([LIBNFNETLINK], [libnfnetlink >= 0.0.41])
 
 dnl Output the makefiles
 AC_OUTPUT(Makefile include/Makefile include/libnetfilter_queue/Makefile src/Makefile utils/Makefile libnetfilter_queue.pc doxygen.cfg)
diff --git a/src/Makefile.am b/src/Makefile.am
index c408961..aa1f5ba 100644
--- a/src/Makefile.am
+++ b/src/Makefile.am
@@ -21,11 +21,11 @@
 LIBVERSION=2:0:1
 
 AM_CPPFLAGS = -I$(top_srcdir)/include -I${KERNELDIR}
-AM_CFLAGS = -fPIC -Wall
-LIBS = @LIBNFQUEUE_LIBS@
+AM_CFLAGS = -fPIC -Wall ${LIBNFNETLINK_CFLAGS}
 
 lib_LTLIBRARIES = libnetfilter_queue.la
 
 libnetfilter_queue_la_LDFLAGS = -Wc,-nostartfiles -lnfnetlink \
 				-version-info $(LIBVERSION)
 libnetfilter_queue_la_SOURCES = libnetfilter_queue.c 
+libnetfilter_queue_la_LIBADD  = ${LIBNFNETLINK_LIBS}
-- 
1.7.1

[PATCH 07/10] build: set Libs.private for pkgconfig file

[Jan Engelhardt]

Similar to the commit in iptables, add Libs.private to tell about
dependencies for static linking.

Signed-off-by: Jan Engelhardt <jengelh@medozas.de>
---
 libnetfilter_queue.pc.in |    1 +
 1 files changed, 1 insertions(+), 0 deletions(-)

diff --git a/libnetfilter_queue.pc.in b/libnetfilter_queue.pc.in
index 962c686..9c6c2c4 100644
--- a/libnetfilter_queue.pc.in
+++ b/libnetfilter_queue.pc.in
@@ -12,4 +12,5 @@ Version: @VERSION@
 Requires: libnfnetlink
 Conflicts:
 Libs: -L${libdir} -lnetfilter_queue
+Libs.private: @LIBNFNETLINK_LIBS@
 Cflags: -I${includedir}
-- 
1.7.1

[PATCH 08/10] build: remove statements without effect

[Jan Engelhardt]

Signed-off-by: Jan Engelhardt <jengelh@medozas.de>
---
 Makefile.am |    4 ----
 1 files changed, 0 insertions(+), 4 deletions(-)

diff --git a/Makefile.am b/Makefile.am
index b4e604b..576a69b 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -8,7 +8,3 @@ man_MANS = #nfnetlink_queue.3 nfnetlink_queue.7
 
 pkgconfigdir = $(libdir)/pkgconfig
 pkgconfig_DATA = libnetfilter_queue.pc
-
-$(OBJECTS): libtool
-libtool: $(LIBTOOL_DEPS)
-	$(SHELL) ./config.status --recheck
-- 
1.7.1

[PATCH 09/10] build: remove -fPIC flag

[Jan Engelhardt]

libtool automatically adds PIC flags as needed.

Signed-off-by: Jan Engelhardt <jengelh@medozas.de>
---
 src/Makefile.am |    2 +-
 1 files changed, 1 insertions(+), 1 deletions(-)

diff --git a/src/Makefile.am b/src/Makefile.am
index aa1f5ba..a745129 100644
--- a/src/Makefile.am
+++ b/src/Makefile.am
@@ -21,7 +21,7 @@
 LIBVERSION=2:0:1
 
 AM_CPPFLAGS = -I$(top_srcdir)/include -I${KERNELDIR}
-AM_CFLAGS = -fPIC -Wall ${LIBNFNETLINK_CFLAGS}
+AM_CFLAGS = -Wall ${LIBNFNETLINK_CFLAGS}
 
 lib_LTLIBRARIES = libnetfilter_queue.la
 
-- 
1.7.1

[PATCH 10/10] Update .gitignore

[Jan Engelhardt]

Signed-off-by: Jan Engelhardt <jengelh@medozas.de>
---
 .gitignore       |   33 ++++++++++++++++++---------------
 utils/.gitignore |    1 +
 2 files changed, 19 insertions(+), 15 deletions(-)
 create mode 100644 utils/.gitignore

diff --git a/.gitignore b/.gitignore
index 99e943d..dbd9ac7 100644
--- a/.gitignore
+++ b/.gitignore
@@ -1,17 +1,20 @@
-doxygen.cfg
-doxygen
+.deps
+.libs
+Makefile
+Makefile.in
+*.o
+*.la
+*.lo
 
-config.guess
-config.log
-config.sub
-config.status
-configure
-autom4te.cache
-libtool
-ltmain.sh
-missing
-install-sh
-depcomp
-aclocal.m4
+/aclocal.m4
+/autom4te.cache
+/config.*
+/configure
+/depcomp
+/install-sh
+/libtool
+/ltmain.sh
+/missing
 
-libnetfilter_queue.pc
+/doxygen.cfg
+/libnetfilter_queue.pc
diff --git a/utils/.gitignore b/utils/.gitignore
new file mode 100644
index 0000000..10fe6e9
--- /dev/null
+++ b/utils/.gitignore
@@ -0,0 +1 @@
+/nfqnl_test
-- 
1.7.1

Re: libnetfilter_queue: build system cleanups

[Pablo Neira Ayuso]

On 31/10/10 00:11, Jan Engelhardt wrote:
>   git://dev.medozas.de/libnetfilter_queue master

pulled and pushed, thanks Jan.