[meta-oe][PATCH 0/2] Breakpad and ktap recipes

[meta-oe][PATCH 0/2] Breakpad and ktap recipes

[Anders Darander]

[Resending with meta-oe in subject.]

These are a couple of recipes that we've been using internally for some time. They
were developed and mostly used on a dylan-based setup. Testing has primarily been 
performed on ARM, both qemuarm and our custom machine.

Breakpad is a crash reporting tool, that's getting a wider use.
Please, let me know if there's a more efficient way (or otherwise better way) to 
have the bbclass generate the symbol file.

Ktap is a new scripting dynamic tracing tool for Linux. This recipe will be of
use until everyone is on 3.13+ kernels (ktap has been merged for the 3.13 series).

The following changes since commit f8903f53db717294d63a8d79b5ef7ca34b3c189e:

  libhugetlbfs: install perl lib to directory perl instead of perl5 (2013-10-15 13:43:53 +0200)

are available in the git repository at:

  git://github.com/darander/meta-oe breakpad-ktap
  https://github.com/darander/meta-oe/tree/breakpad-ktap

Anders Darander (2):
  breakpad: add initial recipe
  ktap: add initial recipe

 meta-oe/classes/breakpad.bbclass                  | 32 ++++++++++
 meta-oe/recipes-devtools/breakpad/breakpad_svn.bb | 72 +++++++++++++++++++++++
 meta-oe/recipes-kernel/ktap/ktap-module_0.3.bb    | 19 ++++++
 meta-oe/recipes-kernel/ktap/ktap.inc              | 11 ++++
 meta-oe/recipes-kernel/ktap/ktap_0.3.bb           | 17 ++++++
 5 files changed, 151 insertions(+)
 create mode 100644 meta-oe/classes/breakpad.bbclass
 create mode 100644 meta-oe/recipes-devtools/breakpad/breakpad_svn.bb
 create mode 100644 meta-oe/recipes-kernel/ktap/ktap-module_0.3.bb
 create mode 100644 meta-oe/recipes-kernel/ktap/ktap.inc
 create mode 100644 meta-oe/recipes-kernel/ktap/ktap_0.3.bb

-- 
1.8.4.rc3

[meta-oe][PATCH 1/2] breakpad: add initial recipe

[Anders Darander]

Breakpad is an open-source multi-platform crash reporting system.

Apart from the breakpad recipe, add a bbclass for applications that want
to use this library. This bbclass will set up the include path and also
generate the symbol file.

Signed-off-by: Anders Darander <anders@chargestorm.se>
---
 meta-oe/classes/breakpad.bbclass                  | 32 ++++++++++
 meta-oe/recipes-devtools/breakpad/breakpad_svn.bb | 72 +++++++++++++++++++++++
 2 files changed, 104 insertions(+)
 create mode 100644 meta-oe/classes/breakpad.bbclass
 create mode 100644 meta-oe/recipes-devtools/breakpad/breakpad_svn.bb

