[PATCH 0/7] Integrate OpenMP Accelerator Model

[PATCH 0/7] Integrate OpenMP Accelerator Model

[Jacob Stiffler]

Jacob Stiffler (7):
  openmpacc: Add clacc, the OpenMP-Acc compiler
  openmpacc: Add OpenMP-Acc library
  openmpacc-examples: Add the OpenMP-Acc examples
  arago-source-ipk: Enable openmpacc-examples source ipk
  packagegroup-arago-tisdk-addons*: Integrate openmpacc into the SDK
  nativesdk-packagegroup-arago-sdk-host: Add clacc to the devkit
  ti-tisdk-makefile: Add openmpacc-examples target

 .../conf/distro/arago-source-ipk.conf              |  3 +
 .../packagegroup-arago-tisdk-addons-sdk-host.bb    |  6 +-
 .../packagegroup-arago-tisdk-addons-sdk-target.bb  | 15 +++--
 .../packagegroup-arago-tisdk-addons.bb             |  6 +-
 .../ti-tisdk-makefile/Makefile_openmpacc-examples  | 32 ++++++++++
 .../ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb     |  7 ++-
 .../nativesdk-packagegroup-arago-sdk-host.bb       |  3 +-
 .../recipes-ti/openmpacc/clacc_git.bb              | 38 ++++++++++++
 .../recipes-ti/openmpacc/openmpacc-examples_git.bb | 72 ++++++++++++++++++++++
 .../recipes-ti/openmpacc/openmpacc.inc             | 21 +++++++
 .../recipes-ti/openmpacc/openmpacc_git.bb          | 19 ++++++
 11 files changed, 214 insertions(+), 8 deletions(-)
 create mode 100644 meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_openmpacc-examples
 create mode 100644 meta-arago-extras/recipes-ti/openmpacc/clacc_git.bb
 create mode 100644 meta-arago-extras/recipes-ti/openmpacc/openmpacc-examples_git.bb
 create mode 100644 meta-arago-extras/recipes-ti/openmpacc/openmpacc.inc
 create mode 100644 meta-arago-extras/recipes-ti/openmpacc/openmpacc_git.bb

-- 
1.9.1

[PATCH 1/7] openmpacc: Add clacc, the OpenMP-Acc compiler

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../recipes-ti/openmpacc/clacc_git.bb              | 38 ++++++++++++++++++++++
 .../recipes-ti/openmpacc/openmpacc.inc             | 21 ++++++++++++
 2 files changed, 59 insertions(+)
 create mode 100644 meta-arago-extras/recipes-ti/openmpacc/clacc_git.bb
 create mode 100644 meta-arago-extras/recipes-ti/openmpacc/openmpacc.inc

