[meta-webserver][PATCH 0/2] nginx: make mainline and stable version available

[meta-webserver][PATCH 0/2] nginx: make mainline and stable version available

[Pascal Bach]

Nginx has two supported branches, mainline and stable.
Currently meta-webserver contains the mainline version (1.9.x) of nginx.
For embedded system it might however be more appropriate to use the stable version (1.8.x)
which only receives security updates and bugfixes.

This changeset restructures the nginx recipe to provide recipes for both 1.8 and 1.9 branches.

Pascal Bach (2):
  nginx: split parts out of the recipe into nginx.inc
  nginx: add stable version 1.8.1 as alternative to the mainline version
    1.9.x

 meta-webserver/recipes-httpd/nginx/nginx.inc       | 136 +++++++++++++++++++++
 meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb  |   4 +
 meta-webserver/recipes-httpd/nginx/nginx_1.9.10.bb | 136 +--------------------
 3 files changed, 141 insertions(+), 135 deletions(-)
 create mode 100644 meta-webserver/recipes-httpd/nginx/nginx.inc
 create mode 100644 meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb

-- 
2.1.4

[meta-webserver][PATCH 1/2] nginx: split parts out of the recipe into nginx.inc

[Pascal Bach]

nginx has two maintained branches.
- stable: is the long term maintained branch where only bugfixes occur
- mainline: is the branch where new features get added

This change is in preparation to support these two branches.
---
 meta-webserver/recipes-httpd/nginx/nginx.inc       | 136 +++++++++++++++++++++
 meta-webserver/recipes-httpd/nginx/nginx_1.9.10.bb | 136 +--------------------
 2 files changed, 137 insertions(+), 135 deletions(-)
 create mode 100644 meta-webserver/recipes-httpd/nginx/nginx.inc

