[meta-oe][PATCH v2 0/2] Add mraa/upm recipes from meta-refkit-core

[meta-oe][PATCH v2 0/2] Add mraa/upm recipes from meta-refkit-core

[Paul Eggleton]

Move in recipes from meta-refkit-core for the mraa I/O library and upm
sensor library.

Changes since v1:
* Set COMPATIBLE_HOST based upon what mraa's CMakeLists.txt checks for


The following changes since commit 06e8aa6bda49b4c103dcb41b059e3dba168ee37a:

  mongodb: Fix build on aarch64 (2017-10-02 12:35:39 +0000)

are available in the git repository at:

  git://git.openembedded.org/meta-openembedded-contrib paule/mraa
  http://cgit.openembedded.org/meta-openembedded-contrib/log/?h=paule/mraa

Paul Eggleton (2):
  mraa: move recipe from meta-refkit-core
  upm: add recipe from meta-refkit-core

 meta-oe/recipes-extended/mraa/mraa_git.bb          | 51 ++++++++++++++++++++
 ...15-fixed-case-logic-in-getThresh-function.patch | 54 ++++++++++++++++++++++
 meta-oe/recipes-extended/upm/upm_git.bb            | 45 ++++++++++++++++++
 3 files changed, 150 insertions(+)
 create mode 100644 meta-oe/recipes-extended/mraa/mraa_git.bb
 create mode 100644 meta-oe/recipes-extended/upm/files/ads1x15-fixed-case-logic-in-getThresh-function.patch
 create mode 100644 meta-oe/recipes-extended/upm/upm_git.bb

-- 
2.9.5

[meta-oe][PATCH v2 1/2] mraa: move recipe from meta-refkit-core

[Paul Eggleton]

Make this recipe a little more widely visible (has previously appeared
in meta-refkit-core and meta-intel-iot-middleware). Also make couple of
minor tweaks:

* Make SUMMARY more accurate by borrowing the first part of the short
  description now in the mraa github repo
* Set HOMEPAGE
* Drop AUTHOR as this is field is only really intended for older
  software where there is no real point of contact for upstream other
  than an author's email address.
* Set COMPATIBLE_HOST to match what is checked by mraa's CMakeLists.txt

Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
---
 meta-oe/recipes-extended/mraa/mraa_git.bb | 51 +++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 meta-oe/recipes-extended/mraa/mraa_git.bb

diff --git a/meta-oe/recipes-extended/mraa/mraa_git.bb b/meta-oe/recipes-extended/mraa/mraa_git.bb
new file mode 100644
index 0000000..616048f
--- /dev/null
+++ b/meta-oe/recipes-extended/mraa/mraa_git.bb
@@ -0,0 +1,51 @@
+SUMMARY = "Linux Library for low speed I/O Communication"
+HOMEPAGE = "https://github.com/intel-iot-devkit/mraa"
+SECTION = "libs"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=66493d54e65bfc12c7983ff2e884f37f"
+
+SRCREV = "8ddbcde84e2d146bc0f9e38504d6c89c14291480"
+PV = "1.7.0-git${SRCPV}"
+
+SRC_URI = "git://github.com/intel-iot-devkit/${BPN}.git;protocol=http"
+
+S = "${WORKDIR}/git"
+
+# CMakeLists.txt checks the architecture, only x86 and ARM supported for now
+COMPATIBLE_HOST = "(x86_64.*|i.86.*|aarch64.*|arm.*)-linux"
+
+inherit cmake distutils3-base
+
+DEPENDS += "json-c"
+
+EXTRA_OECMAKE_append = " -DINSTALLTOOLS:BOOL=ON -DFIRMATA=ON -DCMAKE_SKIP_RPATH=ON"
+
+# Prepend mraa-utils to make sure bindir ends up in there
+PACKAGES =+ "${PN}-utils"
+
+FILES_${PN}-doc += "${datadir}/mraa/examples/"
+
+FILES_${PN}-utils = "${bindir}/"
+
+# override this in local.conf to get needed bindings.
+# BINDINGS_pn-mraa="python"
+# will result in only the python bindings being built/packaged.
+BINDINGS ??= "python ${@ 'nodejs' if oe.types.boolean(d.getVar('HAVE_NODEJS') or '0') else '' }"
+
+PACKAGECONFIG ??= "${@bb.utils.contains('PACKAGES', 'node-${PN}', 'nodejs', '', d)} \
+ ${@bb.utils.contains('PACKAGES', '${PYTHON_PN}-${PN}', 'python', '', d)}"
+
+PACKAGECONFIG[python] = "-DBUILDSWIGPYTHON=ON, -DBUILDSWIGPYTHON=OFF, swig-native ${PYTHON_PN},"
+PACKAGECONFIG[nodejs] = "-DBUILDSWIGNODE=ON, -DBUILDSWIGNODE=OFF, swig-native nodejs-native,"
+PACKAGECONFIG[ft4222] = "-DUSBPLAT=ON -DFTDI4222=ON, -DUSBPLAT=OFF -DFTDI4222=OFF,, libft4222"
+
+FILES_${PYTHON_PN}-${PN} = "${PYTHON_SITEPACKAGES_DIR}/"
+RDEPENDS_${PYTHON_PN}-${PN} += "${PYTHON_PN}"
+
+FILES_node-${PN} = "${prefix}/lib/node_modules/"
+RDEPENDS_node-${PN} += "nodejs"
+
+### Include desired language bindings ###
+PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'nodejs', 'node-${PN}', '', d)}"
+PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'python', '${PYTHON_PN}-${PN}', '', d)}"
-- 
2.9.5