diff --git a/meta-arago-extras/recipes-ti/openmpacc/clacc_git.bb b/meta-arago-extras/recipes-ti/openmpacc/clacc_git.bb
new file mode 100644
index 0000000..f41c291
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/openmpacc/clacc_git.bb
@@ -0,0 +1,38 @@
+DESCRIPTION = "TI OpenMP-Acc C compiler"
+
+include openmpacc.inc
+
+PR = "${INC_PR}.0"
+
+DEPENDS = "boost elfutils"
+RDEPENDS_${PN} += "clocl"
+
+S = "${WORKDIR}/git/host"
+
+TARGET_class-target = "clacc_arm"
+TARGET_class-native = "clacc_x86"
+TARGET_class-nativesdk = "clacc_x86"
+
+export LINUX_DEVKIT_ROOT = "${STAGING_DIR_HOST}"
+export X86_HOST_ROOT = "${STAGING_DIR_HOST}"
+
+PARALLEL_MAKE = ""
+
+EXTRA_OEMAKE = " -C ${S}/clacc \
+                  ${TARGET} \
+                  CXX="${CXX}" \
+"
+
+do_compile() {
+    oe_runmake
+}
+
+do_install() {
+    install -d ${D}${bindir}
+    install -m 755 clacc/${TARGET} ${D}${bindir}/clacc
+
+    install -d ${D}${mandir}/man1
+    install -m 644 clacc/clacc.1 ${D}${mandir}/man1
+}
+
+BBCLASSEXTEND = "native nativesdk"
diff --git a/meta-arago-extras/recipes-ti/openmpacc/openmpacc.inc b/meta-arago-extras/recipes-ti/openmpacc/openmpacc.inc
new file mode 100644
index 0000000..4f55d0d
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/openmpacc/openmpacc.inc
@@ -0,0 +1,21 @@
+SUMMARY = "TI OpenMP Accelerator Model"
+HOMEPAGE = "http://downloads.ti.com/mctools/esd/docs/openmpacc/"
+LICENSE = "BSD"
+
+PV = "1.3.0.1"
+INC_PR = "r0"
+
+LIC_FILES_CHKSUM = "file://../debian/copyright;md5=aaa2a0939d08197132fc382e97b62eb0"
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/openmpacc:"
+
+OMPACC_GIT_URI = "git://git.ti.com/openmp/ti-openmpacc.git"
+OMPACC_GIT_PROTOCOL = "git"
+OMPACC_GIT_BRANCH = "master"
+
+OMPACC_SRCREV = "814accdbb441a3b258a548c6fbaa087b314ee18b"
+
+BRANCH = "${OMPACC_GIT_BRANCH}"
+SRC_URI = "${OMPACC_GIT_URI};protocol=${OMPACC_GIT_PROTOCOL};branch=${BRANCH}"
+SRCREV = "${OMPACC_SRCREV}"
+
-- 
1.9.1

[PATCH 2/7] openmpacc: Add OpenMP-Acc library

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../recipes-ti/openmpacc/openmpacc_git.bb             | 19 +++++++++++++++++++
 1 file changed, 19 insertions(+)
 create mode 100644 meta-arago-extras/recipes-ti/openmpacc/openmpacc_git.bb

diff --git a/meta-arago-extras/recipes-ti/openmpacc/openmpacc_git.bb b/meta-arago-extras/recipes-ti/openmpacc/openmpacc_git.bb
new file mode 100644
index 0000000..89f6b79
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/openmpacc/openmpacc_git.bb
@@ -0,0 +1,19 @@
+DESCRIPTION = "TI OpenMP-Acc host runtime and development packages"
+
+include openmpacc.inc
+
+PR = "${INC_PR}.0"
+
+inherit cmake
+
+DEPENDS = "boost boost-native opencl"
+RDEPENDS_${PN} += "opencl-runtime"
+
+S = "${WORKDIR}/git/host"
+
+export TARGET_ROOTDIR = "${STAGING_DIR_HOST}"
+export LINUX_DEVKIT_ROOT = "${STAGING_DIR_HOST}"
+
+EXTRA_OECMAKE += "-DVERSION="${PV}" -DBUILD_OUTPUT=lib"
+
+FILES_${PN} += "/usr/share/ti/openmpacc/*"
-- 
1.9.1

[PATCH 3/7] openmpacc-examples: Add the OpenMP-Acc examples

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../recipes-ti/openmpacc/openmpacc-examples_git.bb | 72 ++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 meta-arago-extras/recipes-ti/openmpacc/openmpacc-examples_git.bb

