[PATCH 1/4] p11-kit: remove obsolete compile error workaround

[PATCH 1/4] p11-kit: remove obsolete compile error workaround

[Ross Burton]

I couldn't replicate this compile error from 2024 so it's presumably no
longer needed.

Signed-off-by: Ross Burton <ross.burton@arm.com>
---
 meta/recipes-support/p11-kit/p11-kit_0.26.2.bb | 10 ----------
 1 file changed, 10 deletions(-)

diff --git a/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb b/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
index 5f553f11bbb..aa8b28e0e71 100644
--- a/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
+++ b/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
@@ -33,14 +33,4 @@ INSANE_SKIP:${PN} = "dev-so"
 
 BBCLASSEXTEND = "native nativesdk"
 
-# # This one is reproducible only on 32bit MACHINEs
-# http://errors.yoctoproject.org/Errors/Details/766969/
-# git/p11-kit/import-object.c:223:62: error: passing argument 3 of 'p11_asn1_read' from incompatible pointer type [-Wincompatible-pointer-types]
-# git/p11-kit/import-object.c:229:70: error: passing argument 3 of 'p11_asn1_read' from incompatible pointer type [-Wincompatible-pointer-types]
-# git/p11-kit/import-object.c:264:78: error: passing argument 3 of 'p11_asn1_read' from incompatible pointer type [-Wincompatible-pointer-types]
-# git/p11-kit/import-object.c:223:62: error: passing argument 3 of 'p11_asn1_read' from incompatible pointer type [-Wincompatible-pointer-types]
-# git/p11-kit/import-object.c:229:70: error: passing argument 3 of 'p11_asn1_read' from incompatible pointer type [-Wincompatible-pointer-types]
-# git/p11-kit/import-object.c:264:78: error: passing argument 3 of 'p11_asn1_read' from incompatible pointer type [-Wincompatible-pointer-types]
-CFLAGS += "-Wno-error=incompatible-pointer-types"
-
 CVE_STATUS[CVE-2026-2100] = "fixed-version: fixed since 0.26.2"
-- 
2.43.0

[PATCH 2/4] p11-kit: add PACKAGECONFIG for trust and systemd

[Ross Burton]

libtasn dependencies are specific to the trust module, add a PACKAGECONFIG
for that and move the dependencies. This is currently enabled by default
to preserve behaviour.

p11-kit has optional systemd user units for the remote server, add a
PACKAGECONFIG for that that respects the systemd DISTRO_FEATURE.

Signed-off-by: Ross Burton <ross.burton@arm.com>
---
 meta/recipes-support/p11-kit/p11-kit_0.26.2.bb | 9 +++++----
 1 file changed, 5 insertions(+), 4 deletions(-)

diff --git a/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb b/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
index aa8b28e0e71..a0e2e17d026 100644
--- a/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
+++ b/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
@@ -6,16 +6,17 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=02933887f609807fbb57aa4237d14a50"
 
 inherit meson gettext pkgconfig gtk-doc bash-completion manpages
 
-DEPENDS = "libtasn1 libtasn1-native libffi"
+DEPENDS = "libffi"
 
 DEPENDS:append = "${@' glib-2.0' if d.getVar('GTKDOC_ENABLED') == 'True' else ''}"
 
-SRC_URI = "gitsm://github.com/p11-glue/p11-kit;branch=master;protocol=https;tag=${PV} \
-           "
+SRC_URI = "gitsm://github.com/p11-glue/p11-kit;branch=master;protocol=https;tag=${PV}"
 SRCREV = "8e6e4e6d64d9fe91c62b0052c105b2b72d4c24ef"
 
-PACKAGECONFIG ??= ""
+PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} trust"
+PACKAGECONFIG[systemd] = "-Dsystemd=enabled,-Dsystemd=disabled,systemd"
 PACKAGECONFIG[manpages] = "-Dman=true,-Dman=false,libxslt-native"
+PACKAGECONFIG[trust] = "-Dtrust_module=enabled,-Dtrust_module=disabled,libtasn1-native libtasn1"
 PACKAGECONFIG[trust-paths] = "-Dtrust_paths=/etc/ssl/certs/ca-certificates.crt,,,ca-certificates"
 
 EXTRA_OEMESON:append = " -Dnls=${@'false' if d.getVar('USE_NLS') == 'no' else 'true'}"
