[PATCH v2 0/3] neard fixes

[PATCH v2 0/3] neard fixes

[Jukka Rissanen]

Hi,

there was too many unrelated changes in my earlier patch so this one splits
it more.


Cheers,
Jukka


Jukka Rissanen (3):
  neard: Rename the recipe as we are already in 0.10
  neard: Use SRCREV instead of SRCPV
  neard: Split recipe to two parts

 meta/recipes-connectivity/neard/neard.inc     | 59 +++++++++++++++++++++++
 meta/recipes-connectivity/neard/neard_0.10.bb | 11 +++++
 meta/recipes-connectivity/neard/neard_0.9.bb  | 69 ---------------------------
 3 files changed, 70 insertions(+), 69 deletions(-)
 create mode 100644 meta/recipes-connectivity/neard/neard.inc
 create mode 100644 meta/recipes-connectivity/neard/neard_0.10.bb
 delete mode 100644 meta/recipes-connectivity/neard/neard_0.9.bb

-- 
1.7.11.7

[PATCH v2 1/3] neard: Rename the recipe as we are already in 0.10

[Jukka Rissanen]

Signed-off-by: Jukka Rissanen <jukka.rissanen@linux.intel.com>
---
 meta/recipes-connectivity/neard/neard_0.10.bb | 69 +++++++++++++++++++++++++++
 meta/recipes-connectivity/neard/neard_0.9.bb  | 69 ---------------------------
 2 files changed, 69 insertions(+), 69 deletions(-)
 create mode 100644 meta/recipes-connectivity/neard/neard_0.10.bb
 delete mode 100644 meta/recipes-connectivity/neard/neard_0.9.bb

