[PATCH] gptfdisk: Use PACKAGECONFIG to control ncurses and popt dependencies

[PATCH] gptfdisk: Use PACKAGECONFIG to control ncurses and popt dependencies

[Jacob Kroon]

gptfdisk uses a simple Makefile with no automatic detection of
external library support. Use PACKAGECONFIG_CONFARGS and pass
the make targets in EXTRA_OEMAKE.

Signed-off-by: Jacob Kroon <jacob.kroon@gmail.com>
---
 meta/recipes-devtools/fdisk/gptfdisk_1.0.4.bb | 15 +++++++++++----
 1 file changed, 11 insertions(+), 4 deletions(-)

diff --git a/meta/recipes-devtools/fdisk/gptfdisk_1.0.4.bb b/meta/recipes-devtools/fdisk/gptfdisk_1.0.4.bb
index 4426a795e2..b043c96543 100644
--- a/meta/recipes-devtools/fdisk/gptfdisk_1.0.4.bb
+++ b/meta/recipes-devtools/fdisk/gptfdisk_1.0.4.bb
@@ -4,7 +4,7 @@ DESCRIPTION = "GPT fdisk is a disk partitioning tool loosely modeled on Linux fd
 LICENSE = "GPLv2"
 LIC_FILES_CHKSUM = "file://COPYING;md5=59530bdf33659b29e73d4adb9f9f6552"
 
-DEPENDS = "util-linux popt ncurses"
+DEPENDS = "util-linux"
 
 SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${PV}/${BP}.tar.gz"
 SRC_URI[md5sum] = "5ecc3c44913bb6b53d3708d1ac7ac295"
@@ -13,13 +13,20 @@ SRC_URI[sha256sum] = "b663391a6876f19a3cd901d862423a16e2b5ceaa2f4a3b9bb681e64b9c
 UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/gptfdisk/files/gptfdisk/"
 UPSTREAM_CHECK_REGEX = "/gptfdisk/(?P<pver>(\d+[\.\-_]*)+)/"
 
-EXTRA_OEMAKE = "'CC=${CC}' 'CXX=${CXX}'"
+EXTRA_OEMAKE = "'CC=${CC}' 'CXX=${CXX}' gdisk fixparts ${PACKAGECONFIG_CONFARGS}"
+
+PACKAGECONFIG ??= "ncurses popt"
+PACKAGECONFIG[ncurses] = "cgdisk,,ncurses"
+PACKAGECONFIG[popt] = "sgdisk,,popt"
 
 do_install() {
     install -d ${D}${sbindir}
-    install -m 0755 cgdisk ${D}${sbindir}
+    for f in cgdisk sgdisk; do
+        if [ -x $f ]; then
+            install -m 0755 $f ${D}${sbindir}
+        fi
+    done
     install -m 0755 gdisk ${D}${sbindir}
-    install -m 0755 sgdisk ${D}${sbindir}
     install -m 0755 fixparts ${D}${sbindir}
 }
 
-- 
2.11.0