[PATCH 0/4] Qt4 application fixes

[PATCH 0/4] Qt4 application fixes

[Paul Eggleton]

Fix Qt4 runtime dependencies for all of our current Qt4 applications.
Addresses [BUGID: 524].

Some notes:
* qmmp is now building with cmake. This took quite a few additions to 
  EXTRA_OECMAKE and I suspect there is a case for having a "qt4cmake" bbclass
  or similar to make this reusable - further discussion needed.
* qmmp packaging is not perfect, there are still quite a few unpackaged 
  files; however it should at least now be usable. How much further to go 
  really depends on the purpose of having it in poky.

Pull URL: git://git.pokylinux.org/poky-contrib.git
  Branch: paule/qt-fixes
  Browse: http://git.pokylinux.org/cgit.cgi/poky-contrib/log/?h=paule/qt-fixes

Thanks,
    Paul Eggleton <paul.eggleton@linux.intel.com>
---


Paul Eggleton (4):
  qmake2.bbclass: add space to end of DEPENDS_prepend
  fotowall: fix runtime Qt4 dependencies
  quicky: fix Qt4 runtime dependencies
  qmmp: fix dependencies and packaging

 meta/classes/qmake2.bbclass             |    2 +-
 meta/recipes-qt/qt-apps/fotowall_0.9.bb |    4 ++-
 meta/recipes-qt/qt-apps/qmmp_0.4.1.bb   |   54 +++++++++++++++++-------------
 meta/recipes-qt/qt-apps/quicky_0.4.bb   |    1 -
 4 files changed, 35 insertions(+), 26 deletions(-)

[PATCH 1/4] qmake2.bbclass: add space to end of DEPENDS_prepend

[Paul Eggleton]

There needs to be a space at the end of DEPENDS_prepend or otherwise it can
collide with the contents of DEPENDS. The OE version of this file has this.

Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
---
 meta/classes/qmake2.bbclass |    2 +-
 1 files changed, 1 insertions(+), 1 deletions(-)

diff --git a/meta/classes/qmake2.bbclass b/meta/classes/qmake2.bbclass
index e681026..3772189 100644
--- a/meta/classes/qmake2.bbclass
+++ b/meta/classes/qmake2.bbclass
@@ -3,7 +3,7 @@
 #
 inherit qmake_base
 
-DEPENDS_prepend = "qt4-tools-native"
+DEPENDS_prepend = "qt4-tools-native "
 
 export QMAKESPEC = "${STAGING_DATADIR}/qt4/mkspecs/${TARGET_OS}-oe-g++"
 export OE_QMAKE_UIC = "${STAGING_BINDIR_NATIVE}/uic4"
-- 
1.7.1

[PATCH 2/4] fotowall: fix runtime Qt4 dependencies

[Paul Eggleton]

Fix the runtime dependencies of fotowall so it doesn't drag in the whole of
Qt4. As a bonus the appropriate Qt image plugins for loading jpeg, gif & tiff
files are now installed with fotowall making it actually usable.

Fixes [BUGID: #524]

Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
---
 meta/recipes-qt/qt-apps/fotowall_0.9.bb |    4 +++-
 1 files changed, 3 insertions(+), 1 deletions(-)

diff --git a/meta/recipes-qt/qt-apps/fotowall_0.9.bb b/meta/recipes-qt/qt-apps/fotowall_0.9.bb
index 30dca4e..c5c751d 100644
--- a/meta/recipes-qt/qt-apps/fotowall_0.9.bb
+++ b/meta/recipes-qt/qt-apps/fotowall_0.9.bb
@@ -7,8 +7,10 @@ LIC_FILES_CHKSUM = "file://GPL_V2;md5=79808397c3355f163c012616125c9e26 \
                     file://main.cpp;beginline=6;endline=11;md5=b569acc2bf8974a3082b58fc53b9d8dc"
 SECTION = "x11/apps"
 
+PR = "r1"
+
 DEPENDS = "qt4-x11-free"
-RDEPENDS = "qt4-x11-free"
+RRECOMMENDS_${PN} += "qt4-plugin-imageformat-gif qt4-plugin-imageformat-jpeg qt4-plugin-imageformat-tiff"
 
 SRC_URI = "http://qt-apps.org/CONTENT/content-files/71316-Fotowall-0.9.tar.bz2"
 
-- 
1.7.1

[PATCH 3/4] quicky: fix Qt4 runtime dependencies

[Paul Eggleton]

Avoid dragging in all of Qt4

Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
---
 meta/recipes-qt/qt-apps/quicky_0.4.bb |    1 -
 1 files changed, 0 insertions(+), 1 deletions(-)

diff --git a/meta/recipes-qt/qt-apps/quicky_0.4.bb b/meta/recipes-qt/qt-apps/quicky_0.4.bb
index 004e029..9e367f2 100644
--- a/meta/recipes-qt/qt-apps/quicky_0.4.bb
+++ b/meta/recipes-qt/qt-apps/quicky_0.4.bb
@@ -5,7 +5,6 @@ LIC_FILES_CHKSUM = "file://version.h;endline=19;md5=878bdaff438dab86298301fd1a21
 SECTION = "x11/apps"
 
 DEPENDS = "qt4-x11-free"
-RDEPENDS = "qt4-x11-free"
 
 SRC_URI = "http://qt-apps.org/CONTENT/content-files/80325-quicky-0.4.tar.gz"
 
-- 
1.7.1

[PATCH 4/4] qmmp: fix dependencies and packaging

[Paul Eggleton]

* Don't drag in all of Qt as runtime dependencies
* Use cmake instead of qmake. This ensures plugins are configured correctly.
* Split out vorbis and mad input plugins into separate packages
* Fix main package to include an output plugin and various other base files.

Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
---
 meta/recipes-qt/qt-apps/qmmp_0.4.1.bb |   54 +++++++++++++++++++--------------
 1 files changed, 31 insertions(+), 23 deletions(-)

diff --git a/meta/recipes-qt/qt-apps/qmmp_0.4.1.bb b/meta/recipes-qt/qt-apps/qmmp_0.4.1.bb
index c5afd91..bf99697 100644
--- a/meta/recipes-qt/qt-apps/qmmp_0.4.1.bb
+++ b/meta/recipes-qt/qt-apps/qmmp_0.4.1.bb
@@ -4,32 +4,40 @@ LICENSE = "GPLv2"
 LIC_FILES_CHKSUM = "file://COPYING;md5=393a5ca445f6965873eca0259a17f833"
 SECTION = "multimedia"
 
-PR = "r1"
+PR = "r2"
 
-DEPENDS = "qt4-x11-free taglib"
-RDEPENDS = "qt4-x11-free libmad libvorbis libogg taglib alsa-lib curl"
+DEPENDS = "qt4-x11-free taglib libmad libvorbis libogg alsa-lib"
+RDEPENDS_${PN} += "taglib alsa-lib curl"
 
 SRC_URI = "http://qmmp.ylsoftware.com/files/qmmp-0.4.1.tar.bz2"
 
 PARALLEL_MAKE = ""
 
-inherit qmake2 pkgconfig
-
-do_configure_prepend() {
-	# fix qt4 lrelease name
-	sed -i -e 's/lrelease-qt4/lrelease4/' ${S}/qmmp.pro
-
-	# disable the unsupported plugin
-	for plugin in sndfile wavpack ; do
-		sed -i -e "s/$plugin//" ${S}/src/plugins/Input/Input.pro
-	done
-	sed -i -e 's/mms//' ${S}/src/plugins/Transports/Transports.pro
-	sed -i -e 's/srconverter//' ${S}/src/plugins/Effect/Effect.pro
-
-	sed -i -e 's/^CONFIG/#CONFIG/' ${S}/qmmp.pri
-	sed -i -e 's/CONFIG += WITH_ENCA/#CONFIG += WITH_ENCA/' ${S}/qmmp.pri
-}
-
-do_install() {
-	oe_runmake INSTALL_ROOT=${D} install
-}
+inherit qmake2 cmake
+
+export EXTRA_OECMAKE = "-DQT_QMAKE_EXECUTABLE=${OE_QMAKE_QMAKE} \
+                        -DQT_LRELEASE_EXECUTABLE=${OE_QMAKE_LRELEASE} \
+                        -DQT_MOC_EXECUTABLE=${OE_QMAKE_MOC} \
+                        -DQT_UIC_EXECUTABLE=${OE_QMAKE_UIC} \
+                        -DQT_RCC_EXECUTABLE=${OE_QMAKE_RCC} \
+                        -DQT_LIBRARY_DIR=${OE_QMAKE_LIBDIR_QT} \
+                        -DQT_HEADERS_DIR=${OE_QMAKE_INCDIR_QT} \
+                        -DQT_QTCORE_INCLUDE_DIR=${OE_QMAKE_INCDIR_QT}/QtCore \
+                        "
+
+FILES_${PN} = "${bindir}/qmmp ${libdir}/*.so* \ 
+               ${libdir}/qmmp/PlaylistFormats/*.so \
+               ${libdir}/qmmp/Output/libalsa.so \
+               ${libdir}/qmmp/Transports/libhttp.so \
+               ${libdir}/qmmp/Visual/libanalyzer.so \
+               ${datadir}/icons/* \
+               ${datadir}/qmmp/images/* \
+               ${datadir}/applications/qmmp.desktop \
+               "
+
+PACKAGES += "${PN}-plugin-input-mad ${PN}-plugin-input-vorbis"
+
+FILES_${PN}-plugin-input-mad = "${libdir}/qmmp/Input/libmad.so"
+RDEPENDS_${PN}-plugin-input-mad = "libmad"
+FILES_${PN}-plugin-input-vorbis = "${libdir}/qmmp/Input/libvorbis.so"
+RDEPENDS_${PN}-plugin-input-vorbis = "libvorbis libogg"
-- 
1.7.1

Re: [PATCH 0/4] Qt4 application fixes

[Richard Purdie]

On Thu, 2010-12-23 at 15:10 +0000, Paul Eggleton wrote:
> Fix Qt4 runtime dependencies for all of our current Qt4 applications.
> Addresses [BUGID: 524].
> 
> Some notes:
> * qmmp is now building with cmake. This took quite a few additions to 
>   EXTRA_OECMAKE and I suspect there is a case for having a "qt4cmake" bbclass
>   or similar to make this reusable - further discussion needed.
> * qmmp packaging is not perfect, there are still quite a few unpackaged 
>   files; however it should at least now be usable. How much further to go 
>   really depends on the purpose of having it in poky.
> 
> Pull URL: git://git.pokylinux.org/poky-contrib.git
>   Branch: paule/qt-fixes
>   Browse: http://git.pokylinux.org/cgit.cgi/poky-contrib/log/?h=paule/qt-fixes

These look good to me, merged into master, thanks!

Richard