[PATCH 0/9] The patches to run gtk over directfb

[PATCH 0/9] The patches to run gtk over directfb

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

Hi Richard & all,

I fixed some problems found at previous submitting and use PACKAGECONFIG to get mutual configuration between directfb and x11. I hope this submitting isn't a horrible mess :).

One previous problem about what happen when user want to have both directfb and x11 in DISTRO_FEATURES?

I think directfb and x11 can't be defined in DISTRO_FEATURES at the same time because directfb and x11 are the lowest level library for GUI with different mechanism.
x11 and directfb should be mutual in DISTRO_FEATURES. User may use file "meta-yocto/conf/local.conf.sample.extended" to select the mode they want to need.
but directfb can work in an image with x11. for example, "directfb" and "direcrfb-examples" can be added to task-core-x11-sato.bb. you can run df_andi, a demo based on directfb, on matchbox term running on core-image-sato with x11. So directfb and x11 can exist in the same image but not be defined in DISTRO_FEATURES at same time.

If you have any suggestion, I will fix them again.

Pull URL: git://git.pokylinux.org/poky-contrib.git
  Branch: xiaofeng/gtk+-directfb
  Browse: http://git.pokylinux.org/cgit.cgi/poky-contrib/log/?h=xiaofeng/gtk+-directfb

Thanks,
    Xiaofeng Yan <xiaofeng.yan@windriver.com>
---


Xiaofeng Yan (9):
  qemu-config: Disable dbus-x11 when no x11 in DISTRO_FEATURES
  gconf: Disable dbus-x11 when x11 isn't in DISTRO_FEATURES
  gtk.inc: add directfb DISTRO_FEATURE
  gtk+: add demos to the configuation of gtk+
  cairo: add directfb DISTRO_FEATURE
  pango: add directfb DISTRO_FEATURE
  directfb-examples: add package directfb-examples to OE-core
  task-gtk-directfb.bb: Add task list to run gtk over directfb
  core-image-gtk-directfb.bb: add an image for gtk over directfb

 meta/recipes-bsp/qemu-config/qemu-config.bb        |    4 +-
 meta/recipes-gnome/gnome/gconf_3.2.3.bb            |    4 ++-
 meta/recipes-gnome/gtk+/gtk+.inc                   |   20 ++++++++++++---
 meta/recipes-gnome/gtk+/gtk+_2.24.6.bb             |    7 ++++-
 meta/recipes-graphics/cairo/cairo.inc              |   12 +++++++--
 .../directfb/directfb-examples_1.2.0.bb            |   18 +++++++++++++
 .../images/core-image-gtk-directfb.bb              |   21 ++++++++++++++++
 meta/recipes-graphics/pango/pango.inc              |   19 +++++++++++---
 meta/recipes-graphics/tasks/task-gtk-directfb.bb   |   26 ++++++++++++++++++++
 9 files changed, 115 insertions(+), 16 deletions(-)
 create mode 100644 meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb
 create mode 100644 meta/recipes-graphics/images/core-image-gtk-directfb.bb
 create mode 100644 meta/recipes-graphics/tasks/task-gtk-directfb.bb

[PATCH 1/9] qemu-config: Disable dbus-x11 when no x11 in DISTRO_FEATURES

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

dbus-x11 could be not needed by an image without x11.
So I modified this bb file to enable dbus-x11 when x11 is in DISTRO_FEATURES and disable \
dbus-x11 without x11 feature.

[YOCTO #1674]

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>
---
 meta/recipes-bsp/qemu-config/qemu-config.bb |    4 ++--
 1 files changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta/recipes-bsp/qemu-config/qemu-config.bb b/meta/recipes-bsp/qemu-config/qemu-config.bb
index ebf957a..deaf3a5 100644
--- a/meta/recipes-bsp/qemu-config/qemu-config.bb
+++ b/meta/recipes-bsp/qemu-config/qemu-config.bb
@@ -5,7 +5,7 @@ LIC_FILES_CHKSUM = "file://${WORKDIR}/COPYING.GPL;md5=751419260aa954499f7abaabaa
 
 COMPATIBLE_MACHINE = "(qemuarm|qemux86|qemumips|qemuppc)"
 
-PR = "r22"
+PR = "r23"
 
 SRC_URI = "file://distcc.sh \
            file://anjuta-remote-run \
@@ -37,7 +37,7 @@ pkg_postinst_${PN} () {
         sed -i $D${datadir}/applications/shutdown.desktop -e 's/^Exec=halt/Exec=reboot/'
 }
 