diff --git a/meta-webserver/recipes-httpd/nginx/nginx.inc b/meta-webserver/recipes-httpd/nginx/nginx.inc
new file mode 100644
index 0000000..a785e7b
--- /dev/null
+++ b/meta-webserver/recipes-httpd/nginx/nginx.inc
@@ -0,0 +1,136 @@
+SUMMARY = "HTTP and reverse proxy server"
+
+DESCRIPTION = "Nginx is a web server and a reverse proxy server for \
+HTTP, SMTP, POP3 and IMAP protocols, with a strong focus on high  \
+concurrency, performance and low memory usage."
+
+HOMEPAGE = "http://nginx.org/"
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=0bb58ed0dfd4f5dbece3b52aba79f023"
+SECTION = "net"
+
+DEPENDS = "libpcre gzip openssl"
+
+SRC_URI = " \
+	http://nginx.org/download/nginx-${PV}.tar.gz \
+	file://nginx-cross.patch \
+	file://nginx.conf \
+	file://nginx.init \
+	file://nginx-volatile.conf \
+	file://nginx.service \
+"
+
+inherit update-rc.d useradd
+
+CFLAGS_append = " -fPIE -pie"
+CXXFLAGS_append = " -fPIE -pie"
+
+NGINX_WWWDIR ?= "${localstatedir}/www/localhost"
+NGINX_USER   ?= "www"
+
+EXTRA_OECONF = ""
+
+do_configure () {
+	if [ "${SITEINFO_BITS}" = "64" ]; then
+		PTRSIZE=8
+	else
+		PTRSIZE=4
+	fi
+
+	echo $CFLAGS
+	echo $LDFLAGS
+
+	./configure \
+	--crossbuild=Linux:${TUNE_ARCH} \
+	--with-endian=${@base_conditional('SITEINFO_ENDIANNESS', 'le', 'little', 'big', d)} \
+	--with-int=4 \
+	--with-long=${PTRSIZE} \
+	--with-long-long=8 \
+	--with-ptr-size=${PTRSIZE} \
+	--with-sig-atomic-t=${PTRSIZE} \
+	--with-size-t=${PTRSIZE} \
+	--with-off-t=${PTRSIZE} \
+	--with-time-t=${PTRSIZE} \
+	--with-sys-nerr=132 \
+	--conf-path=${sysconfdir}/nginx/nginx.conf \
+	--http-log-path=${localstatedir}/log/nginx/access.log \
+	--error-log-path=${localstatedir}/log/nginx/error.log \
+	--pid-path=/run/nginx/nginx.pid \
+	--prefix=${prefix} \
+	--with-http_ssl_module \
+	--with-http_gzip_static_module \
+	${EXTRA_OECONF}
+}
+
+do_install () {
+	oe_runmake 'DESTDIR=${D}' install
+	rm -fr ${D}${localstatedir}/run ${D}/run
+	if ${@base_contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+		install -d ${D}${sysconfdir}/tmpfiles.d
+		echo "d /run/${BPN} - - - -" \
+		     > ${D}${sysconfdir}/tmpfiles.d/${BPN}.conf
+	fi
+	install -d ${D}${sysconfdir}/${BPN}
+	ln -snf ${localstatedir}/run/${BPN} ${D}${sysconfdir}/${BPN}/run
+	install -d ${D}${NGINX_WWWDIR}
+	mv ${D}/usr/html ${D}${NGINX_WWWDIR}/
+	chown ${NGINX_USER}:www-data -R ${D}${NGINX_WWWDIR}
+
+	install -d ${D}${sysconfdir}/init.d
+	install -m 0755 ${WORKDIR}/nginx.init ${D}${sysconfdir}/init.d/nginx
+	sed -i 's,/usr/sbin/,${sbindir}/,g' ${D}${sysconfdir}/init.d/nginx
+	sed -i 's,/etc/,${sysconfdir}/,g'  ${D}${sysconfdir}/init.d/nginx
+
+	install -d ${D}${sysconfdir}/nginx
+	install -m 0644 ${WORKDIR}/nginx.conf ${D}${sysconfdir}/nginx/nginx.conf
+	sed -i 's,/var/,${localstatedir}/,g' ${D}${sysconfdir}/nginx/nginx.conf
+	install -d ${D}${sysconfdir}/nginx/sites-enabled
+
+	install -d ${D}${sysconfdir}/default/volatiles
+	install -m 0644 ${WORKDIR}/nginx-volatile.conf ${D}${sysconfdir}/default/volatiles/99_nginx
+	sed -i 's,/var/,${localstatedir}/,g' ${D}${sysconfdir}/default/volatiles/99_nginx
+
+        if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)};then
+            install -d ${D}${systemd_unitdir}/system
+            install -m 0644 ${WORKDIR}/nginx.service ${D}${systemd_unitdir}/system/
+            sed -i -e 's,@SYSCONFDIR@,${sysconfdir},g' \
+                    -e 's,@LOCALSTATEDIR@,${localstatedir},g' \
+                    -e 's,@BASEBINDIR@,${base_bindir},g' \
+                    ${D}${systemd_unitdir}/system/nginx.service
+        fi
+}
+
+pkg_postinst_${PN} () {
+	if [ -z "$D" ]; then
+		if type systemd-tmpfiles >/dev/null; then
+			systemd-tmpfiles --create
+		elif [ -e ${sysconfdir}/init.d/populate-volatile.sh ]; then
+			${sysconfdir}/init.d/populate-volatile.sh update
+		fi
+	fi
+}
+
+FILES_${PN} += "${localstatedir}/ \
+                ${systemd_unitdir}/system/nginx.service \
+                "
+
+CONFFILES_${PN} = "${sysconfdir}/nginx/nginx.conf \
+		${sysconfdir}/nginx/fastcgi.conf\
+		${sysconfdir}/nginx/fastcgi_params \
+		${sysconfdir}/nginx/koi-utf \
+		${sysconfdir}/nginx/koi-win \
+		${sysconfdir}/nginx/mime.types \
+		${sysconfdir}/nginx/scgi_params \
+		${sysconfdir}/nginx/uwsgi_params \
+		${sysconfdir}/nginx/win-utf \
+"
+
+INITSCRIPT_NAME = "nginx"
+INITSCRIPT_PARAMS = "defaults 92 20"
+
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM_${PN} = " \
+    --system --no-create-home \
+    --home ${NGINX_WWWDIR} \
+    --groups www-data \
+    --user-group ${NGINX_USER}"
diff --git a/meta-webserver/recipes-httpd/nginx/nginx_1.9.10.bb b/meta-webserver/recipes-httpd/nginx/nginx_1.9.10.bb
index 5d63d41..287aa97 100644
--- a/meta-webserver/recipes-httpd/nginx/nginx_1.9.10.bb
+++ b/meta-webserver/recipes-httpd/nginx/nginx_1.9.10.bb
@@ -1,138 +1,4 @@
-SUMMARY = "HTTP and reverse proxy server"
+require nginx.inc
 