Re: [meta-oe][PATCH v2 1/2] mraa: move recipe from meta-refkit-core

[Khem Raj]

On Mon, Oct 2, 2017 at 12:40 PM, Paul Eggleton
<paul.eggleton@linux.intel.com> wrote:
> Make this recipe a little more widely visible (has previously appeared
> in meta-refkit-core and meta-intel-iot-middleware). Also make couple of
> minor tweaks:
>
> * Make SUMMARY more accurate by borrowing the first part of the short
>   description now in the mraa github repo
> * Set HOMEPAGE
> * Drop AUTHOR as this is field is only really intended for older
>   software where there is no real point of contact for upstream other
>   than an author's email address.
> * Set COMPATIBLE_HOST to match what is checked by mraa's CMakeLists.txt
>
> Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
> ---
>  meta-oe/recipes-extended/mraa/mraa_git.bb | 51 +++++++++++++++++++++++++++++++
>  1 file changed, 51 insertions(+)
>  create mode 100644 meta-oe/recipes-extended/mraa/mraa_git.bb
>
> diff --git a/meta-oe/recipes-extended/mraa/mraa_git.bb b/meta-oe/recipes-extended/mraa/mraa_git.bb
> new file mode 100644
> index 0000000..616048f
> --- /dev/null
> +++ b/meta-oe/recipes-extended/mraa/mraa_git.bb
> @@ -0,0 +1,51 @@
> +SUMMARY = "Linux Library for low speed I/O Communication"
> +HOMEPAGE = "https://github.com/intel-iot-devkit/mraa"
> +SECTION = "libs"
> +
> +LICENSE = "MIT"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=66493d54e65bfc12c7983ff2e884f37f"
> +
> +SRCREV = "8ddbcde84e2d146bc0f9e38504d6c89c14291480"
> +PV = "1.7.0-git${SRCPV}"
> +
> +SRC_URI = "git://github.com/intel-iot-devkit/${BPN}.git;protocol=http"
> +
> +S = "${WORKDIR}/git"
> +
> +# CMakeLists.txt checks the architecture, only x86 and ARM supported for now
> +COMPATIBLE_HOST = "(x86_64.*|i.86.*|aarch64.*|arm.*)-linux"

May be it should be "linux*" at the end so musl is covered too.