-RDEPENDS_${PN} = "distcc dbus-x11 task-core-nfs-server oprofileui-server rsync bash"
+RDEPENDS_${PN} = "distcc ${@base_contains('DISTRO_FEATURES', 'x11', 'dbus-x11', '', d)}  task-core-nfs-server oprofileui-server rsync bash"
 
 inherit update-rc.d allarch
 
-- 
1.7.0.4

[PATCH 2/9] gconf: Disable dbus-x11 when x11 isn't in DISTRO_FEATURES

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

If x11 isn't defined in DISTRO_FEATURES, then an error information "no providers ..." will \
arise. I modified this bb file to disable "dbus-x11" when x11 isn't in DISTRO_FEATURES.

[YOCTO #1674]

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>
---
 meta/recipes-gnome/gnome/gconf_3.2.3.bb |    4 +++-
 1 files changed, 3 insertions(+), 1 deletions(-)

diff --git a/meta/recipes-gnome/gnome/gconf_3.2.3.bb b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
index 3d3e65f..7feafea 100644
--- a/meta/recipes-gnome/gnome/gconf_3.2.3.bb
+++ b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
@@ -30,7 +30,9 @@ do_install_append() {
 	rm ${D}${libdir}/gio/*/*.*a
 }
 
-RDEPENDS_${PN} += "dbus-x11"
+# disable dbus-x11 without x11 feature in DISTRO_FEATURES
+RDEPENDS_${PN} += "${@base_contains('DISTRO_FEATURES', 'x11', 'dbus-x11', '', d)}"
+
 FILES_${PN} += "${libdir}/GConf/* \
 	        ${libdir}/gio/*/*.so \
 		${datadir}/polkit* \
-- 
1.7.0.4

[PATCH 3/9] gtk.inc: add directfb DISTRO_FEATURE

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

gtk run over x11 at current OE-core. If gtk want to run over directfb, then \
the configuration related to x11 should be disabled and directfb should be enabled.

[YOCTO #1674]

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>
---
 meta/recipes-gnome/gtk+/gtk+.inc |   20 ++++++++++++++++----
 1 files changed, 16 insertions(+), 4 deletions(-)

diff --git a/meta/recipes-gnome/gtk+/gtk+.inc b/meta/recipes-gnome/gtk+/gtk+.inc
index 0e5c45c..926f7dd 100644
--- a/meta/recipes-gnome/gtk+/gtk+.inc
+++ b/meta/recipes-gnome/gtk+/gtk+.inc
@@ -9,13 +9,20 @@ LICENSE = "LGPLv2 & LGPLv2+ & LGPLv2.1+"
 LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7"
 
 SECTION = "libs"
-DEPENDS = "glib-2.0 pango atk jpeg libpng libxext libxcursor \
-           gtk-doc-native docbook-utils-native libxrandr libgcrypt \
-           libxdamage libxrender libxcomposite cairo gdk-pixbuf"
+X11DEPENDS = "virtual/libx11 libxext libxcursor libxrandr libxdamage libxrender libxcomposite"
+
+DEPENDS = "glib-2.0 pango atk jpeg libpng gtk-doc-native gdk-pixbuf-native docbook-utils-native \
+           libgcrypt cairo gdk-pixbuf"
+
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
+           ${@base_contains('DISTRO_FEATURES', 'directfb', 'directfb', '', d)}"
+
+PACKAGECONFIG[x11] = "--with-x=yes --with-gdktarget=x11,--with-x=no,${X11DEPENDS}"
+PACKAGECONFIG[directfb] = "--with-gdktarget=directfb,,directfb"
 
 inherit autotools pkgconfig
 
-PACKAGES += "libgail"
+PACKAGES += "libgail gtk-demo"
 
 FILES_${PN} = "${bindir}/gtk-update-icon-cache \
 	${bindir}/gtk-query-immodules-2.0 \
@@ -40,6 +47,11 @@ FILES_${PN}-dbg += " \
 	${libdir}/gtk-2.0/${LIBV}/engines/.debug/* \
 	${libdir}/gtk-2.0/${LIBV}/printbackends/.debug/*"
 
+FILES_gtk-demo = " \
+        ${datadir}/gtk-2.0/demo/* \
+        ${bindir}/gtk-demo \
+        "
+
 FILES_libgail = " \
 	${libdir}/gtk-2.0/modules/libgail.so \
 	${libdir}/gtk-2.0/modules/libferret.so \
-- 
1.7.0.4

[PATCH 4/9] gtk+: add demos to the configuation of gtk+

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

Add demos for checking whether gtk+ run over directfb successfully or not.

[YOCTO #1674]

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>
---
 meta/recipes-gnome/gtk+/gtk+_2.24.6.bb |    7 +++++--
 1 files changed, 5 insertions(+), 2 deletions(-)

diff --git a/meta/recipes-gnome/gtk+/gtk+_2.24.6.bb b/meta/recipes-gnome/gtk+/gtk+_2.24.6.bb
index cd5c8cb..4ef0bc8 100644
--- a/meta/recipes-gnome/gtk+/gtk+_2.24.6.bb
+++ b/meta/recipes-gnome/gtk+/gtk+_2.24.6.bb
@@ -8,12 +8,15 @@ SRC_URI = "http://download.gnome.org/sources/gtk+/2.24/gtk+-${PV}.tar.bz2 \
            file://xsettings.patch \
            file://run-iconcache.patch \
            file://hardcoded_libtool.patch \
-           file://no-demos.patch \
+		   ${@base_contains('DISTRO_FEATURES', 'directfb', '','${NODEMOS_SRC_URI}', d)} \
            file://cellrenderer-cairo.patch;striplevel=0 \
            file://toggle-font.diff;striplevel=0 \
            file://0001-bgo-584832-Duplicate-the-exec-string-returned-by-gtk.patch \
            file://doc-fixes.patch \
 	  "
+
+NODEMOS_SRC_URI = "file://no-demos.patch"
+
 # TO MERGE
 #           file://entry-cairo.patch;striplevel=0
 #           file://filesystem-volumes.patch
@@ -26,7 +29,7 @@ SRC_URI = "http://download.gnome.org/sources/gtk+/2.24/gtk+-${PV}.tar.bz2 \
 #        file://combo-arrow-size.patch;striplevel=0
 #            file://configurefix.patch
 
-PR = "r1"
+PR = "r2"
 
 SRC_URI[md5sum] = "421100f6597e613234f8dead6091a9fe"
 SRC_URI[sha256sum] = "6f45bdbf9ea27eb3b5f977d7ee2365dede0d0ce454985680c26e5210163bbf37"
-- 
1.7.0.4

[PATCH 5/9] cairo: add directfb DISTRO_FEATURE

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

cairo run over x11 at current OE-core. If cairo want to run over directfb, then \
the configuration related to x11 should be disabled and directfb should be enabled.

[YOCTO #1674]

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>
---
 meta/recipes-graphics/cairo/cairo.inc |   12 +++++++++---
 1 files changed, 9 insertions(+), 3 deletions(-)

diff --git a/meta/recipes-graphics/cairo/cairo.inc b/meta/recipes-graphics/cairo/cairo.inc
index 876acad..d7f7347 100644
--- a/meta/recipes-graphics/cairo/cairo.inc
+++ b/meta/recipes-graphics/cairo/cairo.inc
@@ -10,14 +10,20 @@ HOMEPAGE = "http://cairographics.org"
 BUGTRACKER = "http://bugs.freedesktop.org"
 SECTION = "libs"
 LICENSE = "MPL-1 & LGPLv2.1"
+
 X11DEPENDS = "virtual/libx11 libsm libxrender"
-DEPENDS = "libpng fontconfig pixman glib-2.0 ${@base_contains('DISTRO_FEATURES', 'x11', '${X11DEPENDS}', '', d)}"
+DEPENDS = "libpng fontconfig pixman glib-2.0"
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
+           ${@base_contains('DISTRO_FEATURES', 'directfb', 'directfb', '', d)}"
+PACKAGECONFIG[x11] = "--with-x=yes,--without-x,${X11DEPENDS}"
+PACKAGECONFIG[directfb] = "--enable-directfb=yes,,directfb"
+
 
 #check for TARGET_FPU=soft and inform configure of the result so it can disable some floating points 
 require cairo-fpu.inc
-EXTRA_OECONF += "${@get_cairo_fpu_setting(bb, d)} ${@base_contains('DISTRO_FEATURES', 'x11', '--with-x', '--without-x', d)}"
+EXTRA_OECONF += "${@get_cairo_fpu_setting(bb, d)}"
 
 inherit autotools pkgconfig
 
 # We don't depend on binutils so we need to disable this
-export ac_cv_lib_bfd_bfd_openr=no
\ No newline at end of file
+export ac_cv_lib_bfd_bfd_openr=no
-- 
1.7.0.4

[PATCH 6/9] pango: add directfb DISTRO_FEATURE

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

pango run over x11 at current OE-core. If pango want to run over directfb, then \
the configuration related to x11 should be disabled and directfb should be enabled.

[YOCTO #1674]

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>
---
 meta/recipes-graphics/pango/pango.inc |   19 +++++++++++++++----
 1 files changed, 15 insertions(+), 4 deletions(-)

diff --git a/meta/recipes-graphics/pango/pango.inc b/meta/recipes-graphics/pango/pango.inc
index 6d94e02..6822694 100644
--- a/meta/recipes-graphics/pango/pango.inc
+++ b/meta/recipes-graphics/pango/pango.inc
@@ -10,14 +10,24 @@ SECTION = "libs"
 LICENSE = "LGPL"
 
 X11DEPENDS = "virtual/libx11 libxft"
-DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libiconv gtk-doc-native cairo ${@base_contains('DISTRO_FEATURES', 'x11', '${X11DEPENDS}', '', d)}"
+DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libiconv gtk-doc-native cairo "
 
 PACKAGES_DYNAMIC = "pango-module-*"
 
 RRECOMMENDS_${PN} = "${@base_contains('DISTRO_FEATURES', 'x11', 'pango-module-basic-x', '', d)} pango-module-basic-fc" 
 
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
+           ${@base_contains('DISTRO_FEATURES', 'directfb', 'directfb', '', d)}"
+PACKAGECONFIG[x11] = "--with-x,--without-x,${X11DEPENDS}"
+PACKAGECONFIG[directfb] = ",,directfb"
+
 inherit gnome
 
+# Create a pango-modules package
+ALLOW_EMPTY_${BPN}-modules = "1"
+PACKAGES += "${BPN}-modules"
+RRECOMMENDS_${BPN}-modules =  "${@" ".join([p for p in d.getVar('PACKAGES', True).split() if p.find("pango-module") != -1])}"
+
 EXTRA_AUTORECONF = ""
 
 # seems to go wrong with default cflags
@@ -25,17 +35,18 @@ FULL_OPTIMIZATION_arm = "-O2"
 
 EXTRA_OECONF = "--disable-glibtest \
 		--enable-explicit-deps=no \
-	        --disable-debug \
-		${@base_contains('DISTRO_FEATURES', 'x11', '--with-x', '--without-x', d)}"
+	        --disable-debug"
 
 LEAD_SONAME = "libpango-1.0*"
 LIBV = "1.6.0"
 
+# No "etc" in "${D}" except for "usr", So add "/etc/pango" in the following function. \
+# Because "prologue + 'pango-querymodules > /etc/pango/pango.modules'" use this directory.
 postinst_prologue() {
 if [ "x$D" != "x" ]; then
   exit 1
 fi
-
+    [ ! -d "/etc/pango" ] && mkdir -p /etc/pango/
 }
 
 python populate_packages_prepend () {
-- 
1.7.0.4

[PATCH 7/9] directfb-examples: add package directfb-examples to OE-core

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

Add this package for checking whether directfb run rightly or not.
It also is an useful tool to test directfb.

[YOCTO #1674]

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>
---
 .../directfb/directfb-examples_1.2.0.bb            |   18 ++++++++++++++++++
 1 files changed, 18 insertions(+), 0 deletions(-)
 create mode 100644 meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb

diff --git a/meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb b/meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb
new file mode 100644
index 0000000..08cdc8f
--- /dev/null
+++ b/meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb
@@ -0,0 +1,18 @@
+DESCRIPTION = "DirectFB extra providers"
+DEPENDS = "directfb"
+SECTION = "libs"
+LICENSE = "GPL"
+PR = "r0"
+
+SRC_URI = " \
+           http://www.directfb.org/downloads/Extras/DirectFB-examples-${PV}.tar.gz \
+          "
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=ecf6fd2b19915afc4da56043926ca18f"
+
+S = "${WORKDIR}/DirectFB-examples-${PV}"
+
+inherit autotools
+
+SRC_URI[md5sum] = "ce018f681b469a1d72ffc32650304b98"
+SRC_URI[sha256sum] = "830a1bd6775d8680523596a88a72fd8e4c6a74bf886d3e169b06d234a5cf7e3e"
-- 
1.7.0.4

[PATCH 8/9] task-gtk-directfb.bb: Add task list to run gtk over directfb

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

Add task-gtk-directfb.bb to OE core for running gtk over directfb.

[YOCTO #1674]

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>
---
 meta/recipes-graphics/tasks/task-gtk-directfb.bb |   26 ++++++++++++++++++++++
 1 files changed, 26 insertions(+), 0 deletions(-)
 create mode 100644 meta/recipes-graphics/tasks/task-gtk-directfb.bb

diff --git a/meta/recipes-graphics/tasks/task-gtk-directfb.bb b/meta/recipes-graphics/tasks/task-gtk-directfb.bb
new file mode 100644
index 0000000..239e0c1
--- /dev/null
+++ b/meta/recipes-graphics/tasks/task-gtk-directfb.bb
@@ -0,0 +1,26 @@
+DESCRIPTION = "gkt+ over directfb without x11"
+PR = "r0"
+LICENSE = "MIT"
+
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
+                    file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+inherit task
+
+TOUCH = ' ${@base_contains("MACHINE_FEATURES", "touchscreen", "tslib tslib-calibrate tslib-tests", "",d)}'
+
+PACKAGES += " \
+	${PN}-base \
+"
+
+RDEPENDS_${PN}-base = " \
+		directfb \
+		directfb-examples \
+		pango \
+		pango-modules \
+		fontconfig \
+		gtk+ \
+		gtk-demo \
+		dropbear \
+		${TOUCH} \
+"
-- 
1.7.0.4

[PATCH 9/9] core-image-gtk-directfb.bb: add an image for gtk over directfb

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

This file can make an image to run gtk over directfb.

[YOCTO #1674]

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>
---
 .../images/core-image-gtk-directfb.bb              |   21 ++++++++++++++++++++
 1 files changed, 21 insertions(+), 0 deletions(-)
 create mode 100644 meta/recipes-graphics/images/core-image-gtk-directfb.bb

diff --git a/meta/recipes-graphics/images/core-image-gtk-directfb.bb b/meta/recipes-graphics/images/core-image-gtk-directfb.bb
new file mode 100644
index 0000000..00ba5cf
--- /dev/null
+++ b/meta/recipes-graphics/images/core-image-gtk-directfb.bb
@@ -0,0 +1,21 @@
+LICENSE = "MIT"
+PR="r0"
+
+LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
+                    file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+
+DEPENDS += "task-gtk-directfb"
+
+RDEPENDS_${PN} += " \
+	task-gtk-directfb-base \
+	"
+
+inherit core-image
+
+IMAGE_INSTALL += "\
+	${POKY_BASE_INSTALL} \
+	task-core-basic \
+	module-init-tools \
+	task-gtk-directfb-base \
+"
-- 
1.7.0.4

Re: [PATCH 0/9] The patches to run gtk over directfb

[Koen Kooi]

[-- Attachment #1: Type: text/plain, Size: 1621 bytes --]


Op 23 nov. 2011, om 07:47 heeft Xiaofeng Yan het volgende geschreven:

> From: Xiaofeng Yan <xiaofeng.yan@windriver.com>
> 
> Hi Richard & all,
> 
> I fixed some problems found at previous submitting and use PACKAGECONFIG to get mutual configuration between directfb and x11. I hope this submitting isn't a horrible mess :).
> 
> One previous problem about what happen when user want to have both directfb and x11 in DISTRO_FEATURES?

That was the question I was going to ask

> I think directfb and x11 can't be defined in DISTRO_FEATURES at the same time because directfb and x11 are the lowest level library for GUI with different mechanism.

I don't understand what the above means, but I've been building both directfb and x11 for some years now and they don't clash.

> x11 and directfb should be mutual in DISTRO_FEATURES. User may use file "meta-yocto/conf/local.conf.sample.extended" to select the mode they want to need.
> but directfb can work in an image with x11. for example, "directfb" and "direcrfb-examples" can be added to task-core-x11-sato.bb. you can run df_andi, a demo based on directfb, on matchbox term running on core-image-sato with x11. So directfb and x11 can exist in the same image but not be defined in DISTRO_FEATURES at same time.
> 
> If you have any suggestion, I will fix them again.

Last time I looked both gtk+ and pango had their backend modularized, so you can build both and install the right one in the rootfs. I think that would be a better way to go. Just look at debian with their gtk-directfb installer, they have gtk-X as well :)

regards,

Koen

[-- Attachment #2: Message signed with OpenPGP using GPGMail --]
[-- Type: application/pgp-signature, Size: 169 bytes --]

Re: [PATCH 0/9] The patches to run gtk over directfb

[Xiaofeng Yan]

[-- Attachment #1: Type: text/plain, Size: 2979 bytes --]

On 2011?11?23? 15:31, Koen Kooi wrote:
> Op 23 nov. 2011, om 07:47 heeft Xiaofeng Yan het volgende geschreven:
>
>> From: Xiaofeng Yan<xiaofeng.yan@windriver.com>
>>
>> Hi Richard&  all,
>>
>> I fixed some problems found at previous submitting and use PACKAGECONFIG to get mutual configuration between directfb and x11. I hope this submitting isn't a horrible mess :).
>>
>> One previous problem about what happen when user want to have both directfb and x11 in DISTRO_FEATURES?
> That was the question I was going to ask
>
>> I think directfb and x11 can't be defined in DISTRO_FEATURES at the same time because directfb and x11 are the lowest level library for GUI with different mechanism.
> I don't understand what the above means, but I've been building both directfb and x11 for some years now and they don't clash.
>
Hi koen,

Thanks for your comment.
I want to build an image only including directfb and gtk without x11. 
There are no any stuff related to x11 in this image. You know, directfb 
often is used in many embedded device because directfb is enough for 
their requirement. Perhaps they feel more familiar with directfb or gtk+ 
rather than x11. The purpose of building this image is for some people 
who  want to use yocto to develop their production getting  an image 
based on directfb anf gtk+ very easily.  So it need an mechanism making 
an mutual operation between directfb and x11 when compiling 
core-image-gtk-directfb for getting directfb image without x11. Of 
course, you can add directfb to DISTRO_FEATURES with x11, if you want to 
have both of them. But if you want to get an image without x11, then I 
think you can only remove x11 from DISTRO_FEATURES at current status 
because x11 is the default configuration.
>> x11 and directfb should be mutual in DISTRO_FEATURES. User may use file "meta-yocto/conf/local.conf.sample.extended" to select the mode they want to need.
>> but directfb can work in an image with x11. for example, "directfb" and "direcrfb-examples" can be added to task-core-x11-sato.bb. you can run df_andi, a demo based on directfb, on matchbox term running on core-image-sato with x11. So directfb and x11 can exist in the same image but not be defined in DISTRO_FEATURES at same time.
>>
>> If you have any suggestion, I will fix them again.
> Last time I looked both gtk+ and pango had their backend modularized, so you can build both and install the right one in the rootfs. I think that would be a better way to go. Just look at debian with their gtk-directfb installer, they have gtk-X as well :)
>
I know what you mean. It could be a good method to have both in an 
image. It may become a new task after completing  this feature.

Thanks
Yan
> regards,
>
> Koen
>
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core


[-- Attachment #2: Type: text/html, Size: 4537 bytes --]

Re: [PATCH 7/9] directfb-examples: add package directfb-examples to OE-core

[Saul Wold]

On 11/22/2011 10:48 PM, Xiaofeng Yan wrote:
> From: Xiaofeng Yan<xiaofeng.yan@windriver.com>
>
> Add this package for checking whether directfb run rightly or not.
> It also is an useful tool to test directfb.
>
> [YOCTO #1674]
>
> Signed-off-by: Xiaofeng Yan<xiaofeng.yan@windriver.com>
> ---
>   .../directfb/directfb-examples_1.2.0.bb            |   18 ++++++++++++++++++
>   1 files changed, 18 insertions(+), 0 deletions(-)
>   create mode 100644 meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb
>
> diff --git a/meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb b/meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb
> new file mode 100644
> index 0000000..08cdc8f
> --- /dev/null
> +++ b/meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb
> @@ -0,0 +1,18 @@
> +DESCRIPTION = "DirectFB extra providers"
Not very descriptive, please include more details, if needed add s 
SUMMARY line also that is a brief one liner.

> +DEPENDS = "directfb"
> +SECTION = "libs"
> +LICENSE = "GPL"
Which GPL?  Please include Version such as GPLv2

Sau!

> +PR = "r0"
> +
> +SRC_URI = " \
> +           http://www.directfb.org/downloads/Extras/DirectFB-examples-${PV}.tar.gz \
> +          "
> +
> +LIC_FILES_CHKSUM = "file://COPYING;md5=ecf6fd2b19915afc4da56043926ca18f"
> +
> +S = "${WORKDIR}/DirectFB-examples-${PV}"
> +
> +inherit autotools
> +
> +SRC_URI[md5sum] = "ce018f681b469a1d72ffc32650304b98"
> +SRC_URI[sha256sum] = "830a1bd6775d8680523596a88a72fd8e4c6a74bf886d3e169b06d234a5cf7e3e"

Re: [PATCH 0/9] The patches to run gtk over directfb

[Saul Wold]

On 11/22/2011 10:47 PM, Xiaofeng Yan wrote:
> From: Xiaofeng Yan<xiaofeng.yan@windriver.com>
>
> Hi Richard&  all,
>
> I fixed some problems found at previous submitting and use PACKAGECONFIG to get mutual configuration between directfb and x11. I hope this submitting isn't a horrible mess :).
>
> One previous problem about what happen when user want to have both directfb and x11 in DISTRO_FEATURES?
>
> I think directfb and x11 can't be defined in DISTRO_FEATURES at the same time because directfb and x11 are the lowest level library for GUI with different mechanism.
> x11 and directfb should be mutual in DISTRO_FEATURES. User may use file "meta-yocto/conf/local.conf.sample.extended" to select the mode they want to need.
> but directfb can work in an image with x11. for example, "directfb" and "direcrfb-examples" can be added to task-core-x11-sato.bb. you can run df_andi, a demo based on directfb, on matchbox term running on core-image-sato with x11. So directfb and x11 can exist in the same image but not be defined in DISTRO_FEATURES at same time.
>
> If you have any suggestion, I will fix them again.
>
Please double check PR bumps, I noted that some recipes changes have PR 
bumps and other do not.  Also double check all the other recipes that 
rely on directfb (I think you have most of them here) and ensure that PR 
bumps are made as appropriate.

Sau!

> Pull URL: git://git.pokylinux.org/poky-contrib.git
>    Branch: xiaofeng/gtk+-directfb
>    Browse: http://git.pokylinux.org/cgit.cgi/poky-contrib/log/?h=xiaofeng/gtk+-directfb
>
> Thanks,
>      Xiaofeng Yan<xiaofeng.yan@windriver.com>
> ---
>
>
> Xiaofeng Yan (9):
>    qemu-config: Disable dbus-x11 when no x11 in DISTRO_FEATURES
>    gconf: Disable dbus-x11 when x11 isn't in DISTRO_FEATURES
>    gtk.inc: add directfb DISTRO_FEATURE
>    gtk+: add demos to the configuation of gtk+
>    cairo: add directfb DISTRO_FEATURE
>    pango: add directfb DISTRO_FEATURE
>    directfb-examples: add package directfb-examples to OE-core
>    task-gtk-directfb.bb: Add task list to run gtk over directfb
>    core-image-gtk-directfb.bb: add an image for gtk over directfb
>
>   meta/recipes-bsp/qemu-config/qemu-config.bb        |    4 +-
>   meta/recipes-gnome/gnome/gconf_3.2.3.bb            |    4 ++-
>   meta/recipes-gnome/gtk+/gtk+.inc                   |   20 ++++++++++++---
>   meta/recipes-gnome/gtk+/gtk+_2.24.6.bb             |    7 ++++-
>   meta/recipes-graphics/cairo/cairo.inc              |   12 +++++++--
>   .../directfb/directfb-examples_1.2.0.bb            |   18 +++++++++++++
>   .../images/core-image-gtk-directfb.bb              |   21 ++++++++++++++++
>   meta/recipes-graphics/pango/pango.inc              |   19 +++++++++++---
>   meta/recipes-graphics/tasks/task-gtk-directfb.bb   |   26 ++++++++++++++++++++
>   9 files changed, 115 insertions(+), 16 deletions(-)
>   create mode 100644 meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb
>   create mode 100644 meta/recipes-graphics/images/core-image-gtk-directfb.bb
>   create mode 100644 meta/recipes-graphics/tasks/task-gtk-directfb.bb
>
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core
>

[PATCH 7/9] directfb-examples: add package directfb-examples to OE-core

[Xiaofeng Yan]

From: Xiaofeng Yan <xiaofeng.yan@windriver.com>

Add this package for checking whether directfb run rightly or not.
It also is an useful tool to test directfb.

[YOCTO #1674]

Signed-off-by: Xiaofeng Yan <xiaofeng.yan@windriver.com>
---
 .../directfb/directfb-examples_1.2.0.bb            |   20 ++++++++++++++++++++
 1 files changed, 20 insertions(+), 0 deletions(-)
 create mode 100644 meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb

diff --git a/meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb b/meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb
new file mode 100644
index 0000000..215426e
--- /dev/null
+++ b/meta/recipes-graphics/directfb/directfb-examples_1.2.0.bb
@@ -0,0 +1,20 @@
+DESCRIPTION = "The DirectFB-examples package contains a set of simple DirectFB \
+      applications that can be used to test and demonstrate various DirectFB \
+      features"
+DEPENDS = "directfb"
+SECTION = "libs"
+LICENSE = "MIT"
+PR = "r0"
+
+SRC_URI = " \
+           http://www.directfb.org/downloads/Extras/DirectFB-examples-${PV}.tar.gz \
+          "
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=ecf6fd2b19915afc4da56043926ca18f"
+
+S = "${WORKDIR}/DirectFB-examples-${PV}"
+
+inherit autotools
+
+SRC_URI[md5sum] = "ce018f681b469a1d72ffc32650304b98"
+SRC_URI[sha256sum] = "830a1bd6775d8680523596a88a72fd8e4c6a74bf886d3e169b06d234a5cf7e3e"
-- 
1.7.0.4