* [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2
2012-12-20 12:52 Migrate GUPnP to meta-multimedia Ross Burton
@ 2012-12-20 12:52 ` Ross Burton
2012-12-21 9:43 ` Martin Jansa
2012-12-21 12:07 ` Koen Kooi
2012-12-20 12:52 ` [meta-multimedia PATCH 2/6] gupnp: add 0.18.4 and 0.19.3 Ross Burton
` (4 subsequent siblings)
5 siblings, 2 replies; 11+ messages in thread
From: Ross Burton @ 2012-12-20 12:52 UTC (permalink / raw)
To: openembedded-devel
Signed-off-by: Ross Burton <ross.burton@intel.com>
---
meta-multimedia/recipes-connectivity/gupnp/gssdp.inc | 16 ++++++++++++++++
.../recipes-connectivity/gupnp/gssdp_0.12.2.1.bb | 5 +++++
.../recipes-connectivity/gupnp/gssdp_0.13.2.bb | 8 ++++++++
3 files changed, 29 insertions(+)
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc b/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
new file mode 100644
index 0000000..51befd9
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
@@ -0,0 +1,16 @@
+SUMMARY = "Resource discovery and announcement over SSDP"
+DESCRIPTION = "GSSDP implements resource discovery and announcement over SSDP (Simpe Service Discovery Protocol)."
+LICENSE = "LGPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7"
+DEPENDS = "glib-2.0 libsoup-2.4 gobject-introspection-stub vala-stub-native"
+
+inherit autotools pkgconfig
+
+PACKAGES =+ "gssdp-tools"
+
+FILES_gssdp-tools = "${bindir}/gssdp* ${datadir}/gssdp/*.glade"
+
+EXTRA_OECONF = "--disable-introspection"
+
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'x11', 'gtk', '', d)}"
+PACKAGECONFIG[gtk] = "--with-gtk,--without-gtk,gtk+"
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
new file mode 100644
index 0000000..29cc721
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
@@ -0,0 +1,5 @@
+require gssdp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.12/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "8ac3a544ef0dcf8caaf7c249d2a50dc2"
+SRC_URI[sha256sum] = "928aa257815d044fdbfc740f5799530d41897947b5d7854173f636b36d728414"
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
new file mode 100644
index 0000000..c308fa0
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
@@ -0,0 +1,8 @@
+require gssdp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.13/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "758ed423cdd258a9a22d59c321b535ed"
+SRC_URI[sha256sum] = "8f663f8a72b66254f5c20a3610ff853ac8d00bf6f253828e37e51579caa34dce"
+
+# This is a development release so don't prefer it
+DEFAULT_PREFERENCE = "-1"
--
1.7.10
^ permalink raw reply related [flat|nested] 11+ messages in thread* Re: [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2
2012-12-20 12:52 ` [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2 Ross Burton
@ 2012-12-21 9:43 ` Martin Jansa
2012-12-21 12:36 ` Burton, Ross
2012-12-21 12:07 ` Koen Kooi
1 sibling, 1 reply; 11+ messages in thread
From: Martin Jansa @ 2012-12-21 9:43 UTC (permalink / raw)
To: openembedded-devel
[-- Attachment #1: Type: text/plain, Size: 3165 bytes --]
On Thu, Dec 20, 2012 at 12:52:38PM +0000, Ross Burton wrote:
> Signed-off-by: Ross Burton <ross.burton@intel.com>
> ---
> meta-multimedia/recipes-connectivity/gupnp/gssdp.inc | 16 ++++++++++++++++
> .../recipes-connectivity/gupnp/gssdp_0.12.2.1.bb | 5 +++++
> .../recipes-connectivity/gupnp/gssdp_0.13.2.bb | 8 ++++++++
> 3 files changed, 29 insertions(+)
> create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
> create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
> create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
>
> diff --git a/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc b/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
> new file mode 100644
> index 0000000..51befd9
> --- /dev/null
> +++ b/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
> @@ -0,0 +1,16 @@
> +SUMMARY = "Resource discovery and announcement over SSDP"
> +DESCRIPTION = "GSSDP implements resource discovery and announcement over SSDP (Simpe Service Discovery Protocol)."
> +LICENSE = "LGPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7"
> +DEPENDS = "glib-2.0 libsoup-2.4 gobject-introspection-stub vala-stub-native"
vala-stub-native does not exist afaik, why not use vala-native?
> +
> +inherit autotools pkgconfig
> +
> +PACKAGES =+ "gssdp-tools"
> +
> +FILES_gssdp-tools = "${bindir}/gssdp* ${datadir}/gssdp/*.glade"
> +
> +EXTRA_OECONF = "--disable-introspection"
> +
> +PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'x11', 'gtk', '', d)}"
> +PACKAGECONFIG[gtk] = "--with-gtk,--without-gtk,gtk+"
> diff --git a/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
> new file mode 100644
> index 0000000..29cc721
> --- /dev/null
> +++ b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
> @@ -0,0 +1,5 @@
> +require gssdp.inc
> +
> +SRC_URI = "http://download.gnome.org/sources/${BPN}/0.12/${BPN}-${PV}.tar.xz"
> +SRC_URI[md5sum] = "8ac3a544ef0dcf8caaf7c249d2a50dc2"
> +SRC_URI[sha256sum] = "928aa257815d044fdbfc740f5799530d41897947b5d7854173f636b36d728414"
> diff --git a/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
> new file mode 100644
> index 0000000..c308fa0
> --- /dev/null
> +++ b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
> @@ -0,0 +1,8 @@
> +require gssdp.inc
> +
> +SRC_URI = "http://download.gnome.org/sources/${BPN}/0.13/${BPN}-${PV}.tar.xz"
> +SRC_URI[md5sum] = "758ed423cdd258a9a22d59c321b535ed"
> +SRC_URI[sha256sum] = "8f663f8a72b66254f5c20a3610ff853ac8d00bf6f253828e37e51579caa34dce"
> +
> +# This is a development release so don't prefer it
> +DEFAULT_PREFERENCE = "-1"
> --
> 1.7.10
>
>
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-devel
--
Martin 'JaMa' Jansa jabber: Martin.Jansa@gmail.com
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]
^ permalink raw reply [flat|nested] 11+ messages in thread* Re: [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2
2012-12-21 9:43 ` Martin Jansa
@ 2012-12-21 12:36 ` Burton, Ross
2012-12-21 13:46 ` Burton, Ross
0 siblings, 1 reply; 11+ messages in thread
From: Burton, Ross @ 2012-12-21 12:36 UTC (permalink / raw)
To: openembedded-devel
On 21 December 2012 09:43, Martin Jansa <martin.jansa@gmail.com> wrote:
> vala-stub-native does not exist afaik, why not use vala-native?
Whoops, that patch didn't go anywhere did it.
commit 2471e89fe8b535c9fb4a1e15cb910d7d14b463b3
Author: Ross Burton <ross.burton@intel.com>
Date: Thu Dec 20 12:40:17 2012 +0000
vala-stub: add a stub for vala-native
Some packages have optional support for Vala but require vala.m4 to provide
VALA_PROG_VAPIGEN so that autoreconf works.
vala-stub provides a dummy VALA_PROG_VAPIGEN which doesn't do
anything, so the
configure script runs and believes that vala isn't present.
Signed-off-by: Ross Burton <ross.burton@intel.com>
(pending for oe-core)
For software that's written in C but has optional Vala bindings you
need Vala to configure even if you're going to turn it off. A stub
macro that lets configure run is all you need if you don't want to
build all of Vala (for example because you don't want to pull all of
meta-oe into your project).
I meant to change that to vala-native once I'd added the provides to
vala-stub, V2 shortly.
Ross
^ permalink raw reply [flat|nested] 11+ messages in thread* Re: [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2
2012-12-21 12:36 ` Burton, Ross
@ 2012-12-21 13:46 ` Burton, Ross
0 siblings, 0 replies; 11+ messages in thread
From: Burton, Ross @ 2012-12-21 13:46 UTC (permalink / raw)
To: openembedded-devel
On 21 December 2012 12:36, Burton, Ross <ross.burton@intel.com> wrote:
> On 21 December 2012 09:43, Martin Jansa <martin.jansa@gmail.com> wrote:
>> vala-stub-native does not exist afaik, why not use vala-native?
V2 sent, Vala is a pointless dependency for the GUPnP stack as it
requires gobject-introspection first, so we'll be building vala just
to get an autoconf macro that is never used.
Avoid the vala-stub debate now by simply commenting out that macro for now.
Ross
^ permalink raw reply [flat|nested] 11+ messages in thread
* Re: [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2
2012-12-20 12:52 ` [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2 Ross Burton
2012-12-21 9:43 ` Martin Jansa
@ 2012-12-21 12:07 ` Koen Kooi
1 sibling, 0 replies; 11+ messages in thread
From: Koen Kooi @ 2012-12-21 12:07 UTC (permalink / raw)
To: openembedded-devel
-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1
Op 20-12-12 13:52, Ross Burton schreef:
> Signed-off-by: Ross Burton <ross.burton@intel.com> ---
> meta-multimedia/recipes-connectivity/gupnp/gssdp.inc | 16
> ++++++++++++++++ .../recipes-connectivity/gupnp/gssdp_0.12.2.1.bb |
> 5 +++++ .../recipes-connectivity/gupnp/gssdp_0.13.2.bb | 8
> ++++++++ 3 files changed, 29 insertions(+) create mode 100644
> meta-multimedia/recipes-connectivity/gupnp/gssdp.inc create mode 100644
> meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb create mode
> 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
>
> diff --git a/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
> b/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc new file mode
> 100644 index 0000000..51befd9 --- /dev/null +++
> b/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc @@ -0,0 +1,16 @@
> +SUMMARY = "Resource discovery and announcement over SSDP" +DESCRIPTION =
> "GSSDP implements resource discovery and announcement over SSDP (Simpe
> Service Discovery Protocol)." +LICENSE = "LGPLv2" +LIC_FILES_CHKSUM =
> "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7" +DEPENDS =
> "glib-2.0 libsoup-2.4 gobject-introspection-stub vala-stub-native" +
> +inherit autotools pkgconfig + +PACKAGES =+ "gssdp-tools" +
> +FILES_gssdp-tools = "${bindir}/gssdp* ${datadir}/gssdp/*.glade" +
> +EXTRA_OECONF = "--disable-introspection" + +PACKAGECONFIG ??=
> "${@base_contains('DISTRO_FEATURES', 'x11', 'gtk', '', d)}"
> +PACKAGECONFIG[gtk] = "--with-gtk,--without-gtk,gtk+"
Minor nit: variables are grouped by task and ordered by task order, so
FILES/PACKAGES/R* goes below EXTRA_OECONF/do_configure/do_compile/do_install
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
Comment: GPGTools - http://gpgtools.org
iD8DBQFQ1FDpMkyGM64RGpERAh9SAJ0Yg4G0MXH+zAfMEoEfNAB42YGu4gCfbhpC
y6er7oRE3tVTjJekedFm02Q=
=fT9I
-----END PGP SIGNATURE-----
^ permalink raw reply [flat|nested] 11+ messages in thread
* [meta-multimedia PATCH 2/6] gupnp: add 0.18.4 and 0.19.3
2012-12-20 12:52 Migrate GUPnP to meta-multimedia Ross Burton
2012-12-20 12:52 ` [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2 Ross Burton
@ 2012-12-20 12:52 ` Ross Burton
2012-12-20 12:52 ` [meta-multimedia PATCH 3/6] gupnp-av: add 0.10.3 and 0.11.6 Ross Burton
` (3 subsequent siblings)
5 siblings, 0 replies; 11+ messages in thread
From: Ross Burton @ 2012-12-20 12:52 UTC (permalink / raw)
To: openembedded-devel
Signed-off-by: Ross Burton <ross.burton@intel.com>
---
.../recipes-connectivity/gupnp/gupnp.inc | 19 +++++++++++++++++++
.../recipes-connectivity/gupnp/gupnp_0.18.4.bb | 8 ++++++++
.../recipes-connectivity/gupnp/gupnp_0.19.3.bb | 10 ++++++++++
3 files changed, 37 insertions(+)
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp.inc
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp_0.18.4.bb
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp_0.19.3.bb
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp.inc b/meta-multimedia/recipes-connectivity/gupnp/gupnp.inc
new file mode 100644
index 0000000..91eae15
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp.inc
@@ -0,0 +1,19 @@
+SUMMARY = "UPnP framework"
+DESCRIPTION = "GUPnP is an elegant, object-oriented open source framework for creating UPnP devices and control points, written in C using GObject and libsoup. The GUPnP API is intended to be easy to use, efficient and flexible. It provides the same set of features as libupnp, but shields the developer from most of UPnP's internals."
+LICENSE = "LGPLv2+"
+
+DEPENDS = "e2fsprogs gssdp libsoup-2.4 libxml2 gnome-icon-theme gobject-introspection-stub"
+
+EXTRA_OECONF = "--disable-introspection"
+
+inherit autotools pkgconfig
+
+FILES_${PN} = "${libdir}/*.so.*"
+FILES_${PN}-dev += "${bindir}/gupnp-binding-tool"
+
+SYSROOT_PREPROCESS_FUNCS += "gupnp_sysroot_preprocess"
+
+gupnp_sysroot_preprocess () {
+ install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
+ install -m 755 ${D}${bindir}/gupnp-binding-tool ${SYSROOT_DESTDIR}${bindir_crossscripts}/
+}
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.18.4.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.18.4.bb
new file mode 100644
index 0000000..4fb1d05
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.18.4.bb
@@ -0,0 +1,8 @@
+require gupnp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.18/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "0e15fa26be7b1a0255e6dec07c285527"
+SRC_URI[sha256sum] = "6b437d5711b212292c6080626b97480268310da636a6cf937ad6119291af78a1"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+ file://libgupnp/gupnp.h;beginline=1;endline=20;md5=28c49b17d623afc3335efc2e511879e1"
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.19.3.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.19.3.bb
new file mode 100644
index 0000000..bab74b8
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.19.3.bb
@@ -0,0 +1,10 @@
+require gupnp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.19/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "8165c3ad3d16576a0a99250b75df23f8"
+SRC_URI[sha256sum] = "0d3097c419e1f8af0ff8ee91318d75e8896b3b92924cb1a5cf93010795a7118b"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+ file://libgupnp/gupnp.h;beginline=1;endline=20;md5=d78a69d9b6e63ee2dc72e7b674d97520"
+
+DEFAULT_PREFERENCE = "-1"
--
1.7.10
^ permalink raw reply related [flat|nested] 11+ messages in thread* [meta-multimedia PATCH 3/6] gupnp-av: add 0.10.3 and 0.11.6
2012-12-20 12:52 Migrate GUPnP to meta-multimedia Ross Burton
2012-12-20 12:52 ` [meta-multimedia PATCH 1/6] gssdp: add 0.12.2.1 and 0.13.2 Ross Burton
2012-12-20 12:52 ` [meta-multimedia PATCH 2/6] gupnp: add 0.18.4 and 0.19.3 Ross Burton
@ 2012-12-20 12:52 ` Ross Burton
2012-12-20 12:52 ` [meta-multimedia PATCH 4/6] gupnp-dlna: add 0.9.2 Ross Burton
` (2 subsequent siblings)
5 siblings, 0 replies; 11+ messages in thread
From: Ross Burton @ 2012-12-20 12:52 UTC (permalink / raw)
To: openembedded-devel
Signed-off-by: Ross Burton <ross.burton@intel.com>
---
meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc | 6 ++++++
.../recipes-connectivity/gupnp/gupnp-av_0.10.3.bb | 8 ++++++++
.../recipes-connectivity/gupnp/gupnp-av_0.11.6.bb | 10 ++++++++++
3 files changed, 24 insertions(+)
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.10.3.bb
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.11.6.bb
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc
new file mode 100644
index 0000000..32cef94
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc
@@ -0,0 +1,6 @@
+SUMMARY = "Helpers for AV applications using UPnP"
+DESCRIPTION = "GUPnP-AV is a collection of helpers for building AV (audio/video) applications using GUPnP."
+LICENSE = "LGPLv2"
+DEPENDS = "gupnp"
+
+inherit autotools pkgconfig
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.10.3.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.10.3.bb
new file mode 100644
index 0000000..5f8e73a
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.10.3.bb
@@ -0,0 +1,8 @@
+require gupnp-av.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.10/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "2c57e56b201765b2297946d8d99bd01c"
+SRC_URI[sha256sum] = "d0dbb727d87bc9f2dc834455d14a30700b16b41a57e9dcde2e822b378ca8f1e2"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+ file://libgupnp-av/gupnp-av.h;beginline=1;endline=22;md5=d344132a8766641fcb11213ff5982086"
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.11.6.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.11.6.bb
new file mode 100644
index 0000000..b402dd8
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.11.6.bb
@@ -0,0 +1,10 @@
+require gupnp-av.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.11/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "ee200393207323f0b594f11d6184556c"
+SRC_URI[sha256sum] = "401991336babb18c4ebed16e75e0b4d3e5848cff7bb878bbfd54a5d15203c4cc"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+ file://libgupnp-av/gupnp-av.h;beginline=1;endline=22;md5=2b47b7b5f799d2ebabe62b895e848820"
+
+DEFAULT_PREFERENCE = "-1"
--
1.7.10
^ permalink raw reply related [flat|nested] 11+ messages in thread* [meta-multimedia PATCH 4/6] gupnp-dlna: add 0.9.2
2012-12-20 12:52 Migrate GUPnP to meta-multimedia Ross Burton
` (2 preceding siblings ...)
2012-12-20 12:52 ` [meta-multimedia PATCH 3/6] gupnp-av: add 0.10.3 and 0.11.6 Ross Burton
@ 2012-12-20 12:52 ` Ross Burton
2012-12-20 12:52 ` [meta-multimedia PATCH 5/6] gupnp-igd: add 0.2.2 Ross Burton
2012-12-20 12:52 ` [meta-multimedia PATCH 6/6] gupnp-tools: add 0.8.1 Ross Burton
5 siblings, 0 replies; 11+ messages in thread
From: Ross Burton @ 2012-12-20 12:52 UTC (permalink / raw)
To: openembedded-devel
Signed-off-by: Ross Burton <ross.burton@intel.com>
---
.../recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb | 18 ++++++++++++++++++
1 file changed, 18 insertions(+)
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb
new file mode 100644
index 0000000..1748e35
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb
@@ -0,0 +1,18 @@
+SUMMARY = "Helpers for AV applications using DLNA"
+LICENSE = "LGPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
+ file://libgupnp-dlna/gupnp-dlna-profile.h;beginline=1;endline=22;md5=1b85459f65cb1e73a885ca137aab6274"
+
+DEPENDS = "libxml2 glib-2.0"
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.9/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "d972f9b03f0f3793cb895eb034ea314f"
+SRC_URI[sha256sum] = "c28d5650604c7da4f193e6b85049a4885f3a01f1996df768d55b5cb898a9fc53"
+
+inherit autotools pkgconfig
+
+# The GStreamer metadata backend requires GStreamer 1.0, so skip this until we
+# have that packaged.
+EXTRA_OECONF = "--disable-gstreamer-metadata-backend"
+
+FILES_${PN} += "${datadir}/gupnp-dlna-2.0/dlna-profiles"
--
1.7.10
^ permalink raw reply related [flat|nested] 11+ messages in thread* [meta-multimedia PATCH 5/6] gupnp-igd: add 0.2.2
2012-12-20 12:52 Migrate GUPnP to meta-multimedia Ross Burton
` (3 preceding siblings ...)
2012-12-20 12:52 ` [meta-multimedia PATCH 4/6] gupnp-dlna: add 0.9.2 Ross Burton
@ 2012-12-20 12:52 ` Ross Burton
2012-12-20 12:52 ` [meta-multimedia PATCH 6/6] gupnp-tools: add 0.8.1 Ross Burton
5 siblings, 0 replies; 11+ messages in thread
From: Ross Burton @ 2012-12-20 12:52 UTC (permalink / raw)
To: openembedded-devel
Signed-off-by: Ross Burton <ross.burton@intel.com>
---
.../recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb | 14 ++++++++++++++
1 file changed, 14 insertions(+)
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb
new file mode 100644
index 0000000..112bc4b
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb
@@ -0,0 +1,14 @@
+SUMMARY = "Helpers for interacting with Internet Gateway Devices over UPnP"
+LICENSE = "LGPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
+ file://libgupnp-igd/gupnp-simple-igd.c;beginline=1;endline=21;md5=aa292c0d9390463a6e1055dc5fc68e80"
+
+DEPENDS = "glib-2.0 gupnp"
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.2/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "f881323304185c02634034e3bda714ba"
+SRC_URI[sha256sum] = "73b6a98a0f13b29b34c3bfc07f99f78b1319211cb95a8585752873af2b9067d3"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--disable-introspection --disable-python"
--
1.7.10
^ permalink raw reply related [flat|nested] 11+ messages in thread* [meta-multimedia PATCH 6/6] gupnp-tools: add 0.8.1
2012-12-20 12:52 Migrate GUPnP to meta-multimedia Ross Burton
` (4 preceding siblings ...)
2012-12-20 12:52 ` [meta-multimedia PATCH 5/6] gupnp-igd: add 0.2.2 Ross Burton
@ 2012-12-20 12:52 ` Ross Burton
5 siblings, 0 replies; 11+ messages in thread
From: Ross Burton @ 2012-12-20 12:52 UTC (permalink / raw)
To: openembedded-devel
Signed-off-by: Ross Burton <ross.burton@intel.com>
---
.../recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb | 11 +++++++++++
1 file changed, 11 insertions(+)
create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb
new file mode 100644
index 0000000..7a26453
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb
@@ -0,0 +1,11 @@
+DESCRIPTION = "Tools for GUPnP"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
+ file://src/network-light/main.c;beginline=1;endline=21;md5=033bf37c030780c5a72165846b3003f6"
+DEPENDS = "gupnp gupnp-av gtk+ gnome-icon-theme"
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.8/${BPN}-${PV}.tar.bz2"
+SRC_URI[md5sum] = "cafc2a4f2d1a91a8c1228799073d1d7d"
+SRC_URI[sha256sum] = "57d5ca899f8da7e4ae69e5f98d75d1603aa7f388022f9ccb357f90abb22b75b6"
+
+inherit autotools pkgconfig
--
1.7.10
^ permalink raw reply related [flat|nested] 11+ messages in thread