[PATCH 0/3] emgd-1.10: new recipe

[PATCH 0/3] emgd-1.10: new recipe

[tom.zanussi]

From: Tom Zanussi <tom.zanussi@intel.com>

This patchset adds support for emgd-1.10.  This version relies on a new
licensing mechanism called LICENSE_FLAGS, which has been posted separately.
The LICENSE_FLAGS implementation provides the mechanism needed for this new
emgd recipe to be automatically downloaded from the emgd site and used by
the recipe rather than using the manual-copy method required by the emgd-1.8
and previous recipes.

In order to allow emgd-1.10 to be built, however, the emgd license string,
"License_emgd-driver-bin_1.10" must be added to the LICENSE_FLAGS_WHITELIST
variable in local.conf e.g.:

LICENSE_FLAGS_WHITELIST = "License_emgd-driver-bin_1.10"

This patchset also removes the 1.8 recipe in the process.

All the basic funcionality has been tested and works i.e. 2D graphics, mouse,
keyboard, 3D graphics (glxgears), and video accelaration
(big_buck_bunny_1080p_h264.mov).


The following changes since commit 7c3db7010479970f3f92501349827c517de3c36a:
  Tom Zanussi (1):
        meta-intel: change EMGD xserver libva dependency to libva-x11

are available in the git repository at:

  git://git.yoctoproject.org/meta-intel.git tzanussi/emgd-1.10.v0
  http://git.yoctoproject.org/cgit/cgit.cgi/meta-intel/log/?h=tzanussi/emgd-1.10.v0

Tom Zanussi (3):
  meta-intel: new recipe for emgd 1.10 driver
  meta-crownbay: pin to emgd-driver-bin_1.10
  meta-intel: remove emgd-1.8

 .../xorg-xserver/emgd-driver-bin_1.10.bb           |   97 ++++++++++++++++++++
 .../xorg-xserver/emgd-driver-bin_1.8.bb            |   39 --------
 meta-crownbay/conf/machine/crownbay.conf           |    2 +-
 3 files changed, 98 insertions(+), 40 deletions(-)
 delete mode 100644 common/recipes-graphics/xorg-xserver/emgd-driver-bin-1.8/.gitignore
 create mode 100644 common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.10.bb
 delete mode 100644 common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.8.bb

[PATCH 1/3] meta-intel: new recipe for emgd 1.10 driver

[tom.zanussi]

From: Tom Zanussi <tom.zanussi@intel.com>

This adds a new recipe for the emgd 1.10 driver.

Signed-off-by: Tom Zanussi <tom.zanussi@intel.com>
---
 .../xorg-xserver/emgd-driver-bin_1.10.bb           |   97 ++++++++++++++++++++
 1 files changed, 97 insertions(+), 0 deletions(-)
 create mode 100644 common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.10.bb