diff --git a/meta-oe/classes/breakpad.bbclass b/meta-oe/classes/breakpad.bbclass
new file mode 100644
index 0000000..8c49ca7
--- /dev/null
+++ b/meta-oe/classes/breakpad.bbclass
@@ -0,0 +1,32 @@
+# Class to inherit when you want to build against Breakpad.
+# Apart from inheriting this class, you need to set BREAKPAD_BIN in
+# your recipe, and make sure that you link against libbreakpad_client.a.
+
+DEPENDS += "breakpad breakpad-native"
+
+CFLAGS += "-I${STAGING_DIR_TARGET}${includedir}/breakpad "
+
+BREAKPAD_BIN ?= ""
+
+python () {
+    breakpad_bin = d.getVar("BREAKPAD_BIN", True)
+
+    if not breakpad_bin:
+       PN = d.getVar("PN", True)
+       FILE = os.path.basename(d.getVar("FILE", True))
+       bb.error("To build %s, see breakpad.bbclass for instructions on \
+                 setting up your Breakpad configuration" % PN)
+       raise ValueError('BREAKPAD_BIN not defined in %s' % PN)
+}
+
+# Add creation of symbols here
+PACKAGE_PREPROCESS_FUNCS += "breakpad_package_preprocess"
+breakpad_package_preprocess () {
+    mkdir -p ${PKGD}/usr/share/breakpad-syms
+    find ${D} -name ${BREAKPAD_BIN} -exec sh -c "dump_syms {} > ${PKGD}/usr/share/breakpad-syms/${BREAKPAD_BIN}.syms" \;
+}
+
+PACKAGES =+ "${PN}-breakpad"
+
+FILES_${PN}-breakpad = "/usr/share/breakpad-syms"
+
diff --git a/meta-oe/recipes-devtools/breakpad/breakpad_svn.bb b/meta-oe/recipes-devtools/breakpad/breakpad_svn.bb
new file mode 100644
index 0000000..7c7024a
--- /dev/null
+++ b/meta-oe/recipes-devtools/breakpad/breakpad_svn.bb
@@ -0,0 +1,72 @@
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+# Applications using this library needs to add link against libbreakpad_client.a.
+
+SUMMARY = "An open-source multi-platform crash reporting system"
+DESCRIPTION = "Breakpad is a library and tool suite that allows you to distribute an application to users with compiler-provided debugging information removed, record crashes in compact \"minidump\" files, send them back to your server, and produce C and C++ stack traces from these minidumps. "
+HOMEPAGE = "https://code.google.com/p/google-breakpad/"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://COPYING;md5=c80d1a3b623f72bb85a4c75b556551df"
+SECTION = "libs"
+
+inherit autotools
+
+BBCLASSEXTEND = "native"
+
+SRCREV = "r1218"
+SRC_URI = "svn://google-breakpad.googlecode.com/svn;module=trunk;protocol=http"
+S = "${WORKDIR}/trunk"
+
+do_install_append() {
+        install -d ${D}${includedir}
+        install -d ${D}${includedir}/breakpad
+
+        install -d ${D}${includedir}/breakpad/client/linux/crash_generation
+        install -m 0644 ${S}/src/client/linux/crash_generation/crash_generation_client.h  ${D}${includedir}/breakpad/client/linux/crash_generation/crash_generation_client.h
+
+        install -d ${D}${includedir}/breakpad/client/linux/handler/
+        install -m 0644 ${S}/src/client/linux/handler/exception_handler.h ${D}${includedir}/breakpad/client/linux/handler/exception_handler.h
+        install -m 0644 ${S}/src/client/linux/handler/minidump_descriptor.h ${D}${includedir}/breakpad/client/linux/handler/minidump_descriptor.h
+
+        install -d ${D}${includedir}/breakpad/client/linux/minidump_writer
+        install -m 0644 ${S}/src/client/linux/minidump_writer/linux_dumper.h ${D}${includedir}/breakpad/client/linux/minidump_writer/linux_dumper.h
+        install -m 0644 ${S}/src/client/linux/minidump_writer/minidump_writer.h ${D}${includedir}/breakpad/client/linux/minidump_writer/minidump_writer.h
+
+        install -d ${D}${includedir}/breakpad/common
+        install -m 0644 ${S}/src/common/memory.h ${D}${includedir}/breakpad/common/memory.h
+        install -m 0644 ${S}/src/common/scoped_ptr.h ${D}${includedir}/breakpad/common/scoped_ptr.h
+        install -m 0644 ${S}/src/common/using_std_string.h ${D}${includedir}/breakpad/common/using_std_string.h
+
+        install -d ${D}${includedir}/breakpad/google_breakpad/common
+        install -m 0644 ${S}/src/google_breakpad/common/breakpad_types.h ${D}${includedir}/breakpad/google_breakpad/common/breakpad_types.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_format.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_format.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_cpu_amd64.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_cpu_amd64.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_cpu_arm.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_cpu_arm.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_cpu_mips.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_cpu_mips.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_cpu_ppc64.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_cpu_ppc64.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_cpu_ppc.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_cpu_ppc.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_cpu_sparc.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_cpu_sparc.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_cpu_x86.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_cpu_x86.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_exception_linux.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_exception_linux.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_exception_mac.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_exception_mac.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_exception_ps3.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_exception_ps3.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_exception_solaris.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_exception_solaris.h
+        install -m 0644 ${S}/src/google_breakpad/common/minidump_exception_win32.h ${D}${includedir}/breakpad/google_breakpad/common/minidump_exception_win32.h
+
+        install -d ${D}${includedir}/breakpad/third_party/lss
+        install -m 0644 ${S}/src/third_party/lss/linux_syscall_support.h ${D}${includedir}/breakpad/third_party/lss/linux_syscall_support.h
+}
+
+PACKAGES =+ "${PN}-minidump-upload ${PN}-sym-upload"
+
+FILES_${PN}-minidump-upload = "${bindir}/minidump_upload"
+FILES_${PN}-sym-upload = "${bindir}/sym_upload"
+
+
+SYSROOT_PREPROCESS_FUNCS += "breakpad_populate_sysroot"
+breakpad_populate_sysroot() {
+        sysroot_stage_dir ${D}/usr/include ${SYSROOT_DESTDIR}/usr/include
+        sysroot_stage_dir ${D}/usr/lib ${SYSROOT_DESTDIR}/usr/lib
+        sysroot_stage_dir ${D}/usr/lib ${SYSROOT_DESTDIR}/usr/lib
+}
+
-- 
1.8.4.rc3