-DESCRIPTION = "Nginx is a web server and a reverse proxy server for \
-HTTP, SMTP, POP3 and IMAP protocols, with a strong focus on high  \
-concurrency, performance and low memory usage."
-
-HOMEPAGE = "http://nginx.org/"
-LICENSE = "BSD-2-Clause"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=0bb58ed0dfd4f5dbece3b52aba79f023"
-SECTION = "net"
-
-DEPENDS = "libpcre gzip openssl"
-
-SRC_URI = " \
-	http://nginx.org/download/nginx-${PV}.tar.gz \
-	file://nginx-cross.patch \
-	file://nginx.conf \
-	file://nginx.init \
-	file://nginx-volatile.conf \
-	file://nginx.service \
-"
 SRC_URI[md5sum] = "64cc970988356a5e0fc4fcd1ab84fe57"
 SRC_URI[sha256sum] = "fb14d76844cab0a5a0880768be28965e74f9956790f618c454ef6098e26631d9"
-
-inherit update-rc.d useradd
-
-CFLAGS_append = " -fPIE -pie"
-CXXFLAGS_append = " -fPIE -pie"
-
-NGINX_WWWDIR ?= "${localstatedir}/www/localhost"
-NGINX_USER   ?= "www"
-
-EXTRA_OECONF = ""
-
-do_configure () {
-	if [ "${SITEINFO_BITS}" = "64" ]; then
-		PTRSIZE=8
-	else
-		PTRSIZE=4
-	fi
-
-	echo $CFLAGS
-	echo $LDFLAGS
-
-	./configure \
-	--crossbuild=Linux:${TUNE_ARCH} \
-	--with-endian=${@base_conditional('SITEINFO_ENDIANNESS', 'le', 'little', 'big', d)} \
-	--with-int=4 \
-	--with-long=${PTRSIZE} \
-	--with-long-long=8 \
-	--with-ptr-size=${PTRSIZE} \
-	--with-sig-atomic-t=${PTRSIZE} \
-	--with-size-t=${PTRSIZE} \
-	--with-off-t=${PTRSIZE} \
-	--with-time-t=${PTRSIZE} \
-	--with-sys-nerr=132 \
-	--conf-path=${sysconfdir}/nginx/nginx.conf \
-	--http-log-path=${localstatedir}/log/nginx/access.log \
-	--error-log-path=${localstatedir}/log/nginx/error.log \
-	--pid-path=/run/nginx/nginx.pid \
-	--prefix=${prefix} \
-	--with-http_ssl_module \
-	--with-http_gzip_static_module \
-	${EXTRA_OECONF}
-}
-
-do_install () {
-	oe_runmake 'DESTDIR=${D}' install
-	rm -fr ${D}${localstatedir}/run ${D}/run
-	if ${@base_contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
-		install -d ${D}${sysconfdir}/tmpfiles.d
-		echo "d /run/${BPN} - - - -" \
-		     > ${D}${sysconfdir}/tmpfiles.d/${BPN}.conf
-	fi
-	install -d ${D}${sysconfdir}/${BPN}
-	ln -snf ${localstatedir}/run/${BPN} ${D}${sysconfdir}/${BPN}/run
-	install -d ${D}${NGINX_WWWDIR}
-	mv ${D}/usr/html ${D}${NGINX_WWWDIR}/
-	chown ${NGINX_USER}:www-data -R ${D}${NGINX_WWWDIR}
-
-	install -d ${D}${sysconfdir}/init.d
-	install -m 0755 ${WORKDIR}/nginx.init ${D}${sysconfdir}/init.d/nginx
-	sed -i 's,/usr/sbin/,${sbindir}/,g' ${D}${sysconfdir}/init.d/nginx
-	sed -i 's,/etc/,${sysconfdir}/,g'  ${D}${sysconfdir}/init.d/nginx
-
-	install -d ${D}${sysconfdir}/nginx
-	install -m 0644 ${WORKDIR}/nginx.conf ${D}${sysconfdir}/nginx/nginx.conf
-	sed -i 's,/var/,${localstatedir}/,g' ${D}${sysconfdir}/nginx/nginx.conf
-	install -d ${D}${sysconfdir}/nginx/sites-enabled
-
-	install -d ${D}${sysconfdir}/default/volatiles
-	install -m 0644 ${WORKDIR}/nginx-volatile.conf ${D}${sysconfdir}/default/volatiles/99_nginx
-	sed -i 's,/var/,${localstatedir}/,g' ${D}${sysconfdir}/default/volatiles/99_nginx
-
-        if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)};then
-            install -d ${D}${systemd_unitdir}/system
-            install -m 0644 ${WORKDIR}/nginx.service ${D}${systemd_unitdir}/system/
-            sed -i -e 's,@SYSCONFDIR@,${sysconfdir},g' \
-                    -e 's,@LOCALSTATEDIR@,${localstatedir},g' \
-                    -e 's,@BASEBINDIR@,${base_bindir},g' \
-                    ${D}${systemd_unitdir}/system/nginx.service
-        fi
-}
-
-pkg_postinst_${PN} () {
-	if [ -z "$D" ]; then
-		if type systemd-tmpfiles >/dev/null; then
-			systemd-tmpfiles --create
-		elif [ -e ${sysconfdir}/init.d/populate-volatile.sh ]; then
-			${sysconfdir}/init.d/populate-volatile.sh update
-		fi
-	fi
-}
-
-FILES_${PN} += "${localstatedir}/ \
-                ${systemd_unitdir}/system/nginx.service \
-                "
-
-CONFFILES_${PN} = "${sysconfdir}/nginx/nginx.conf \
-		${sysconfdir}/nginx/fastcgi.conf\
-		${sysconfdir}/nginx/fastcgi_params \
-		${sysconfdir}/nginx/koi-utf \
-		${sysconfdir}/nginx/koi-win \
-		${sysconfdir}/nginx/mime.types \
-		${sysconfdir}/nginx/scgi_params \
-		${sysconfdir}/nginx/uwsgi_params \
-		${sysconfdir}/nginx/win-utf \
-"
-
-INITSCRIPT_NAME = "nginx"
-INITSCRIPT_PARAMS = "defaults 92 20"
-
-USERADD_PACKAGES = "${PN}"
-USERADD_PARAM_${PN} = " \
-    --system --no-create-home \
-    --home ${NGINX_WWWDIR} \
-    --groups www-data \
-    --user-group ${NGINX_USER}"
-- 
2.1.4