diff --git a/common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.10.bb b/common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.10.bb
new file mode 100644
index 0000000..2ef3cff
--- /dev/null
+++ b/common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.10.bb
@@ -0,0 +1,97 @@
+SUMMARY = "EMGD 1.10 xserver binaries"
+DESCRIPTION = "EMGD 1.10 includes some userspace binaries that use non-free \
+licensing, which are now available via a non-click-through downloadable \
+tarball, and is what this recipe now uses.  Since it is a non-free license, \
+this recipe is marked as 'License_emgd-driver-bin_1.10' and you need to add \
+to LICENSE_FLAGS_WHITELIST += \"License_emgd-driver-bin_1.10\" to your \
+local.conf in order to enable it in a build."
+LICENSE = "Intel-binary-only"
+LICENSE_FLAGS = "License_${PN}_${PV}"
+PR = "r0"
+
+EMGD_LIC_DIR = "IEMGD_HEAD_Linux/License"
+EMGD_RPM_DIR = "IEMGD_HEAD_Linux/MeeGo1.2"
+EMGD_VIDEO_PLUGIN_DIR = "../common/video_plugin"
+
+LIC_FILES_CHKSUM = "file://${WORKDIR}/${EMGD_LIC_DIR}/License.txt;md5=b54f01caaf8483b3cb60c0c40f2bf22d"
+
+DEPENDS = "rpm-native xz-native"
+
+SRC_URI = "https://edc.intel.com/App_Shared/Downloads/LIN_EMGD_1_10_RC_2209.tgz"
+
+SRC_URI[md5sum] = "e4a38d9efa0b086ae21b68145c4db4e9"
+SRC_URI[sha256sum] = "acea5f0f93a31553553428623c007d7ed0c604cf715fd87dfe075751da4be548"
+
+FILES_${PN} += "${libdir}/dri ${libdir}/gstreamer-0.10 ${libdir}/xorg/modules/drivers"
+FILES_${PN}-dev += "${libdir}/dri ${libdir}/xorg/modules/drivers"
+FILES_${PN}-dbg += "${libdir}/xorg/modules/drivers/.debug ${libdir}/dri/.debug"
+
+S = "${WORKDIR}/${EMGD_RPM_DIR}"
+
+do_install () {
+    # A gstreamer VA buffer library
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/gst-vabuffer*.rpm | cpio -id
+
+    # MIX Common contains common classes, datatype, header files used by other MIX components
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/mixcommon*.rpm | cpio -id
+
+    # MIX Video Bitstream Parser is an user library interface for various video format bitstream parsing
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/mixvbp*.rpm | cpio -id
+
+    # MIX Video is an user library interface for various video codecs available on the platform.
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/mixvideo*.rpm | cpio -id
+
+    install -d -m 0755                                    ${D}${libdir}/gstreamer-0.10
+    install -m 0755 ${S}/usr/lib/*                        ${D}${libdir}/
+
+    # A gstreamer plugin that uses MIX Video for hardware accelerated video decoding and rendering.
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/gst-plugins-mixvideo*.rpm | cpio -id
+
+    # A collection of gstreamer plugins that uses VA libraries for hardware accelerated video rendering and text overlay.
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/gst-plugins-va*.rpm | cpio -id
+
+    install -m 0755 ${S}/usr/lib/gstreamer-0.10/*         ${D}${libdir}/gstreamer-0.10/
+
+    # EMGD runtime graphics libraries
+    rpm2cpio ${S}/emgd-bin*.rpm | xz -d | cpio -id
+
+    install -d -m 0755                                    ${D}${libdir}/dri
+    install -d -m 0755                                    ${D}${libdir}/xorg/modules/drivers
+    install -d -m 0755                                    ${D}${sysconfdir}
+    install -d -m 0755                                    ${D}${mandir}/man4
+    install -m 0755 ${S}/usr/lib/*.so.*                   ${D}${libdir}/
+    install -m 0755 ${S}/usr/lib/dri/*                    ${D}${libdir}/dri/
+    install -m 0755 ${S}/usr/lib/xorg/modules/drivers/*   ${D}${libdir}/xorg/modules/drivers/
+    install -m 0755 ${S}/etc/*                            ${D}${sysconfdir}/
+    install -m 0755 ${S}/usr/share/man/man4/*             ${D}${mandir}/man4/
+
+    # emgdgui is a GUI tool to configure the emgd driver
+    rpm2cpio ${S}/emgd-gui*.rpm | xz -d | cpio -id
+
+    install -d -m 0755                                    ${D}/usr/share/applications
+    install -d -m 0755                                    ${D}${bindir}
+    install -m 0755 ${S}/usr/share/applications/*         ${D}/usr/share/applications/
+    install -m 0755 ${S}/usr/bin/*                        ${D}${bindir}/
+
+    # Khronos development headers needed for EGL, OpenGL-ES, and OpenVG development
+    rpm2cpio ${S}/emgd-devel*.rpm | xz -d | cpio -id
+
+    install -d -m 0755                                    ${D}${includedir}/EGL
+    install -m 0755 ${S}/usr/include/EGL/*.h              ${D}${includedir}/EGL/
+    install -d -m 0755                                    ${D}${includedir}/GLES
+    install -m 0755 ${S}/usr/include/GLES/*.h             ${D}${includedir}/GLES/
+    install -d -m 0755                                    ${D}${includedir}/GLES2
+    install -m 0755 ${S}/usr/include/GLES2/*.h            ${D}${includedir}/GLES2/
+    install -d -m 0755                                    ${D}${includedir}/KHR
+    install -m 0755 ${S}/usr/include/KHR/*.h              ${D}${includedir}/KHR/
+    install -d -m 0755                                    ${D}${includedir}/VG
+    install -m 0755 ${S}/usr/include/VG/*.h               ${D}${includedir}/VG/
+
+    ln -sf libEGL.so.1                                    ${D}${libdir}/libEGL.so
+    ln -sf libGLES_CM.so.1                                ${D}${libdir}/libGLES_CM.so
+    ln -sf libGLESv2.so.2                                 ${D}${libdir}/libGLESv2.so
+    ln -sf libOpenVG.so.1                                 ${D}${libdir}/libOpenVG.so
+    ln -sf libOpenVGU.so.1                                ${D}${libdir}/libOpenVGU.so
+}
+
+LEAD_SONAME = "libEGL.so"
-- 
1.7.0.4

[PATCH 2/3] meta-crownbay: pin to emgd-driver-bin_1.10

[tom.zanussi]

From: Tom Zanussi <tom.zanussi@intel.com>

Make sure crownbay uses emgd-driver-bin 1.10.

Signed-off-by: Tom Zanussi <tom.zanussi@intel.com>
---
 meta-crownbay/conf/machine/crownbay.conf |    2 +-
 1 files changed, 1 insertions(+), 1 deletions(-)

diff --git a/meta-crownbay/conf/machine/crownbay.conf b/meta-crownbay/conf/machine/crownbay.conf
index 1bf3bdd..94815b0 100644
--- a/meta-crownbay/conf/machine/crownbay.conf
+++ b/meta-crownbay/conf/machine/crownbay.conf
@@ -14,7 +14,7 @@ XSERVER ?= "${XSERVER_IA32_BASE} \
 
 PREFERRED_VERSION_xserver-xorg ?= "1.9.3"
 PREFERRED_VERSION_mesa-dri ?= "7.11"
-PREFERRED_VERSION_emgd-driver-bin ?= "1.8"
+PREFERRED_VERSION_emgd-driver-bin ?= "1.10"
 
 APPEND += "video=vesafb vga=0x318"
 
-- 
1.7.0.4

[PATCH 3/3] meta-intel: remove emgd-1.8

[tom.zanussi]

From: Tom Zanussi <tom.zanussi@intel.com>

emgd-1.8 is now obsoleted by emgd-1.10, so remove support for it.

Signed-off-by: Tom Zanussi <tom.zanussi@intel.com>
---
 .../xorg-xserver/emgd-driver-bin_1.8.bb            |   39 --------------------
 1 files changed, 0 insertions(+), 39 deletions(-)
 delete mode 100644 common/recipes-graphics/xorg-xserver/emgd-driver-bin-1.8/.gitignore
 delete mode 100644 common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.8.bb

diff --git a/common/recipes-graphics/xorg-xserver/emgd-driver-bin-1.8/.gitignore b/common/recipes-graphics/xorg-xserver/emgd-driver-bin-1.8/.gitignore
deleted file mode 100644
index e69de29..0000000
diff --git a/common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.8.bb b/common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.8.bb
deleted file mode 100644
index bb98962..0000000
--- a/common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.8.bb
+++ /dev/null
@@ -1,39 +0,0 @@
-SUMMARY = "EMGD 1.8 xserver binaries"
-DESCRIPTION = "EMGD 1.8 includes some userspace binaries that use non-free \
-licensing.  Intel Open Source Technology Center unfortunately has no power \
-to change that, but tries to make their use as painless as possible.  Please \
-see the README in meta-crownbay/ for instructions on the (simple) manual \
-steps necessary to make the necessary binaries available to this recipe.  \
-Please do that before building an image."
-LICENSE = "Intel-binary-only"
-PR = "r8"
-
-LIC_FILES_CHKSUM = "file://${WORKDIR}/License.txt;md5=b54f01caaf8483b3cb60c0c40f2bf22d"
-
-FILESPATH = "${FILE_DIRNAME}/emgd-driver-bin-1.8"
-
-SRC_URI = "file://lib \
-           file://License.txt"
-
-FILES_${PN} += "${libdir}/dri ${libdir}/gstreamer-0.10 ${libdir}/xorg/modules/drivers"
-FILES_${PN}-dev += "${libdir}/*.so"
-FILES_${PN}-dbg += "${libdir}/xorg/modules/drivers/.debug ${libdir}/dri/.debug"
-
-S = "${WORKDIR}"
-
-do_install () {
-    install -d -m 0755                              ${D}/${libdir}/dri
-    install -d -m 0755                              ${D}/${libdir}/gstreamer-0.10
-    install -d -m 0755                              ${D}/${libdir}/xorg/modules/drivers
-    install -m 0755 ${S}/lib/*.so.*                 ${D}${libdir}/
-    install -m 0755 ${S}/lib/dri/*                  ${D}${libdir}/dri/
-    install -m 0755 ${S}/lib/gstreamer-0.10/*       ${D}${libdir}/gstreamer-0.10/
-    install -m 0755 ${S}/lib/xorg/modules/drivers/* ${D}${libdir}/xorg/modules/drivers/
-
-    ln -sf libEGL.so.1                              ${D}${libdir}/libEGL.so
-    ln -sf libGLES_CM.so.1                          ${D}${libdir}/libGLES_CM.so
-    ln -sf libGLESv2.so.2                           ${D}${libdir}/libGLESv2.so
-    ln -sf libEMGDScopeServices.so.1.5.15.3226      ${D}${libdir}/libPVRScopeServices.so
-}
-
-LEAD_SONAME = "libEGL.so"
-- 
1.7.0.4