[PATCH] pstree: added receipt pstree: added shorewall: updated to 4.2-shell and 4.4-perl versions

[PATCH] pstree: added receipt pstree: added shorewall: updated to 4.2-shell and 4.4-perl versions

[Dvorkin Dmitry]

Signed-off-by: Dvorkin Dmitry <dvorkin@tibbo.com>
---
 recipes/pstree/pstree.inc                   |   17 +++++++++++++++++
 recipes/pstree/pstree_2.33.bb               |    8 ++++++++
 recipes/shorewall/shorewall-deps.inc        |   20 ++++++++++++++++++++
 recipes/shorewall/shorewall-shell_4.2.11.bb |   14 ++++++++++++++
 recipes/shorewall/shorewall.inc             |   17 +++++++++++++++++
 recipes/shorewall/shorewall_4.4.14.bb       |   12 ++++++++++++
 6 files changed, 88 insertions(+), 0 deletions(-)
 create mode 100644 recipes/pstree/pstree.inc
 create mode 100644 recipes/pstree/pstree_2.33.bb
 create mode 100644 recipes/shorewall/shorewall-deps.inc
 create mode 100644 recipes/shorewall/shorewall-shell_4.2.11.bb
 create mode 100644 recipes/shorewall/shorewall.inc
 create mode 100644 recipes/shorewall/shorewall_4.4.14.bb

diff --git a/recipes/pstree/pstree.inc b/recipes/pstree/pstree.inc
new file mode 100644
index 0000000..fdee863
--- /dev/null
+++ b/recipes/pstree/pstree.inc
@@ -0,0 +1,17 @@
+AUTHOR = "Dvorkin Dmitry dvorkin@tibbo.com"
+SECTION = "base"
+DESCRIPTION = "pstree cli tool to nicely show processes tree"
+LICENSE = "GPL"
+DEPENDS = "libnl"
+PR = "r0"
+
+S = "${WORKDIR}"
+
+do_compile() {
+  ${CC} -O ${CFLAGS} ${LDFLAGS} -o pstree pstree.c
+}
+
+do_install() {
+  install -d ${D}/bin/
+  install -m 0755 pstree ${D}/bin/
+}
diff --git a/recipes/pstree/pstree_2.33.bb b/recipes/pstree/pstree_2.33.bb
new file mode 100644
index 0000000..b94e002
--- /dev/null
+++ b/recipes/pstree/pstree_2.33.bb
@@ -0,0 +1,8 @@
+require pstree.inc
+
+SRC_URI = "\
+  ftp://ftp.thp.uni-duisburg.de/pub/source/${PN}-${PV}.tar.gz \
+"
+
+SRC_URI[md5sum] = "b0a85caacd85f78bd83700afa86ec2e9"
+SRC_URI[sha256sum] = "0f06116208cf15932cf99785d001c053e523e0aed474b936858f1b7f61a6c990"
diff --git a/recipes/shorewall/shorewall-deps.inc b/recipes/shorewall/shorewall-deps.inc
new file mode 100644
index 0000000..5ad98f0
--- /dev/null
+++ b/recipes/shorewall/shorewall-deps.inc
@@ -0,0 +1,20 @@
+
+# version 4.4.x requires perl + some perl modules
+RDEPENDS_${PN} += "\
+    perl \
+    perl-module-lib \
+    perl-module-autouse \
+    perl-module-cwd \
+    perl-module-file-basename \
+    perl-module-file-temp \
+    perl-module-getopt-long \
+    perl-module-carp \
+    perl-module-findbin \
+    perl-module-file-spec-unix \
+    perl-module-scalar-util \
+    perl-module-io \
+    perl-module-io-handle \
+    perl-module-exporter-heavy \
+    perl-module-list-util \
+    perl-module-socket \
+"
diff --git a/recipes/shorewall/shorewall-shell_4.2.11.bb b/recipes/shorewall/shorewall-shell_4.2.11.bb
new file mode 100644
index 0000000..45cf2da
--- /dev/null
+++ b/recipes/shorewall/shorewall-shell_4.2.11.bb
@@ -0,0 +1,14 @@
+require shorewall.inc
+
+PR = "r0"
+
+# this version (4.2, legacy!) require only shell as parser
+
+SRC_URI = " \
+    http://www.shorewall.net/pub/shorewall/4.2/shorewall-${PV}/${PN}-${PV}.tar.bz2 \
+    "
+
+FILES_${PN} += "/usr/share/shorewall-shell/*"
+
+SRC_URI[md5sum] = "518a7f389a6f606c109acb7dfbe18372"
+SRC_URI[sha256sum] = "c85c8400015794b8fb191e519a0b8711028c865ca2b7e85099c7be26fe479e02"
diff --git a/recipes/shorewall/shorewall.inc b/recipes/shorewall/shorewall.inc
new file mode 100644
index 0000000..d48d195
--- /dev/null
+++ b/recipes/shorewall/shorewall.inc
@@ -0,0 +1,17 @@
+DESCRIPTION = "Shorewall is a high-level tool for configuring Netfilter."
+HOMEPAGE = "http://www.shorewall.net/"
+LICENSE = "GPLv2"
+SECTION = "network"
+PRIORITY = "optional"
+
+S = "${WORKDIR}/${PN}-${PV}"
+
+RDEPENDS_${PN} += "iptables"
+RRECOMMENDS_${PN} = "kernel-module-ip-tables kernel-module-ip-conntrack kernel-module-ipt-conntrack kernel-module-ipt-multiport kernel-module-ipt-log kernel-module-ipt-mac kernel-module-ipt-mark kernel-module-ipt-masquerade kernel-module-ipt-pkttype kernel-module-ipt-reject kernel-module-ipt-state kernel-module-ipt-tos kernel-module-iptable-filter kernel-module-iptable-mangle kernel-module-iptable-nat"
+
+do_install() {
+	export PREFIX=${D}
+	${WORKDIR}/${PN}-${PV}/install.sh
+}
+
+FILES_${PN} += "/usr/share/shorewall/*"
diff --git a/recipes/shorewall/shorewall_4.4.14.bb b/recipes/shorewall/shorewall_4.4.14.bb
new file mode 100644
index 0000000..98930b6
--- /dev/null
+++ b/recipes/shorewall/shorewall_4.4.14.bb
@@ -0,0 +1,12 @@
+require shorewall.inc
+# this version (4.4) requires some deps (perl)
+require shorewall-deps.inc
+
+PR = "r6"
+
+SRC_URI = " \
+    http://www.shorewall.net/pub/shorewall/4.4/shorewall-${PV}/${PN}-${PV}.tar.bz2 \
+    "
+
+SRC_URI[md5sum] = "9f8705d69d42eb949e352af72c3af8bb"
+SRC_URI[sha256sum] = "af097fc18c0d5a3b562812814107b627bfd3d802e3b5fe45fec4e53a4e84f17c"
-- 
1.6.4.4

Re: [PATCH] pstree: added receipt pstree: added shorewall: updated to 4.2-shell and 4.4-perl versions

[Michael Smith]

Hi Dmitry,

Dvorkin Dmitry wrote:
> Signed-off-by: Dvorkin Dmitry <dvorkin@tibbo.com>
> ---
>  recipes/pstree/pstree.inc                   |   17 +++++++++++++++++
>  recipes/pstree/pstree_2.33.bb               |    8 ++++++++
>  recipes/shorewall/shorewall-deps.inc        |   20 ++++++++++++++++++++
>  recipes/shorewall/shorewall-shell_4.2.11.bb |   14 ++++++++++++++
>  recipes/shorewall/shorewall.inc             |   17 +++++++++++++++++
>  recipes/shorewall/shorewall_4.4.14.bb       |   12 ++++++++++++

Please split the pstree and shorewall changes into two separate patches.

For pstree, there's no need for a .inc as likely only one version will 
be in the tree at a time.

For shorewall, please use INC_PR. e.g. set INC_PR = "r0" in 
shorewall.inc and set PR = "${INC_PR}.0" in the recipes which include it.

Thanks,
Mike