* [PATCH 0/8] opkg recipe improvements
@ 2014-12-21 22:11 Paul Barker
2014-12-21 22:11 ` [PATCH 1/8] opkg-collateral: Use new lists_dir syntax Paul Barker
` (7 more replies)
0 siblings, 8 replies; 11+ messages in thread
From: Paul Barker @ 2014-12-21 22:11 UTC (permalink / raw)
To: OE Core
This patch series implements the changes I suggested on the mailing list a few
days ago.
Summary of changes:
- The opkg recipe is cleanup up and opkg.inc is merged into opkg_0.2.4.bb.
- opkg-collateral is updated and then merged into the main opkg recipe.
- The cryptically named opkg-config-base is given the much more obvious name
opkg-arch-config.
- poky-feed-config-opkg is dropped, it is recommended that people use
distro-feed-configs from meta-oe.
- A new opkg-keyrings recipe is created to package up keys used to verify
packages and package feeds. The functionality within opkg which this depends
upon is backported.
After these changes:
- All generic files are in 'opkg', including the main opkg config which should
be upgraded in step with opkg itself.
- Arch-specific config is only in 'opkg-arch-config' which has MACHINE_ARCH.
Additional arch-specific config can easily be added to this package with a
bbappend.
- Distro-specific config is in 'distro-feed-config' and 'opkg-keyrings'.
Additional distro-specific config is probably best added as extra recipes.
I think this is a much cleaner layout but let me know if you disagree, I'm happy
to discuss/improve/respin these patches.
All these changes work locally in qemuarm and the on-target upgrade path is
mostly clean. opkg-collateral does get left behind on the target filesystem
after an upgrade but it's effectively an empty package. I don't think this poses
any problems.
Paul Barker (8):
opkg-collateral: Use new lists_dir syntax
opkg-arch-config: Renamed from opkg-config-base
opkg-collateral: Simplify source files
opkg: Merge opkg.inc into recipe and tidy up
opkg: Merge in opkg-collateral
poky-feed-config-opkg: Remove
opkg: Backport improvements to opkg-key
opkg-keyrings: New recipe
meta/classes/rootfs_ipk.bbclass | 2 +-
meta/conf/layer.conf | 2 +-
.../feed-config/poky-feed-config-opkg_1.0.bb | 44 -----------
...-config-base_1.0.bb => opkg-arch-config_1.0.bb} | 3 +-
meta/recipes-devtools/opkg/opkg-collateral.bb | 24 ------
meta/recipes-devtools/opkg/opkg-collateral/dest | 1 -
meta/recipes-devtools/opkg/opkg-collateral/src | 0
meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb | 48 ++++++++++++
meta/recipes-devtools/opkg/opkg.inc | 76 -------------------
.../opkg/0001-opkg-key-Backport-improvements.patch | 78 +++++++++++++++++++
.../opkg.conf.comments => opkg/opkg.conf} | 2 +
meta/recipes-devtools/opkg/opkg_0.2.4.bb | 88 +++++++++++++++++++++-
12 files changed, 218 insertions(+), 150 deletions(-)
delete mode 100644 meta/recipes-core/feed-config/poky-feed-config-opkg_1.0.bb
rename meta/recipes-devtools/opkg/{opkg-config-base_1.0.bb => opkg-arch-config_1.0.bb} (87%)
delete mode 100644 meta/recipes-devtools/opkg/opkg-collateral.bb
delete mode 100644 meta/recipes-devtools/opkg/opkg-collateral/dest
delete mode 100644 meta/recipes-devtools/opkg/opkg-collateral/src
create mode 100644 meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb
delete mode 100644 meta/recipes-devtools/opkg/opkg.inc
create mode 100644 meta/recipes-devtools/opkg/opkg/0001-opkg-key-Backport-improvements.patch
rename meta/recipes-devtools/opkg/{opkg-collateral/opkg.conf.comments => opkg/opkg.conf} (92%)
--
1.9.1
^ permalink raw reply [flat|nested] 11+ messages in thread
* [PATCH 1/8] opkg-collateral: Use new lists_dir syntax
2014-12-21 22:11 [PATCH 0/8] opkg recipe improvements Paul Barker
@ 2014-12-21 22:11 ` Paul Barker
2014-12-21 22:11 ` [PATCH 2/8] opkg-arch-config: Renamed from opkg-config-base Paul Barker
` (6 subsequent siblings)
7 siblings, 0 replies; 11+ messages in thread
From: Paul Barker @ 2014-12-21 22:11 UTC (permalink / raw)
To: OE Core
Since opkg v0.2.3, it has been possible to use the new syntax for the
'lists_dir' option in an opkg configuration file. From v0.3.0, this new syntax
is required. The new syntax matches the way other options are set.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/recipes-devtools/opkg/opkg-collateral.bb | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/meta/recipes-devtools/opkg/opkg-collateral.bb b/meta/recipes-devtools/opkg/opkg-collateral.bb
index b121827..3825ffb 100644
--- a/meta/recipes-devtools/opkg/opkg-collateral.bb
+++ b/meta/recipes-devtools/opkg/opkg-collateral.bb
@@ -13,7 +13,7 @@ do_compile () {
cat ${WORKDIR}/opkg.conf.comments >${WORKDIR}/opkg.conf
cat ${WORKDIR}/src >>${WORKDIR}/opkg.conf
cat ${WORKDIR}/dest >>${WORKDIR}/opkg.conf
- echo "lists_dir ext ${OPKGLIBDIR}/opkg" >>${WORKDIR}/opkg.conf
+ echo "option lists_dir ${OPKGLIBDIR}/opkg" >>${WORKDIR}/opkg.conf
}
do_install () {
--
1.9.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [PATCH 2/8] opkg-arch-config: Renamed from opkg-config-base
2014-12-21 22:11 [PATCH 0/8] opkg recipe improvements Paul Barker
2014-12-21 22:11 ` [PATCH 1/8] opkg-collateral: Use new lists_dir syntax Paul Barker
@ 2014-12-21 22:11 ` Paul Barker
2014-12-22 11:05 ` Martin Jansa
2014-12-21 22:11 ` [PATCH 3/8] opkg-collateral: Simplify source files Paul Barker
` (5 subsequent siblings)
7 siblings, 1 reply; 11+ messages in thread
From: Paul Barker @ 2014-12-21 22:11 UTC (permalink / raw)
To: OE Core
The name 'opkg-arch-config' is much more descriptive.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/conf/layer.conf | 2 +-
.../opkg/{opkg-config-base_1.0.bb => opkg-arch-config_1.0.bb} | 3 ++-
meta/recipes-devtools/opkg/opkg.inc | 2 +-
3 files changed, 4 insertions(+), 3 deletions(-)
rename meta/recipes-devtools/opkg/{opkg-config-base_1.0.bb => opkg-arch-config_1.0.bb} (87%)
diff --git a/meta/conf/layer.conf b/meta/conf/layer.conf
index de96548..4fd3a16 100644
--- a/meta/conf/layer.conf
+++ b/meta/conf/layer.conf
@@ -18,7 +18,7 @@ COREBASE = '${@os.path.normpath("${LAYERDIR}/../")}'
SIGGEN_EXCLUDERECIPES_ABISAFE += " \
sysvinit-inittab \
shadow-securetty \
- opkg-config-base \
+ opkg-arch-config \
netbase \
init-ifupdown \
connman-conf \
diff --git a/meta/recipes-devtools/opkg/opkg-config-base_1.0.bb b/meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
similarity index 87%
rename from meta/recipes-devtools/opkg/opkg-config-base_1.0.bb
rename to meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
index acbe129..f700865 100644
--- a/meta/recipes-devtools/opkg/opkg-config-base_1.0.bb
+++ b/meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
@@ -1,4 +1,4 @@
-SUMMARY = "Base configuration files for opkg"
+SUMMARY = "Architecture-dependent configuration for opkg"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
PACKAGE_ARCH = "${MACHINE_ARCH}"
@@ -28,3 +28,4 @@ FILES_${PN} = "${sysconfdir}/opkg/ "
CONFFILES_${PN} += "${sysconfdir}/opkg/arch.conf"
+RREPLACES_${PN} = "opkg-config-base"
diff --git a/meta/recipes-devtools/opkg/opkg.inc b/meta/recipes-devtools/opkg/opkg.inc
index 56c54b6..991c114 100644
--- a/meta/recipes-devtools/opkg/opkg.inc
+++ b/meta/recipes-devtools/opkg/opkg.inc
@@ -38,7 +38,7 @@ EXTRA_OECONF = "\
--with-opkglibdir=${OPKGLIBDIR} \
"
-RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-config-base run-postinsts"
+RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config run-postinsts"
RDEPENDS_${PN}_class-native = ""
RDEPENDS_${PN}_class-nativesdk = ""
RREPLACES_${PN} = "opkg-nogpg"
--
1.9.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [PATCH 3/8] opkg-collateral: Simplify source files
2014-12-21 22:11 [PATCH 0/8] opkg recipe improvements Paul Barker
2014-12-21 22:11 ` [PATCH 1/8] opkg-collateral: Use new lists_dir syntax Paul Barker
2014-12-21 22:11 ` [PATCH 2/8] opkg-arch-config: Renamed from opkg-config-base Paul Barker
@ 2014-12-21 22:11 ` Paul Barker
2014-12-21 22:11 ` [PATCH 4/8] opkg: Merge opkg.inc into recipe and tidy up Paul Barker
` (4 subsequent siblings)
7 siblings, 0 replies; 11+ messages in thread
From: Paul Barker @ 2014-12-21 22:11 UTC (permalink / raw)
To: OE Core
Instead of having the source files 'opkg.conf.comments', 'dest' and 'src', we
simply have one 'opkg.conf' file containing all the necessary configuration.
This does mean that replacing 'src' in a bbappend to define distro-specific
package feeds is no longer supported, but these feed configurations should be
packaged separately from the rest of the opkg configuration anyway so that
things can be updated independently. The best recipe to use for managing feed
configs is currently distro-feed-config in the meta-oe layer.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/recipes-devtools/opkg/opkg-collateral.bb | 7 +------
meta/recipes-devtools/opkg/opkg-collateral/dest | 1 -
.../opkg/opkg-collateral/{opkg.conf.comments => opkg.conf} | 2 ++
meta/recipes-devtools/opkg/opkg-collateral/src | 0
4 files changed, 3 insertions(+), 7 deletions(-)
delete mode 100644 meta/recipes-devtools/opkg/opkg-collateral/dest
rename meta/recipes-devtools/opkg/opkg-collateral/{opkg.conf.comments => opkg.conf} (92%)
delete mode 100644 meta/recipes-devtools/opkg/opkg-collateral/src
diff --git a/meta/recipes-devtools/opkg/opkg-collateral.bb b/meta/recipes-devtools/opkg/opkg-collateral.bb
index 3825ffb..b16579c 100644
--- a/meta/recipes-devtools/opkg/opkg-collateral.bb
+++ b/meta/recipes-devtools/opkg/opkg-collateral.bb
@@ -4,15 +4,10 @@ LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
PR = "r2"
-SRC_URI = "file://opkg.conf.comments \
- file://dest \
- file://src "
+SRC_URI = "file://opkg.conf"
OPKGLIBDIR = "${localstatedir}/lib"
do_compile () {
- cat ${WORKDIR}/opkg.conf.comments >${WORKDIR}/opkg.conf
- cat ${WORKDIR}/src >>${WORKDIR}/opkg.conf
- cat ${WORKDIR}/dest >>${WORKDIR}/opkg.conf
echo "option lists_dir ${OPKGLIBDIR}/opkg" >>${WORKDIR}/opkg.conf
}
diff --git a/meta/recipes-devtools/opkg/opkg-collateral/dest b/meta/recipes-devtools/opkg/opkg-collateral/dest
deleted file mode 100644
index 088ca40..0000000
--- a/meta/recipes-devtools/opkg/opkg-collateral/dest
+++ /dev/null
@@ -1 +0,0 @@
-dest root /
diff --git a/meta/recipes-devtools/opkg/opkg-collateral/opkg.conf.comments b/meta/recipes-devtools/opkg/opkg-collateral/opkg.conf
similarity index 92%
rename from meta/recipes-devtools/opkg/opkg-collateral/opkg.conf.comments
rename to meta/recipes-devtools/opkg/opkg-collateral/opkg.conf
index e1fdada..c2e9e92 100644
--- a/meta/recipes-devtools/opkg/opkg-collateral/opkg.conf.comments
+++ b/meta/recipes-devtools/opkg/opkg-collateral/opkg.conf
@@ -24,3 +24,5 @@
# Offline mode (for use in constructing flash images offline)
#option offline_root target
+# Default destination for installed packages
+dest root /
diff --git a/meta/recipes-devtools/opkg/opkg-collateral/src b/meta/recipes-devtools/opkg/opkg-collateral/src
deleted file mode 100644
index e69de29..0000000
--
1.9.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [PATCH 4/8] opkg: Merge opkg.inc into recipe and tidy up
2014-12-21 22:11 [PATCH 0/8] opkg recipe improvements Paul Barker
` (2 preceding siblings ...)
2014-12-21 22:11 ` [PATCH 3/8] opkg-collateral: Simplify source files Paul Barker
@ 2014-12-21 22:11 ` Paul Barker
2014-12-21 22:11 ` [PATCH 5/8] opkg: Merge in opkg-collateral Paul Barker
` (3 subsequent siblings)
7 siblings, 0 replies; 11+ messages in thread
From: Paul Barker @ 2014-12-21 22:11 UTC (permalink / raw)
To: OE Core
There is no benefit to having a separate .inc file when we only support one
version of opkg.
The .inc file had multiple do_install_append functions and several variables
were defined out of the usual order. This arrangement should be better.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/recipes-devtools/opkg/opkg.inc | 76 -------------------------------
meta/recipes-devtools/opkg/opkg_0.2.4.bb | 77 +++++++++++++++++++++++++++++++-
2 files changed, 75 insertions(+), 78 deletions(-)
delete mode 100644 meta/recipes-devtools/opkg/opkg.inc
diff --git a/meta/recipes-devtools/opkg/opkg.inc b/meta/recipes-devtools/opkg/opkg.inc
deleted file mode 100644
index 991c114..0000000
--- a/meta/recipes-devtools/opkg/opkg.inc
+++ /dev/null
@@ -1,76 +0,0 @@
-SUMMARY = "Open Package Manager"
-SUMMARY_libopkg = "Open Package Manager library"
-SECTION = "base"
-HOMEPAGE = "http://code.google.com/p/opkg/"
-BUGTRACKER = "http://code.google.com/p/opkg/issues/list"
-LICENSE = "GPLv2+"
-LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
- file://src/opkg-cl.c;beginline=1;endline=20;md5=321f658c3f6b6c832e25c8850b5dffba"
-
-PE = "1"
-
-# Werror gives all kinds bounds issuses with gcc 4.3.3
-do_configure_prepend() {
- sed -i -e s:-Werror::g ${S}/libopkg/Makefile.am
-}
-
-inherit autotools pkgconfig systemd
-
-python () {
- if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
- pn = d.getVar('PN', True)
- d.setVar('SYSTEMD_SERVICE_%s' % (pn), 'opkg-configure.service')
-}
-
-target_localstatedir := "${localstatedir}"
-OPKGLIBDIR = "${target_localstatedir}/lib"
-
-PACKAGECONFIG ??= ""
-
-PACKAGECONFIG[gpg] = "--enable-gpg,--disable-gpg,gpgme libgpg-error,gnupg"
-PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl"
-PACKAGECONFIG[ssl-curl] = "--enable-ssl-curl,--disable-ssl-curl,curl openssl"
-PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
-PACKAGECONFIG[sha256] = "--enable-sha256,--disable-sha256"
-PACKAGECONFIG[pathfinder] = "--enable-pathfinder,--disable-pathfinder,pathfinder"
-
-EXTRA_OECONF = "\
- --with-opkglibdir=${OPKGLIBDIR} \
-"
-
-RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config run-postinsts"
-RDEPENDS_${PN}_class-native = ""
-RDEPENDS_${PN}_class-nativesdk = ""
-RREPLACES_${PN} = "opkg-nogpg"
-
-PACKAGES =+ "libopkg-dev libopkg-staticdev libopkg"
-
-FILES_libopkg-dev = "${libdir}/*.la ${libdir}/*.so ${includedir}/libopkg"
-FILES_libopkg-staticdev = "${libdir}/*.a"
-FILES_libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/"
-FILES_${PN} += "${systemd_unitdir}/system/"
-
-do_install_append() {
- # We need to create the lock directory
- install -d ${D}${OPKGLIBDIR}/opkg
-
- if ${@bb.utils.contains('DISTRO_FEATURES','sysvinit','false','true',d)};then
- install -d ${D}${systemd_unitdir}/system
- install -m 0644 ${WORKDIR}/opkg-configure.service ${D}${systemd_unitdir}/system/
- sed -i -e 's,@BASE_BINDIR@,${base_bindir},g' \
- -e 's,@SYSCONFDIR@,${sysconfdir},g' \
- -e 's,@BINDIR@,${bindir},g' \
- -e 's,@SYSTEMD_UNITDIR@,${systemd_unitdir},g' \
- ${D}${systemd_unitdir}/system/opkg-configure.service
- fi
-
- # The installed binary is 'opkg-cl' but people and scripts often expect
- # it to just be 'opkg'
- ln -sf opkg-cl ${D}${bindir}/opkg
-}
-
-do_install_append() {
- rm ${D}${bindir}/update-alternatives
-}
-
-BBCLASSEXTEND = "native nativesdk"
diff --git a/meta/recipes-devtools/opkg/opkg_0.2.4.bb b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
index 2cca63c..573195a 100644
--- a/meta/recipes-devtools/opkg/opkg_0.2.4.bb
+++ b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
@@ -1,13 +1,86 @@
-require opkg.inc
+SUMMARY = "Open Package Manager"
+SUMMARY_libopkg = "Open Package Manager library"
+SECTION = "base"
+HOMEPAGE = "http://code.google.com/p/opkg/"
+BUGTRACKER = "http://code.google.com/p/opkg/issues/list"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+ file://src/opkg-cl.c;beginline=1;endline=20;md5=321f658c3f6b6c832e25c8850b5dffba"
+
+PE = "1"
SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz \
file://no-install-recommends.patch \
file://add-exclude.patch \
- file://opkg-configure.service \
file://libopkg-opkg_remove.c-avoid-remove-pkg-repeatly-with.patch \
+ file://opkg-configure.service \
"
S = "${WORKDIR}/${BPN}-${PV}"
SRC_URI[md5sum] = "40ed2aee15abc8d550539449630091bd"
SRC_URI[sha256sum] = "0f40c7e457d81edf9aedc07c778f4697111ab163a38ef95999faece015453086"
+
+inherit autotools pkgconfig systemd
+
+python () {
+ if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
+ pn = d.getVar('PN', True)
+ d.setVar('SYSTEMD_SERVICE_%s' % (pn), 'opkg-configure.service')
+}
+
+target_localstatedir := "${localstatedir}"
+OPKGLIBDIR = "${target_localstatedir}/lib"
+
+PACKAGECONFIG ??= ""
+
+PACKAGECONFIG[gpg] = "--enable-gpg,--disable-gpg,gpgme libgpg-error,gnupg"
+PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl"
+PACKAGECONFIG[ssl-curl] = "--enable-ssl-curl,--disable-ssl-curl,curl openssl"
+PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
+PACKAGECONFIG[sha256] = "--enable-sha256,--disable-sha256"
+PACKAGECONFIG[pathfinder] = "--enable-pathfinder,--disable-pathfinder,pathfinder"
+
+EXTRA_OECONF = "\
+ --with-opkglibdir=${OPKGLIBDIR} \
+"
+
+# Werror gives all kinds bounds issuses with gcc 4.3.3
+do_configure_prepend() {
+ sed -i -e s:-Werror::g ${S}/libopkg/Makefile.am
+}
+
+do_install_append () {
+ # We need to create the lock directory
+ install -d ${D}${OPKGLIBDIR}/opkg
+
+ if ${@bb.utils.contains('DISTRO_FEATURES','sysvinit','false','true',d)};then
+ install -d ${D}${systemd_unitdir}/system
+ install -m 0644 ${WORKDIR}/opkg-configure.service ${D}${systemd_unitdir}/system/
+ sed -i -e 's,@BASE_BINDIR@,${base_bindir},g' \
+ -e 's,@SYSCONFDIR@,${sysconfdir},g' \
+ -e 's,@BINDIR@,${bindir},g' \
+ -e 's,@SYSTEMD_UNITDIR@,${systemd_unitdir},g' \
+ ${D}${systemd_unitdir}/system/opkg-configure.service
+ fi
+
+ # The installed binary is 'opkg-cl' but people and scripts often expect
+ # it to just be 'opkg'
+ ln -sf opkg-cl ${D}${bindir}/opkg
+
+ rm ${D}${bindir}/update-alternatives
+}
+
+RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config run-postinsts"
+RDEPENDS_${PN}_class-native = ""
+RDEPENDS_${PN}_class-nativesdk = ""
+RREPLACES_${PN} = "opkg-nogpg"
+
+PACKAGES =+ "libopkg-dev libopkg-staticdev libopkg"
+
+FILES_libopkg-dev = "${libdir}/*.la ${libdir}/*.so ${includedir}/libopkg"
+FILES_libopkg-staticdev = "${libdir}/*.a"
+FILES_libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/"
+FILES_${PN} += "${systemd_unitdir}/system/"
+
+BBCLASSEXTEND = "native nativesdk"
--
1.9.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [PATCH 5/8] opkg: Merge in opkg-collateral
2014-12-21 22:11 [PATCH 0/8] opkg recipe improvements Paul Barker
` (3 preceding siblings ...)
2014-12-21 22:11 ` [PATCH 4/8] opkg: Merge opkg.inc into recipe and tidy up Paul Barker
@ 2014-12-21 22:11 ` Paul Barker
2014-12-21 22:11 ` [PATCH 6/8] poky-feed-config-opkg: Remove Paul Barker
` (2 subsequent siblings)
7 siblings, 0 replies; 11+ messages in thread
From: Paul Barker @ 2014-12-21 22:11 UTC (permalink / raw)
To: OE Core
All non-arch-specific and non-distro-specific configuration is now kept in the
main 'opkg' recipe and package.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/classes/rootfs_ipk.bbclass | 2 +-
meta/recipes-devtools/opkg/opkg-collateral.bb | 19 -------------------
.../opkg/{opkg-collateral => opkg}/opkg.conf | 0
meta/recipes-devtools/opkg/opkg_0.2.4.bb | 12 +++++++++++-
4 files changed, 12 insertions(+), 21 deletions(-)
delete mode 100644 meta/recipes-devtools/opkg/opkg-collateral.bb
rename meta/recipes-devtools/opkg/{opkg-collateral => opkg}/opkg.conf (100%)
diff --git a/meta/classes/rootfs_ipk.bbclass b/meta/classes/rootfs_ipk.bbclass
index 6139cc7..dd144e4 100644
--- a/meta/classes/rootfs_ipk.bbclass
+++ b/meta/classes/rootfs_ipk.bbclass
@@ -6,7 +6,7 @@
#
EXTRAOPKGCONFIG ?= ""
-ROOTFS_PKGMANAGE = "opkg opkg-collateral ${EXTRAOPKGCONFIG}"
+ROOTFS_PKGMANAGE = "opkg ${EXTRAOPKGCONFIG}"
ROOTFS_PKGMANAGE_BOOTSTRAP = "run-postinsts"
do_rootfs[depends] += "opkg-native:do_populate_sysroot opkg-utils-native:do_populate_sysroot"
diff --git a/meta/recipes-devtools/opkg/opkg-collateral.bb b/meta/recipes-devtools/opkg/opkg-collateral.bb
deleted file mode 100644
index b16579c..0000000
--- a/meta/recipes-devtools/opkg/opkg-collateral.bb
+++ /dev/null
@@ -1,19 +0,0 @@
-SUMMARY = "Constructs the main configuration file for opkg"
-SECTION = "base"
-LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
-PR = "r2"
-
-SRC_URI = "file://opkg.conf"
-
-OPKGLIBDIR = "${localstatedir}/lib"
-do_compile () {
- echo "option lists_dir ${OPKGLIBDIR}/opkg" >>${WORKDIR}/opkg.conf
-}
-
-do_install () {
- install -d ${D}${sysconfdir}/opkg
- install -m 0644 ${WORKDIR}/opkg.conf ${D}${sysconfdir}/opkg/opkg.conf
-}
-
-CONFFILES_${PN} = "${sysconfdir}/opkg/opkg.conf"
diff --git a/meta/recipes-devtools/opkg/opkg-collateral/opkg.conf b/meta/recipes-devtools/opkg/opkg/opkg.conf
similarity index 100%
rename from meta/recipes-devtools/opkg/opkg-collateral/opkg.conf
rename to meta/recipes-devtools/opkg/opkg/opkg.conf
diff --git a/meta/recipes-devtools/opkg/opkg_0.2.4.bb b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
index 573195a..6cb89e9 100644
--- a/meta/recipes-devtools/opkg/opkg_0.2.4.bb
+++ b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
@@ -14,6 +14,7 @@ SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz
file://add-exclude.patch \
file://libopkg-opkg_remove.c-avoid-remove-pkg-repeatly-with.patch \
file://opkg-configure.service \
+ file://opkg.conf \
"
S = "${WORKDIR}/${BPN}-${PV}"
@@ -50,7 +51,14 @@ do_configure_prepend() {
sed -i -e s:-Werror::g ${S}/libopkg/Makefile.am
}
+do_compile_append () {
+ echo "option lists_dir ${OPKGLIBDIR}/opkg" >>${WORKDIR}/opkg.conf
+}
+
do_install_append () {
+ install -d ${D}${sysconfdir}/opkg
+ install -m 0644 ${WORKDIR}/opkg.conf ${D}${sysconfdir}/opkg/opkg.conf
+
# We need to create the lock directory
install -d ${D}${OPKGLIBDIR}/opkg
@@ -74,7 +82,7 @@ do_install_append () {
RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config run-postinsts"
RDEPENDS_${PN}_class-native = ""
RDEPENDS_${PN}_class-nativesdk = ""
-RREPLACES_${PN} = "opkg-nogpg"
+RREPLACES_${PN} = "opkg-nogpg opkg-collateral"
PACKAGES =+ "libopkg-dev libopkg-staticdev libopkg"
@@ -84,3 +92,5 @@ FILES_libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/"
FILES_${PN} += "${systemd_unitdir}/system/"
BBCLASSEXTEND = "native nativesdk"
+
+CONFFILES_${PN} = "${sysconfdir}/opkg/opkg.conf"
--
1.9.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [PATCH 6/8] poky-feed-config-opkg: Remove
2014-12-21 22:11 [PATCH 0/8] opkg recipe improvements Paul Barker
` (4 preceding siblings ...)
2014-12-21 22:11 ` [PATCH 5/8] opkg: Merge in opkg-collateral Paul Barker
@ 2014-12-21 22:11 ` Paul Barker
2014-12-21 22:11 ` [PATCH 7/8] opkg: Backport improvements to opkg-key Paul Barker
2014-12-21 22:11 ` [PATCH 8/8] opkg-keyrings: New recipe Paul Barker
7 siblings, 0 replies; 11+ messages in thread
From: Paul Barker @ 2014-12-21 22:11 UTC (permalink / raw)
To: OE Core
This recipe was not usable as-is. A much better way of configuring package feeds
for opkg is provided by the distro-feed-config recipe in meta-oe.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
.../feed-config/poky-feed-config-opkg_1.0.bb | 44 ----------------------
1 file changed, 44 deletions(-)
delete mode 100644 meta/recipes-core/feed-config/poky-feed-config-opkg_1.0.bb
diff --git a/meta/recipes-core/feed-config/poky-feed-config-opkg_1.0.bb b/meta/recipes-core/feed-config/poky-feed-config-opkg_1.0.bb
deleted file mode 100644
index fb312f8..0000000
--- a/meta/recipes-core/feed-config/poky-feed-config-opkg_1.0.bb
+++ /dev/null
@@ -1,44 +0,0 @@
-SUMMARY = "Poky example feed configuration"
-LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
-PR = "r2"
-PACKAGE_ARCH = "${MACHINE_ARCH}"
-INHIBIT_DEFAULT_DEPS = "1"
-
-#FEEDNAMEPREFIX ?= "INVALID"
-#FEEDURIPREFIX ?= "INVALID"
-
-do_compile() {
- mkdir -p ${S}/${sysconfdir}/opkg/
-
- archconf=${S}/${sysconfdir}/opkg/arch.conf
-
- rm -f $archconf
- ipkgarchs="${ALL_MULTILIB_PACKAGE_ARCHS}"
- priority=1
- for arch in $ipkgarchs; do
- echo "arch $arch $priority" >> $archconf
- priority=$(expr $priority + 5)
- done
-
- basefeedconf=${S}/${sysconfdir}/opkg/base-feeds.conf
-
- rm -f $basefeedconf
- touch $basefeedconf
-
- #for arch in $ipkgarchs; do
- # echo "src/gz ${FEEDNAMEPREFIX}-$arch http://pokylinux.org/${FEEDURIPREFIX}$arch" >> $basefeedconf
- #done
-}
-
-
-do_install () {
- install -d ${D}${sysconfdir}/opkg
- install -m 0644 ${S}/${sysconfdir}/opkg/* ${D}${sysconfdir}/opkg/
-}
-
-FILES_${PN} = "${sysconfdir}/opkg/ "
-
-CONFFILES_${PN} += "${sysconfdir}/opkg/base-feeds.conf \
- ${sysconfdir}/opkg/arch.conf"
-
--
1.9.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [PATCH 7/8] opkg: Backport improvements to opkg-key
2014-12-21 22:11 [PATCH 0/8] opkg recipe improvements Paul Barker
` (5 preceding siblings ...)
2014-12-21 22:11 ` [PATCH 6/8] poky-feed-config-opkg: Remove Paul Barker
@ 2014-12-21 22:11 ` Paul Barker
2014-12-21 22:11 ` [PATCH 8/8] opkg-keyrings: New recipe Paul Barker
7 siblings, 0 replies; 11+ messages in thread
From: Paul Barker @ 2014-12-21 22:11 UTC (permalink / raw)
To: OE Core
The improvements to opkg-key made for v0.3.0 are backported. The rest of v0.3.0
needs further testing and bugfixing prior to release, but the improvements to
opkg-key have been tested and work well.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
.../opkg/0001-opkg-key-Backport-improvements.patch | 78 ++++++++++++++++++++++
meta/recipes-devtools/opkg/opkg_0.2.4.bb | 1 +
2 files changed, 79 insertions(+)
create mode 100644 meta/recipes-devtools/opkg/opkg/0001-opkg-key-Backport-improvements.patch
diff --git a/meta/recipes-devtools/opkg/opkg/0001-opkg-key-Backport-improvements.patch b/meta/recipes-devtools/opkg/opkg/0001-opkg-key-Backport-improvements.patch
new file mode 100644
index 0000000..ae319ce
--- /dev/null
+++ b/meta/recipes-devtools/opkg/opkg/0001-opkg-key-Backport-improvements.patch
@@ -0,0 +1,78 @@
+From 87bec8300a1122829b2ed565db7da5bacfa88919 Mon Sep 17 00:00:00 2001
+From: Paul Barker <paul@paulbarker.me.uk>
+Date: Sun, 12 Oct 2014 09:59:53 +0000
+Subject: [PATCH] opkg-key: Backport improvements
+
+The improvements to opkg-key made for v0.3.0 are backported. The rest of v0.3.0
+needs further testing and bugfixing prior to release, but the improvements to
+opkg-key have been tested and work well.
+
+ 1) opkg-key: Add 'reset' option
+
+ This option removes the keyrings used to verify package signatures,
+ effectively resetting opkg to the initial state where it recognises no
+ keys.
+
+ 2) opkg-key: Add 'populate' option
+
+ This option causes all keyrings in /usr/share/opkg/keyrings to be
+ imported. Thus distributions may install their keys into this directory
+ and use 'opkg-key populate' to ensure the correct keys are loaded.
+
+ 3) opkg-key: Improve usage output
+
+Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
+Upstream-status: Backport
+---
+ utils/opkg-key | 26 ++++++++++++++++++++++----
+ 1 file changed, 22 insertions(+), 4 deletions(-)
+
+diff --git a/utils/opkg-key b/utils/opkg-key
+index 266bb66..085f1e8 100755
+--- a/utils/opkg-key
++++ b/utils/opkg-key
+@@ -10,12 +10,17 @@ usage() {
+ echo
+ echo "Manage opkg's list of trusted keys"
+ echo
+- echo " opkg-key add <file> - add the key contained in <file> ('-' for stdin)"
+- echo " opkg-key del <keyid> - remove the key <keyid>"
+- echo " opkg-key list - list keys"
++ echo "Commands and arguments:"
++ echo " add <file> - Add the key contained in <file> ('-' for stdin)"
++ echo " del <keyid> - Remove the key <keyid>"
++ echo " list - List keys"
++ echo " fingerprint - List keys with fingerprints"
++ echo " reset - Remove all keys, resetting the keyring"
++ echo " populate - Import keys from /usr/share/opkg/keyrings"
++ echo " help - Print this usage message and exit"
+ echo
+ echo "Options:"
+- echo " -o <root> Use <root> as the offline root directory"
++ echo " -o <root> - Use <root> as the offline root directory"
+ echo
+ }
+
+@@ -64,6 +69,19 @@ case "$command" in
+ echo "Executing: $GPG $*"
+ $GPG $*
+ ;;
++ reset)
++ rm -f $ROOT/etc/opkg/trusted.gpg $ROOT/etc/opkg/trusted.gpg~
++ rm -f $ROOT/etc/opkg/secring.gpg $ROOT/etc/opkg/secring.gpg~
++ rm -f $ROOT/etc/opkg/trustdb.gpg $ROOT/etc/opkg/trustdb.gpg~
++ echo "OK"
++ ;;
++ populate)
++ for f in $ROOT/usr/share/opkg/keyrings/*.gpg; do
++ echo "Importing keys from '`basename $f`'..."
++ $GPG --quiet --batch --import "$f"
++ done
++ echo "OK"
++ ;;
+ help)
+ usage
+ ;;
+--
+1.9.1
+
diff --git a/meta/recipes-devtools/opkg/opkg_0.2.4.bb b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
index 6cb89e9..9c14734 100644
--- a/meta/recipes-devtools/opkg/opkg_0.2.4.bb
+++ b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
@@ -15,6 +15,7 @@ SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz
file://libopkg-opkg_remove.c-avoid-remove-pkg-repeatly-with.patch \
file://opkg-configure.service \
file://opkg.conf \
+ file://0001-opkg-key-Backport-improvements.patch \
"
S = "${WORKDIR}/${BPN}-${PV}"
--
1.9.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* [PATCH 8/8] opkg-keyrings: New recipe
2014-12-21 22:11 [PATCH 0/8] opkg recipe improvements Paul Barker
` (6 preceding siblings ...)
2014-12-21 22:11 ` [PATCH 7/8] opkg: Backport improvements to opkg-key Paul Barker
@ 2014-12-21 22:11 ` Paul Barker
7 siblings, 0 replies; 11+ messages in thread
From: Paul Barker @ 2014-12-21 22:11 UTC (permalink / raw)
To: OE Core
This recipe wraps package and package feed verification keys into a package,
making the management and deployment of verification keys much easier. Comments
on how to select keys for inclusion in this package are provided in the recipe
file.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb | 48 +++++++++++++++++++++++++
1 file changed, 48 insertions(+)
create mode 100644 meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb
diff --git a/meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb b/meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb
new file mode 100644
index 0000000..18d6abd
--- /dev/null
+++ b/meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb
@@ -0,0 +1,48 @@
+SUMMARY = "Keyrings for verifying opkg packages and feeds"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+# Distro-specific keys can be added to this package in two ways:
+#
+# 1) In a .bbappend, add .gpg and/or .asc files to SRC_URI and install them to
+# ${D}${datadir}/opkg/keyrings/ in a do_install_append function. These
+# files should not be named 'key-$name.gpg' to ensure they don't conflict
+# with keys exported as per (2).
+#
+# 2) In a .bbappend, distro config or local.conf, override the variable
+# OPKG_KEYRING_KEYS to contain a space-separated list of key names. For
+# each name, 'gpg --export $name' will be ran to export the public key to a
+# file named 'key-$name.gpg'. The public key must therefore be in the gpg
+# keyrings on the build machine.
+
+OPKG_KEYRING_KEYS ?= ""
+
+do_compile() {
+ for name in ${OPKG_KEYRING_KEYS}; do
+ gpg --export ${name} > ${B}/key-${name}.gpg
+ done
+}
+
+do_install () {
+ install -d ${D}${datadir}/opkg/keyrings/
+ for name in ${OPKG_KEYRING_KEYS}; do
+ install -m 0644 ${B}/key-${name}.gpg ${D}${datadir}/opkg/keyrings/
+ done
+}
+
+FILES_${PN} = "${datadir}/opkg/keyrings"
+
+# We need 'opkg-key' to run the postinst script
+RDEPENDS_${PN} = "opkg"
+
+pkg_postinst_${PN} () {
+#! /bin/sh
+set -e
+
+if [ x"$D" = "x" ]; then
+ # On target
+ opkg-key populate
+else
+ exit 1
+fi
+}
--
1.9.1
^ permalink raw reply related [flat|nested] 11+ messages in thread
* Re: [PATCH 2/8] opkg-arch-config: Renamed from opkg-config-base
2014-12-21 22:11 ` [PATCH 2/8] opkg-arch-config: Renamed from opkg-config-base Paul Barker
@ 2014-12-22 11:05 ` Martin Jansa
2014-12-22 11:58 ` Paul Barker
0 siblings, 1 reply; 11+ messages in thread
From: Martin Jansa @ 2014-12-22 11:05 UTC (permalink / raw)
To: Paul Barker; +Cc: OE Core
[-- Attachment #1: Type: text/plain, Size: 2986 bytes --]
On Sun, Dec 21, 2014 at 10:11:51PM +0000, Paul Barker wrote:
> The name 'opkg-arch-config' is much more descriptive.
>
> Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
> ---
> meta/conf/layer.conf | 2 +-
> .../opkg/{opkg-config-base_1.0.bb => opkg-arch-config_1.0.bb} | 3 ++-
> meta/recipes-devtools/opkg/opkg.inc | 2 +-
> 3 files changed, 4 insertions(+), 3 deletions(-)
> rename meta/recipes-devtools/opkg/{opkg-config-base_1.0.bb => opkg-arch-config_1.0.bb} (87%)
>
> diff --git a/meta/conf/layer.conf b/meta/conf/layer.conf
> index de96548..4fd3a16 100644
> --- a/meta/conf/layer.conf
> +++ b/meta/conf/layer.conf
> @@ -18,7 +18,7 @@ COREBASE = '${@os.path.normpath("${LAYERDIR}/../")}'
> SIGGEN_EXCLUDERECIPES_ABISAFE += " \
> sysvinit-inittab \
> shadow-securetty \
> - opkg-config-base \
> + opkg-arch-config \
> netbase \
> init-ifupdown \
> connman-conf \
> diff --git a/meta/recipes-devtools/opkg/opkg-config-base_1.0.bb b/meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
> similarity index 87%
> rename from meta/recipes-devtools/opkg/opkg-config-base_1.0.bb
> rename to meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
> index acbe129..f700865 100644
> --- a/meta/recipes-devtools/opkg/opkg-config-base_1.0.bb
> +++ b/meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
> @@ -1,4 +1,4 @@
> -SUMMARY = "Base configuration files for opkg"
> +SUMMARY = "Architecture-dependent configuration for opkg"
> LICENSE = "MIT"
> LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
> PACKAGE_ARCH = "${MACHINE_ARCH}"
> @@ -28,3 +28,4 @@ FILES_${PN} = "${sysconfdir}/opkg/ "
>
> CONFFILES_${PN} += "${sysconfdir}/opkg/arch.conf"
>
> +RREPLACES_${PN} = "opkg-config-base"
Is this enough for opkg to automatically replace opkg-config-base with
opkg-arch-config during opkg upgrade?
With older opkg releases you always had to use whole combo
RPROVIDES+RREPLACES+RCONFLICTS.
> diff --git a/meta/recipes-devtools/opkg/opkg.inc b/meta/recipes-devtools/opkg/opkg.inc
> index 56c54b6..991c114 100644
> --- a/meta/recipes-devtools/opkg/opkg.inc
> +++ b/meta/recipes-devtools/opkg/opkg.inc
> @@ -38,7 +38,7 @@ EXTRA_OECONF = "\
> --with-opkglibdir=${OPKGLIBDIR} \
> "
>
> -RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-config-base run-postinsts"
> +RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config run-postinsts"
> RDEPENDS_${PN}_class-native = ""
> RDEPENDS_${PN}_class-nativesdk = ""
> RREPLACES_${PN} = "opkg-nogpg"
> --
> 1.9.1
>
> --
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core
--
Martin 'JaMa' Jansa jabber: Martin.Jansa@gmail.com
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 188 bytes --]
^ permalink raw reply [flat|nested] 11+ messages in thread
* Re: [PATCH 2/8] opkg-arch-config: Renamed from opkg-config-base
2014-12-22 11:05 ` Martin Jansa
@ 2014-12-22 11:58 ` Paul Barker
0 siblings, 0 replies; 11+ messages in thread
From: Paul Barker @ 2014-12-22 11:58 UTC (permalink / raw)
To: Martin Jansa; +Cc: OE Core
[-- Attachment #1: Type: text/plain, Size: 1546 bytes --]
On Mon, Dec 22, 2014 at 12:05:41PM +0100, Martin Jansa wrote:
> On Sun, Dec 21, 2014 at 10:11:51PM +0000, Paul Barker wrote:
> > +RREPLACES_${PN} = "opkg-config-base"
>
> Is this enough for opkg to automatically replace opkg-config-base with
> opkg-arch-config during opkg upgrade?
>
> With older opkg releases you always had to use whole combo
> RPROVIDES+RREPLACES+RCONFLICTS.
>
It works because the RDEPENDS of opkg was also changed and nothing else depends
on opkg-config-base. It may be a little more reliable to add RPROVIDES and
RCONFLICTS just incase anything else I've not spotted depends on opkg-config-base.
The same can be said for merging opkg-collateral into opkg, we may need to add
RPROVIDES and RCONFLICTS incase anything else still depends on opkg-collateral.
> > diff --git a/meta/recipes-devtools/opkg/opkg.inc b/meta/recipes-devtools/opkg/opkg.inc
> > index 56c54b6..991c114 100644
> > --- a/meta/recipes-devtools/opkg/opkg.inc
> > +++ b/meta/recipes-devtools/opkg/opkg.inc
> > @@ -38,7 +38,7 @@ EXTRA_OECONF = "\
> > --with-opkglibdir=${OPKGLIBDIR} \
> > "
> >
> > -RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-config-base run-postinsts"
> > +RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config run-postinsts"
> > RDEPENDS_${PN}_class-native = ""
> > RDEPENDS_${PN}_class-nativesdk = ""
> > RREPLACES_${PN} = "opkg-nogpg"
> > --
> > 1.9.1
> >
Thanks,
--
Paul Barker
Email: paul@paulbarker.me.uk
http://www.paulbarker.me.uk
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 501 bytes --]
^ permalink raw reply [flat|nested] 11+ messages in thread
end of thread, other threads:[~2014-12-22 11:58 UTC | newest]
Thread overview: 11+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-12-21 22:11 [PATCH 0/8] opkg recipe improvements Paul Barker
2014-12-21 22:11 ` [PATCH 1/8] opkg-collateral: Use new lists_dir syntax Paul Barker
2014-12-21 22:11 ` [PATCH 2/8] opkg-arch-config: Renamed from opkg-config-base Paul Barker
2014-12-22 11:05 ` Martin Jansa
2014-12-22 11:58 ` Paul Barker
2014-12-21 22:11 ` [PATCH 3/8] opkg-collateral: Simplify source files Paul Barker
2014-12-21 22:11 ` [PATCH 4/8] opkg: Merge opkg.inc into recipe and tidy up Paul Barker
2014-12-21 22:11 ` [PATCH 5/8] opkg: Merge in opkg-collateral Paul Barker
2014-12-21 22:11 ` [PATCH 6/8] poky-feed-config-opkg: Remove Paul Barker
2014-12-21 22:11 ` [PATCH 7/8] opkg: Backport improvements to opkg-key Paul Barker
2014-12-21 22:11 ` [PATCH 8/8] opkg-keyrings: New recipe Paul Barker
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox