[PATCH 0/6] transfig recipe and dependencies

[PATCH 0/6] transfig recipe and dependencies

[Scott Garman]

From: Scott Garman <scott.a.garman@intel.com>

Hi Saul,

This patch series adds the transfig recipe to Poky and its
dependencies. prelink is the first package I've found which
requires transfig. 

Additionally, these changes will allow us to build other
packages which use Imake / xmkfms (and old build system
used commonly by older X11 utilities).

Pull URL: git://git.pokylinux.org/poky-contrib.git
  Branch: sgarman/transfig
  Browse: http://git.pokylinux.org/cgit.cgi/poky-contrib/log/?h=sgarman/transfig

Thanks,
    Scott Garman <scott.a.garman@intel.com>
---


Scott Garman (6):
  xorg-cf-files: new recipe v1.0.4
  libxext: add native support to recipe
  libxpm: add native support to recipe
  imake: add native support to recipe and update DEPENDS
  transfig: new recipe v3.2.5d
  prelink: add transfig to DEPENDS

 meta/recipes-devtools/prelink/prelink_git.bb       |    2 +-
 .../transfig/transfig-native_3.2.5d.bb             |   40 ++++++++++++++++++++
 meta/recipes-graphics/xorg-lib/libxext_1.2.0.bb    |    2 +-
 meta/recipes-graphics/xorg-lib/libxpm_3.5.9.bb     |    2 +
 meta/recipes-graphics/xorg-util/imake_1.0.4.bb     |   10 ++--
 .../xorg-util/xorg-cf-files_1.0.4.bb               |   14 +++++++
 6 files changed, 63 insertions(+), 7 deletions(-)
 create mode 100644 meta/recipes-devtools/transfig/transfig-native_3.2.5d.bb
 create mode 100644 meta/recipes-graphics/xorg-util/xorg-cf-files_1.0.4.bb

-- 
1.7.4

[PATCH 3/6] libxpm: add native support to recipe

[Scott Garman]

From: Scott Garman <scott.a.garman@intel.com>

The native recipe is needed by the transfig-native dependency chain.

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 meta/recipes-graphics/xorg-lib/libxpm_3.5.9.bb |    2 ++
 1 files changed, 2 insertions(+), 0 deletions(-)

diff --git a/meta/recipes-graphics/xorg-lib/libxpm_3.5.9.bb b/meta/recipes-graphics/xorg-lib/libxpm_3.5.9.bb
index 1a548fa..a4b3c0d 100644
--- a/meta/recipes-graphics/xorg-lib/libxpm_3.5.9.bb
+++ b/meta/recipes-graphics/xorg-lib/libxpm_3.5.9.bb
@@ -21,3 +21,5 @@ FILES_sxpm = "${bindir}/sxpm"
 
 SRC_URI[md5sum] = "2de3a1b9541f4b3a6f9d84b69d25530e"
 SRC_URI[sha256sum] = "8add01029cab0598ca86e01a2f7781a636f74b757abe6b50ba61b2a6e2fd621e"
+
+BBCLASSEXTEND = "native"
-- 
1.7.4

[PATCH 1/6] xorg-cf-files: new recipe v1.0.4

[Scott Garman]

From: Scott Garman <scott.a.garman@intel.com>

This package includes configuration files needed for old x11
imake-based packages - transfig in particular.

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 .../xorg-util/xorg-cf-files_1.0.4.bb               |   14 ++++++++++++++
 1 files changed, 14 insertions(+), 0 deletions(-)
 create mode 100644 meta/recipes-graphics/xorg-util/xorg-cf-files_1.0.4.bb

diff --git a/meta/recipes-graphics/xorg-util/xorg-cf-files_1.0.4.bb b/meta/recipes-graphics/xorg-util/xorg-cf-files_1.0.4.bb
new file mode 100644
index 0000000..a5de00a
--- /dev/null
+++ b/meta/recipes-graphics/xorg-util/xorg-cf-files_1.0.4.bb
@@ -0,0 +1,14 @@
+require xorg-util-common.inc
+
+SUMMARY = "Data files for the imake utility"
+DESCRIPTION = "Data files for the imake utility"
+LIC_FILES_CHKSUM = "file://COPYING;md5=0f334a06f2de517e37e86d6757167d88"
+
+DEPENDS = "font-util"
+
+PR = "r0"
+
+SRC_URI[md5sum] = "ff4502b6e31aac90e24ce134090d0e46"
+SRC_URI[sha256sum] = "8fc8a1224d2a716b1f3f1ca85dfda02387ab215251b8eddd03551eac998c9cb8"
+
+BBCLASSEXTEND = "native"
-- 
1.7.4

[PATCH 4/6] imake: add native support to recipe and update DEPENDS

[Scott Garman]

From: Scott Garman <scott.a.garman@intel.com>

xorg-cf-files includes configuration files used by imake-based
recipes. Also add native support to the recipe.

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 meta/recipes-graphics/xorg-util/imake_1.0.4.bb |   10 +++++-----
 1 files changed, 5 insertions(+), 5 deletions(-)

diff --git a/meta/recipes-graphics/xorg-util/imake_1.0.4.bb b/meta/recipes-graphics/xorg-util/imake_1.0.4.bb
index 9202317..e313442 100644
--- a/meta/recipes-graphics/xorg-util/imake_1.0.4.bb
+++ b/meta/recipes-graphics/xorg-util/imake_1.0.4.bb
@@ -1,20 +1,20 @@
 require xorg-util-common.inc
 
 SUMMARY = "C preprocessor interface to the make utility"
-
 DESCRIPTION = "Imake is used to generate Makefiles from a template, a \
 set of cpp macro functions, and a per-directory input file called an \
 Imakefile. This allows machine dependencies (such as compiler options, \
 alternate command names, and special make rules) to be kept separate \
 from the descriptions of the various items to be built."
+LIC_FILES_CHKSUM = "file://COPYING;md5=b9c6cfb044c6d0ff899eaafe4c729367"
 
-DEPENDS = "util-macros"
+DEPENDS = "util-macros xproto xorg-cf-files"
 RDEPENDS_${PN} = "perl xproto"
 
-LIC_FILES_CHKSUM = "file://COPYING;md5=b9c6cfb044c6d0ff899eaafe4c729367"
-
-PR = "r1"
+PR = "r2"
 PE = "1"
 
 SRC_URI[md5sum] = "0fd1e53d94142ddee5340f87de0b9561"
 SRC_URI[sha256sum] = "68038fa67929c5553044ad7417e1a64cabe954f04213b305dd36a04a61317d31"
+
+BBCLASSEXTEND = "native"
-- 
1.7.4

[PATCH 2/6] libxext: add native support to recipe

[Scott Garman]

From: Scott Garman <scott.a.garman@intel.com>

The native recipe is needed by the transfig-native dependency chain.

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 meta/recipes-graphics/xorg-lib/libxext_1.2.0.bb |    2 +-
 1 files changed, 1 insertions(+), 1 deletions(-)

diff --git a/meta/recipes-graphics/xorg-lib/libxext_1.2.0.bb b/meta/recipes-graphics/xorg-lib/libxext_1.2.0.bb
index b907b9f..679bb1a 100644
--- a/meta/recipes-graphics/xorg-lib/libxext_1.2.0.bb
+++ b/meta/recipes-graphics/xorg-lib/libxext_1.2.0.bb
@@ -21,7 +21,7 @@ PE = "1"
 
 XORG_PN = "libXext"
 
-BBCLASSEXTEND = "nativesdk"
+BBCLASSEXTEND = "native nativesdk"
 
 SRC_URI[md5sum] = "9bb236ff0193e9fc1c1fb504dd840331"
 SRC_URI[sha256sum] = "4aed3e211e41c47908c293515580e731c26048f61a1212bf0888d1f456de6ff7"
-- 
1.7.4

[PATCH 5/6] transfig: new recipe v3.2.5d

[Scott Garman]

From: Scott Garman <scott.a.garman@intel.com>

