[RFC][meta-oe][PATCH] jenkins: add 1.547

[RFC][meta-oe][PATCH] jenkins: add 1.547

[Koen Kooi]

The package split is based on the debian packages which have -common/-server and -slave.

Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
---

This introduces a dependency on meta-java, which is of course a big no-no for meta-oe :( That leaves me with a few questions:

1) What's the best place for the jenkins recipe?
2) Do we have a virtual/runtime thing to express a dependency on /usr/bin/java without dragging in meta-java?
3) Any ideas for the contents and deps of the jenkins-slave package? 

 .../jenkins/jenkins/jenkins-server.service         | 11 +++++++
 meta-oe/recipes-devtools/jenkins/jenkins_1.547.bb  | 36 ++++++++++++++++++++++
 2 files changed, 47 insertions(+)
 create mode 100644 meta-oe/recipes-devtools/jenkins/jenkins/jenkins-server.service
 create mode 100644 meta-oe/recipes-devtools/jenkins/jenkins_1.547.bb

diff --git a/meta-oe/recipes-devtools/jenkins/jenkins/jenkins-server.service b/meta-oe/recipes-devtools/jenkins/jenkins/jenkins-server.service
new file mode 100644
index 0000000..302d8bd
--- /dev/null
+++ b/meta-oe/recipes-devtools/jenkins/jenkins/jenkins-server.service
@@ -0,0 +1,11 @@
+[Unit]
+Description=Jenkins Daemon
+After=syslog.target
+
+[Service]
+Type=simple
+ExecStart=/usr/bin/java -jar /usr/share/jenkins/jenkins.war
+User=jenkins
+
+[Install]
+WantedBy=multi-user.target
diff --git a/meta-oe/recipes-devtools/jenkins/jenkins_1.547.bb b/meta-oe/recipes-devtools/jenkins/jenkins_1.547.bb
new file mode 100644
index 0000000..79d6dfc
--- /dev/null
+++ b/meta-oe/recipes-devtools/jenkins/jenkins_1.547.bb
@@ -0,0 +1,36 @@
+SUMMARY = "Continuous Integration and Job Scheduling Server"
+
+LICENSE = "MIT & Apache-2.0"
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58"
+
+SRC_URI = "http://mirrors.jenkins-ci.org/war/${PV}/jenkins.war \
+           file://jenkins-server.service \
+          "
+SRC_URI[md5sum] = "539f6871ea89228edf779d3bc5051393"
+SRC_URI[sha256sum] = "e8e11089df2331de368de38030134dfd3b9a2c38beffb52e3af9b30a9bddcca9"
+
+inherit allarch systemd useradd
+
+do_install() {
+    install -d ${D}${datadir}/jenkins
+    install -m0644 ${WORKDIR}/jenkins.war ${D}${datadir}/jenkins/
+
+    install -d ${D}${systemd_unitdir}/system
+    install -m0644 ${WORKDIR}/jenkins-server.service ${D}${systemd_unitdir}/system
+    sed -i -e s:/usr/share:${datadir}: ${D}${systemd_unitdir}/system/jenkins-server.service
+}
+
+PACKAGES =+ "jenkins-common"
+FILES_jenkins-common = "${datadir}/jenkins/jenkins.war"
+
+PACKAGES =+ "jenkins-server" 
+FILES_jenkins-server = "${systemd_unitdir}"
+
+USERADD_PACKAGES = "${PN}-server"
+USERADD_PARAM_${PN}-server = "--system --create-home --home-dir ${localstatedir}/lib/jenkins jenkins"
+
+SYSTEMD_PACKAGES = "${PN}-server"
+SYSTEMD_SERVICE_jenkins-server = "jenkins-server.service"
+
+# From the debian packages, not sure about psmisc.
+RDEPENDS_jenkins-server = "openjdk-7-jre procps file psmisc jenkins-common"
-- 
1.8.4.2

Re: [RFC][meta-oe][PATCH] jenkins: add 1.547

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 1433 bytes --]

On Sat, Jan 18, 2014 at 12:04:04PM +0100, Koen Kooi wrote:
> The package split is based on the debian packages which have -common/-server and -slave.
> 
> Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>
> ---
> 
> This introduces a dependency on meta-java, which is of course a big no-no for meta-oe :( That leaves me with a few questions:
> 
> 1) What's the best place for the jenkins recipe?

That's really hard question, I can only think that meta-java or
completly new layer would fit.

> 2) Do we have a virtual/runtime thing to express a dependency on /usr/bin/java without dragging in meta-java?

I think this isn't enough, because it would still show error that
virtual/java-foo isn't provided in included layers.

You can make it PACKAGECONFIG (sort of like RP did with python for
opkg-utils) which means that without PACKAGECONFIG change it won't build
at all.

> 3) Any ideas for the contents and deps of the jenkins-slave package? 

Just something like jenkins user and runtime dependency on java and leave
slave setup on jenkins master?

>  .../jenkins/jenkins/jenkins-server.service         | 11 +++++++
>  meta-oe/recipes-devtools/jenkins/jenkins_1.547.bb  | 36 ++++++++++++++++++++++
>  2 files changed, 47 insertions(+)
>  create mode 100644 meta-oe/recipes-devtools/jenkins/jenkins/jenkins-server.service
>  create mode 100644 meta-oe/recipes-devtools/jenkins/jenkins_1.547.bb

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

Re: [RFC][meta-oe][PATCH] jenkins: add 1.547

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

Martin Jansa schreef op 19-01-14 14:43:
> On Sat, Jan 18, 2014 at 12:04:04PM +0100, Koen Kooi wrote:
>> The package split is based on the debian packages which have
>> -common/-server and -slave.
>> 
>> Signed-off-by: Koen Kooi <koen@dominion.thruhere.net> ---
>> 
>> This introduces a dependency on meta-java, which is of course a big
>> no-no for meta-oe :( That leaves me with a few questions:
>> 
>> 1) What's the best place for the jenkins recipe?
> 
> That's really hard question, I can only think that meta-java or completly
> new layer would fit.

That's what I feared, I'll think about creating yet-another-layer.

> 
>> 2) Do we have a virtual/runtime thing to express a dependency on
>> /usr/bin/java without dragging in meta-java?
> 
> I think this isn't enough, because it would still show error that 
> virtual/java-foo isn't provided in included layers.
> 
> You can make it PACKAGECONFIG (sort of like RP did with python for 
> opkg-utils) which means that without PACKAGECONFIG change it won't build 
> at all.
> 
>> 3) Any ideas for the contents and deps of the jenkins-slave package?
> 
> Just something like jenkins user and runtime dependency on java and
> leave slave setup on jenkins master?

That is pretty much what I had in mind, except I'd like to add openssh-sshd,
scp and rsync to the mix as well.

regards,

Koen

-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
Comment: GPGTools - http://gpgtools.org

iD8DBQFS3Q4lMkyGM64RGpERAisiAKCePl0geAlE8oVO8jVJ7iyrKW+I2ACgrJeG
N9n2LW9ZUqt2eW8Z0QAjiHk=
=mDag
-----END PGP SIGNATURE-----