[meta-mono] [PATCH 00/11] Refactor common mono build bits into mono.bbclass

[meta-mono] [PATCH 00/11] Refactor common mono build bits into mono.bbclass

[Richard Tollerton]

Building CLI packages involves lots of boilerplate recipe settings, particularly
involving FILES and DEPENDS. This is a first attempt at refactoring these
settings into a single bbclass that can be inherited by all CLI packages that do
not require unusual build settings.

I attempted to refactor every recipe in the layer with these exceptions:

- cefglue, because it doesn't actually install anything (!)
- monotools-server, because I haven't been able to build it successfully
- mono-upnp and taglib-sharp because I don't use them


The following changes since commit 136ed556de19bd497279d6c3ae8704551fb1ec4d:

  mono-xsp-3.x.inc: use autogen.sh (2015-07-16 18:56:23 +0100)

are available in the git repository at:

  git://github.com/rtollert/meta-mono dev/rtollert/v4/bbclass
  https://github.com/rtollert/meta-mono/tree/dev/rtollert/v4/bbclass

Richard Tollerton (11):
  mono.bbclass: add
  dbus-sharp-glib: use mono.bbclass
  dbus-sharp: use mono.bbclass
  fsharp.inc: use mono.bbclass
  mono-addins: use mono.bbclass
  mono-helloworld: use mono.bbclass
  mono-xsp: use mono.bbclass
  mono-basic-4.xx.inc: use mono.bbclass
  gtk-sharp.inc: use mono.bbclass and make some FILES fixes
  gtk-sharp-native: remove mono-native dependency
  gtk-sharp: remove mono-native dependency

 classes/mono.bbclass                               | 32 ++++++++++++++++++++++
 recipes-mono/dbus-sharp-glib/dbus-sharp-glib.inc   | 13 ++-------
 recipes-mono/dbus-sharp/dbus-sharp.inc             | 13 +--------
 recipes-mono/fsharp/fsharp.inc                     | 19 +------------
 recipes-mono/gtk-sharp/gtk-sharp-native_2.12.21.bb |  2 +-
 recipes-mono/gtk-sharp/gtk-sharp.inc               | 23 +++-------------
 recipes-mono/gtk-sharp/gtk-sharp_2.12.21.bb        |  2 +-
 recipes-mono/mono-addins/mono-addins.inc           | 14 ++--------
 recipes-mono/mono-basic/mono-basic-4.xx.inc        | 13 +--------
 recipes-mono/mono-helloworld/mono-helloworld.inc   |  4 +--
 recipes-mono/mono-xsp/mono-xsp-3.x.inc             |  3 +-
 11 files changed, 47 insertions(+), 91 deletions(-)
 create mode 100644 classes/mono.bbclass

-- 
2.4.4

[meta-mono] [PATCH 01/11] mono.bbclass: add

[Richard Tollerton]

The DEPENDS_*, RDEPENDS_*, and FILES_* settings between C# packages
share a lot in common. We can refactor these bits into their own
bbclass:

- DEPEND on mono-native because we need it to compile stuff
- DEPEND on mono to have the native sysroot available
- RDEPEND on mono to make sure we can run the package
- ${PN} contains dlls, exes, and config bits thereof
- ${PN}-dbg contains mono debug (mdb) files
- ${PN}-dev contains:
  - build response (rsp) files
  - machine-readable assembly documentation (xml)
  - xbuild-related files
- ${PN}-doc contains monodoc output

Some C# packages build native code, though, so don't set
PACKAGE_ARCH="all".

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 classes/mono.bbclass | 32 ++++++++++++++++++++++++++++++++
 1 file changed, 32 insertions(+)
 create mode 100644 classes/mono.bbclass