diff --git a/meta/recipes-connectivity/neard/neard_0.10.bb b/meta/recipes-connectivity/neard/neard_0.10.bb
new file mode 100644
index 0000000..dc43f7e
--- /dev/null
+++ b/meta/recipes-connectivity/neard/neard_0.10.bb
@@ -0,0 +1,69 @@
+SUMMARY = "Linux NFC daemon"
+DESCRIPTION = "A daemon for the Linux Near Field Communication stack"
+HOMEPAGE = "http://01.org/linux-nfc"
+LICENSE = "GPLv2"
+
+DEPENDS = "dbus glib-2.0 libnl"
+
+SRC_URI = "git://git.kernel.org/pub/scm/network/nfc/neard.git;protocol=git \
+           file://neard.in \
+           file://neard.service.in \
+          "
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
+ file://src/near.h;beginline=1;endline=20;md5=358e4deefef251a4761e1ffacc965d13 \
+ "
+
+S = "${WORKDIR}/git"
+SRCREV = "eb486bf35e24d7d1db61350f5ab393a0c880523d"
+PV = "0.10+git${SRCPV}"
+PR = "r0"
+
+inherit autotools pkgconfig systemd update-rc.d
+
+EXTRA_OECONF += "--enable-tools"
+
+do_install() {
+	oe_runmake DESTDIR=${D} libexecdir=${libexecdir} install
+}
+
+# This would copy neard start-stop shell and test scripts
+do_install_append() {
+	if ${@base_contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
+		install -d ${D}${sysconfdir}/init.d/
+		sed "s:@installpath@:${libexecdir}:" ${WORKDIR}/neard.in \
+		  > ${D}${sysconfdir}/init.d/neard
+		chmod 0755 ${D}${sysconfdir}/init.d/neard
+	fi
+
+	if ${@base_contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+		install -d ${D}${systemd_unitdir}/system
+		sed "s:@installpath@:${libexecdir}:" ${WORKDIR}/neard.service.in \
+		  > ${D}${systemd_unitdir}/system/neard.service
+	fi
+
+	# Install the tests for neard-tests
+	install -d ${D}${libdir}/neard
+	install -m 0755 ${S}/test/* ${D}${libdir}/${BPN}/
+	install -m 0755 ${S}/tools/nfctool/nfctool ${D}${libdir}/${BPN}/
+}
+
+PACKAGES =+ "${PN}-tests"
+
+FILES_${PN}-tests = "${libdir}/${BPN}/*-test"
+FILES_${PN}-dbg += "${libdir}/${BPN}/*/.debug"
+
+RDEPENDS_${PN} = "dbus python python-dbus python-pygobject"
+
+# Bluez & Wifi are not mandatory except for handover
+RRECOMMENDS_${PN} = "\
+                     ${@base_contains('DISTRO_FEATURES', 'bluetooth', 'bluez4', '', d)} \
+                     ${@base_contains('DISTRO_FEATURES', 'wifi','wpa-supplicant', '', d)} \
+                    "
+
+RDEPENDS_${PN}-tests = "python python-dbus python-pygobject"
+
+INITSCRIPT_NAME = "neard"
+INITSCRIPT_PARAMS = "defaults 64"
+
+SYSTEMD_SERVICE_${PN} = "neard.service"
diff --git a/meta/recipes-connectivity/neard/neard_0.9.bb b/meta/recipes-connectivity/neard/neard_0.9.bb
deleted file mode 100644
index dc43f7e..0000000
--- a/meta/recipes-connectivity/neard/neard_0.9.bb
+++ /dev/null
@@ -1,69 +0,0 @@
-SUMMARY = "Linux NFC daemon"
-DESCRIPTION = "A daemon for the Linux Near Field Communication stack"
-HOMEPAGE = "http://01.org/linux-nfc"
-LICENSE = "GPLv2"
-
-DEPENDS = "dbus glib-2.0 libnl"
-
-SRC_URI = "git://git.kernel.org/pub/scm/network/nfc/neard.git;protocol=git \
-           file://neard.in \
-           file://neard.service.in \
-          "
-
-LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
- file://src/near.h;beginline=1;endline=20;md5=358e4deefef251a4761e1ffacc965d13 \
- "
-
-S = "${WORKDIR}/git"
-SRCREV = "eb486bf35e24d7d1db61350f5ab393a0c880523d"
-PV = "0.10+git${SRCPV}"
-PR = "r0"
-
-inherit autotools pkgconfig systemd update-rc.d
-
-EXTRA_OECONF += "--enable-tools"
-
-do_install() {
-	oe_runmake DESTDIR=${D} libexecdir=${libexecdir} install
-}
-
-# This would copy neard start-stop shell and test scripts
-do_install_append() {
-	if ${@base_contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
-		install -d ${D}${sysconfdir}/init.d/
-		sed "s:@installpath@:${libexecdir}:" ${WORKDIR}/neard.in \
-		  > ${D}${sysconfdir}/init.d/neard
-		chmod 0755 ${D}${sysconfdir}/init.d/neard
-	fi
-
-	if ${@base_contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
-		install -d ${D}${systemd_unitdir}/system
-		sed "s:@installpath@:${libexecdir}:" ${WORKDIR}/neard.service.in \
-		  > ${D}${systemd_unitdir}/system/neard.service
-	fi
-
-	# Install the tests for neard-tests
-	install -d ${D}${libdir}/neard
-	install -m 0755 ${S}/test/* ${D}${libdir}/${BPN}/
-	install -m 0755 ${S}/tools/nfctool/nfctool ${D}${libdir}/${BPN}/
-}
-
-PACKAGES =+ "${PN}-tests"
-
-FILES_${PN}-tests = "${libdir}/${BPN}/*-test"
-FILES_${PN}-dbg += "${libdir}/${BPN}/*/.debug"
-
-RDEPENDS_${PN} = "dbus python python-dbus python-pygobject"
-
-# Bluez & Wifi are not mandatory except for handover
-RRECOMMENDS_${PN} = "\
-                     ${@base_contains('DISTRO_FEATURES', 'bluetooth', 'bluez4', '', d)} \
-                     ${@base_contains('DISTRO_FEATURES', 'wifi','wpa-supplicant', '', d)} \
-                    "
-
-RDEPENDS_${PN}-tests = "python python-dbus python-pygobject"
-
-INITSCRIPT_NAME = "neard"
-INITSCRIPT_PARAMS = "defaults 64"
-
-SYSTEMD_SERVICE_${PN} = "neard.service"
-- 
1.7.11.7

[PATCH v2 2/3] neard: Use SRCREV instead of SRCPV

[Jukka Rissanen]

Signed-off-by: Jukka Rissanen <jukka.rissanen@linux.intel.com>
---
 meta/recipes-connectivity/neard/neard_0.10.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/recipes-connectivity/neard/neard_0.10.bb b/meta/recipes-connectivity/neard/neard_0.10.bb
index dc43f7e..b9198af 100644
--- a/meta/recipes-connectivity/neard/neard_0.10.bb
+++ b/meta/recipes-connectivity/neard/neard_0.10.bb
@@ -16,7 +16,7 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
 
 S = "${WORKDIR}/git"
 SRCREV = "eb486bf35e24d7d1db61350f5ab393a0c880523d"
-PV = "0.10+git${SRCPV}"
+PV = "0.10+git${SRCREV}"
 PR = "r0"
 
 inherit autotools pkgconfig systemd update-rc.d
-- 
1.7.11.7

Re: [PATCH v2 2/3] neard: Use SRCREV instead of SRCPV

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 1134 bytes --]

On Thu, May 02, 2013 at 05:56:32PM +0300, Jukka Rissanen wrote:
> 
> Signed-off-by: Jukka Rissanen <jukka.rissanen@linux.intel.com>
> ---
>  meta/recipes-connectivity/neard/neard_0.10.bb | 2 +-
>  1 file changed, 1 insertion(+), 1 deletion(-)
> 
> diff --git a/meta/recipes-connectivity/neard/neard_0.10.bb b/meta/recipes-connectivity/neard/neard_0.10.bb
> index dc43f7e..b9198af 100644
> --- a/meta/recipes-connectivity/neard/neard_0.10.bb
> +++ b/meta/recipes-connectivity/neard/neard_0.10.bb
> @@ -16,7 +16,7 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
>  
>  S = "${WORKDIR}/git"
>  SRCREV = "eb486bf35e24d7d1db61350f5ab393a0c880523d"
> -PV = "0.10+git${SRCPV}"
> +PV = "0.10+git${SRCREV}"

Why? SRCPV is better.

>  PR = "r0"
>  
>  inherit autotools pkgconfig systemd update-rc.d
> -- 
> 1.7.11.7
> 
> 
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

Re: [PATCH v2 2/3] neard: Use SRCREV instead of SRCPV

[Burton, Ross]

On 2 May 2013 16:39, Martin Jansa <martin.jansa@gmail.com> wrote:
>> -PV = "0.10+git${SRCPV}"
>> +PV = "0.10+git${SRCREV}"

As the git revision is the 0.10 tag, wouldn't it be clearer to not set
PV as the git revision is a detail of the fetcher - this *is* 0.10.

Ross

Re: [PATCH v2 2/3] neard: Use SRCREV instead of SRCPV

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 524 bytes --]

On Thu, May 02, 2013 at 05:11:28PM +0100, Burton, Ross wrote:
> On 2 May 2013 16:39, Martin Jansa <martin.jansa@gmail.com> wrote:
> >> -PV = "0.10+git${SRCPV}"
> >> +PV = "0.10+git${SRCREV}"
> 
> As the git revision is the 0.10 tag, wouldn't it be clearer to not set
> PV as the git revision is a detail of the fetcher - this *is* 0.10.

That's fine too as long as nobody bumps SRCREV without updating PV or
uses AUTOREV from some .inc or local.conf.

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

Re: [PATCH v2 2/3] neard: Use SRCREV instead of SRCPV

[Richard Purdie]

On Thu, 2013-05-02 at 18:46 +0200, Martin Jansa wrote:
> On Thu, May 02, 2013 at 05:11:28PM +0100, Burton, Ross wrote:
> > On 2 May 2013 16:39, Martin Jansa <martin.jansa@gmail.com> wrote:
> > >> -PV = "0.10+git${SRCPV}"
> > >> +PV = "0.10+git${SRCREV}"
> > 
> > As the git revision is the 0.10 tag, wouldn't it be clearer to not set
> > PV as the git revision is a detail of the fetcher - this *is* 0.10.
> 
> That's fine too as long as nobody bumps SRCREV without updating PV or
> uses AUTOREV from some .inc or local.conf.

Agreed, regardless, SRCREV in PV is not correct, we shouldn't do that
and we have SRCPV for a reason.

Cheers,

Richard

[PATCH v2 3/3] neard: Split recipe to two parts

[Jukka Rissanen]

This way it is easier to override settings if needed.

Signed-off-by: Jukka Rissanen <jukka.rissanen@linux.intel.com>
---
 meta/recipes-connectivity/neard/neard.inc     | 59 ++++++++++++++++++++++++++
 meta/recipes-connectivity/neard/neard_0.10.bb | 60 +--------------------------
 2 files changed, 60 insertions(+), 59 deletions(-)
 create mode 100644 meta/recipes-connectivity/neard/neard.inc

diff --git a/meta/recipes-connectivity/neard/neard.inc b/meta/recipes-connectivity/neard/neard.inc
new file mode 100644
index 0000000..7cccbdc
--- /dev/null
+++ b/meta/recipes-connectivity/neard/neard.inc
@@ -0,0 +1,59 @@
+SUMMARY = "Linux NFC daemon"
+DESCRIPTION = "A daemon for the Linux Near Field Communication stack"
+HOMEPAGE = "http://01.org/linux-nfc"
+LICENSE = "GPLv2"
+
+DEPENDS = "dbus glib-2.0 libnl"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
+ file://src/near.h;beginline=1;endline=20;md5=358e4deefef251a4761e1ffacc965d13 \
+ "
+
+inherit autotools pkgconfig systemd update-rc.d
+
+EXTRA_OECONF += "--enable-tools"
+
+do_install() {
+	oe_runmake DESTDIR=${D} libexecdir=${libexecdir} install
+}
+
+# This would copy neard start-stop shell and test scripts
+do_install_append() {
+	if ${@base_contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
+		install -d ${D}${sysconfdir}/init.d/
+		sed "s:@installpath@:${libexecdir}:" ${WORKDIR}/neard.in \
+		  > ${D}${sysconfdir}/init.d/neard
+		chmod 0755 ${D}${sysconfdir}/init.d/neard
+	fi
+
+	if ${@base_contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+		install -d ${D}${systemd_unitdir}/system
+		sed "s:@installpath@:${libexecdir}:" ${WORKDIR}/neard.service.in \
+		  > ${D}${systemd_unitdir}/system/neard.service
+	fi
+
+	# Install the tests for neard-tests
+	install -d ${D}${libdir}/neard
+	install -m 0755 ${S}/test/* ${D}${libdir}/${BPN}/
+	install -m 0755 ${S}/tools/nfctool/nfctool ${D}${libdir}/${BPN}/
+}
+
+PACKAGES =+ "${PN}-tests"
+
+FILES_${PN}-tests = "${libdir}/${BPN}/*-test"
+FILES_${PN}-dbg += "${libdir}/${BPN}/*/.debug"
+
+RDEPENDS_${PN} = "dbus python python-dbus python-pygobject"
+
+# Bluez & Wifi are not mandatory except for handover
+RRECOMMENDS_${PN} = "\
+                     ${@base_contains('DISTRO_FEATURES', 'bluetooth', 'bluez4', '', d)} \
+                     ${@base_contains('DISTRO_FEATURES', 'wifi','wpa-supplicant', '', d)} \
+                    "
+
+RDEPENDS_${PN}-tests = "python python-dbus python-pygobject"
+
+INITSCRIPT_NAME = "neard"
+INITSCRIPT_PARAMS = "defaults 64"
+
+SYSTEMD_SERVICE_${PN} = "neard.service"
diff --git a/meta/recipes-connectivity/neard/neard_0.10.bb b/meta/recipes-connectivity/neard/neard_0.10.bb
index b9198af..09f97be 100644
--- a/meta/recipes-connectivity/neard/neard_0.10.bb
+++ b/meta/recipes-connectivity/neard/neard_0.10.bb
@@ -1,69 +1,11 @@
-SUMMARY = "Linux NFC daemon"
-DESCRIPTION = "A daemon for the Linux Near Field Communication stack"
-HOMEPAGE = "http://01.org/linux-nfc"
-LICENSE = "GPLv2"
-
-DEPENDS = "dbus glib-2.0 libnl"
+require neard.inc
 
 SRC_URI = "git://git.kernel.org/pub/scm/network/nfc/neard.git;protocol=git \
            file://neard.in \
            file://neard.service.in \
           "
 
-LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
- file://src/near.h;beginline=1;endline=20;md5=358e4deefef251a4761e1ffacc965d13 \
- "
-
 S = "${WORKDIR}/git"
 SRCREV = "eb486bf35e24d7d1db61350f5ab393a0c880523d"
 PV = "0.10+git${SRCREV}"
 PR = "r0"
-
-inherit autotools pkgconfig systemd update-rc.d
-
-EXTRA_OECONF += "--enable-tools"
-
-do_install() {
-	oe_runmake DESTDIR=${D} libexecdir=${libexecdir} install
-}
-
-# This would copy neard start-stop shell and test scripts
-do_install_append() {
-	if ${@base_contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
-		install -d ${D}${sysconfdir}/init.d/
-		sed "s:@installpath@:${libexecdir}:" ${WORKDIR}/neard.in \
-		  > ${D}${sysconfdir}/init.d/neard
-		chmod 0755 ${D}${sysconfdir}/init.d/neard
-	fi
-
-	if ${@base_contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
-		install -d ${D}${systemd_unitdir}/system
-		sed "s:@installpath@:${libexecdir}:" ${WORKDIR}/neard.service.in \
-		  > ${D}${systemd_unitdir}/system/neard.service
-	fi
-
-	# Install the tests for neard-tests
-	install -d ${D}${libdir}/neard
-	install -m 0755 ${S}/test/* ${D}${libdir}/${BPN}/
-	install -m 0755 ${S}/tools/nfctool/nfctool ${D}${libdir}/${BPN}/
-}
-
-PACKAGES =+ "${PN}-tests"
-
-FILES_${PN}-tests = "${libdir}/${BPN}/*-test"
-FILES_${PN}-dbg += "${libdir}/${BPN}/*/.debug"
-
-RDEPENDS_${PN} = "dbus python python-dbus python-pygobject"
-
-# Bluez & Wifi are not mandatory except for handover
-RRECOMMENDS_${PN} = "\
-                     ${@base_contains('DISTRO_FEATURES', 'bluetooth', 'bluez4', '', d)} \
-                     ${@base_contains('DISTRO_FEATURES', 'wifi','wpa-supplicant', '', d)} \
-                    "
-
-RDEPENDS_${PN}-tests = "python python-dbus python-pygobject"
-
-INITSCRIPT_NAME = "neard"
-INITSCRIPT_PARAMS = "defaults 64"
-
-SYSTEMD_SERVICE_${PN} = "neard.service"
-- 
1.7.11.7