Transfig provides fig2dev, which is used when building
documentation for many packages.

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 .../transfig/transfig-native_3.2.5d.bb             |   40 ++++++++++++++++++++
 1 files changed, 40 insertions(+), 0 deletions(-)
 create mode 100644 meta/recipes-devtools/transfig/transfig-native_3.2.5d.bb

diff --git a/meta/recipes-devtools/transfig/transfig-native_3.2.5d.bb b/meta/recipes-devtools/transfig/transfig-native_3.2.5d.bb
new file mode 100644
index 0000000..62b8023
--- /dev/null
+++ b/meta/recipes-devtools/transfig/transfig-native_3.2.5d.bb
@@ -0,0 +1,40 @@
+SUMMARY = "Utilities for converting XFig figure files"
+DESCRIPTION = "This package contains utilities (mainly fig2dev) to \
+handle XFig (Facility for Interactive Generation of figures) files."
+HOMEPAGE = "http://www-epb.lbl.gov/xfig/"
+SECTION = "console/utils"
+PRIORITY = "required"
+LICENSE = "xfig"
+LIC_FILES_CHKSUM = "file://fig2dev/fig2dev.c;endline=16;md5=6bab01e017409cf9ab21d3e953b793f7"
+PR = "r0"
+
+DEPENDS = "imake-native xorg-cf-files-native zlib-native jpeg-native libpng-native libxpm-native"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/mcj/transfig.${PV}.tar.gz"
+
+SRC_URI[md5sum] = "f9eac7f265668ecbfda6aaf7581989ad"
+SRC_URI[sha256sum] = "ae81214177fb05f91f6e43b0b42633b6e0024570cbc6591a3858e12100ce8aaa"
+
+S = "${WORKDIR}/transfig.${PV}"
+
+EXTRA_OEMAKE = "-I${S}"
+
+inherit native
+
+do_configure() {
+	xmkmf
+	make Makefiles
+
+	# Fix hardcoded references to host build locations
+	sed -i -e "s|SYSTEMUSRLIBDIR = /usr/lib64|SYSTEMUSRLIBDIR = ${libdir}|g" fig2dev/Makefile
+	sed -i -e "s|SYSTEMUSRINCDIR = /usr/include|SYSTEMUSRINCDIR = ${includedir}|g" fig2dev/Makefile
+	sed -i -e "s|XPMINC = -I/usr/include/X11|XPMINC = -I${includedir}/X11|g" fig2dev/Makefile 
+	sed -i -e "s|/usr/lib64|/usr/lib|g" fig2dev/Makefile || true
+	sed -i -e "s|/usr/lib64|/usr/lib|g" fig2dev/dev/Makefile || true
+	sed -i -e "s|/usr/local/lib|${libdir}|g" fig2dev/Makefile
+	sed -i -e "s|/usr/local/lib|${libdir}|g" fig2dev/dev/Makefile
+}
+
+do_install() {
+	oe_runmake install DESTDIR=${D}
+}
-- 
1.7.4

[PATCH 6/6] prelink: add transfig to DEPENDS

[Scott Garman]

From: Scott Garman <scott.a.garman@intel.com>

Building prelink's documentaiton requires fig2dev, which is
provided by transfig.

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 meta/recipes-devtools/prelink/prelink_git.bb |    2 +-
 1 files changed, 1 insertions(+), 1 deletions(-)

diff --git a/meta/recipes-devtools/prelink/prelink_git.bb b/meta/recipes-devtools/prelink/prelink_git.bb
index 8620513..6f39742 100644
--- a/meta/recipes-devtools/prelink/prelink_git.bb
+++ b/meta/recipes-devtools/prelink/prelink_git.bb
@@ -1,6 +1,6 @@
 SECTION = "devel"
 # Need binutils for libiberty.a
-DEPENDS = "elfutils binutils"
+DEPENDS = "elfutils binutils transfig"
 SUMMARY = "An ELF prelinking utility"
 DESCRIPTION = "The prelink package contains a utility which modifies ELF shared libraries \
 and executables, so that far fewer relocations need to be resolved at \
-- 
1.7.4