diff --git a/classes/mono.bbclass b/classes/mono.bbclass
new file mode 100644
index 0000000..315ee82
--- /dev/null
+++ b/classes/mono.bbclass
@@ -0,0 +1,32 @@
+# Class for building C# packages. If your package is all-managed, add
+# PACKAGE_ARCH="all"
+
+DEPENDS += "mono-native mono"
+RDEPENDS_${PN} += "mono"
+
+FILES_${PN} += "\
+  ${libdir}/mono/*/*.exe \
+  ${libdir}/mono/*/*.dll \
+  ${libdir}/mono/*/*.config \
+  ${libdir}/mono/gac/*/*/*.dll \
+  ${libdir}/mono/gac/*/*/*.*.config \
+"
+
+FILES_${PN}-dbg += "\
+  ${libdir}/mono/*/*.mdb \
+  ${libdir}/mono/gac/*/*/*.mdb \
+"
+
+FILES_${PN}-dev += "\
+  ${libdir}/mono/*/*.rsp \
+  ${libdir}/mono/*/*.xml \
+  ${libdir}/mono/gac/*/*/*.xml \
+  ${libdir}/mono/xbuild/* \
+  ${libdir}/mono/xbuild-frameworks/* \
+  ${libdir}/mono/Microsoft* \
+  ${libdir}/mono/*/*.Targets \
+"
+
+FILES_${PN}-doc += "\
+  ${libdir}/monodoc/* \
+"
-- 
2.4.4

[meta-mono] [PATCH 02/11] dbus-sharp-glib: use mono.bbclass

[Richard Tollerton]

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 recipes-mono/dbus-sharp-glib/dbus-sharp-glib.inc | 13 ++-----------
 1 file changed, 2 insertions(+), 11 deletions(-)

diff --git a/recipes-mono/dbus-sharp-glib/dbus-sharp-glib.inc b/recipes-mono/dbus-sharp-glib/dbus-sharp-glib.inc
index 2028609..8be7a65 100644
--- a/recipes-mono/dbus-sharp-glib/dbus-sharp-glib.inc
+++ b/recipes-mono/dbus-sharp-glib/dbus-sharp-glib.inc
@@ -1,11 +1,12 @@
 SUMMARY = "C# implementation of D-Bus GlibC integration module"
 DESCRIPTION = "This is a fork of ndesk-dbus-glib, which provides GLib main loop integration for Managed D-Bus."
 SECTION = "devel/mono"
-DEPENDS = "mono dbus-sharp"
+DEPENDS = "dbus-sharp"
 LICENSE = "MIT"
 LIC_FILES_CHKSUM = "files://COPYING;md5=ea73672fbe49f67f1c1b44a7e763dab4"
 
 inherit autotools
+inherit mono
 
 def dbus_sharp_glib_download_version(d):
     pvsplit = d.getVar('PV', True).split('.')
@@ -19,16 +20,6 @@ S = "${WORKDIR}/${PN}-${SDIRVER}"
 
 FILESPATH =. "${FILE_DIRNAME}/${PN}-${PV}:"
 
-FILES_${PN} += " \
-  ${libdir}/mono/dbus-sharp-glib-2.0/dbus-sharp-glib.dll \
-  ${libdir}/mono/gac/dbus-sharp-glib/*/*.config \
-  ${libdir}/mono/gac/dbus-sharp-glib/*/*dll \
-"
-
-FILES_${PN}-dbg += " \
-  ${libdir}/mono/gac/dbus-sharp-glib/*/*.mdb \
-"
-
 do_configure_prepend() {
   export DBUS_SHARP_LIBS="/r:${STAGING_LIBDIR}/mono/dbus-sharp-2.0/dbus-sharp.dll"
 }
-- 
2.4.4

[meta-mono] [PATCH 03/11] dbus-sharp: use mono.bbclass

[Richard Tollerton]

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 recipes-mono/dbus-sharp/dbus-sharp.inc | 13 +------------
 1 file changed, 1 insertion(+), 12 deletions(-)

diff --git a/recipes-mono/dbus-sharp/dbus-sharp.inc b/recipes-mono/dbus-sharp/dbus-sharp.inc
index 243b489..a458082 100644
--- a/recipes-mono/dbus-sharp/dbus-sharp.inc
+++ b/recipes-mono/dbus-sharp/dbus-sharp.inc
@@ -1,11 +1,11 @@
 SUMMARY = "C# implementation of D-Bus"
 DESCRIPTION = "An inter-process communication framework that lets applications	interface with the system event bus as well as allowing them to talk to one another in a peer-to-peer configuration."
 SECTION = "devel/mono"
-DEPENDS = "mono"
 LICENSE = "MIT"
 LIC_FILES_CHKSUM = "files://COPYING;md5=09d60852216ea29fdba9ea146513336c"
 
 inherit autotools
+inherit mono
 
 def dbus_sharp_download_version(d):
     pvsplit = d.getVar('PV', True).split('.')
