Re: [PATCH 04/10] meta-rt: add linux-yocto-rt_3.0 recipe

[Darren Hart <dvhart@linux.intel.com>]

On 08/11/2011 05:40 PM, Bruce Ashfield wrote:
> On 11-08-11 7:08 PM, Darren Hart wrote:
>> Add the initial linux-yocto-rt_3.0 recipe.
>>
>> TODO: replace the AUTOREV with real commit ids.
> 
> I think you did this!
> 
>>
>> Signed-off-by: Darren Hart<dvhart@linux.intel.com>
>> Signed-off-by: Bruce Ashfield<bruce.ashfield@windriver.com>
>> ---
>>   meta-rt/recipes-kernel/linux/linux-yocto-rt_3.0.bb |   55 ++++++++++++++++++++
>>   1 files changed, 55 insertions(+), 0 deletions(-)
>>   create mode 100644 meta-rt/recipes-kernel/linux/linux-yocto-rt_3.0.bb
>>
>> diff --git a/meta-rt/recipes-kernel/linux/linux-yocto-rt_3.0.bb b/meta-rt/recipes-kernel/linux/linux-yocto-rt_3.0.bb
>> new file mode 100644
>> index 0000000..7eaeb0f
>> --- /dev/null
>> +++ b/meta-rt/recipes-kernel/linux/linux-yocto-rt_3.0.bb
>> @@ -0,0 +1,55 @@
>> +inherit kernel
>> +require recipes-kernel/linux/linux-yocto.inc
>> +
>> +KMACHINE = "yocto/standard/preempt-rt/base"
> 
> I just noticed this on the way through, this could likely just
> be set to "common-pc", all it really is supposed to be
> is a fallback if a machine specific override doesn't work.
> 
> (I see that you actually do this in patch 8/10 for 2.6.34 anyway).
> 
>> +KMACHINE_qemux86  = "common-pc"
>> +KMACHINE_qemux86-64  = "common-pc-64"
>> +KMACHINE_qemuarm  = "arm-versatile-926ejs"
>> +# qemuppc hangs at boot
>> +#KMACHINE_qemuppc  = "qemu-ppc32"
>> +# qemumips panics at boot
>> +#KMACHINE_qemumips = "mti-malta32-be"
>> +
>> +KBRANCH = ${KMACHINE}
> 
> And instead of the above, you could just say:
> 
> KBRANCH = "yocto/standard/preempt-rt/base"
> 
> to have a fallback in place that keeps the fetcher chugging along.
> That's all that the KMACHINE default was doing in the end anyway.
> 
> Sorry I didn't see this earlier, but seeing it in front of me
> here, it jumped out.
> 
> The rest looks good.
> 
> Bruce

Rather than resend the entire series, I have updated this patch at the
same pull URL. The new patch follows:

From 87720452dfcd4e244dd89e43aa39d9d8dc27655e Mon Sep 17 00:00:00 2001
Message-Id: <87720452dfcd4e244dd89e43aa39d9d8dc27655e.1313118839.git.dvhart@linux.intel.com>
In-Reply-To: <cover.1313118839.git.dvhart@linux.intel.com>
References: <cover.1313118839.git.dvhart@linux.intel.com>
From: Darren Hart <dvhart@linux.intel.com>
Date: Wed, 20 Jul 2011 09:18:09 -0700
Subject: [PATCH 04/10] meta-rt: add linux-yocto-rt_3.0 recipe

Add the initial linux-yocto-rt_3.0 recipe.

qemumips and qemuppc doesn't work quite yet, so they have been omitted from
COMPATIBLE_MACHINE.

Signed-off-by: Darren Hart <dvhart@linux.intel.com>
Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com>
---
 meta-rt/recipes-kernel/linux/linux-yocto-rt_3.0.bb |   46 ++++++++++++++++++++
 1 files changed, 46 insertions(+), 0 deletions(-)
 create mode 100644 meta-rt/recipes-kernel/linux/linux-yocto-rt_3.0.bb

diff --git a/meta-rt/recipes-kernel/linux/linux-yocto-rt_3.0.bb b/meta-rt/recipes-kernel/linux/linux-yocto-rt_3.0.bb
new file mode 100644
index 0000000..c8a175d
--- /dev/null
+++ b/meta-rt/recipes-kernel/linux/linux-yocto-rt_3.0.bb
@@ -0,0 +1,46 @@
+inherit kernel
+require recipes-kernel/linux/linux-yocto.inc
+
+KMACHINE = "common-pc"
+KMACHINE_qemux86  = "common-pc"
+KMACHINE_qemux86-64  = "common-pc-64"
+KMACHINE_qemuarm  = "arm-versatile-926ejs"
+KMACHINE_qemuppc  = "qemu-ppc32"
+KMACHINE_qemumips = "mti-malta32-be"
+
+KBRANCH = "yocto/standard/preempt-rt/base"
+KMETA = meta
+
+LINUX_VERSION ?= "3.0"
+LINUX_KERNEL_TYPE = "preempt-rt"
+LINUX_VERSION_EXTENSION ?= "-yocto-${LINUX_KERNEL_TYPE}"
+
+SRCREV_machine = "7e1e5b6c8a13c615feb0d7b6d37988a094aae98f"
+SRCREV_meta = "7782fc673afd6a1c742409896ae787560d96fce8"
+
+PR = "r0"
+PV = "${LINUX_VERSION}+git${SRCPV}"
+SRCREV_FORMAT = "meta_machine"
+
+SRC_URI = "git://git.yoctoproject.org/linux-yocto-3.0.git;protocol=git;nocheckout=1;branch=${KBRANCH},meta;name=machine,meta"
+
+# Omit broken machines from COMPATIBLE_MACHINE
+#   qemuppc hangs at boot
+#   qemumips panics at boot
+COMPATIBLE_MACHINE = "(qemux86|qemux86-64|qemuarm)"
+
+# Functionality flags
+KERNEL_REVISION_CHECKING ?= "t"
+KERNEL_FEATURES=features/netfilter
+KERNEL_FEATURES_append=" features/taskstats"
+KERNEL_FEATURES_append_qemux86=" cfg/sound"
+KERNEL_FEATURES_append_qemux86-64=" cfg/sound"
+
+YOCTO_KERNEL_META_DATA=t
+
+# extra tasks
+addtask kernel_link_vmlinux after do_compile before do_install
+addtask validate_branches before do_patch after do_kernel_checkout
+addtask kernel_configcheck after do_configure before do_compile
+
+require recipes-kernel/linux/linux-tools.inc
-- 
1.7.6


-- 
Darren Hart
Intel Open Source Technology Center
Yocto Project - Linux Kernel