diff --git a/meta-arago-extras/recipes-ti/openmpacc/openmpacc-examples_git.bb b/meta-arago-extras/recipes-ti/openmpacc/openmpacc-examples_git.bb
new file mode 100644
index 0000000..9c7e85e
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/openmpacc/openmpacc-examples_git.bb
@@ -0,0 +1,72 @@
+DESCRIPTION = "TI OpenMP-Acc example applications"
+
+include openmpacc.inc
+
+PR = "${INC_PR}.0"
+
+DEPENDS = "openmpacc clacc-native clocl-native ti-cgt6x-native"
+RDEPENDS_${PN} += "opencl-runtime"
+
+S = "${WORKDIR}/git/openmpacc-examples-src"
+
+OMPACC_EXAMPLE_LIST = " target_update \
+                        vecadd \
+                        printf_debug \
+                        edmamgr \
+                        dspheap \
+                        target_orphan_call \
+                        target_implicit_map \
+                        vecadd_t \
+                        vecadd_complex \
+                        local \
+                        null \
+                        dsplib_fft \
+                        vecadd_lib \
+                        edmabw \
+                        sub_section \
+"
+
+python do_unpack_append() {
+    import shutil
+
+    git_dir = d.expand("${WORKDIR}/git/examples")
+    s = d.getVar("S", True)
+
+    os.makedirs(s)
+    shutil.copy(os.path.join(git_dir,"Makefile"),s)
+    shutil.copy(os.path.join(git_dir,"make.inc"),s)
+    shutil.copy(os.path.join(git_dir,"ompacc_env.sh"),s)
+    for example in d.getVar("OMPACC_EXAMPLE_LIST").split():
+        shutil.copytree(os.path.join(git_dir,example), os.path.join(s,example))
+}
+
+EXTRA_OEMAKE = " TARGET_ROOTDIR=${STAGING_DIR_HOST} \
+                 TI_OCL_CGT_INSTALL=${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x \
+"
+
+do_compile() {
+    oe_runmake
+}
+
+do_install() {
+    install -d ${D}${datadir}/ti/examples/openmpacc
+
+    install -m 644 ${B}/Makefile ${D}${datadir}/ti/examples/openmpacc
+    install -m 644 ${B}/make.inc ${D}${datadir}/ti/examples/openmpacc
+    install -m 644 ${B}/ompacc_env.sh ${D}${datadir}/ti/examples/openmpacc
+
+    for ompacc_example in ${OMPACC_EXAMPLE_LIST}; do
+        install -d ${D}${datadir}/ti/examples/openmpacc/${ompacc_example}
+        cp -rv ${B}/${ompacc_example}/* ${D}${datadir}/ti/examples/openmpacc/${ompacc_example}
+    done
+}
+
+FILES_${PN} += "\
+    ${datadir}/ti/examples/openmpacc \
+"
+
+FILES_${PN}-dbg += "\
+    ${datadir}/ti/examples/openmpacc/*/.debug \
+"
+
+INSANE_SKIP_${PN} = "arch ldflags textrel staticdev"
-- 
1.9.1

[PATCH 4/7] arago-source-ipk: Enable openmpacc-examples source ipk

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 meta-arago-distro/conf/distro/arago-source-ipk.conf | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/meta-arago-distro/conf/distro/arago-source-ipk.conf b/meta-arago-distro/conf/distro/arago-source-ipk.conf
index aec669e..054a86a 100644
--- a/meta-arago-distro/conf/distro/arago-source-ipk.conf
+++ b/meta-arago-distro/conf/distro/arago-source-ipk.conf
@@ -341,6 +341,9 @@ SRCIPK_INSTALL_DIR_pn-oe-layersetup = "bin/oe-layersetup"
 CREATE_SRCIPK_pn-opencl-examples = "1"
 SRCIPK_INSTALL_DIR_pn-opencl-examples = "example-applications/${PN}-${PV}"
 
+CREATE_SRCIPK_pn-openmpacc-examples = "1"
+SRCIPK_INSTALL_DIR_pn-openmpacc-examples = "example-applications/${PN}-${PV}"
+
 CREATE_SRCIPK_pn-qt-opencv-opencl-opengl-multithreaded = "1"
 SRCIPK_INSTALL_DIR_pn-qt-opencv-opencl-opengl-multithreaded = "example-applications/${PN}-${PV}"
 
-- 
1.9.1

[PATCH 5/7] packagegroup-arago-tisdk-addons*: Integrate openmpacc into the SDK

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../packagegroup-arago-tisdk-addons-sdk-host.bb           |  6 +++++-
 .../packagegroup-arago-tisdk-addons-sdk-target.bb         | 15 +++++++++++----
 .../packagegroups/packagegroup-arago-tisdk-addons.bb      |  6 +++++-
 3 files changed, 21 insertions(+), 6 deletions(-)

diff --git a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-host.bb b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-host.bb
index 3b97c18..a7b90fd 100644
--- a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-host.bb
+++ b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-host.bb
@@ -1,6 +1,6 @@
 DESCRIPTION = "Task to install sources for additional utilities/demos for SDKs"
 LICENSE = "MIT"
-PR = "r18"
+PR = "r19"
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
@@ -33,18 +33,22 @@ UTILS_append_ti43x = " \
 
 UTILS_append_dra7xx = " \
     opencl-examples-src \
+    openmpacc-examples-src \
 "
 
 UTILS_append_k2hk-evm = " \
     opencl-examples-src \
+    openmpacc-examples-src \
 "
 
 UTILS_append_k2l-evm = " \
     opencl-examples-src \
+    openmpacc-examples-src \
 "
 
 UTILS_append_k2e-evm = " \
     opencl-examples-src \
+    openmpacc-examples-src \
 "
 
 EXTRA_LIBS = ""
diff --git a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-target.bb b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-target.bb
index 6322ee8..6931150 100644
--- a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-target.bb
+++ b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons-sdk-target.bb
@@ -1,6 +1,6 @@
 DESCRIPTION = "Task to install headers and libraries related to addons into the SDK"
 LICENSE = "MIT"
-PR = "r23"
+PR = "r24"
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
@@ -123,10 +123,17 @@ UTILS_append_dra7xx = " canutils-dev \
                         opencl-staticdev \
                         elfutils-dev \
                         elfutils-staticdev \
+                        openmpacc-dev \
+"
+UTILS_append_k2hk-evm = " opencl-staticdev \
+                          openmpacc-dev \
+"
+UTILS_append_k2l-evm = " opencl-staticdev \
+                         openmpacc-dev \
+"
+UTILS_append_k2e-evm = " opencl-staticdev \
+                         openmpacc-dev \
 "
-UTILS_append_k2hk-evm = " opencl-staticdev"
-UTILS_append_k2l-evm = " opencl-staticdev"
-UTILS_append_k2e-evm = " opencl-staticdev"
 UTILS_append_k2g-evm = " canutils-dev"
 
 EXTRA_LIBS = ""
diff --git a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons.bb b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons.bb
index 3ab3bf8..8af7fcc 100644
--- a/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons.bb
+++ b/meta-arago-distro/recipes-core/packagegroups/packagegroup-arago-tisdk-addons.bb
@@ -1,6 +1,6 @@
 DESCRIPTION = "Task to install additional utilities/demos for SDKs"
 LICENSE = "MIT"
-PR = "r41"
+PR = "r42"
 
 PACKAGE_ARCH = "${MACHINE_ARCH}"
 
@@ -105,18 +105,22 @@ EXTRA_PACKAGES = " \
 EXTRA_PACKAGES_append_dra7xx = " \
     opencl-staticdev \
     opencl-examples-dev \
+    openmpacc-examples-dev \
 "
 EXTRA_PACKAGES_append_k2hk-evm = " \
     opencl-staticdev \
     opencl-examples-dev \
+    openmpacc-examples-dev \
 "
 EXTRA_PACKAGES_append_k2l-evm = " \
     opencl-staticdev \
     opencl-examples-dev \
+    openmpacc-examples-dev \
 "
 EXTRA_PACKAGES_append_k2e-evm = " \
     opencl-staticdev \
     opencl-examples-dev \
+    openmpacc-examples-dev \
 "
 
 RDEPENDS_${PN} = "\
-- 
1.9.1

[PATCH 6/7] nativesdk-packagegroup-arago-sdk-host: Add clacc to the devkit

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../packagegroups/nativesdk-packagegroup-arago-sdk-host.bb             | 3 ++-
 1 file changed, 2 insertions(+), 1 deletion(-)

diff --git a/meta-arago-extras/recipes-core/packagegroups/nativesdk-packagegroup-arago-sdk-host.bb b/meta-arago-extras/recipes-core/packagegroups/nativesdk-packagegroup-arago-sdk-host.bb
index 8f47c9c..42b93e7 100644
--- a/meta-arago-extras/recipes-core/packagegroups/nativesdk-packagegroup-arago-sdk-host.bb
+++ b/meta-arago-extras/recipes-core/packagegroups/nativesdk-packagegroup-arago-sdk-host.bb
@@ -1,5 +1,5 @@
 DESCRIPTION = "Host packages for a standalone Arago SDK or external toolchain"
-PR = "r11"
+PR = "r12"
 LICENSE = "MIT"
 
 inherit packagegroup nativesdk
@@ -7,6 +7,7 @@ inherit packagegroup nativesdk
 EXTRA_TOOLS = "nativesdk-ti-cgt6x \
                nativesdk-ti-cgt-pru \
                nativesdk-clocl \
+               nativesdk-clacc \
 "
 
 RDEPENDS_${PN} = "\
-- 
1.9.1

[PATCH 7/7] ti-tisdk-makefile: Add openmpacc-examples target

[Jacob Stiffler]

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
---
 .../ti-tisdk-makefile/Makefile_openmpacc-examples  | 32 ++++++++++++++++++++++
 .../ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb     |  7 ++++-
 2 files changed, 38 insertions(+), 1 deletion(-)
 create mode 100644 meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_openmpacc-examples

diff --git a/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_openmpacc-examples b/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_openmpacc-examples
new file mode 100644
index 0000000..e1842ba
--- /dev/null
+++ b/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_openmpacc-examples
@@ -0,0 +1,32 @@
+# OpenMP Accelerator Examples build targets
+openmpacc-examples:
+	@echo ================================================
+	@echo     Building the OpenMP Accelerator Examples
+	@echo ================================================
+	@cd example-applications; cd `find . -name "*openmpacc-examples*"`; . $(ENV_SETUP); make TARGET_ROOTDIR=$(SDK_PATH_TARGET) TI_OCL_CGT_INSTALL=$(SDK_PATH_TARGET)/usr/share/ti/cgt-c6x
+
+openmpacc-examples_install:
+	@echo ==================================================
+	@echo     Installing the OpenMP Accelerator Examples
+	@echo ==================================================
+	@if [ ! -d $(DESTDIR) ] ; then \
+		echo "The extracted target filesystem directory doesn't exist."; \
+		echo "Please run setup.sh in the SDK's root directory and then try again."; \
+		exit 1; \
+	fi
+	@cd example-applications; \
+	cd `find . -name "*openmpacc-examples*"`; \
+	for example in `find . -executable -not \( -type d -o -iname 'make*' \)`; do \
+		install -d $(DESTDIR)/usr/share/ti/examples/openmpacc/`dirname $${example}` ; \
+		install -m 755 $${example} $(DESTDIR)/usr/share/ti/examples/openmpacc/`dirname $${example}` ; \
+		if [ -f `dirname $${example}`/*.out ]; then \
+			install -m 755 `dirname $${example}`/*.out $(DESTDIR)/usr/share/ti/examples/openmpacc/`dirname $${example}` ; \
+		fi \
+	done
+
+openmpacc-examples_clean:
+	@echo ==================================================
+	@echo     Cleaning the OpenMP Accelerator Examples
+	@echo ==================================================
+	@cd example-applications; cd `find . -name "*openmpacc-examples*"`; . $(ENV_SETUP); make TARGET_ROOTDIR=$(SDK_PATH_TARGET) clean
+
diff --git a/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb b/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb
index b762b0e..bcd78ba 100644
--- a/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb
+++ b/meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb
@@ -44,9 +44,10 @@ SRC_URI = "\
     file://Makefile_pru-icss \
     file://Makefile_qt-opencv-opencl-opengl-multithreaded \
     file://Makefile_ipsecmgr-mod \
+    file://Makefile_openmpacc-examples \
 "
 
-PR = "r67"
+PR = "r68"
 
 MAKEFILES_MATRIX_GUI = "matrix-gui-browser \
                         refresh-screen \
@@ -101,6 +102,7 @@ MAKEFILES_append_dra7xx = " cryptodev \
                             debugss-module-drv \
                             gdbserverproxy-module-drv \
                             opencl-examples \
+                            openmpacc-examples \
                             qt-opencv-opencl-opengl-multithreaded \
 "
 
@@ -130,16 +132,19 @@ MAKEFILES_append_keystone = " u-boot-spl \
 MAKEFILES_append_k2hk-evm = " opencl-examples \
                               gdbserverproxy-module-drv \
                               debugss-module-drv \
+                              openmpacc-examples \
 "
 
 MAKEFILES_append_k2l-evm = " opencl-examples \
                              gdbserverproxy-module-drv \
                              debugss-module-drv \
+                             openmpacc-examples \
 "
 
 MAKEFILES_append_k2e-evm = " opencl-examples \
                              gdbserverproxy-module-drv \
                              debugss-module-drv \
+                             openmpacc-examples \
 "
 
 # Use ARCH format expected by the makefile
-- 
1.9.1

Re: [PATCH 0/7] Integrate OpenMP Accelerator Model

[Jacob Stiffler]

Ping,

On 2/19/2016 2:42 PM, Jacob Stiffler wrote:
> Jacob Stiffler (7):
>    openmpacc: Add clacc, the OpenMP-Acc compiler
>    openmpacc: Add OpenMP-Acc library
>    openmpacc-examples: Add the OpenMP-Acc examples
>    arago-source-ipk: Enable openmpacc-examples source ipk
>    packagegroup-arago-tisdk-addons*: Integrate openmpacc into the SDK
>    nativesdk-packagegroup-arago-sdk-host: Add clacc to the devkit
>    ti-tisdk-makefile: Add openmpacc-examples target
>
>   .../conf/distro/arago-source-ipk.conf              |  3 +
>   .../packagegroup-arago-tisdk-addons-sdk-host.bb    |  6 +-
>   .../packagegroup-arago-tisdk-addons-sdk-target.bb  | 15 +++--
>   .../packagegroup-arago-tisdk-addons.bb             |  6 +-
>   .../ti-tisdk-makefile/Makefile_openmpacc-examples  | 32 ++++++++++
>   .../ti-tisdk-makefile/ti-tisdk-makefile_1.0.bb     |  7 ++-
>   .../nativesdk-packagegroup-arago-sdk-host.bb       |  3 +-
>   .../recipes-ti/openmpacc/clacc_git.bb              | 38 ++++++++++++
>   .../recipes-ti/openmpacc/openmpacc-examples_git.bb | 72 ++++++++++++++++++++++
>   .../recipes-ti/openmpacc/openmpacc.inc             | 21 +++++++
>   .../recipes-ti/openmpacc/openmpacc_git.bb          | 19 ++++++
>   11 files changed, 214 insertions(+), 8 deletions(-)
>   create mode 100644 meta-arago-distro/recipes-tisdk/ti-tisdk-makefile/ti-tisdk-makefile/Makefile_openmpacc-examples
>   create mode 100644 meta-arago-extras/recipes-ti/openmpacc/clacc_git.bb
>   create mode 100644 meta-arago-extras/recipes-ti/openmpacc/openmpacc-examples_git.bb
>   create mode 100644 meta-arago-extras/recipes-ti/openmpacc/openmpacc.inc
>   create mode 100644 meta-arago-extras/recipes-ti/openmpacc/openmpacc_git.bb
>