@@ -18,14 +18,3 @@ SRC_URI = "https://github.com/mono/dbus-sharp/archive/v${SDIRVER}.tar.gz"
 S = "${WORKDIR}/${PN}-${SDIRVER}"
 
 FILESPATH =. "${FILE_DIRNAME}/${PN}-${PV}:"
-
-FILES_${PN} += " \
-  ${libdir}/mono/dbus-sharp-2.0/* \
-  ${libdir}/mono/gac/dbus-sharp/*/*.dll \
-  ${libdir}/mono/gac/dbus-sharp/*/*.config \
-"
-
-FILES_${PN}-dbg += " \
-  ${libdir}/mono/gac/dbus-sharp/*/*.mdb \
-"
-
-- 
2.4.4

[meta-mono] [PATCH 04/11] fsharp.inc: use mono.bbclass

[Richard Tollerton]

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 recipes-mono/fsharp/fsharp.inc | 19 +------------------
 1 file changed, 1 insertion(+), 18 deletions(-)

diff --git a/recipes-mono/fsharp/fsharp.inc b/recipes-mono/fsharp/fsharp.inc
index 25c41b6..f5bdcc1 100644
--- a/recipes-mono/fsharp/fsharp.inc
+++ b/recipes-mono/fsharp/fsharp.inc
@@ -1,36 +1,19 @@
 SUMMARY = "F# programming language"
 DESCRIPTION = "F# is a strongly-typed, functional-first programming language for writing simple code to solve complex problems."
 SECTION = "devel/mono"
-DEPENDS = "mono"
 LICENSE = "Apache-2.0"
 LIC_FILES_CHKSUM = "files://LICENSE;md5=512efb9375da0bd2fee9e2b9352c08af"
 
 inherit autotools-brokensep
+inherit mono
 
 # For some reason the URL template changes from version to version,
 # therefore use some variables for the directory and extension
 SRC_URI = "https://github.com/fsharp/fsharp/archive/${PV}.tar.gz"
 
 FILES_${PN} += "\
-  ${libdir}/mono/*/*.exe \
-  ${libdir}/mono/*/*.dll \
-  ${libdir}/mono/*/*.config \
   ${libdir}/mono/*/*.optdata \
   ${libdir}/mono/*/*.sigdata \
-  ${libdir}/mono/gac/*/*/*.config \
   ${libdir}/mono/gac/*/*/*.optdata \
   ${libdir}/mono/gac/*/*/*.sigdata \
 "
-
-FILES_${PN}-dbg += "\
-  ${libdir}/mono/gac/*/*/*.mdb \
-"
-
-FILES_${PN}-dev = "\
-  ${libdir}/mono/xbuild/* \
-  ${libdir}/mono/xbuild-frameworks/* \
-  ${libdir}/mono/Microsoft* \
-  ${libdir}/mono/*/*.Targets \
-  ${libdir}/mono/*/*.xml \
-  ${libdir}/mono/gac/*/*/*.xml \
-"
-- 
2.4.4

[meta-mono] [PATCH 05/11] mono-addins: use mono.bbclass

[Richard Tollerton]

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 recipes-mono/mono-addins/mono-addins.inc | 14 ++------------
 1 file changed, 2 insertions(+), 12 deletions(-)

diff --git a/recipes-mono/mono-addins/mono-addins.inc b/recipes-mono/mono-addins/mono-addins.inc
index 767ad78..5549fb9 100644
--- a/recipes-mono/mono-addins/mono-addins.inc
+++ b/recipes-mono/mono-addins/mono-addins.inc
@@ -6,7 +6,7 @@ SECTION = "mono/applications"
 PRIORITY = "optional"
 LICENSE = "MIT"
 LIC_FILES_CHKSUM = "file://COPYING;md5=4e024d772d8266e3ff9747185842ca82"
-DEPENDS = "mono gtk-sharp"
+DEPENDS = "gtk-sharp"
 
 SRCREV = "64a45d96f39d4714ec85adf0fe04b68ec7273ae1"
 SRCBRANCH = "master"
@@ -16,14 +16,4 @@ SRC_URI = "git://github.com/mono/mono-addins.git;branch=${SRCBRANCH}"
 S = "${WORKDIR}/git"
 
 inherit autotools pkgconfig
