[PATCH 1/2] udev: add 177

[PATCH 1/2] udev: add 177

[Koen Kooi]

* 'udevadm' moved to ${PN} avoiding the need for the udev-utils package to be installed, so 'udev' has all the needed programs by itself.
* 'blkid' isn't needed anymore, since 176 udev links against libblkid
* 'modprobe' and 'depmod' aren't needed anymore, udev now links against libkmod
* The entire source including the license files were re-indented hence the LIC_FILES_CHKSUM changes

Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
---
 meta-oe/recipes-core/udev/udev_177.bb |   88 +++++++++++++++++++++++++++++++++
 1 files changed, 88 insertions(+), 0 deletions(-)
 create mode 100644 meta-oe/recipes-core/udev/udev_177.bb

diff --git a/meta-oe/recipes-core/udev/udev_177.bb b/meta-oe/recipes-core/udev/udev_177.bb
new file mode 100644
index 0000000..de1ea6c
--- /dev/null
+++ b/meta-oe/recipes-core/udev/udev_177.bb
@@ -0,0 +1,88 @@
+DESCRIPTION = "udev is a daemon which dynamically creates and removes device nodes from \
+/dev/, handles hotplug events and loads drivers at boot time."
+
+DEFAULT_PREFERENCE = "-1"
+
+# udev 169 and up require kernel 2.6.36 for ARM: 
+# http://git.kernel.org/?p=linux/hotplug/udev.git;a=commit;h=67a77c8bf299f6264f001677becd056316ebce2f
+
+LICENSE = "GPLv2+ & LGPLv2.1+"
+LICENSE_${PN} = "GPLv2+"
+LICENSE_libudev = "LGPLv2.1+"
+LICENSE_libgudev = "LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+                    file://src/COPYING;md5=17c4e5fb495e6707ac92a3864926f979 \
+                    file://src/extras/gudev/COPYING;md5=fb494485a7d0505308cb68e4997cc266"
+
+# glib-2.0: Needed for udev-extras
+# util-linux: Needed for libblkid
+# kmod: needed for libkmod
+DEPENDS = "gperf-native usbutils acl glib-2.0 util-linux kmod"
+
+# 1305ffe0456cc016a78c1fc7ca17645cfef39778 -> 177 tag
+SRCREV = "1305ffe0456cc016a78c1fc7ca17645cfef39778"
+
+# version specific SRC_URI
+SRC_URI = "git://git.kernel.org/pub/scm/linux/hotplug/udev.git;protocol=git \
+           file://0001-rip-put-doc-generation-it-depends-on-a-working-docto.patch \
+           file://gtk-doc.make"
+
+# generic SRC_URI
+SRC_URI += " \
+       file://touchscreen.rules \
+       file://modprobe.rules \
+"
+
+S = "${WORKDIR}/git"
+
+# Machine specific udev rules should be in their own recipe that ${PN} can add to RRECOMMENDS
+
+inherit autotools
+
+EXTRA_OECONF += " \
+                  --disable-introspection \
+                  --with-pci-ids-path=/usr/share/misc \
+                  ac_cv_file__usr_share_pci_ids=no \
+                  ac_cv_file__usr_share_hwdata_pci_ids=no \
+                  ac_cv_file__usr_share_misc_pci_ids=yes \
+                  --sbindir=${base_sbindir} \
+                  --libexecdir=${base_libdir} \
+                  --with-rootlibdir=${base_libdir} \
+                  --disable-gtk-doc-html \
+                  --with-systemdsystemunitdir=${base_libdir}/systemd/system/ \
+"
+
+do_configure_prepend() {
+	cp ${WORKDIR}/gtk-doc.make ${S}
+}
+
+PACKAGES =+ "${PN}-systemd libudev libgudev udev-consolekit"
+
+FILES_${PN}-systemd = "${base_libdir}/systemd"
+RDEPENDS_${PN}-systemd += "udev"
+# udev-adm is now in ${PN}
+RREPLACES_${PN} = "udev-utils"
+
+FILES_libudev = "${base_libdir}/libudev.so.*"
+FILES_libgudev = "${base_libdir}/libgudev*.so.*"
+
+RPROVIDES_${PN} = "hotplug"
+FILES_${PN} += "${usrbindir}/* ${usrsbindir}/udevd"
+FILES_${PN}-dbg += "${usrbindir}/.debug ${usrsbindir}/.debug"
+
+# udev installs binaries under $(udev_prefix)/lib/udev, even if ${libdir}
+# is ${prefix}/lib64
+FILES_${PN} += "/lib/udev*"
+FILES_${PN}-dbg += "/lib/udev/.debug"
+
+FILES_${PN}-consolekit += "${libdir}/ConsoleKit"
+RDEPENDS_${PN}-consolekit += "consolekit"
+
+do_install () {
+	install -d ${D}${usrsbindir} \
+		   ${D}${sbindir}
+	oe_runmake 'DESTDIR=${D}' INSTALL=install install
+
+	install -m 0644 ${WORKDIR}/*.rules         ${D}${sysconfdir}/udev/rules.d/
+}
+
-- 
1.7.2.5

[PATCH 2/2] systemd: update to v38+git

[Koen Kooi]

* This introduces the 'journal' feature.
* Upstream is following the fedora /usr move so EXTRA_OECONF needs to get updated to keep the paths the same for the OE usecase

Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
---
 .../systemd/0001-disable-xsltproc-completely.patch |   36 ------------------
 .../0001-docs-fix-build-without-xsltproc.patch     |   38 ++++++++++++++++++++
 meta-oe/recipes-core/systemd/systemd_git.bb        |    9 +++--
 3 files changed, 43 insertions(+), 40 deletions(-)
 delete mode 100644 meta-oe/recipes-core/systemd/systemd/0001-disable-xsltproc-completely.patch
 create mode 100644 meta-oe/recipes-core/systemd/systemd/0001-docs-fix-build-without-xsltproc.patch

diff --git a/meta-oe/recipes-core/systemd/systemd/0001-disable-xsltproc-completely.patch b/meta-oe/recipes-core/systemd/systemd/0001-disable-xsltproc-completely.patch
deleted file mode 100644
index 24940c7..0000000
--- a/meta-oe/recipes-core/systemd/systemd/0001-disable-xsltproc-completely.patch
+++ /dev/null
@@ -1,36 +0,0 @@
-From 2649787d76cfe7d89abb1b5afab7cb7cd54b601b Mon Sep 17 00:00:00 2001
-From: Koen Kooi <koen@dominion.thruhere.net>
-Date: Sun, 2 Oct 2011 19:54:29 +0200
-Subject: [PATCH] docs: fix build without xsltproc
-
-Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
----
-
-Upstream-status: Pending
-
- Makefile.am  |    2 ++
- 2 files changed, 2 insertions(+), 1 deletions(-)
-
-diff --git a/Makefile.am b/Makefile.am
-index f4a17aa..01240a5 100644
---- a/Makefile.am
-+++ b/Makefile.am
-@@ -750,6 +750,7 @@ EXTRA_DIST += \
-         src/dbus-loop.h \
-         src/spawn-agent.h
- 
-+if HAVE_XSLTPROC
- MANPAGES = \
- 	man/systemd.1 \
- 	man/systemctl.1 \
-@@ -844,6 +845,7 @@ EXTRA_DIST += \
- 	$(XML_IN_FILES) \
- 	${nodist_man_MANS:=.in} \
- 	${XML_IN_FILES:.xml.in=.html.in}
-+endif
- 
- systemd_SOURCES = \
- 	src/main.c
--- 
-1.6.6.1
-
diff --git a/meta-oe/recipes-core/systemd/systemd/0001-docs-fix-build-without-xsltproc.patch b/meta-oe/recipes-core/systemd/systemd/0001-docs-fix-build-without-xsltproc.patch
new file mode 100644
index 0000000..1fec570
--- /dev/null
+++ b/meta-oe/recipes-core/systemd/systemd/0001-docs-fix-build-without-xsltproc.patch
@@ -0,0 +1,38 @@
+From 97719ec99e3bd0040b616b044ab6ae33ae1cfd15 Mon Sep 17 00:00:00 2001
+From: Koen Kooi <koen@dominion.thruhere.net>
+Date: Sun, 2 Oct 2011 19:54:29 +0200
+Subject: [PATCH 1/2] docs: fix build without xsltproc
+
+Make would choke on missing rules for man/systemd.1
+
+Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
+---
+ Makefile.am |    5 +++++
+ 1 files changed, 5 insertions(+), 0 deletions(-)
+
+diff --git a/Makefile.am b/Makefile.am
+index 110a2f4..a5e57b7 100644
+--- a/Makefile.am
++++ b/Makefile.am
+@@ -650,6 +650,7 @@ EXTRA_DIST += \
+ 	src/acl-util.h \
+ 	src/logs-show.h
+ 
++if HAVE_XSLTPROC
+ MANPAGES = \
+ 	man/systemd.1 \
+ 	man/systemctl.1 \
+@@ -721,6 +722,10 @@ EXTRA_DIST += \
+ 	$(XML_IN_FILES) \
+ 	${nodist_man_MANS:=.in} \
+ 	${XML_IN_FILES:.xml.in=.html.in}
++else
++MANPAGES =
++MANPAGES_ALIAS =
++endif
+ 
+ systemd_SOURCES = \
+ 	src/main.c
+-- 
+1.7.2.5
+
diff --git a/meta-oe/recipes-core/systemd/systemd_git.bb b/meta-oe/recipes-core/systemd/systemd_git.bb
index bdaaf16..32bdee9 100644
--- a/meta-oe/recipes-core/systemd/systemd_git.bb
+++ b/meta-oe/recipes-core/systemd/systemd_git.bb
@@ -14,14 +14,14 @@ inherit gitpkgv
 PKGV = "v${GITPKGVTAG}"
 
 PV = "git"
-PR = "r7"
+PR = "r8"
 
 inherit useradd pkgconfig autotools vala perlnative
 
-SRCREV = "f6cebb3bd5a00d79c8131637c0f6796a75e6af99"
+SRCREV = "a3f914b2a21decb0c4bd7a763ddd3ace215091cb"
 
 SRC_URI = "git://anongit.freedesktop.org/systemd/systemd;protocol=git \
-           file://0001-disable-xsltproc-completely.patch \
+           file://0001-docs-fix-build-without-xsltproc.patch \
            ${UCLIBCPATCHES} \
           "
 UCLIBCPATCHES = ""
@@ -38,7 +38,8 @@ SYSTEMDDISTRO_angstrom = "angstrom"
 
 # The gtk+ tools should get built as a separate recipe e.g. systemd-tools
 EXTRA_OECONF = " --with-distro=${SYSTEMDDISTRO} \
-                 --with-rootdir=${base_prefix} \
+                 --with-rootprefix=${base_prefix} \
+                 --with-rootlibdir=${base_libdir} \
                  ${@base_contains('DISTRO_FEATURES', 'pam', '--enable-pam', '--disable-pam', d)} \
                  --disable-gtk \
                "
-- 
1.7.2.5

Re: [PATCH 1/2] udev: add 177

[Otavio Salvador]

On Thu, Jan 19, 2012 at 11:05, Koen Kooi <koen@dominion.thruhere.net> wrote:

> * 'udevadm' moved to ${PN} avoiding the need for the udev-utils package to
> be installed, so 'udev' has all the needed programs by itself.
>

NACK!

I have some images that use mdev and I use udevadm to tigger events so
please allow for this flexibility.


> * 'blkid' isn't needed anymore, since 176 udev links against libblkid
> * 'modprobe' and 'depmod' aren't needed anymore, udev now links against
> libkmod
> * The entire source including the license files were re-indented hence the
> LIC_FILES_CHKSUM changes
>

Awesome changes :-)

-- 
Otavio Salvador                             O.S. Systems
E-mail: otavio@ossystems.com.br  http://www.ossystems.com.br
Mobile: +55 53 9981-7854              http://projetos.ossystems.com.br

Re: [PATCH 2/2] systemd: update to v38+git

[Otavio Salvador]

On Thu, Jan 19, 2012 at 11:05, Koen Kooi <koen@dominion.thruhere.net> wrote:

>  .../0001-docs-fix-build-without-xsltproc.patch     |   38
> ++++++++++++++++++++
>

Please use the Upstream-Status field as it makes easy to spot if it has
been a backport or already send for upstream.

-- 
Otavio Salvador                             O.S. Systems
E-mail: otavio@ossystems.com.br  http://www.ossystems.com.br
Mobile: +55 53 9981-7854              http://projetos.ossystems.com.br

Re: [PATCH 1/2] udev: add 177

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

Op 20-01-12 04:37, Otavio Salvador schreef:
> On Thu, Jan 19, 2012 at 11:05, Koen Kooi <koen@dominion.thruhere.net>
> wrote:
> 
>> * 'udevadm' moved to ${PN} avoiding the need for the udev-utils package
>> to be installed, so 'udev' has all the needed programs by itself.
>> 
> 
> NACK!
> 
> I have some images that use mdev and I use udevadm to tigger events so 
> please allow for this flexibility.

So that's what the package split was for! I'll fix that in v2
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.11 (Darwin)
Comment: GPGTools - http://gpgtools.org

iEYEARECAAYFAk8ZGEEACgkQMkyGM64RGpFRrgCgslxtJzS9MubgqUQPHS/RJbW2
II0An228NmDxGMyoNv5ZFytrWQ10Z3yQ
=8j/8
-----END PGP SIGNATURE-----