[meta-oe][PATCH 2/2] ktap: add initial recipe

[Anders Darander]

Ktap is a new scripting dynamic tracing tool for Linux.

From kernel v3.13 it'll live inside the kernel tree, but for earlier kernels,
this recipe will be usefull.

Signed-off-by: Anders Darander <anders@chargestorm.se>
---
 meta-oe/recipes-kernel/ktap/ktap-module_0.3.bb | 19 +++++++++++++++++++
 meta-oe/recipes-kernel/ktap/ktap.inc           | 11 +++++++++++
 meta-oe/recipes-kernel/ktap/ktap_0.3.bb        | 17 +++++++++++++++++
 3 files changed, 47 insertions(+)
 create mode 100644 meta-oe/recipes-kernel/ktap/ktap-module_0.3.bb
 create mode 100644 meta-oe/recipes-kernel/ktap/ktap.inc
 create mode 100644 meta-oe/recipes-kernel/ktap/ktap_0.3.bb

diff --git a/meta-oe/recipes-kernel/ktap/ktap-module_0.3.bb b/meta-oe/recipes-kernel/ktap/ktap-module_0.3.bb
new file mode 100644
index 0000000..12167ea
--- /dev/null
+++ b/meta-oe/recipes-kernel/ktap/ktap-module_0.3.bb
@@ -0,0 +1,19 @@
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+require ktap.inc
+
+DESCRIPTION = "KTAP is a scripting dynamic tracing tool for Linux"
+
+inherit module
+
+# Only build the module
+MAKE_TARGETS = "mod"
+
+# Kernel module packages MUST begin with 'kernel-module-', otherwise
+# multilib image generation can fail.
+#
+# The following line is only necessary if the recipe name does not begin
+# with kernel-module-.
+#
+PKG_${PN} = "kernel-module-${PN}"
+
diff --git a/meta-oe/recipes-kernel/ktap/ktap.inc b/meta-oe/recipes-kernel/ktap/ktap.inc
new file mode 100644
index 0000000..7fde165
--- /dev/null
+++ b/meta-oe/recipes-kernel/ktap/ktap.inc
@@ -0,0 +1,11 @@
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+HOMEPAGE = "http://www.ktap.org"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://LICENSE-GPL;md5=eb723b61539feef013de476e68b5c50a"
+
+SRCREV = "6a5100b77321ce5792dfea34fa500ea537b1858c"
+SRC_URI = "git://github.com/ktap/ktap.git"
+
+S = "${WORKDIR}/git"
+
diff --git a/meta-oe/recipes-kernel/ktap/ktap_0.3.bb b/meta-oe/recipes-kernel/ktap/ktap_0.3.bb
new file mode 100644
index 0000000..f5dd62f
--- /dev/null
+++ b/meta-oe/recipes-kernel/ktap/ktap_0.3.bb
@@ -0,0 +1,17 @@
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+require ktap.inc
+
+SUMMARY = "KTAP is a scripting dynamic tracing tool for Linux"
+DEPENDS = "ktap-module"
+
+# Only build the userspace app
+EXTRA_OEMAKE = "ktap"
+
+do_install() {
+    install -d ${D}${bindir}
+    install -m 0755 ${S}/ktap ${D}${bindir}/
+}
+
+RDEPENDS_${PN} = "kernel-module-ktapvm"
+
-- 
1.8.4.rc3