-
-FILES_${PN} += " \
-  ${libdir}/mono/gac/* \
-  ${libdir}/mono/gac/*/*/*.dll \
-  ${libdir}/mono/gac/*/*/*.config \
-  ${libdir}/mono/${PN}/* \
-"
-
-FILES_${PN}-dbg += " \
-  ${libdir}/mono/gac/*/*/*.mdb \
-"
+inherit mono
-- 
2.4.4

[meta-mono] [PATCH 06/11] mono-helloworld: use mono.bbclass

[Richard Tollerton]

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 recipes-mono/mono-helloworld/mono-helloworld.inc | 4 +---
 1 file changed, 1 insertion(+), 3 deletions(-)

diff --git a/recipes-mono/mono-helloworld/mono-helloworld.inc b/recipes-mono/mono-helloworld/mono-helloworld.inc
index 8fa046f..d63ca8c 100644
--- a/recipes-mono/mono-helloworld/mono-helloworld.inc
+++ b/recipes-mono/mono-helloworld/mono-helloworld.inc
@@ -6,16 +6,14 @@ SECTION = "mono/applications"
 PRIORITY = "optional"
 LICENSE = "GPLv3"
 LIC_FILES_CHKSUM = "file://LICENSE;md5=783b7e40cdfb4a1344d15b1f7081af66"
-DEPENDS = "mono"
 
 SRC_URI = "https://github.com/DynamicDevices/mono-helloworld/archive/v${PV}.tar.gz"
 
 inherit autotools
+inherit mono
 
 FILES_${PN} = "${libdir}/helloworld/helloworld.exe \
 		${bindir}/helloworld \
         	${libdir}/helloworld/helloworldform.exe \
 		${bindir}/helloworldform \
 "
-
-RDEPENDS_${PN} += "mono"
-- 
2.4.4

[meta-mono] [PATCH 07/11] mono-xsp: use mono.bbclass

[Richard Tollerton]

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 recipes-mono/mono-xsp/mono-xsp-3.x.inc | 3 +--
 1 file changed, 1 insertion(+), 2 deletions(-)

diff --git a/recipes-mono/mono-xsp/mono-xsp-3.x.inc b/recipes-mono/mono-xsp/mono-xsp-3.x.inc
index bee35ea..dac2b1a 100644
--- a/recipes-mono/mono-xsp/mono-xsp-3.x.inc
+++ b/recipes-mono/mono-xsp/mono-xsp-3.x.inc
@@ -1,11 +1,10 @@
 DESCRIPTION = "Standalone web server written in C# that can be used to run ASP.NET applications"
 SECTION = "devel/mono"
-DEPENDS = "mono"
-RDEPENDS_${PN} = "mono"
 LICENSE = "MIT"
 LIC_FILES_CHKSUM = "file://COPYING;md5=9e1603e27acd337015fdfa7f7ff936c7"
 
 inherit autotools-brokensep
+inherit mono
 
 SRC_URI = "https://github.com/mono/xsp/archive/${PV}.tar.gz"
 
-- 
2.4.4

[meta-mono] [PATCH 08/11] mono-basic-4.xx.inc: use mono.bbclass

[Richard Tollerton]

*.Pdb and *.Mdb files were not found in the install so they are not
added to FILES.

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 recipes-mono/mono-basic/mono-basic-4.xx.inc | 13 +------------
 1 file changed, 1 insertion(+), 12 deletions(-)

diff --git a/recipes-mono/mono-basic/mono-basic-4.xx.inc b/recipes-mono/mono-basic/mono-basic-4.xx.inc
index 8b0a11e..cac0fb1 100644
--- a/recipes-mono/mono-basic/mono-basic-4.xx.inc
+++ b/recipes-mono/mono-basic/mono-basic-4.xx.inc
@@ -6,21 +6,10 @@ LICENSE = "LGPLv2"
 LIC_FILES_CHKSUM = "file://LICENSE;md5=d8c5dc22eb6f25667cf8d96f603635e7"
 
 inherit autotools 
+inherit mono
 
 SRC_URI = "https://github.com/mono/mono-basic/archive/${PV}.tar.gz"
 
