[PATCH] wireless-regdb: Add recipe

[PATCH] wireless-regdb: Add recipe

[Adrian Bunk]

Since wpa-supplicant is provided,
the database of permitted frequencies should also be provided.

wireless-regdb-static should be used with kernel >= 4.15.
wireless-regdb can be used with older kernels and is mostly
irrelevant here, but keeping it in meta-networking would
create needless recipe duplication.

This package was previously in meta-networking.

Signed-off-by: Adrian Bunk <bunk@stusta.de>
---
 meta/conf/distro/include/maintainers.inc      |  1 +
 .../packagegroups/packagegroup-base.bb        |  1 +
 .../wireless-regdb_2019.06.03.bb              | 44 +++++++++++++++++++
 3 files changed, 46 insertions(+)
 create mode 100644 meta/recipes-kernel/wireless-regdb/wireless-regdb_2019.06.03.bb

diff --git a/meta/conf/distro/include/maintainers.inc b/meta/conf/distro/include/maintainers.inc
index 38fc711f5c..26851d66e0 100644
--- a/meta/conf/distro/include/maintainers.inc
+++ b/meta/conf/distro/include/maintainers.inc
@@ -726,6 +726,7 @@ RECIPE_MAINTAINER_pn-weston-init = "Denys Dmytriyenko <denys@ti.com>"
 RECIPE_MAINTAINER_pn-wget = "Yi Zhao <yi.zhao@windriver.com>"
 RECIPE_MAINTAINER_pn-which = "Anuj Mittal <anuj.mittal@intel.com>"
 RECIPE_MAINTAINER_pn-wic-tools = "Anuj Mittal <anuj.mittal@intel.com>"
+RECIPE_MAINTAINER_pn-wireless-regdb = "Adrian Bunk <bunk@kernel.org>"
 RECIPE_MAINTAINER_pn-wpa-supplicant = "Changhyeok Bae <changhyeok.bae@gmail.com>"
 RECIPE_MAINTAINER_pn-x11perf = "Armin Kuster <akuster808@gmail.com>"
 RECIPE_MAINTAINER_pn-x264 = "Anuj Mittal <anuj.mittal@intel.com>"
diff --git a/meta/recipes-core/packagegroups/packagegroup-base.bb b/meta/recipes-core/packagegroups/packagegroup-base.bb
index cae704aa24..d05403635c 100644
--- a/meta/recipes-core/packagegroups/packagegroup-base.bb
+++ b/meta/recipes-core/packagegroups/packagegroup-base.bb
@@ -271,6 +271,7 @@ RRECOMMENDS_packagegroup-base-ipsec = "\
 SUMMARY_packagegroup-base-wifi = "WiFi support"
 RDEPENDS_packagegroup-base-wifi = "\
     iw \
+    wireless-regdb-static \
     wpa-supplicant"
 
 RRECOMMENDS_packagegroup-base-wifi = "\
diff --git a/meta/recipes-kernel/wireless-regdb/wireless-regdb_2019.06.03.bb b/meta/recipes-kernel/wireless-regdb/wireless-regdb_2019.06.03.bb
new file mode 100644
index 0000000000..df50938a1a
--- /dev/null
+++ b/meta/recipes-kernel/wireless-regdb/wireless-regdb_2019.06.03.bb
@@ -0,0 +1,44 @@
+SUMMARY = "Wireless Central Regulatory Domain Database"
+HOMEPAGE = "http://wireless.kernel.org/en/developers/Regulatory/CRDA"
+SECTION = "net"
+LICENSE = "ISC"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=07c4f6dea3845b02a18dc00c8c87699c"
+
+SRC_URI = "https://www.kernel.org/pub/software/network/${BPN}/${BP}.tar.xz"
+SRC_URI[md5sum] = "4b5ba3f089db7fdb7b9daae6a7c1f2cb"
+SRC_URI[sha256sum] = "cd917ed86b63ce8d93947979f1f18948f03a4ac0ad89ec25227b36ac00dc54bf"
+
+inherit bin_package allarch
+
+do_install() {
+    install -d -m0755 ${D}${nonarch_libdir}/crda
+    install -d -m0755 ${D}${sysconfdir}/wireless-regdb/pubkeys
+    install -m 0644 regulatory.bin ${D}${nonarch_libdir}/crda/regulatory.bin
+    install -m 0644 sforshee.key.pub.pem ${D}${sysconfdir}/wireless-regdb/pubkeys/sforshee.key.pub.pem
+
+    install -m 0644 -D regulatory.db ${D}${nonarch_base_libdir}/firmware/regulatory.db
+    install -m 0644 regulatory.db.p7s ${D}${nonarch_base_libdir}/firmware/regulatory.db.p7s
+}
+
+# Install static regulatory DB in /lib/firmware for kernel to load.
+# This requires Linux kernel >= v4.15.
+# For kernel <= v4.14, inherit the kernel_wireless_regdb.bbclass
+# (in meta-networking) in kernel's recipe.
+PACKAGES =+ "${PN}-static"
+RCONFLICTS_${PN} = "${PN}-static"
+
+FILES_${PN}-static = " \
+    ${nonarch_base_libdir}/firmware/regulatory.db \
+    ${nonarch_base_libdir}/firmware/regulatory.db.p7s \
+"
+
+# Native users might want to use the source of regulatory DB.
+# This is for example used by Linux kernel <= v4.14 and
+# kernel_wireless_regdb.bbclass in meta-networking.
+do_install_append_class-native() {
+    install -m 0644 -D db.txt ${D}${libdir}/crda/db.txt
+}
+
+RSUGGESTS_${PN} = "crda"
+
+BBCLASSEXTEND = "native"
-- 
2.17.1

