[PATCH] help2man: Add native recipe, drop check for being provided.

[PATCH] help2man: Add native recipe, drop check for being provided.

[Tom Rini]

With a recent change to auto* to not build the man pages for
native recipes, we can make build progress without help2man
being there already.  This adds help2man to local.conf.sample
as an example of something that is assumed to be provided,
drops the sanity.bbclass check and adds a help2man-native recipe.
In order to catch the cases where help2man is likely to have been
an implicit requirement before we add it to the list that
autotools brings in.

Signed-off-by: Tom Rini <tom_rini@mentor.com>
---
 classes/autotools.bbclass           |    4 ++--
 classes/sanity.bbclass              |    2 +-
 conf/local.conf.sample              |    4 ++++
 recipes/help2man/help2man_1.37.1.bb |   21 +++++++++++++++++++++
 4 files changed, 28 insertions(+), 3 deletions(-)
 create mode 100644 recipes/help2man/help2man_1.37.1.bb

diff --git a/classes/autotools.bbclass b/classes/autotools.bbclass
index 2c27d0f..94dec13 100644
--- a/classes/autotools.bbclass
+++ b/classes/autotools.bbclass
@@ -8,9 +8,9 @@ def autotools_deps(d):
 	pn = bb.data.getVar('PN', d, 1)
 	deps = ''
 
-	if pn in ['autoconf-native', 'automake-native']:
+	if pn in ['autoconf-native', 'automake-native', 'help2man-native']:
 		return deps
-	deps += 'autoconf-native automake-native '
+	deps += 'autoconf-native automake-native help2man-native'
 
 	if not pn in ['libtool', 'libtool-native', 'libtool-cross']:
 		deps += 'libtool-native '
diff --git a/classes/sanity.bbclass b/classes/sanity.bbclass
index 575530a..1e6b170 100644
--- a/classes/sanity.bbclass
+++ b/classes/sanity.bbclass
@@ -84,7 +84,7 @@ def check_sanity(e):
 	if not check_app_exists('${BUILD_PREFIX}g++', e.data):
 		missing = missing + "C++ Compiler (${BUILD_PREFIX}g++),"
 
-	required_utilities = "patch help2man diffstat texi2html makeinfo cvs svn bzip2 tar gzip gawk md5sum chrpath"
+	required_utilities = "patch diffstat texi2html makeinfo cvs svn bzip2 tar gzip gawk md5sum chrpath"
 
 	# If we'll be running qemu, perform some sanity checks
 	if data.getVar('ENABLE_BINARY_LOCALE_GENERATION', e.data, True):
diff --git a/conf/local.conf.sample b/conf/local.conf.sample
index c53c037..1085163 100644
--- a/conf/local.conf.sample
+++ b/conf/local.conf.sample
@@ -30,6 +30,10 @@ BBFILES := "${@bb.fatal('Edit your conf/local.conf: BBFILES')}"
 # This is a regulary expression, so be sure to get your parenthesis balanced.
 BBMASK = ""
 
+# Comment this if your host distribution does not provide the
+# help2man tool.
+ASSUME_PROVIDED += "help2man-native"
+
 # Uncomment this if your host distribution has recent enough Linux
 # Kernel header files.  Utilities we use to generate certain types of
 # target filesystems need somewhat recent header files.
diff --git a/recipes/help2man/help2man_1.37.1.bb b/recipes/help2man/help2man_1.37.1.bb
new file mode 100644
index 0000000..3a47aa1
--- /dev/null
+++ b/recipes/help2man/help2man_1.37.1.bb
@@ -0,0 +1,21 @@
+DESCRIPTION = "Program to create simple man pages"
+SECTION = "devel"
+LICENSE = "GPLv3"
+DEPENDS = "gettext-native perl-native liblocale-gettext-perl-native"
+DEPENDS_virtclass-native = ""
+RDEPENDS_pn-help2man = "gettext perl liblocale-gettext-perl"
+PR = "r0"
+
+SRC_URI = "${GNU_MIRROR}/help4man/help2man-${PV}.tar.gz"
+SRC_URI[md5sum] = "371b5cc74fe9c2ea3ee1ca23c19b19a8"
+SRC_URI[sha256sum] = "3b44a91ef8e722c570a2a2d0e3f1cd249aac25dd2b2692c7792d87b30ed61561"
+
+inherit autotools
+
+EXTRA_OECONF = "--disable-nls"
+
+BBCLASSEXTEND = "native"
+
+do_configure() {
+	oe_runconf
+}
-- 
1.7.0.4

Re: [PATCH] help2man: Add native recipe, drop check for being provided.

[Michael Smith]

On Wed, 17 Nov 2010, Tom Rini wrote:

> --- a/classes/autotools.bbclass
> +++ b/classes/autotools.bbclass
> -	deps += 'autoconf-native automake-native '
> +	deps += 'autoconf-native automake-native help2man-native'

Need a space before that closing quote.

> --- /dev/null
> +++ b/recipes/help2man/help2man_1.37.1.bb
> @@ -0,0 +1,21 @@
> +SRC_URI = "${GNU_MIRROR}/help4man/help2man-${PV}.tar.gz"

s/4/2/ :)

> +do_configure() {
> +	oe_runconf
> +}

Is this necessary? The old 1.36 recipe has it, too. Is it because auto* 
may not be built yet? Could you add a comment explaining why it's there?

I haven't tested from a clean build with help2man not installed, but I 
like the idea - help2man can be hard to track down for older systems 
sometimes.

Acked-by: Michael Smith <msmith@cbnco.com>

Mike

Re: [PATCH] help2man: Add native recipe, drop check for being provided.

[Tom Rini]

On 11/17/2010 07:02 PM, Michael Smith wrote:
> On Wed, 17 Nov 2010, Tom Rini wrote:
>
>> --- a/classes/autotools.bbclass
>> +++ b/classes/autotools.bbclass
>> -	deps += 'autoconf-native automake-native '
>> +	deps += 'autoconf-native automake-native help2man-native'
>
> Need a space before that closing quote.

Will go fix.

>
>> --- /dev/null
>> +++ b/recipes/help2man/help2man_1.37.1.bb
>> @@ -0,0 +1,21 @@
>> +SRC_URI = "${GNU_MIRROR}/help4man/help2man-${PV}.tar.gz"
>
> s/4/2/ :)
>
>> +do_configure() {
>> +	oe_runconf
>> +}
>
> Is this necessary? The old 1.36 recipe has it, too. Is it because auto*
> may not be built yet? Could you add a comment explaining why it's there?
>

The problem is that it gets mad about perl stuff not being around yet 
(since we use host perl here, like with automake/conf).  I'll add a 
comment as well.

-- 
Tom Rini
Mentor Graphics Corporation