> +
> +inherit cmake distutils3-base
> +
> +DEPENDS += "json-c"
> +
> +EXTRA_OECMAKE_append = " -DINSTALLTOOLS:BOOL=ON -DFIRMATA=ON -DCMAKE_SKIP_RPATH=ON"
> +
> +# Prepend mraa-utils to make sure bindir ends up in there
> +PACKAGES =+ "${PN}-utils"
> +
> +FILES_${PN}-doc += "${datadir}/mraa/examples/"
> +
> +FILES_${PN}-utils = "${bindir}/"
> +
> +# override this in local.conf to get needed bindings.
> +# BINDINGS_pn-mraa="python"
> +# will result in only the python bindings being built/packaged.
> +BINDINGS ??= "python ${@ 'nodejs' if oe.types.boolean(d.getVar('HAVE_NODEJS') or '0') else '' }"
> +
> +PACKAGECONFIG ??= "${@bb.utils.contains('PACKAGES', 'node-${PN}', 'nodejs', '', d)} \
> + ${@bb.utils.contains('PACKAGES', '${PYTHON_PN}-${PN}', 'python', '', d)}"
> +
> +PACKAGECONFIG[python] = "-DBUILDSWIGPYTHON=ON, -DBUILDSWIGPYTHON=OFF, swig-native ${PYTHON_PN},"
> +PACKAGECONFIG[nodejs] = "-DBUILDSWIGNODE=ON, -DBUILDSWIGNODE=OFF, swig-native nodejs-native,"
> +PACKAGECONFIG[ft4222] = "-DUSBPLAT=ON -DFTDI4222=ON, -DUSBPLAT=OFF -DFTDI4222=OFF,, libft4222"
> +
> +FILES_${PYTHON_PN}-${PN} = "${PYTHON_SITEPACKAGES_DIR}/"
> +RDEPENDS_${PYTHON_PN}-${PN} += "${PYTHON_PN}"
> +
> +FILES_node-${PN} = "${prefix}/lib/node_modules/"
> +RDEPENDS_node-${PN} += "nodejs"
> +
> +### Include desired language bindings ###
> +PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'nodejs', 'node-${PN}', '', d)}"
> +PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'python', '${PYTHON_PN}-${PN}', '', d)}"
> --
> 2.9.5
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

Re: [meta-oe][PATCH v2 1/2] mraa: move recipe from meta-refkit-core

[Paul Eggleton]

On Tuesday, 3 October 2017 2:45:35 PM NZDT Khem Raj wrote:
> On Mon, Oct 2, 2017 at 12:40 PM, Paul Eggleton
> <paul.eggleton@linux.intel.com> wrote:
> > +# CMakeLists.txt checks the architecture, only x86 and ARM supported for now
> > +COMPATIBLE_HOST = "(x86_64.*|i.86.*|aarch64.*|arm.*)-linux"
> 
> May be it should be "linux*" at the end so musl is covered too.