-- 
2.43.0

[PATCH 3/4] p11-kit: explicitly disable tests and zsh-completions

[Ross Burton]

There's no need to build the tests as we won't run them, and disable the
zsh completion to avoid having to package the files.

Signed-off-by: Ross Burton <ross.burton@arm.com>
---
 meta/recipes-support/p11-kit/p11-kit_0.26.2.bb | 6 +++++-
 1 file changed, 5 insertions(+), 1 deletion(-)

diff --git a/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb b/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
index a0e2e17d026..69fb76658ea 100644
--- a/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
+++ b/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
@@ -19,7 +19,11 @@ PACKAGECONFIG[manpages] = "-Dman=true,-Dman=false,libxslt-native"
 PACKAGECONFIG[trust] = "-Dtrust_module=enabled,-Dtrust_module=disabled,libtasn1-native libtasn1"
 PACKAGECONFIG[trust-paths] = "-Dtrust_paths=/etc/ssl/certs/ca-certificates.crt,,,ca-certificates"
 
-EXTRA_OEMESON:append = " -Dnls=${@'false' if d.getVar('USE_NLS') == 'no' else 'true'}"
+EXTRA_OEMESON = "\
+    -Dtest=false \
+    -Dzsh_completion=disabled \
+    -Dnls=${@'false' if d.getVar('USE_NLS') == 'no' else 'true'}"
+
 GTKDOC_MESON_OPTION = 'gtk_doc'
 
 FILES:${PN} += " \
-- 
2.43.0

[PATCH 4/4] p11-kit: packaging rewrite

[Ross Burton]

p11-kit is actually a library, pluggable modules, and some helper tools.

Add new packages -bin -modules and -remote to package up the pieces
separately, and leave just the library in the main package.

Signed-off-by: Ross Burton <ross.burton@arm.com>
---
 .../recipes-support/p11-kit/p11-kit_0.26.2.bb | 25 ++++++++++++-------
 1 file changed, 16 insertions(+), 9 deletions(-)

diff --git a/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb b/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
index 69fb76658ea..ea636bfb0a8 100644
--- a/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
+++ b/meta/recipes-support/p11-kit/p11-kit_0.26.2.bb
@@ -4,7 +4,7 @@ HOMEPAGE = "https://p11-glue.github.io/p11-glue/p11-kit.html"
 LICENSE = "BSD-3-Clause"
 LIC_FILES_CHKSUM = "file://COPYING;md5=02933887f609807fbb57aa4237d14a50"
 
-inherit meson gettext pkgconfig gtk-doc bash-completion manpages
+inherit meson gettext pkgconfig gtk-doc bash-completion manpages lib_package
 
 DEPENDS = "libffi"
 
@@ -26,15 +26,22 @@ EXTRA_OEMESON = "\
 
 GTKDOC_MESON_OPTION = 'gtk_doc'
 
-FILES:${PN} += " \
-    ${libdir}/p11-kit-proxy.so \
-    ${libdir}/pkcs11/*.so \
-    ${libdir}/pkcs11/*.la \
-    ${datadir} \
-    ${systemd_user_unitdir}/*"
+PACKAGES =+ "${PN}-modules ${PN}-remote"
 
-# PN contains p11-kit-proxy.so, a symlink to a loadable module
-INSANE_SKIP:${PN} = "dev-so"
+FILES:${PN}-bin += "${libexecdir}/p11-kit/trust-extract-compat"
+
+FILES:${PN}-modules = "\
+    ${datadir}/p11-kit/modules \
+    ${libdir}/p11-kit-proxy.so \
+    ${libdir}/pkcs11"
+
+# p11-kit-proxy.so, a symlink to a loadable module
+INSANE_SKIP:${PN}-modules = "dev-so"
+
+FILES:${PN}-remote = "\
+    ${libexecdir}/p11-kit/p11-kit-remote \
+    ${libexecdir}/p11-kit/p11-kit-server \
+    ${systemd_user_unitdir}"
 
 BBCLASSEXTEND = "native nativesdk"
 
-- 
2.43.0