All of lore.kernel.org
 help / color / mirror / Atom feed
* [PATCH] qt4-libs-native: add initial recipe
@ 2011-05-07 13:07 Simon Busch
  2011-05-07 19:17 ` Otavio Salvador
  0 siblings, 1 reply; 15+ messages in thread
From: Simon Busch @ 2011-05-07 13:07 UTC (permalink / raw)
  To: openembedded-devel

The native version of the qt4 libraries is needed by some other native recipes to build.
It's mostly a copy of the qt4-tools-native recipes with some changed configuration optons
and is only available for version 4.7.2 now.

Signed-off-by: Simon Busch <morphis@gravedo.de>
---
 recipes/qt4/qt4-libs-native.inc      |   67 ++++++++++++++++++++++++++++++++++
 recipes/qt4/qt4-libs-native_4.7.2.bb |   19 ++++++++++
 2 files changed, 86 insertions(+), 0 deletions(-)
 create mode 100644 recipes/qt4/qt4-libs-native.inc
 create mode 100644 recipes/qt4/qt4-libs-native_4.7.2.bb

diff --git a/recipes/qt4/qt4-libs-native.inc b/recipes/qt4/qt4-libs-native.inc
new file mode 100644
index 0000000..7d2116a
--- /dev/null
+++ b/recipes/qt4/qt4-libs-native.inc
@@ -0,0 +1,67 @@
+DESCRIPTION = "Native libraries for Qt/[X11|Mac|Embedded] version 4.x"
+DEPENDS = "zlib-native dbus-native"
+SECTION = "libs"
+HOMEPAGE = "http://www.trolltech.com"
+PRIORITY = "optional"
+LICENSE = "GPL"
+
+INC_PR = "r0"
+
+inherit native
+
+SRC_URI = "ftp://ftp.trolltech.com/qt/source/qt-everywhere-opensource-src-${PV}.tar.gz \
+           file://qt-config.patch \
+           file://g++.conf \
+           file://linux.conf"
+S = "${WORKDIR}/qt-everywhere-opensource-src-${PV}"
+
+EXTRA_OECONF = "-prefix ${prefix} \
+                -L ${STAGING_LIBDIR_NATIVE} \
+                -I ${STAGING_INCDIR_NATIVE} \
+                -qt-libjpeg -qt-gif -system-zlib \
+                -no-libjpeg -no-libpng -no-libmng -no-libtiff \
+                -no-accessibility \
+                -no-cups \
+                -no-nas-sound \
+                -no-nis -no-openssl \
+                -verbose -release \
+                -embedded -no-freetype -no-glib -no-iconv \
+                -exceptions -xmlpatterns \
+                -qt3support"
+
+# yank default -e, otherwise we get the following error:
+# moc_qbuffer.cpp: No such file or directory
+EXTRA_OEMAKE = " "
+
+do_configure() {
+   (echo o; echo yes) | ./configure ${EXTRA_OECONF} || die "Configuring qt failed. EXTRA_OECONF was ${EXTRA_OECONF}"
+}
+
+TOBUILD = "\
+  src/tools/moc \
+  src/corelib \
+  src/sql \
+  src/xml \
+  src/network \
+  src/tools/uic \
+  src/tools/rcc \
+  src/xmlpatterns \
+  src/dbus \
+  src/gui \
+  src/testlib \
+  src/qt3support \
+"
+
+do_compile() {
+    for i in ${TOBUILD}; do
+        cd ${S}/$i && oe_runmake CC="${CC}" CXX="${CXX}"
+    done
+}
+
+NATIVE_INSTALL_WORKS = "1"
+
+do_install() {
+    for i in ${TOBUILD}; do
+        cd ${S}/$i && oe_runmake install INSTALL_ROOT=${D}
+    done
+}
diff --git a/recipes/qt4/qt4-libs-native_4.7.2.bb b/recipes/qt4/qt4-libs-native_4.7.2.bb
new file mode 100644
index 0000000..23c5632
--- /dev/null
+++ b/recipes/qt4/qt4-libs-native_4.7.2.bb
@@ -0,0 +1,19 @@
+require qt4-libs-native.inc
+LICENSE = "LGPLv2.1 GPLv3"
+
+PR = "${INC_PR}.0"
+
+# Find the g++.conf/linux.conf in the right directory.
+FILESPATHPKG =. "qt-${PV}:"
+SRC_URI = "ftp://ftp.trolltech.com/qt/source/qt-everywhere-opensource-src-${PV}.tar.gz \
+           file://qt-config.patch \
+           file://g++.conf \
+           file://linux.conf"
+S = "${WORKDIR}/qt-everywhere-opensource-src-${PV}"
+
+EXTRA_OECONF += " -no-fast -silent -no-rpath"
+
+TOBUILD := "src/tools/bootstrap ${TOBUILD}"
+
+SRC_URI[md5sum] = "66b992f5c21145df08c99d21847f4fdb"
+SRC_URI[sha256sum] = "d4783b524b90bcd270ccf6e7a30d5fb51696c47eb5de49ebc2d553cd3eb49336"
-- 
1.7.4.1




^ permalink raw reply related	[flat|nested] 15+ messages in thread
end of thread, other threads:[~2011-05-09  1:38 UTC | newest]

Thread overview: 15+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-05-07 13:07 [PATCH] qt4-libs-native: add initial recipe Simon Busch
2011-05-07 19:17 ` Otavio Salvador
2011-05-08 12:28   ` Simon Busch
2011-05-08 16:33     ` Otavio Salvador
2011-05-08 16:51       ` Simon Busch
2011-05-08 16:55         ` [PATCH] qt4-native: introduce the native version of qt4 Simon Busch
2011-05-08 17:18           ` Otavio Salvador
2011-05-08 17:48             ` Simon Busch
2011-05-08 17:54               ` Otavio Salvador
2011-05-08 18:01                 ` Simon Busch
2011-05-08 18:05                   ` Otavio Salvador
2011-05-08 20:13                   ` [PATCH] qt4-native: introduce the native version of qt4 and remove old qt4-tools-native Simon Busch
2011-05-09  1:35                     ` Otavio Salvador
2011-05-08 16:59         ` [PATCH] qt4-libs-native: add initial recipe Otavio Salvador
2011-05-08 17:14           ` Simon Busch

This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.