Re: [PATCH] wireless-regdb: Add recipe

[Richard Purdie]

On Tue, 2019-06-18 at 09:11 +0300, Adrian Bunk wrote:
> Since wpa-supplicant is provided,
> the database of permitted frequencies should also be provided.
> 
> wireless-regdb-static should be used with kernel >= 4.15.
> wireless-regdb can be used with older kernels and is mostly
> irrelevant here, but keeping it in meta-networking would
> create needless recipe duplication.
> 
> This package was previously in meta-networking.
> 
> Signed-off-by: Adrian Bunk <bunk@stusta.de>
> ---
>  meta/conf/distro/include/maintainers.inc      |  1 +
>  .../packagegroups/packagegroup-base.bb        |  1 +
>  .../wireless-regdb_2019.06.03.bb              | 44
> +++++++++++++++++++
>  3 files changed, 46 insertions(+)
>  create mode 100644 meta/recipes-kernel/wireless-regdb/wireless-
> regdb_2019.06.03.bb

This seems to break deb rootfs construction:

https://autobuilder.yoctoproject.org/typhoon/#/builders/50/builds/712

> diff --git a/meta/conf/distro/include/maintainers.inc
> b/meta/conf/distro/include/maintainers.inc
> index 38fc711f5c..26851d66e0 100644
> --- a/meta/conf/distro/include/maintainers.inc
> +++ b/meta/conf/distro/include/maintainers.inc
> @@ -726,6 +726,7 @@ RECIPE_MAINTAINER_pn-weston-init = "Denys
> Dmytriyenko <denys@ti.com>"
>  RECIPE_MAINTAINER_pn-wget = "Yi Zhao <yi.zhao@windriver.com>"
>  RECIPE_MAINTAINER_pn-which = "Anuj Mittal <anuj.mittal@intel.com>"
>  RECIPE_MAINTAINER_pn-wic-tools = "Anuj Mittal <anuj.mittal@intel.com
> >"
> +RECIPE_MAINTAINER_pn-wireless-regdb = "Adrian Bunk <bunk@kernel.org>
> "
>  RECIPE_MAINTAINER_pn-wpa-supplicant = "Changhyeok Bae <
> changhyeok.bae@gmail.com>"
>  RECIPE_MAINTAINER_pn-x11perf = "Armin Kuster <akuster808@gmail.com>"
>  RECIPE_MAINTAINER_pn-x264 = "Anuj Mittal <anuj.mittal@intel.com>"
> diff --git a/meta/recipes-core/packagegroups/packagegroup-base.bb
> b/meta/recipes-core/packagegroups/packagegroup-base.bb
> index cae704aa24..d05403635c 100644
> --- a/meta/recipes-core/packagegroups/packagegroup-base.bb
> +++ b/meta/recipes-core/packagegroups/packagegroup-base.bb
> @@ -271,6 +271,7 @@ RRECOMMENDS_packagegroup-base-ipsec = "\
>  SUMMARY_packagegroup-base-wifi = "WiFi support"
>  RDEPENDS_packagegroup-base-wifi = "\
>      iw \
> +    wireless-regdb-static \
>      wpa-supplicant"
>  
>  RRECOMMENDS_packagegroup-base-wifi = "\
> diff --git a/meta/recipes-kernel/wireless-regdb/wireless-
> regdb_2019.06.03.bb b/meta/recipes-kernel/wireless-regdb/wireless-
> regdb_2019.06.03.bb
> new file mode 100644
> index 0000000000..df50938a1a
> --- /dev/null
> +++ b/meta/recipes-kernel/wireless-regdb/wireless-regdb_2019.06.03.bb
> @@ -0,0 +1,44 @@
> +SUMMARY = "Wireless Central Regulatory Domain Database"
> +HOMEPAGE = "http://wireless.kernel.org/en/developers/Regulatory/CRDA
> "
> +SECTION = "net"
> +LICENSE = "ISC"
> +LIC_FILES_CHKSUM =
> "file://LICENSE;md5=07c4f6dea3845b02a18dc00c8c87699c"
> +
> +SRC_URI = "
> https://www.kernel.org/pub/software/network/${BPN}/${BP}.tar.xz"
> +SRC_URI[md5sum] = "4b5ba3f089db7fdb7b9daae6a7c1f2cb"
> +SRC_URI[sha256sum] =
> "cd917ed86b63ce8d93947979f1f18948f03a4ac0ad89ec25227b36ac00dc54bf"
> +
> +inherit bin_package allarch
> +
> +do_install() {
> +    install -d -m0755 ${D}${nonarch_libdir}/crda
> +    install -d -m0755 ${D}${sysconfdir}/wireless-regdb/pubkeys
> +    install -m 0644 regulatory.bin
> ${D}${nonarch_libdir}/crda/regulatory.bin
> +    install -m 0644 sforshee.key.pub.pem ${D}${sysconfdir}/wireless-
> regdb/pubkeys/sforshee.key.pub.pem
> +
> +    install -m 0644 -D regulatory.db
> ${D}${nonarch_base_libdir}/firmware/regulatory.db
> +    install -m 0644 regulatory.db.p7s
> ${D}${nonarch_base_libdir}/firmware/regulatory.db.p7s
> +}
> +
> +# Install static regulatory DB in /lib/firmware for kernel to load.
> +# This requires Linux kernel >= v4.15.
> +# For kernel <= v4.14, inherit the kernel_wireless_regdb.bbclass
> +# (in meta-networking) in kernel's recipe.
> +PACKAGES =+ "${PN}-static"
> +RCONFLICTS_${PN} = "${PN}-static"

