[parisc-linux] PIC assembly

[parisc-linux] PIC assembly

[Randolph Chung]

[-- Attachment #1: Type: text/plain, Size: 532 bytes --]

There is bug in the libgcrypt package in Debian where one of the
assembly routines was not written for PIC linking. The bug is:

http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=127863&repeatmerged=yes

I'ved filed a possible patch for this in the bug report, but I'm not
100% convinced I understand this correctly. Can someone please take a
look and let me know? 

the original .S file and the patch are also attached

randolph
-- 
   @..@                                         http://www.TauSq.org/
  (----)
 ( >__< )
 ^^ ~~ ^^

[-- Attachment #2: udiv-qrnnd.S --]
[-- Type: text/plain, Size: 2400 bytes --]

/* HP-PA  __udiv_qrnnd division support, used from longlong.h.
 *	  This version runs fast on PA 7000 and later.
 *
 *      Copyright (C) 1993, 1994, 1998, 
 *                    2001 Free Software Foundation, Inc.
 *
 * This file is part of GnuPG.
 *
 * GnuPG is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 *
 * GnuPG is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
 *
 * Note: This code is heavily based on the GNU MP Library.
 *	 Actually it's the same code with only minor changes in the
 *	 way the data is stored; this is to support the abstraction
 *	 of an optional secure memory allocation which may be used
 *	 to avoid revealing of sensitive data due to paging etc.
 *	 The GNU MP Library itself is published under the LGPL;
 *	 however I decided to publish this code under the plain GPL.
 */



/* INPUT PARAMETERS
 *   rem_ptr	   gr26
 *   n1 	   gr25
 *   n0 	   gr24
 *   d		   gr23
 */

	.code
	.label L$0000
	.word		0x43f00000
	.word		0x0
	.export 	__udiv_qrnnd
	.label		__udiv_qrnnd
	.proc
	.callinfo	frame=64,no_calls
	.entry
	ldo		64(%r30),%r30

	stws		%r25,-16(0,%r30)	; n_hi
	stws		%r24,-12(0,%r30)	; n_lo
	ldil		L'L$0000,%r19           ; '
	ldo		R'L$0000(%r19),%r19     ; '
	fldds		-16(0,%r30),%fr5
	stws		%r23,-12(0,%r30)
	comib,<=	0,%r25,L$1
	fcnvxf,dbl,dbl	%fr5,%fr5
	fldds		0(0,%r19),%fr4
	fadd,dbl	%fr4,%fr5,%fr5
	.label	L$1
	fcpy,sgl	%fr0,%fr6L
	fldws		-12(0,%r30),%fr6R
	fcnvxf,dbl,dbl	%fr6,%fr4

	fdiv,dbl	%fr5,%fr4,%fr5

	fcnvfx,dbl,dbl	%fr5,%fr4
	fstws		%fr4R,-16(%r30)
	xmpyu		%fr4R,%fr6R,%fr6
	ldws		-16(%r30),%r28
	fstds		%fr6,-16(0,%r30)
	ldws		-12(0,%r30),%r21
	ldws		-16(0,%r30),%r20
	sub		%r24,%r21,%r22
	subb		%r25,%r20,%r19
	comib,= 	0,%r19,L$2
	ldo		-64(%r30),%r30

	add		%r22,%r23,%r22
	ldo		-1(%r28),%r28
	.label	L$2
	bv		0(%r2)
	stws		%r22,0(0,%r26)

	.exit
	.procend



[-- Attachment #3: udiv-qrnnd.diff --]
[-- Type: text/plain, Size: 423 bytes --]

--- udiv-qrnnd.S.orig	Thu May 31 03:14:12 2001
+++ udiv-qrnnd.S	Sat Jan  5 23:27:02 2002
@@ -51,8 +51,11 @@
 
 	stws		%r25,-16(0,%r30)	; n_hi
 	stws		%r24,-12(0,%r30)	; n_lo
-	ldil		L'L$0000,%r19           ; '
-	ldo		R'L$0000(%r19),%r19     ; '
+
+	stw             %r19,-32(%r30)
+	addil		LT%L$0000,%r19
+	ldw		RT%L$0000(%r1),%r1
+	ldw		0(%r1), %r19
 	fldds		-16(0,%r30),%fr5
 	stws		%r23,-12(0,%r30)
 	comib,<=	0,%r25,L$1

Re: [parisc-linux] PIC assembly

[John David Anglin]

> I'ved filed a possible patch for this in the bug report, but I'm not
> 100% convinced I understand this correctly. Can someone please take a
> look and let me know? 

The patch needs to be revised.  You can't use r19 as a scratch register
in PIC mode.  There are several places where it is used in the routine.
Maybe you use can use r1 in its place.

> --- udiv-qrnnd.S.orig	Thu May 31 03:14:12 2001
> +++ udiv-qrnnd.S	Sat Jan  5 23:27:02 2002
> @@ -51,8 +51,11 @@
>  
>  	stws		%r25,-16(0,%r30)	; n_hi
>  	stws		%r24,-12(0,%r30)	; n_lo
> -	ldil		L'L$0000,%r19           ; '
> -	ldo		R'L$0000(%r19),%r19     ; '
> +
> +	stw             %r19,-32(%r30)
> +	addil		LT%L$0000,%r19
> +	ldw		RT%L$0000(%r1),%r1

Change following fldds insn to use r1, or change destination register in
the above to some other caller saved register and the fldds insn to match.

> +	ldw		0(%r1), %r19

Wrong.  This would load 0x43f00000 into r19.

Finally, you should put the data in the data section.  There might be a
problem accessing data in the code section with LT% (RT%) because LT%
is "LR% value offset of data linkage slots from linkage table pointer (r19)".

Dave
-- 
J. David Anglin                                  dave.anglin@nrc.ca
National Research Council of Canada              (613) 990-0752 (FAX: 952-6605)

Re: [parisc-linux] PIC assembly

[John David Anglin]

> This page contains links to various useful documents including the 32-bit
> runtime:
> 
> <http://h21007.www2.hp.com/dspp/tech/tech_TechTypeListingPage_IDX/1,1704,10403,00.html>.
> 
> The document itself is here:
> 
> <http://devresource.hp.com/STK/partner/rad_10_20.pdf>.

Maybe copies of these documents could be made accessible from the PA-RISC
LINUX Tech Documentation page as some of these are hard to find.

Dave
-- 
J. David Anglin                                  dave.anglin@nrc.ca
National Research Council of Canada              (613) 990-0752 (FAX: 952-6605)

Re: [parisc-linux] PIC assembly

[Grant Grundler]

"John David Anglin" wrote:
> > This page contains links to various useful documents including the 32-bit
> > runtime:
> > 
> > <http://h21007.www2.hp.com/dspp/tech/tech_TechTypeListingPage_IDX/1,1704,10
>   403,00.html>.
> > 
> > The document itself is here:
> > 
> > <http://devresource.hp.com/STK/partner/rad_10_20.pdf>.
> 
> Maybe copies of these documents could be made accessible from the PA-RISC
> LINUX Tech Documentation page as some of these are hard to find.

I've been given the OK to link into h21007.www2.hp.com website and promised
the URLs for specific documents wouldn't change (too) suddenly.
I'll add those links in the next couple of days to p-l.org
"Tech Documentation" to those.

grant

Re: [parisc-linux] PIC assembly

[Grant Grundler]

Grant Grundler wrote:
> I've been given the OK to link into h21007.www2.hp.com website and promised
> the URLs for specific documents wouldn't change (too) suddenly.
> I'll add those links in the next couple of days to p-l.org
> "Tech Documentation" to those.

I've added links for PA 1.1 and PA 2.0 Instruction Sets among other things.
Please reload:
	http://www.parisc-linux.org/documentation/index.html

Please continue to post requests for links to docs here.
(I'm not promising any new docs at this point).

thanks,
grant