I just borrowed this from another recipe in OE-Core - AFAIK though the regex
isn't anchored so that shouldn't be necessary. Did you try it? (I'll admit
that I haven't).

Cheers,
Paul


-- 

Paul Eggleton
Intel Open Source Technology Centre

Re: [meta-oe][PATCH v2 1/2] mraa: move recipe from meta-refkit-core

[Paul Eggleton]

On Tuesday, 3 October 2017 3:03:59 PM NZDT Paul Eggleton wrote:
> On Tuesday, 3 October 2017 2:45:35 PM NZDT Khem Raj wrote:
> > On Mon, Oct 2, 2017 at 12:40 PM, Paul Eggleton
> > <paul.eggleton@linux.intel.com> wrote:
> > > +# CMakeLists.txt checks the architecture, only x86 and ARM supported for now
> > > +COMPATIBLE_HOST = "(x86_64.*|i.86.*|aarch64.*|arm.*)-linux"
> > 
> > May be it should be "linux*" at the end so musl is covered too.
> 
> I just borrowed this from another recipe in OE-Core - AFAIK though the regex
> isn't anchored so that shouldn't be necessary. Did you try it? (I'll admit
> that I haven't).

OK, I did just try with TCLIBC = "musl" and it seems to pass the
COMPATIBLE_HOST check so the regex is indeed not anchored.

Cheers,
Paul

-- 

Paul Eggleton
Intel Open Source Technology Centre

Re: [meta-oe][PATCH v2 1/2] mraa: move recipe from meta-refkit-core

[Khem Raj]

On Mon, Oct 2, 2017 at 7:21 PM, Paul Eggleton
<paul.eggleton@linux.intel.com> wrote:
> On Tuesday, 3 October 2017 3:03:59 PM NZDT Paul Eggleton wrote:
>> On Tuesday, 3 October 2017 2:45:35 PM NZDT Khem Raj wrote:
>> > On Mon, Oct 2, 2017 at 12:40 PM, Paul Eggleton
>> > <paul.eggleton@linux.intel.com> wrote:
>> > > +# CMakeLists.txt checks the architecture, only x86 and ARM supported for now
>> > > +COMPATIBLE_HOST = "(x86_64.*|i.86.*|aarch64.*|arm.*)-linux"
>> >
>> > May be it should be "linux*" at the end so musl is covered too.
>>
>> I just borrowed this from another recipe in OE-Core - AFAIK though the regex
>> isn't anchored so that shouldn't be necessary. Did you try it? (I'll admit
>> that I haven't).
>
> OK, I did just try with TCLIBC = "musl" and it seems to pass the
> COMPATIBLE_HOST check so the regex is indeed not anchored.

hmm ok.

[meta-oe][PATCH v2 2/2] upm: add recipe from meta-refkit-core

[Paul Eggleton]

Make this recipe a little more widely visible (has previously appeared
in meta-refkit-core and meta-intel-iot-middleware). Also make couple of
minor tweaks:

* Fix BINDINGS example to use the correct recipe name (copy-paste error)
* Set HOMEPAGE
* Drop AUTHOR as this is field is only really intended for older
  software where there is no real point of contact for upstream other
  than an author's email address.
* Set same COMPATIBLE_HOST as mraa since upm depends upon it

Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
---
 ...15-fixed-case-logic-in-getThresh-function.patch | 54 ++++++++++++++++++++++
 meta-oe/recipes-extended/upm/upm_git.bb            | 45 ++++++++++++++++++
 2 files changed, 99 insertions(+)
 create mode 100644 meta-oe/recipes-extended/upm/files/ads1x15-fixed-case-logic-in-getThresh-function.patch
 create mode 100644 meta-oe/recipes-extended/upm/upm_git.bb

diff --git a/meta-oe/recipes-extended/upm/files/ads1x15-fixed-case-logic-in-getThresh-function.patch b/meta-oe/recipes-extended/upm/files/ads1x15-fixed-case-logic-in-getThresh-function.patch
new file mode 100644
index 0000000..c617d14
--- /dev/null
+++ b/meta-oe/recipes-extended/upm/files/ads1x15-fixed-case-logic-in-getThresh-function.patch
@@ -0,0 +1,54 @@
+From c64d04d084f47b4cb3e1cdee6e96348fcc6a756e Mon Sep 17 00:00:00 2001
+From: Mihai Tudor Panu <mihai.tudor.panu@intel.com>
+Date: Tue, 30 May 2017 15:14:09 -0700
+Subject: [PATCH 1/1] ads1x15: fixed case logic in getThresh() function
+
+Signed-off-by: Mihai Tudor Panu <mihai.tudor.panu@intel.com>
+
+Upstream-Status: Backported [c64d04d084f47b4cb3e1cdee6e96348fcc6a756e]
+
+Signed-off-by: Patrick Ohly <patrick.ohly@intel.com>
+
+---
+ src/ads1x15/ads1x15.cxx | 4 ++--
+ src/ads1x15/ads1x15.hpp | 2 +-
+ 2 files changed, 3 insertions(+), 3 deletions(-)
+
+diff --git a/src/ads1x15/ads1x15.cxx b/src/ads1x15/ads1x15.cxx
+index 35782709..47701b2a 100644
+--- a/src/ads1x15/ads1x15.cxx
++++ b/src/ads1x15/ads1x15.cxx
+@@ -116,7 +116,7 @@ ADS1X15::setContinuous(bool mode){
+ 
+ float
+ ADS1X15::getThresh(ADSTHRESH reg){
+-     if( THRESH_HIGH && THRESH_LOW) return getLastSample(reg);
++     if(reg == THRESH_HIGH || reg == THRESH_LOW) return getLastSample(reg);
+      else return 0.0;
+ }
+ 
+@@ -137,7 +137,7 @@ ADS1X15::setThresh(ADSTHRESH reg, float value){
+      case 2:
+      case 3:
+           set_value = value / getMultiplier();
+-         set_value = set_value << m_bitShift;
++          set_value = set_value << m_bitShift;
+           if(i2c->writeWordReg(reg, swapWord(set_value)) != mraa::SUCCESS){
+             throw std::runtime_error(std::string(__FUNCTION__) + ": I2c.write() failed");
+             return;
+diff --git a/src/ads1x15/ads1x15.hpp b/src/ads1x15/ads1x15.hpp
+index 7524572d..efd8c8ec 100644
+--- a/src/ads1x15/ads1x15.hpp
++++ b/src/ads1x15/ads1x15.hpp
+@@ -390,7 +390,7 @@ namespace upm {
+              * @param reg ADSTHRES enum value.
+              * Returns 0.0 unless THRESH_HIGH or THRESH_LOW requested.
+              */
+-            float getThresh(ADSTHRESH reg = THRESH_LOW);
++            float getThresh(ADSTHRESH reg = THRESH_DEFAULT);
+ 
+             /**
+              * Sets threshold levels or configures for conversion ready
+-- 
+2.11.0
+
diff --git a/meta-oe/recipes-extended/upm/upm_git.bb b/meta-oe/recipes-extended/upm/upm_git.bb
new file mode 100644
index 0000000..38065ce
--- /dev/null
+++ b/meta-oe/recipes-extended/upm/upm_git.bb
@@ -0,0 +1,45 @@
+SUMMARY = "Sensor/Actuator repository for Mraa"
+HOMEPAGE = "https://github.com/intel-iot-devkit/upm"
+SECTION = "libs"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=66493d54e65bfc12c7983ff2e884f37f"
+
+DEPENDS = "libjpeg-turbo mraa"
+
+SRCREV = "106b6c706268522ab0168a4ddb19e89ce832e084"
+PV = "1.3.0-git${SRCPV}"
+
+SRC_URI = " \
+    git://github.com/intel-iot-devkit/${BPN}.git;protocol=http \
+    file://ads1x15-fixed-case-logic-in-getThresh-function.patch \
+"
+
+S = "${WORKDIR}/git"
+
+# Depends on mraa which only supports x86 and ARM for now
+COMPATIBLE_HOST = "(x86_64.*|i.86.*|aarch64.*|arm.*)-linux"
+
+inherit distutils3-base cmake
+
+
+# override this in local.conf to get needed bindings.
+# BINDINGS_pn-upm="python"
+# will result in only the python bindings being built/packaged.
+BINDINGS ??= "python ${@ 'nodejs' if oe.types.boolean(d.getVar('HAVE_NODEJS') or '0') else '' }"
+
+PACKAGECONFIG ??= "${@bb.utils.contains('PACKAGES', 'node-${PN}', 'nodejs', '', d)} \
+ ${@bb.utils.contains('PACKAGES', '${PYTHON_PN}-${PN}', 'python', '', d)}"
+
+PACKAGECONFIG[python] = "-DBUILDSWIGPYTHON=ON, -DBUILDSWIGPYTHON=OFF, swig-native ${PYTHON_PN},"
+PACKAGECONFIG[nodejs] = "-DBUILDSWIGNODE=ON, -DBUILDSWIGNODE=OFF, swig-native nodejs-native,"
+
+FILES_${PYTHON_PN}-${PN} = "${PYTHON_SITEPACKAGES_DIR}"
+RDEPENDS_${PYTHON_PN}-${PN} += "${PYTHON_PN}"
+
+FILES_node-${PN} = "${prefix}/lib/node_modules/"
+RDEPENDS_node-${PN} += "nodejs"
+
+### Include desired language bindings ###
+PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'nodejs', 'node-${PN}', '', d)}"
+PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'python', '${PYTHON_PN}-${PN}', '', d)}"
-- 
2.9.5