[PATCH 0/1] meta-yocto: add linux-libc-headers-yocto

[PATCH 0/1] meta-yocto: add linux-libc-headers-yocto

[Bruce Ashfield]

Richard/Saul,

As a follow up to my series to oe-core, this is the movement of 
linux-libc-headers-yocto to meta-yocto. There are still some use cases
for which we want this, but it makes sense to move it to meta-yocto to
support those cases.

Built and booted with this as the PREFERRED_PROVIDER_linux-libc-headers
provider.

Cheers,

Bruce

The following changes since commit 47a6043c6b3b5dcf06c7d57eb5b21c93936be01e:
  Bruce Ashfield (1):
        linux-libc-headers-yocto: remove from oe-core

are available in the git repository at:

  git://git.pokylinux.org/poky-contrib zedd/libc-headers-yocto
  http://git.pokylinux.org/cgit.cgi/poky-contrib/log/?h=zedd/libc-headers-yocto

Bruce Ashfield (1):
  linux-libc-headers-yocto: move to meta-yocto

 .../linux-libc-headers-yocto_git.bb                |   64 ++++++++++++++++++++
 1 files changed, 64 insertions(+), 0 deletions(-)
 create mode 100644 meta-yocto/recipes-kernel/linux-libc-headers/linux-libc-headers-yocto_git.bb

[PATCH 1/1] linux-libc-headers-yocto: move to meta-yocto

[Bruce Ashfield]

linux-libc-headers-yocto is not directly required in meta, so we can
safely move it to meta-yocto.

Machines including meta-yocto that are using linux-yocto that need headers
which are completely up to date with the linux-yocto git tree can use this
as their preferred linux-libc-headers.

Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com>
---
 .../linux-libc-headers-yocto_git.bb                |   64 ++++++++++++++++++++
 1 files changed, 64 insertions(+), 0 deletions(-)
 create mode 100644 meta-yocto/recipes-kernel/linux-libc-headers/linux-libc-headers-yocto_git.bb

diff --git a/meta-yocto/recipes-kernel/linux-libc-headers/linux-libc-headers-yocto_git.bb b/meta-yocto/recipes-kernel/linux-libc-headers/linux-libc-headers-yocto_git.bb
new file mode 100644
index 0000000..756b596
--- /dev/null
+++ b/meta-yocto/recipes-kernel/linux-libc-headers/linux-libc-headers-yocto_git.bb
@@ -0,0 +1,64 @@
+require recipes-kernel/linux-libc-headers/linux-libc-headers.inc
+include recipes-kernel/linux/linux-yocto.inc
+
+B = "${S}"
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS += "unifdef-native"
+PROVIDES = "linux-libc-headers"
+RPROVIDES_${PN}-dev = "linux-libc-headers-dev"
+RPROVIDES_${PN}-dbg = "linux-libc-headers-dbg"
+SRCREV = "21ab5dca134a6bf1316aa59f69f9ee9e091d5702"
+KBRANCH ?= "standard/base"
+KMETA ?= "meta"
+PV = "3.2+git-${SRCPV}"
+PR = "r5"
+
+SRC_URI = "git://git.yoctoproject.org/linux-yocto-3.2;protocol=git;nocheckout=1;branch=${KBRANCH},meta;name=machine,meta"
+
+# force this to empty to prevent installation failures, we aren't
+# building a device tree as part of kern headers
+KERNEL_DEVICETREE = ""
+
+set_arch() {
+	case ${TARGET_ARCH} in
+		arm*)     ARCH=arm ;;
+		i*86*)    ARCH=i386 ;;
+		ia64*)    ARCH=ia64 ;;
+		mips*)    ARCH=mips ;;
+		powerpc*) ARCH=powerpc ;;
+		x86_64*)  ARCH=x86_64 ;;
+	esac
+}
+
+do_configure() {
+	set_arch
+	oe_runmake allnoconfig ARCH=$ARCH
+}
+
+do_install() {
+	set_arch
+	oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix} ARCH=$ARCH
+
+        # The ..install.cmd conflicts between various configure runs
+        find ${D}${includedir} -name ..install.cmd | xargs rm -f
+}
+
+# The following tasks are not required when we just want
+# headers. So we override and stub them out.
+do_kernel_configme() {
+}
+
+do_patch () {
+}
+
+do_compile () {
+}
+
+do_validate_branches () {
+}
+
+do_kernel_configcheck () {
+}
+
+BBCLASSEXTEND = "nativesdk"
-- 
1.7.0.4