[dunfell/master][PATCH 1/2] ti-rtos-metadata: add recipe to fetch and deploy metadata.inc for RTOS FW binary integration

[dunfell/master][PATCH 1/2] ti-rtos-metadata: add recipe to fetch and deploy metadata.inc for RTOS FW binary integration

[Denys Dmytriyenko]

From: Denys Dmytriyenko <denys@ti.com>

Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
 recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb | 41 ++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb

diff --git a/recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb b/recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb
new file mode 100644
index 0000000..985ff8a
--- /dev/null
+++ b/recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb
@@ -0,0 +1,41 @@
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/BSD-3-Clause;md5=550794465ba0ec5312d6919e203a55f9"
+
+COMPATIBLE_MACHINE = "k3"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+inherit nopackages deploy
+
+PLAT_SFX = ""
+PLAT_SFX_j7 = "/j721e"
+PLAT_SFX_j7200-evm = "/j7200"
+PLAT_SFX_am65xx = "/am65xx"
+
+# Use weak assignment to set defaults to TI_RTOS_METADATA_* variables
+TI_RTOS_METADATA_URI ?= "git://git.ti.com/processor-sdk/coresdk_rtos_releases.git"
+TI_RTOS_METADATA_PROTOCOL ?= "git"
+TI_RTOS_METADATA_SRCREV ?= "2290c123a0c4ba4804d794c39532296a9c7b9587"
+TI_RTOS_METADATA_BRANCH ?= "master"
+TI_RTOS_METADATA_DIR ?= "${PLAT_SFX}"
+TI_RTOS_METADATA_FILE ?= "${S}${TI_RTOS_METADATA_DIR}/metadata.inc"
+
+PV = "1.0.0"
+
+S = "${WORKDIR}/git"
+
+SRC_URI = "${TI_RTOS_METADATA_URI};branch=${TI_RTOS_METADATA_BRANCH};protocol=${TI_RTOS_METADATA_PROTOCOL}"
+SRCREV = "${TI_RTOS_METADATA_SRCREV}"
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+do_install[noexec] = "1"
+
+do_deploy () {
+	install -d ${DEPLOYDIR}
+	install -m 0644 ${TI_RTOS_METADATA_FILE} ${DEPLOYDIR}/
+}
+
+addtask deploy before do_build after do_compile
-- 
2.7.4

[dunfell/master][PATCH 2/2] ti-rtos-firmware: add recipe for RTOS FW binary integration

[Denys Dmytriyenko]

From: Denys Dmytriyenko <denys@ti.com>

Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
 recipes-ti/ti-rtos-bin/files/empty         |  1 +
 recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb | 85 ++++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)
 create mode 100644 recipes-ti/ti-rtos-bin/files/empty
 create mode 100644 recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb

diff --git a/recipes-ti/ti-rtos-bin/files/empty b/recipes-ti/ti-rtos-bin/files/empty
new file mode 100644
index 0000000..c6cac69
--- /dev/null
+++ b/recipes-ti/ti-rtos-bin/files/empty
@@ -0,0 +1 @@
+empty
diff --git a/recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb b/recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb
new file mode 100644
index 0000000..9202b52
--- /dev/null
+++ b/recipes-ti/ti-rtos-bin/ti-rtos-firmware.bb
@@ -0,0 +1,85 @@
+SUMMARY = "TI RTOS prebuilt binary firmware images"
+
+LICENSE = "TI-TFL"
+LIC_FILES_CHKSUM = "file://${COREBASE}/../meta-ti/licenses/TI-TFL;md5=a1b59cb7ba626b9dbbcbf00f3fbc438a"
+
+COMPATIBLE_MACHINE = "k3"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+INHIBIT_DEFAULT_DEPS = "1"
+DATEH := "${@time.strftime('%Y%m%d%H',time.gmtime())}"
+
+inherit deploy
+
+# First, let's try including metadata.inc that could be fetched and deployed
+# by ti-rtos-metadata earlier and provide new set of CORESDK_RTOS_* variables
+include ${DEPLOY_DIR_IMAGE}/metadata.inc
+
+# Set some defaults for when metadata.inc is not available
+DEFAULT_RTOS_FAMILY = "jacinto"
+DEFAULT_RTOS_VERSION = "07_01_00_02"
+DEFAULT_RTOS_VERSION_DOT = "07.01.00.02"
+
+DEFAULT_RTOS_SOC = "undefined"
+DEFAULT_RTOS_SOC_j7 = "j721e"
+DEFAULT_RTOS_SOC_j7200-evm = "j7200"
+DEFAULT_RTOS_SOC_am65xx = "am65xx"
+
+DEFAULT_RTOS_WEBLINK = "undefined"
+DEFAULT_RTOS_WEBLINK_j7 = "https://software-dl.ti.com/jacinto7/esd/processor-sdk-rtos-jacinto7/firmware/${CORESDK_RTOS_VERSION}"
+DEFAULT_RTOS_WEBLINK_am65xx = "https://software-dl.ti.com/processor-sdk-rtos/esd/AM65X/firmware/${CORESDK_RTOS_VERSION}"
+
+DEFAULT_FIRMWARE_FILE = "coresdk_rtos_${CORESDK_RTOS_SOC}_${CORESDK_RTOS_VERSION}_firmware.tar.xz"
+
+DEFAULT_FIRMWARE_URL = "file://empty"
+DEFAULT_FIRMWARE_URL_k3 = "${CORESDK_RTOS_WEBLINK}/${DEFAULT_FIRMWARE_FILE}${CORESDK_RTOS_FILE_SUFFIX}"
+
+DEFAULT_FIRMWARE_SHA256SUM = "unknown"
+DEFAULT_FIRMWARE_SHA256SUM_j7 = "e1e2eb0086a28468f1bb4b796571dcf1bfa23aedbb092bd02227e777a078afe3"
+DEFAULT_FIRMWARE_SHA256SUM_j7200-evm = "218e51739c53e306cc61bbb705b3d8eeae3afb63869f2aa82a4c804f7847bd63"
+DEFAULT_FIRMWARE_SHA256SUM_am65xx = "37188564fbb8420ba9dadb74ecf05b3aac2bf39a0e72c18c23272a141e69ace7"
+
+# Use weak assignment for CORESDK_RTOS_* variables to use defaults if not yet set
+CORESDK_RTOS_FAMILY ?= "${DEFAULT_RTOS_FAMILY}"
+CORESDK_RTOS_VERSION ?= "${DEFAULT_RTOS_VERSION}"
+CORESDK_RTOS_VERSION_DOT ?= "${DEFAULT_RTOS_VERSION_DOT}"
+CORESDK_RTOS_SOC ?= "${DEFAULT_RTOS_SOC}"
+CORESDK_RTOS_WEBLINK ?= "${DEFAULT_RTOS_WEBLINK}"
+CORESDK_RTOS_FIRMWARE_URL ?= "${DEFAULT_FIRMWARE_URL}"
+CORESDK_RTOS_FIRMWARE_SHA256SUM ?= "${DEFAULT_FIRMWARE_SHA256SUM}"
+CORESDK_RTOS_FILE_SUFFIX ?= ""
+
+# Common code below
+S = "${WORKDIR}/lib/"
+
+PV = "${CORESDK_RTOS_VERSION_DOT}"
+
+SRC_URI = "${CORESDK_RTOS_FIRMWARE_URL}"
+SRC_URI[sha256sum] = "${CORESDK_RTOS_FIRMWARE_SHA256SUM}"
+
+FILES_${PN} += "${base_libdir}"
+
+python do_unpack_append() {
+    import os.path
+    from os import path
+    fromfn = d.getVar('DATEH')+"-"+d.getVar('DEFAULT_FIRMWARE_FILE')
+    tofn = d.getVar('DEFAULT_FIRMWARE_FILE')
+    if path.exists(fromfn):
+        os.rename(fromfn, tofn)
+}
+
+do_install() {
+	CP_ARGS="-Prf --preserve=mode,timestamps --no-preserve=ownership"
+	install -d ${D}${base_libdir}
+	cp ${CP_ARGS} ${S} ${D}
+}
+
+FILES_${PN} = "${base_libdir}"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INSANE_SKIP_${PN} += "arch"
+
+do_compile[noexec] = "1"
+do_configure[noexec] = "1"
-- 
2.7.4

Re: [EXTERNAL] [meta-ti] [dunfell/master][PATCH 1/2] ti-rtos-metadata: add recipe to fetch and deploy metadata.inc for RTOS FW binary integration

[Jacob Stiffler]