-FILES_${PN} += " \
-  ${libdir}/mono/*/* \
-  ${libdir}/mono/gac/*/*/*.dll \
-"
-
-FILES_${PN}-dbg += " \
-  ${libdir}/mono/*/*.mdb \
-  ${libdir}/mono/*/*.Pdb \
-  ${libdir}/mono/*/*.Mdb \
-  ${libdir}/mono/*/*/*/*.mdb \
-"
-
 do_compile_prepend() {
   sed -e "s|\$(prefix)|${STAGING_DIR_NATIVE}/usr|" -i build/profiles/net_4_0.make
   sed -e "s|\$(prefix)|${STAGING_DIR_NATIVE}/usr|" -i build/profiles/net_4_5.make
-- 
2.4.4

[meta-mono] [PATCH 09/11] gtk-sharp.inc: use mono.bbclass and make some FILES fixes

[Richard Tollerton]

/usr/lib/gtk-sharp-2.0 and /usr/share/gapi-2.0 are (AFAIK) only used for
building, and so belong in gtk-sharp-dev.

All other relevant FILES entries have been rolled into mono.bbclass.

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 recipes-mono/gtk-sharp/gtk-sharp.inc | 23 ++++-------------------
 1 file changed, 4 insertions(+), 19 deletions(-)

diff --git a/recipes-mono/gtk-sharp/gtk-sharp.inc b/recipes-mono/gtk-sharp/gtk-sharp.inc
index 45d12b2..e466a8b 100644
--- a/recipes-mono/gtk-sharp/gtk-sharp.inc
+++ b/recipes-mono/gtk-sharp/gtk-sharp.inc
@@ -2,11 +2,11 @@ SUMMARY = "GUI toolkit for Mono"
 DESCRIPTION = "GTK+ bindings for Mono"
 SECTION = "devel/mono"
 BUGTRACKER = "http://bugzilla.xamarin.com"
-RDEPENDS_${PN} = "mono"
 LICENSE = "LGPL-2.1"
 RDEPENDS_${PN}-dev += "perl"
 
 inherit autotools
+inherit mono
 
 # For some reason the URL template changes from version to version,
 # therefore use some variables for the directory and extension
@@ -21,22 +21,7 @@ def gtk_sharp_download_version(d):
 
 FILESPATH =. "${FILE_DIRNAME}/gtk-sharp-${PV}:"
 
-FILES_${PN} = "\
-  ${bindir}/* \
-  ${libdir}/* \
+FILES_${PN}-dev += "\
+  ${libdir}/${PN}*/* \
+  ${datadir}/* \
 "
-
-FILES_${PN}-dbg = "\
-    ${libdir}/.debug \
-    ${datadir}/* \
-    /usr/src/* \
-"
-
-FILES_${PN}-doc = "\
-    ${libdir}/monodoc/* \
-"
-
-FILES_${PN}-dev = "\
-    ${libdir}/pkgconfig \
-"
-
-- 
2.4.4

[meta-mono] [PATCH 10/11] gtk-sharp-native: remove mono-native dependency

[Richard Tollerton]

mono.bbclass already adds it so it's unnecessary here.

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 recipes-mono/gtk-sharp/gtk-sharp-native_2.12.21.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/recipes-mono/gtk-sharp/gtk-sharp-native_2.12.21.bb b/recipes-mono/gtk-sharp/gtk-sharp-native_2.12.21.bb
index 76eb770..6396b42 100644
--- a/recipes-mono/gtk-sharp/gtk-sharp-native_2.12.21.bb
+++ b/recipes-mono/gtk-sharp/gtk-sharp-native_2.12.21.bb
@@ -2,7 +2,7 @@ require gtk-sharp.inc
 
 inherit pkgconfig native
 
-DEPENDS = "mono-native gtk+-native atk-native pango-native cairo-native glib-2.0-native libglade-native "
+DEPENDS += " gtk+-native atk-native pango-native cairo-native glib-2.0-native libglade-native "
 
 LIC_FILES_CHKSUM = "files://COPYING;md5=f14599a2f089f6ff8c97e2baa4e3d575"
 
-- 
2.4.4

[meta-mono] [PATCH 11/11] gtk-sharp: remove mono-native dependency

[Richard Tollerton]

mono.bbclass already adds it so it's unnecessary here.

Signed-off-by: Richard Tollerton <rich.tollerton@ni.com>
---
 recipes-mono/gtk-sharp/gtk-sharp_2.12.21.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/recipes-mono/gtk-sharp/gtk-sharp_2.12.21.bb b/recipes-mono/gtk-sharp/gtk-sharp_2.12.21.bb
index 563da51..c72b0bb 100644
--- a/recipes-mono/gtk-sharp/gtk-sharp_2.12.21.bb
+++ b/recipes-mono/gtk-sharp/gtk-sharp_2.12.21.bb
@@ -2,7 +2,7 @@ require gtk-sharp.inc
 
 inherit pkgconfig
 
-DEPENDS = "mono gtk+ atk pango cairo glib-2.0 libglade "
+DEPENDS += " gtk+ atk pango cairo glib-2.0 libglade"
 
 LIC_FILES_CHKSUM = "files://COPYING;md5=f14599a2f089f6ff8c97e2baa4e3d575"
 
-- 
2.4.4

Re: [meta-mono] [PATCH 00/11] Refactor common mono build bits into mono.bbclass

[Alex J Lennon]

On 17/07/2015 00:16, Richard Tollerton wrote:
> Building CLI packages involves lots of boilerplate recipe settings, particularly
> involving FILES and DEPENDS. This is a first attempt at refactoring these
> settings into a single bbclass that can be inherited by all CLI packages that do
> not require unusual build settings.
>
> I attempted to refactor every recipe in the layer with these exceptions:
>
> - cefglue, because it doesn't actually install anything (!)
> - monotools-server, because I haven't been able to build it successfully
> - mono-upnp and taglib-sharp because I don't use them
>
>
> The following changes since commit 136ed556de19bd497279d6c3ae8704551fb1ec4d:
>
>   mono-xsp-3.x.inc: use autogen.sh (2015-07-16 18:56:23 +0100)
>
> are available in the git repository at:
>
>   git://github.com/rtollert/meta-mono dev/rtollert/v4/bbclass
>   https://github.com/rtollert/meta-mono/tree/dev/rtollert/v4/bbclass
>
> Richard Tollerton (11):
>   mono.bbclass: add
>   dbus-sharp-glib: use mono.bbclass
>   dbus-sharp: use mono.bbclass
>   fsharp.inc: use mono.bbclass
>   mono-addins: use mono.bbclass
>   mono-helloworld: use mono.bbclass
>   mono-xsp: use mono.bbclass
>   mono-basic-4.xx.inc: use mono.bbclass
>   gtk-sharp.inc: use mono.bbclass and make some FILES fixes
>   gtk-sharp-native: remove mono-native dependency
>   gtk-sharp: remove mono-native dependency
>
>  classes/mono.bbclass                               | 32 ++++++++++++++++++++++
>  recipes-mono/dbus-sharp-glib/dbus-sharp-glib.inc   | 13 ++-------
>  recipes-mono/dbus-sharp/dbus-sharp.inc             | 13 +--------
>  recipes-mono/fsharp/fsharp.inc                     | 19 +------------
>  recipes-mono/gtk-sharp/gtk-sharp-native_2.12.21.bb |  2 +-
>  recipes-mono/gtk-sharp/gtk-sharp.inc               | 23 +++-------------
>  recipes-mono/gtk-sharp/gtk-sharp_2.12.21.bb        |  2 +-
>  recipes-mono/mono-addins/mono-addins.inc           | 14 ++--------
>  recipes-mono/mono-basic/mono-basic-4.xx.inc        | 13 +--------
>  recipes-mono/mono-helloworld/mono-helloworld.inc   |  4 +--
>  recipes-mono/mono-xsp/mono-xsp-3.x.inc             |  3 +-
>  11 files changed, 47 insertions(+), 91 deletions(-)
>  create mode 100644 classes/mono.bbclass
>

Great idea - applied thanks Richard

Cheers, Alex

Re: [meta-mono] [PATCH 00/11] Refactor common mono build bits into mono.bbclass

[Alex J Lennon]

On 17/07/2015 10:19, Alex J Lennon wrote:
>
> On 17/07/2015 00:16, Richard Tollerton wrote:
>> Building CLI packages involves lots of boilerplate recipe settings, particularly
>> involving FILES and DEPENDS. This is a first attempt at refactoring these
>> settings into a single bbclass that can be inherited by all CLI packages that do
>> not require unusual build settings.
>>
>> I attempted to refactor every recipe in the layer with these exceptions:
>>
>> - cefglue, because it doesn't actually install anything (!)
>> - monotools-server, because I haven't been able to build it successfully
>> - mono-upnp and taglib-sharp because I don't use them
>>
>>
>> The following changes since commit 136ed556de19bd497279d6c3ae8704551fb1ec4d:
>>
>>   mono-xsp-3.x.inc: use autogen.sh (2015-07-16 18:56:23 +0100)
>>
>> are available in the git repository at:
>>
>>   git://github.com/rtollert/meta-mono dev/rtollert/v4/bbclass
>>   https://github.com/rtollert/meta-mono/tree/dev/rtollert/v4/bbclass
>>
>> Richard Tollerton (11):
>>   mono.bbclass: add
>>   dbus-sharp-glib: use mono.bbclass
>>   dbus-sharp: use mono.bbclass
>>   fsharp.inc: use mono.bbclass
>>   mono-addins: use mono.bbclass
>>   mono-helloworld: use mono.bbclass
>>   mono-xsp: use mono.bbclass
>>   mono-basic-4.xx.inc: use mono.bbclass
>>   gtk-sharp.inc: use mono.bbclass and make some FILES fixes
>>   gtk-sharp-native: remove mono-native dependency
>>   gtk-sharp: remove mono-native dependency
>>
>>  classes/mono.bbclass                               | 32 ++++++++++++++++++++++
>>  recipes-mono/dbus-sharp-glib/dbus-sharp-glib.inc   | 13 ++-------
>>  recipes-mono/dbus-sharp/dbus-sharp.inc             | 13 +--------
>>  recipes-mono/fsharp/fsharp.inc                     | 19 +------------
>>  recipes-mono/gtk-sharp/gtk-sharp-native_2.12.21.bb |  2 +-
>>  recipes-mono/gtk-sharp/gtk-sharp.inc               | 23 +++-------------
>>  recipes-mono/gtk-sharp/gtk-sharp_2.12.21.bb        |  2 +-
>>  recipes-mono/mono-addins/mono-addins.inc           | 14 ++--------
>>  recipes-mono/mono-basic/mono-basic-4.xx.inc        | 13 +--------
>>  recipes-mono/mono-helloworld/mono-helloworld.inc   |  4 +--
>>  recipes-mono/mono-xsp/mono-xsp-3.x.inc             |  3 +-
>>  11 files changed, 47 insertions(+), 91 deletions(-)
>>  create mode 100644 classes/mono.bbclass
>>
> Great idea - applied thanks Richard
>

Richard,

I'm having some trouble with builds here since that latest patch.

Can you tell me, what version of Mono did you test against, and also did
you have Mono installed out of tree on the host system?
(I've had trouble in the past with the host mono being picked up
incorrectly)

Thanks,

Alex

Re: [meta-mono] [PATCH 00/11] Refactor common mono build bits into mono.bbclass

[Richard Tollerton]

Alex J Lennon <ajlennon@dynamicdevices.co.uk> writes:

> Richard,
>
> I'm having some trouble with builds here since that latest patch.
>
> Can you tell me, what version of Mono did you test against, and also did
> you have Mono installed out of tree on the host system?
> (I've had trouble in the past with the host mono being picked up
> incorrectly)

Sorry for the inconvenience :(

I've been building mono 4.0.2.4 with these changes. I tested the build
both on archlinux, with mono installed on the host, and inside an ubuntu
12.04 chroot, with mono not installed.

Re: [meta-mono] [PATCH 00/11] Refactor common mono build bits into mono.bbclass

[Alex J Lennon]

On 17/07/2015 15:43, Richard Tollerton wrote:
> Alex J Lennon <ajlennon@dynamicdevices.co.uk> writes:
>
>> Richard,
>>
>> I'm having some trouble with builds here since that latest patch.
>>
>> Can you tell me, what version of Mono did you test against, and also did
>> you have Mono installed out of tree on the host system?
>> (I've had trouble in the past with the host mono being picked up
>> incorrectly)
> Sorry for the inconvenience :(
>
> I've been building mono 4.0.2.4 with these changes. I tested the build
> both on archlinux, with mono installed on the host, and inside an ubuntu
> 12.04 chroot, with mono not installed.
>
>

Thanks for coming back to me so quickly. No worries. Perhaps it's finger
trouble on my part somehow as I took the opportunity to clean up the
4.xx build a little today too.

I'm using 4.0.2.4 here too, and have been testing also with 4.0.2.5
support I added in. No mono on the host. Simple tests of the
helloworld/helloworldform apps work fine under qemux86 but I'm seeing
trouble building those updated recipes for some reason.

I'll spend a bit of time investigating.

Cheers, Alex