To work with apt/dpkg this may need an RPROVIDES and/or RREPLACES.

Cheers,

Richard

Re: [PATCH] wireless-regdb: Add recipe

[Richard Purdie]

On Tue, 2019-06-18 at 13:34 +0100, Richard Purdie wrote:
> On Tue, 2019-06-18 at 09:11 +0300, Adrian Bunk wrote:
> > Since wpa-supplicant is provided,
> > the database of permitted frequencies should also be provided.
> > 
> > wireless-regdb-static should be used with kernel >= 4.15.
> > wireless-regdb can be used with older kernels and is mostly
> > irrelevant here, but keeping it in meta-networking would
> > create needless recipe duplication.
> > 
> > This package was previously in meta-networking.
> > 
> > Signed-off-by: Adrian Bunk <bunk@stusta.de>
> > ---
> >  meta/conf/distro/include/maintainers.inc      |  1 +
> >  .../packagegroups/packagegroup-base.bb        |  1 +
> >  .../wireless-regdb_2019.06.03.bb              | 44
> > +++++++++++++++++++
> >  3 files changed, 46 insertions(+)
> >  create mode 100644 meta/recipes-kernel/wireless-regdb/wireless-
> > regdb_2019.06.03.bb
> 
> This seems to break deb rootfs construction:
> 
> https://autobuilder.yoctoproject.org/typhoon/#/builders/50/builds/712

opkg as well:

https://autobuilder.yoctoproject.org/typhoon/#/builders/76/builds/716

basically nothing provides wireless-regdb but wireless-regdb depends on
it.

Cheers,

Richard

Re: [PATCH] wireless-regdb: Add recipe

[Adrian Bunk]

On Tue, Jun 18, 2019 at 02:22:31PM +0100, Richard Purdie wrote:
> On Tue, 2019-06-18 at 13:34 +0100, Richard Purdie wrote:
> > On Tue, 2019-06-18 at 09:11 +0300, Adrian Bunk wrote:
> > > Since wpa-supplicant is provided,
> > > the database of permitted frequencies should also be provided.
> > > 
> > > wireless-regdb-static should be used with kernel >= 4.15.
> > > wireless-regdb can be used with older kernels and is mostly
> > > irrelevant here, but keeping it in meta-networking would
> > > create needless recipe duplication.
> > > 
> > > This package was previously in meta-networking.
> > > 
> > > Signed-off-by: Adrian Bunk <bunk@stusta.de>
> > > ---
> > >  meta/conf/distro/include/maintainers.inc      |  1 +
> > >  .../packagegroups/packagegroup-base.bb        |  1 +
> > >  .../wireless-regdb_2019.06.03.bb              | 44
> > > +++++++++++++++++++
> > >  3 files changed, 46 insertions(+)
> > >  create mode 100644 meta/recipes-kernel/wireless-regdb/wireless-
> > > regdb_2019.06.03.bb
> > 
> > This seems to break deb rootfs construction:
> > 
> > https://autobuilder.yoctoproject.org/typhoon/#/builders/50/builds/712
> 
> opkg as well:
> 
> https://autobuilder.yoctoproject.org/typhoon/#/builders/76/builds/716
> 
> basically nothing provides wireless-regdb but wireless-regdb depends on
> it.

The root problem is that the empty wireless-regdb-dev exists at all,
I'll send a v2 removing it.

> Cheers,
> 
> Richard

cu
Adrian

-- 

       "Is there not promise of rain?" Ling Tan asked suddenly out
        of the darkness. There had been need of rain for many days.
       "Only a promise," Lao Er said.
                                       Pearl S. Buck - Dragon Seed