[-- Attachment #1: Type: text/plain, Size: 2127 bytes --]


On 8/19/2020 11:48 PM, Denys Dmytriyenko wrote:
> From: Denys Dmytriyenko <denys@ti.com>
>
> Signed-off-by: Denys Dmytriyenko <denys@ti.com>
> ---
>   recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb | 41 ++++++++++++++++++++++++++++++
>   1 file changed, 41 insertions(+)
>   create mode 100644 recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb
>
> diff --git a/recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb b/recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb
> new file mode 100644
> index 0000000..985ff8a
> --- /dev/null
> +++ b/recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb
> @@ -0,0 +1,41 @@
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/BSD-3-Clause;md5=550794465ba0ec5312d6919e203a55f9"
> +
> +COMPATIBLE_MACHINE = "k3"
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +INHIBIT_DEFAULT_DEPS = "1"
> +
> +inherit nopackages deploy
> +
> +PLAT_SFX = ""
> +PLAT_SFX_j7 = "/j721e"
> +PLAT_SFX_j7200-evm = "/j7200"
> +PLAT_SFX_am65xx = "/am65xx"
> +
> +# Use weak assignment to set defaults to TI_RTOS_METADATA_* variables
> +TI_RTOS_METADATA_URI ?= "git://git.ti.com/processor-sdk/coresdk_rtos_releases.git"
> +TI_RTOS_METADATA_PROTOCOL ?= "git"
> +TI_RTOS_METADATA_SRCREV ?= "2290c123a0c4ba4804d794c39532296a9c7b9587"
> +TI_RTOS_METADATA_BRANCH ?= "master"
> +TI_RTOS_METADATA_DIR ?= "${PLAT_SFX}"
> +TI_RTOS_METADATA_FILE ?= "${S}${TI_RTOS_METADATA_DIR}/metadata.inc"
> +
> +PV = "1.0.0"

Since this may be set to AUTOREV, I would suggest adding SRCPV here. 
This will help track to exact version as well as ensure that the remote 
is checked upon each build and that the commit ID is not just cached.

> +
> +S = "${WORKDIR}/git"
> +
> +SRC_URI = "${TI_RTOS_METADATA_URI};branch=${TI_RTOS_METADATA_BRANCH};protocol=${TI_RTOS_METADATA_PROTOCOL}"
> +SRCREV = "${TI_RTOS_METADATA_SRCREV}"
> +
> +do_configure[noexec] = "1"
> +do_compile[noexec] = "1"
> +do_install[noexec] = "1"
> +
> +do_deploy () {
> +	install -d ${DEPLOYDIR}
> +	install -m 0644 ${TI_RTOS_METADATA_FILE} ${DEPLOYDIR}/
> +}
> +
> +addtask deploy before do_build after do_compile
>
> 

[-- Attachment #2: Type: text/html, Size: 2968 bytes --]

Re: [EXTERNAL] [meta-ti] [dunfell/master][PATCH 1/2] ti-rtos-metadata: add recipe to fetch and deploy metadata.inc for RTOS FW binary integration

[Denys Dmytriyenko]

On Thu, Aug 20, 2020 at 09:59:58AM -0400, Jacob Stiffler wrote:
> 
> On 8/19/2020 11:48 PM, Denys Dmytriyenko wrote:
> >From: Denys Dmytriyenko <denys@ti.com>
> >
> >Signed-off-by: Denys Dmytriyenko <denys@ti.com>
> >---
> >  recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb | 41 ++++++++++++++++++++++++++++++
> >  1 file changed, 41 insertions(+)
> >  create mode 100644 recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb
> >
> >diff --git a/recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb b/recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb
> >new file mode 100644
> >index 0000000..985ff8a
> >--- /dev/null
> >+++ b/recipes-ti/ti-rtos-bin/ti-rtos-metadata.bb
> >@@ -0,0 +1,41 @@
> >+LICENSE = "BSD-3-Clause"
> >+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/BSD-3-Clause;md5=550794465ba0ec5312d6919e203a55f9"
> >+
> >+COMPATIBLE_MACHINE = "k3"
> >+
> >+PACKAGE_ARCH = "${MACHINE_ARCH}"
> >+
> >+INHIBIT_DEFAULT_DEPS = "1"
> >+
> >+inherit nopackages deploy
> >+
> >+PLAT_SFX = ""
> >+PLAT_SFX_j7 = "/j721e"
> >+PLAT_SFX_j7200-evm = "/j7200"
> >+PLAT_SFX_am65xx = "/am65xx"
> >+
> >+# Use weak assignment to set defaults to TI_RTOS_METADATA_* variables
> >+TI_RTOS_METADATA_URI ?= "git://git.ti.com/processor-sdk/coresdk_rtos_releases.git"
> >+TI_RTOS_METADATA_PROTOCOL ?= "git"
> >+TI_RTOS_METADATA_SRCREV ?= "2290c123a0c4ba4804d794c39532296a9c7b9587"
> >+TI_RTOS_METADATA_BRANCH ?= "master"
> >+TI_RTOS_METADATA_DIR ?= "${PLAT_SFX}"
> >+TI_RTOS_METADATA_FILE ?= "${S}${TI_RTOS_METADATA_DIR}/metadata.inc"
> >+
> >+PV = "1.0.0"
> 
> Since this may be set to AUTOREV, I would suggest adding SRCPV here. This
> will help track to exact version as well as ensure that the remote is
> checked upon each build and that the commit ID is not just cached.

Sounds good, thanks.


> >+S = "${WORKDIR}/git"
> >+
> >+SRC_URI = "${TI_RTOS_METADATA_URI};branch=${TI_RTOS_METADATA_BRANCH};protocol=${TI_RTOS_METADATA_PROTOCOL}"
> >+SRCREV = "${TI_RTOS_METADATA_SRCREV}"
> >+
> >+do_configure[noexec] = "1"
> >+do_compile[noexec] = "1"
> >+do_install[noexec] = "1"
> >+
> >+do_deploy () {
> >+	install -d ${DEPLOYDIR}
> >+	install -m 0644 ${TI_RTOS_METADATA_FILE} ${DEPLOYDIR}/
> >+}
> >+
> >+addtask deploy before do_build after do_compile
> >
> >