[meta-webserver][PATCH 2/2] nginx: add stable version 1.8.1 as alternative to the mainline version 1.9.x

[Pascal Bach]

The 1.8 branch is the current stable branch of nginx.
This means the branch doesn't get new features, but is still supported with bugfixes.

Depending on the use case it is more suitable to use on an embedded device
than the 1.9 branch which adds new features with every release.
---
 meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb | 4 ++++
 1 file changed, 4 insertions(+)
 create mode 100644 meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb

diff --git a/meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb b/meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb
new file mode 100644
index 0000000..ec3aef2
--- /dev/null
+++ b/meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb
@@ -0,0 +1,4 @@
+require nginx.inc
+
+SRC_URI[md5sum] = "2e91695074dbdfbf1bcec0ada9fda462"
+SRC_URI[sha256sum] = "8f4b3c630966c044ec72715754334d1fdf741caa1d5795fb4646c27d09f797b7"
-- 
2.1.4

Re: [meta-webserver][PATCH 0/2] nginx: make mainline and stable version available

[Otavio Salvador]

On Tue, Feb 16, 2016 at 9:40 AM, Pascal Bach <pascal.bach@siemens.com> wrote:
> Nginx has two supported branches, mainline and stable.
> Currently meta-webserver contains the mainline version (1.9.x) of nginx.
> For embedded system it might however be more appropriate to use the stable version (1.8.x)
> which only receives security updates and bugfixes.

Agreed; I also think 1.9 recipe ought to have default preference as -1
so users take the stable by default.

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [meta-webserver][PATCH 0/2] nginx: make mainline and stable version available

[Pascal Bach]

Am 16.02.2016 um 12:51 schrieb Otavio Salvador:
> On Tue, Feb 16, 2016 at 9:40 AM, Pascal Bach <pascal.bach@siemens.com> wrote:
>> Nginx has two supported branches, mainline and stable.
>> Currently meta-webserver contains the mainline version (1.9.x) of nginx.
>> For embedded system it might however be more appropriate to use the stable version (1.8.x)
>> which only receives security updates and bugfixes.
> Agreed; I also think 1.9 recipe ought to have default preference as -1
> so users take the stable by default.
>
I agree, but this will change the version for people using nginx not without setting preferred version.
Is this an issue? If not I will update the patchset and set DEFAULT_PREFERENCE for 1.9 to -1

Re: [meta-webserver][PATCH 2/2] nginx: add stable version 1.8.1 as alternative to the mainline version 1.9.x

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 2307 bytes --]

On Tue, Feb 16, 2016 at 12:40:45PM +0100, Pascal Bach wrote:
> The 1.8 branch is the current stable branch of nginx.
> This means the branch doesn't get new features, but is still supported with bugfixes.
> 
> Depending on the use case it is more suitable to use on an embedded device
> than the 1.9 branch which adds new features with every release.

NOTE: recipe nginx-1.8.1-r0: task do_configure: Started
ERROR: nginx-1.8.1-r0 do_configure: QA Issue: nginx: The
LIC_FILES_CHKSUM does not match for
file://LICENSE;md5=0bb58ed0dfd4f5dbece3b52aba79f023
nginx: The new md5 checksum is 3845852aedfa8d6d7765f55d06cc3ebd
nginx: Check if the license information has changed in
/home/jenkins/oe/world/shr-core/tmp-glibc/work/armv5te-oe-linux-gnueabi/nginx/1.8.1-r0/nginx-1.8.1/LICENSE
to verify that the LICENSE value "BSD-2-Clause" remains valid
[license-checksum]
ERROR: nginx-1.8.1-r0 do_configure: Fatal QA errors found, failing task.
ERROR: nginx-1.8.1-r0 do_configure: Function failed: do_qa_configure
ERROR: Logfile of failure stored in:
/home/jenkins/oe/world/shr-core/tmp-glibc/work/armv5te-oe-linux-gnueabi/nginx/1.8.1-r0/temp/log.do_configure.26965
NOTE: recipe nginx-1.8.1-r0: task do_configure: Failed
ERROR: Task 21522
(/home/jenkins/oe/world/shr-core/meta-openembedded/meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb,
do_configure) failed with exit code '1'

> ---
>  meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb | 4 ++++
>  1 file changed, 4 insertions(+)
>  create mode 100644 meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb
> 
> diff --git a/meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb b/meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb
> new file mode 100644
> index 0000000..ec3aef2
> --- /dev/null
> +++ b/meta-webserver/recipes-httpd/nginx/nginx_1.8.1.bb
> @@ -0,0 +1,4 @@
> +require nginx.inc
> +
> +SRC_URI[md5sum] = "2e91695074dbdfbf1bcec0ada9fda462"
> +SRC_URI[sha256sum] = "8f4b3c630966c044ec72715754334d1fdf741caa1d5795fb4646c27d09f797b7"
> -- 
> 2.1.4
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 188 bytes --]