* [oe-core 01/10] tinylogin: use u-a for getty so we can provide /sbin/getty from util-linux-agetty too
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
@ 2011-11-29 7:00 ` Martin Jansa
2011-11-29 7:00 ` [oe-core 02/10] util-linux: use u-a to provide /sbin/getty from util-linux-agetty Martin Jansa
` (9 subsequent siblings)
10 siblings, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 7:00 UTC (permalink / raw)
To: openembedded-core
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
meta/recipes-core/tinylogin/tinylogin_1.4.bb | 13 ++++++++++++-
1 files changed, 12 insertions(+), 1 deletions(-)
diff --git a/meta/recipes-core/tinylogin/tinylogin_1.4.bb b/meta/recipes-core/tinylogin/tinylogin_1.4.bb
index bad918c..478f69b 100644
--- a/meta/recipes-core/tinylogin/tinylogin_1.4.bb
+++ b/meta/recipes-core/tinylogin/tinylogin_1.4.bb
@@ -7,7 +7,9 @@ and groups on an embedded system."
HOMEPAGE = "http://tinylogin.busybox.net/"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM="file://LICENSE;md5=f1060fa3a366f098b5b1d8c2077ba269"
-PR = "r7"
+PR = "r8"
+
+inherit update-alternatives
SRC_URI = "http://www.angstrom-distribution.org/unstable/sources/tinylogin-${PV}.tar.bz2 \
file://cvs-20040608.patch \
@@ -35,3 +37,12 @@ do_install () {
ln -sf /bin/tinylogin ${D}$i
done
}
+
+do_install_append () {
+ mv ${D}${base_sbindir}/getty ${D}${base_sbindir}/getty.${PN}
+}
+
+ALTERNATIVE_NAME = "getty"
+ALTERNATIVE_LINK = "${base_sbindir}/getty"
+ALTERNATIVE_PATH = "${base_sbindir}/getty.${PN}"
+ALTERNATIVE_PRIORITY = "80"
--
1.7.8.rc3
^ permalink raw reply related [flat|nested] 17+ messages in thread* [oe-core 02/10] util-linux: use u-a to provide /sbin/getty from util-linux-agetty
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
2011-11-29 7:00 ` [oe-core 01/10] tinylogin: use u-a for getty so we can provide /sbin/getty from util-linux-agetty too Martin Jansa
@ 2011-11-29 7:00 ` Martin Jansa
2011-11-29 7:00 ` [oe-core 03/10] mingetty: use u-a to provide /sbin/getty (also provided by util-linux-agetty and tinylogin) Martin Jansa
` (8 subsequent siblings)
10 siblings, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 7:00 UTC (permalink / raw)
To: openembedded-core
* inittab and systemd-serialgetty expects /sbin/getty not agetty
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
meta/recipes-core/util-linux/util-linux.inc | 8 ++++++++
meta/recipes-core/util-linux/util-linux_2.19.1.bb | 2 +-
2 files changed, 9 insertions(+), 1 deletions(-)
diff --git a/meta/recipes-core/util-linux/util-linux.inc b/meta/recipes-core/util-linux/util-linux.inc
index 855a545..acc4a39 100644
--- a/meta/recipes-core/util-linux/util-linux.inc
+++ b/meta/recipes-core/util-linux/util-linux.inc
@@ -236,6 +236,14 @@ pkg_prerm_util-linux-fdisk () {
update-alternatives --remove fdisk fdisk.${PN}
}
+pkg_postinst_util-linux-agetty () {
+ update-alternatives --install ${base_sbindir}/getty getty agetty 100
+}
+
+pkg_prerm_util-linux-agetty () {
+ update-alternatives --remove getty agetty
+}
+
pkg_postinst_util-linux-mount () {
update-alternatives --install ${base_bindir}/mount mount mount.${PN} 100
}
diff --git a/meta/recipes-core/util-linux/util-linux_2.19.1.bb b/meta/recipes-core/util-linux/util-linux_2.19.1.bb
index b65e761..82040ef 100644
--- a/meta/recipes-core/util-linux/util-linux_2.19.1.bb
+++ b/meta/recipes-core/util-linux/util-linux_2.19.1.bb
@@ -1,5 +1,5 @@
MAJOR_VERSION = "2.19"
-PR = "r11"
+PR = "r12"
require util-linux.inc
# note that `lscpu' is under GPLv3+
--
1.7.8.rc3
^ permalink raw reply related [flat|nested] 17+ messages in thread* [oe-core 03/10] mingetty: use u-a to provide /sbin/getty (also provided by util-linux-agetty and tinylogin)
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
2011-11-29 7:00 ` [oe-core 01/10] tinylogin: use u-a for getty so we can provide /sbin/getty from util-linux-agetty too Martin Jansa
2011-11-29 7:00 ` [oe-core 02/10] util-linux: use u-a to provide /sbin/getty from util-linux-agetty Martin Jansa
@ 2011-11-29 7:00 ` Martin Jansa
2011-11-29 7:00 ` [oe-core 04/10] cronie: use useradd.bbclass instead of hardcoded groupadd calls Martin Jansa
` (7 subsequent siblings)
10 siblings, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 7:00 UTC (permalink / raw)
To: openembedded-core
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
meta/recipes-extended/mingetty/mingetty_1.08.bb | 9 ++++++++-
1 files changed, 8 insertions(+), 1 deletions(-)
diff --git a/meta/recipes-extended/mingetty/mingetty_1.08.bb b/meta/recipes-extended/mingetty/mingetty_1.08.bb
index ce4b3d4..fed5dfd 100644
--- a/meta/recipes-extended/mingetty/mingetty_1.08.bb
+++ b/meta/recipes-extended/mingetty/mingetty_1.08.bb
@@ -2,7 +2,7 @@ DESCRIPTION = " A compact getty program for virtual consoles only"
SECTION = "console/utils"
HOMEPAGE = "http://sourceforge.net/projects/mingetty/"
LICENSE = "GPLv2"
-PR = "r0"
+PR = "r1"
LIC_FILES_CHKSUM = "file://COPYING;md5=0c56db0143f4f80c369ee3af7425af6e"
SRC_URI = "http://cdnetworks-kr-1.dl.sourceforge.net/project/mingetty/mingetty/${PV}/mingetty-${PV}.tar.gz"
@@ -17,3 +17,10 @@ do_install(){
mkdir -p ${D}/sbin
oe_runmake install DESTDIR=${D}
}
+
+inherit update-alternatives
+
+ALTERNATIVE_NAME = "getty"
+ALTERNATIVE_LINK = "${base_sbindir}/getty"
+ALTERNATIVE_PATH = "${base_sbindir}/mingetty"
+ALTERNATIVE_PRIORITY = "50"
--
1.7.8.rc3
^ permalink raw reply related [flat|nested] 17+ messages in thread* [oe-core 04/10] cronie: use useradd.bbclass instead of hardcoded groupadd calls
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
` (2 preceding siblings ...)
2011-11-29 7:00 ` [oe-core 03/10] mingetty: use u-a to provide /sbin/getty (also provided by util-linux-agetty and tinylogin) Martin Jansa
@ 2011-11-29 7:00 ` Martin Jansa
2011-11-29 7:00 ` [oe-core 05/10] ppp-dialin: use useradd.bbclass instead of hardcoded adduser/deluser calls Martin Jansa
` (6 subsequent siblings)
10 siblings, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 7:00 UTC (permalink / raw)
To: openembedded-core
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
meta/recipes-extended/cronie/cronie_1.4.8.bb | 33 +++++++++++--------------
1 files changed, 15 insertions(+), 18 deletions(-)
diff --git a/meta/recipes-extended/cronie/cronie_1.4.8.bb b/meta/recipes-extended/cronie/cronie_1.4.8.bb
index 064347e..2d25627 100644
--- a/meta/recipes-extended/cronie/cronie_1.4.8.bb
+++ b/meta/recipes-extended/cronie/cronie_1.4.8.bb
@@ -18,7 +18,7 @@ DEPENDS += "${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
RDEPENDS_${PN} = "${@base_contains('DISTRO_FEATURES', 'pam', '${PAM_DEPS}', '', d)}"
PAM_DEPS = "libpam libpam-runtime pam-plugin-access pam-plugin-loginuid"
-PR = "r1"
+PR = "r2"
SRC_URI = "https://fedorahosted.org/releases/c/r/cronie/cronie-${PV}.tar.gz \
file://crond.init \
@@ -31,7 +31,7 @@ PAM_SRC_URI = "file://crond_pam_config.patch"
SRC_URI[md5sum] = "9b1d2ce6db8d1883e06635f437170657"
SRC_URI[sha256sum] = "a3b910876f255712f1a5c364b74f34b0ceac9f6f3bbc45e854c5722785f513b3"
-inherit autotools update-rc.d
+inherit autotools update-rc.d useradd
EXTRA_OECONF += "\
${@base_contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)}"
@@ -39,6 +39,9 @@ EXTRA_OECONF += "\
INITSCRIPT_NAME = "crond"
INITSCRIPT_PARAMS = "start 90 2 3 4 5 . stop 60 0 1 6 ."
+USERADD_PACKAGES = "${PN}"
+GROUPADD_PARAM_${PN} = "crontab"
+
do_install_append () {
install -d ${D}${sysconfdir}/sysconfig/
install -d ${D}${sysconfdir}/init.d/
@@ -54,25 +57,19 @@ do_install_append () {
mkdir -p ${D}${sysconfdir}/cron.weekly
mkdir -p ${D}${sysconfdir}/cron.monthly
touch ${D}${sysconfdir}/cron.deny
-}
-
-FILES_${PN} += "${sysconfdir}/cron*"
-
-pkg_postinst_${PN} () {
- if [ "x$D" != "x" ] ; then
- exit 1
- fi
-
+
# below setting is necessary to allow normal user using crontab
- # add 'crontab' group and setgid for crontab binary
- grep crontab /etc/group || addgroup crontab
- chown root:crontab /usr/bin/crontab
- chmod 2755 /usr/bin/crontab
+ # setgid for crontab binary
+ chown root:crontab ${D}/usr/bin/crontab
+ chmod 2755 ${D}/usr/bin/crontab
# allow 'crontab' group write to /var/spool/cron
- chown root:crontab /var/spool/cron
- chmod 770 /var/spool/cron
+ chown root:crontab ${D}/var/spool/cron
+ chmod 770 ${D}/var/spool/cron
- chmod 600 /etc/crontab
+ chmod 600 ${D}/etc/crontab
}
+
+FILES_${PN} += "${sysconfdir}/cron*"
+
--
1.7.8.rc3
^ permalink raw reply related [flat|nested] 17+ messages in thread* [oe-core 05/10] ppp-dialin: use useradd.bbclass instead of hardcoded adduser/deluser calls
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
` (3 preceding siblings ...)
2011-11-29 7:00 ` [oe-core 04/10] cronie: use useradd.bbclass instead of hardcoded groupadd calls Martin Jansa
@ 2011-11-29 7:00 ` Martin Jansa
2011-11-29 7:00 ` [oe-core 06/10] libical: add version 0.47 Martin Jansa
` (5 subsequent siblings)
10 siblings, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 7:00 UTC (permalink / raw)
To: openembedded-core
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
.../ppp-dialin/ppp-dialin_0.1.bb | 23 +++++--------------
1 files changed, 6 insertions(+), 17 deletions(-)
diff --git a/meta/recipes-connectivity/ppp-dialin/ppp-dialin_0.1.bb b/meta/recipes-connectivity/ppp-dialin/ppp-dialin_0.1.bb
index d4ac77e..d239c20 100644
--- a/meta/recipes-connectivity/ppp-dialin/ppp-dialin_0.1.bb
+++ b/meta/recipes-connectivity/ppp-dialin/ppp-dialin_0.1.bb
@@ -2,7 +2,7 @@ SECTION = "console/network"
DESCRIPTION = "Enables PPP dial-in through a serial connection"
DEPENDS = "ppp"
RDEPENDS_${PN} = "ppp"
-PR = "r7"
+PR = "r8"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
@@ -10,7 +10,7 @@ LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3
SRC_URI = "file://host-peer \
file://ppp-dialin"
-inherit allarch
+inherit allarch useradd
do_install() {
install -d ${D}${sysconfdir}/ppp/peers
@@ -20,18 +20,7 @@ do_install() {
install -m 0755 ${WORKDIR}/ppp-dialin ${D}${sbindir}
}
-pkg_postinst_${PN} () {
-if test "x$D" != "x"; then
- exit 1
-else
- adduser --system --home /dev/null --no-create-home --empty-password --ingroup nogroup -s ${sbindir}/ppp-dialin ppp
-fi
-}
-
-pkg_postrm_${PN} () {
-if test "x$D" != "x"; then
- exit 1
-else
- deluser ppp
-fi
-}
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM_${PN} = "--system --home /dev/null \
+ --no-create-home --shell ${sbindir}/ppp-dialin \
+ --no-user-group --gid nogroup ppp"
--
1.7.8.rc3
^ permalink raw reply related [flat|nested] 17+ messages in thread* [oe-core 06/10] libical: add version 0.47
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
` (4 preceding siblings ...)
2011-11-29 7:00 ` [oe-core 05/10] ppp-dialin: use useradd.bbclass instead of hardcoded adduser/deluser calls Martin Jansa
@ 2011-11-29 7:00 ` Martin Jansa
2011-11-29 14:09 ` [oe-core 07/10] libical: drop older version 0.46 Martin Jansa
` (4 subsequent siblings)
10 siblings, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 7:00 UTC (permalink / raw)
To: openembedded-core
From: Denis 'GNUtoo' Carikli <GNUtoo@no-log.org>
Signed-off-by: Denis 'GNUtoo' Carikli <GNUtoo@no-log.org>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
meta/recipes-sato/libical/libical_0.47.bb | 14 ++++++++++++++
1 files changed, 14 insertions(+), 0 deletions(-)
create mode 100644 meta/recipes-sato/libical/libical_0.47.bb
diff --git a/meta/recipes-sato/libical/libical_0.47.bb b/meta/recipes-sato/libical/libical_0.47.bb
new file mode 100644
index 0000000..d711d5f
--- /dev/null
+++ b/meta/recipes-sato/libical/libical_0.47.bb
@@ -0,0 +1,14 @@
+DESCRIPTION = "iCal and scheduling (RFC 2445, 2446, 2447) library"
+HOMEPAGE = "http://sourceforge.net/projects/freeassociation/"
+BUGTRACKER = "http://sourceforge.net/tracker/?group_id=16077&atid=116077"
+LICENSE = "LGPLv2.1 | MPL-1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d4fc58309d8ed46587ac63bb449d82f8 \
+ file://LICENSE;md5=d1a0891cd3e582b3e2ec8fe63badbbb6"
+SECTION = "libs"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/project/freeassociation/${BPN}/${P}/${BPN}-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "21f7f8a21e3d857c9476be732e52dc32"
+SRC_URI[sha256sum] = "af4cbb4bb13d9ed3f2262181da9199823feba70802b15cc3e89b263d95da2888"
+
+inherit autotools
--
1.7.8.rc3
^ permalink raw reply related [flat|nested] 17+ messages in thread* [oe-core 07/10] libical: drop older version 0.46
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
` (5 preceding siblings ...)
2011-11-29 7:00 ` [oe-core 06/10] libical: add version 0.47 Martin Jansa
@ 2011-11-29 14:09 ` Martin Jansa
2011-11-29 14:09 ` [oe-core 08/10] libid3tag: add gperf to DEPENDS Martin Jansa
` (3 subsequent siblings)
10 siblings, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 14:09 UTC (permalink / raw)
To: openembedded-core
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
meta/recipes-sato/libical/libical_0.46.bb | 15 ---------------
1 files changed, 0 insertions(+), 15 deletions(-)
delete mode 100644 meta/recipes-sato/libical/libical_0.46.bb
diff --git a/meta/recipes-sato/libical/libical_0.46.bb b/meta/recipes-sato/libical/libical_0.46.bb
deleted file mode 100644
index e0e88ba..0000000
--- a/meta/recipes-sato/libical/libical_0.46.bb
+++ /dev/null
@@ -1,15 +0,0 @@
-DESCRIPTION = "iCal and scheduling (RFC 2445, 2446, 2447) library"
-HOMEPAGE = "http://sourceforge.net/projects/freeassociation/"
-BUGTRACKER = "http://sourceforge.net/tracker/?group_id=16077&atid=116077"
-LICENSE = "LGPLv2.1 | MPL-1"
-LIC_FILES_CHKSUM = "file://COPYING;md5=35da21efce2b9f0ca07524c9f844e6ed \
- file://LICENSE;md5=35da21efce2b9f0ca07524c9f844e6ed"
-SECTION = "libs"
-PR = "r0"
-
-SRC_URI = "${SOURCEFORGE_MIRROR}/freeassociation/${BPN}-${PV}.tar.gz"
-
-SRC_URI[md5sum] = "9c08f88945bfd5d0791d102e4aa4125c"
-SRC_URI[sha256sum] = "000762efb81501421d94ec56343648a62b3bd2884e7cdf6f638e2c207dd8f6a1"
-
-inherit autotools
--
1.7.8.rc3
^ permalink raw reply related [flat|nested] 17+ messages in thread* [oe-core 08/10] libid3tag: add gperf to DEPENDS
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
` (6 preceding siblings ...)
2011-11-29 14:09 ` [oe-core 07/10] libical: drop older version 0.46 Martin Jansa
@ 2011-11-29 14:09 ` Martin Jansa
2011-11-29 14:09 ` [oe-core 09/10] gst-plugins-ugly: bump PR to rebuild after libid3tag fix Martin Jansa
` (2 subsequent siblings)
10 siblings, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 14:09 UTC (permalink / raw)
To: openembedded-core
* see http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=270449
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
.../libid3tag/libid3tag_0.15.1b.bb | 4 ++--
1 files changed, 2 insertions(+), 2 deletions(-)
diff --git a/meta/recipes-multimedia/libid3tag/libid3tag_0.15.1b.bb b/meta/recipes-multimedia/libid3tag/libid3tag_0.15.1b.bb
index 4faa981..05e566e 100644
--- a/meta/recipes-multimedia/libid3tag/libid3tag_0.15.1b.bb
+++ b/meta/recipes-multimedia/libid3tag/libid3tag_0.15.1b.bb
@@ -6,8 +6,8 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
file://COPYRIGHT;md5=5e6279efb87c26c6e5e7a68317a6a87a \
file://version.h;beginline=1;endline=8;md5=86ac68b67f054b7afde9e149bbc3fe63"
SECTION = "libs"
-DEPENDS = "zlib"
-PR = "r3"
+DEPENDS = "zlib gperf-native"
+PR = "r4"
SRC_URI = "ftp://ftp.mars.org/pub/mpeg/libid3tag-${PV}.tar.gz \
file://addpkgconfig.patch"
--
1.7.8.rc3
^ permalink raw reply related [flat|nested] 17+ messages in thread* [oe-core 09/10] gst-plugins-ugly: bump PR to rebuild after libid3tag fix
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
` (7 preceding siblings ...)
2011-11-29 14:09 ` [oe-core 08/10] libid3tag: add gperf to DEPENDS Martin Jansa
@ 2011-11-29 14:09 ` Martin Jansa
2011-11-29 14:09 ` [oe-core 10/10] gconf: add polkit to DEPENDS Martin Jansa
2011-11-30 15:39 ` [oe-core 00/10] Small fixes Richard Purdie
10 siblings, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 14:09 UTC (permalink / raw)
To: openembedded-core
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
.../gstreamer/gst-plugins-ugly_0.10.17.bb | 2 +-
1 files changed, 1 insertions(+), 1 deletions(-)
diff --git a/meta/recipes-multimedia/gstreamer/gst-plugins-ugly_0.10.17.bb b/meta/recipes-multimedia/gstreamer/gst-plugins-ugly_0.10.17.bb
index 2a79c2a..26bc0ba 100644
--- a/meta/recipes-multimedia/gstreamer/gst-plugins-ugly_0.10.17.bb
+++ b/meta/recipes-multimedia/gstreamer/gst-plugins-ugly_0.10.17.bb
@@ -7,7 +7,7 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
file://gst/mpegstream/gstmpegparse.h;beginline=1;endline=18;md5=ff65467b0c53cdfa98d0684c1bc240a9"
DEPENDS += "gst-plugins-base libid3tag libmad mpeg2dec liba52 lame"
-PR = "r1"
+PR = "r2"
inherit gettext
--
1.7.8.rc3
^ permalink raw reply related [flat|nested] 17+ messages in thread* [oe-core 10/10] gconf: add polkit to DEPENDS
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
` (8 preceding siblings ...)
2011-11-29 14:09 ` [oe-core 09/10] gst-plugins-ugly: bump PR to rebuild after libid3tag fix Martin Jansa
@ 2011-11-29 14:09 ` Martin Jansa
2011-11-29 20:25 ` Saul Wold
2011-11-29 22:23 ` [PATCH] gconf: add polkit to DEPENDS only for target recipe and disable default-service for native Martin Jansa
2011-11-30 15:39 ` [oe-core 00/10] Small fixes Richard Purdie
10 siblings, 2 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 14:09 UTC (permalink / raw)
To: openembedded-core
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
meta/recipes-gnome/gnome/gconf_3.2.3.bb | 2 +-
1 files changed, 1 insertions(+), 1 deletions(-)
diff --git a/meta/recipes-gnome/gnome/gconf_3.2.3.bb b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
index aa9da78..907f0ba 100644
--- a/meta/recipes-gnome/gnome/gconf_3.2.3.bb
+++ b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
@@ -3,7 +3,7 @@ SECTION = "x11/gnome"
LICENSE = "LGPLv2+"
LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605"
-DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native"
+DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native polkit"
PR = "r1"
--
1.7.8.rc3
^ permalink raw reply related [flat|nested] 17+ messages in thread* Re: [oe-core 10/10] gconf: add polkit to DEPENDS
2011-11-29 14:09 ` [oe-core 10/10] gconf: add polkit to DEPENDS Martin Jansa
@ 2011-11-29 20:25 ` Saul Wold
2011-11-29 20:43 ` Martin Jansa
2011-11-29 22:23 ` [PATCH] gconf: add polkit to DEPENDS only for target recipe and disable default-service for native Martin Jansa
1 sibling, 1 reply; 17+ messages in thread
From: Saul Wold @ 2011-11-29 20:25 UTC (permalink / raw)
To: Patches and discussions about the oe-core layer; +Cc: Martin Jansa
On 11/29/2011 06:09 AM, Martin Jansa wrote:
> Signed-off-by: Martin Jansa<Martin.Jansa@gmail.com>
> ---
> meta/recipes-gnome/gnome/gconf_3.2.3.bb | 2 +-
> 1 files changed, 1 insertions(+), 1 deletions(-)
>
> diff --git a/meta/recipes-gnome/gnome/gconf_3.2.3.bb b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
> index aa9da78..907f0ba 100644
> --- a/meta/recipes-gnome/gnome/gconf_3.2.3.bb
> +++ b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
> @@ -3,7 +3,7 @@ SECTION = "x11/gnome"
> LICENSE = "LGPLv2+"
> LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605"
>
> -DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native"
> +DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native polkit"
>
> PR = "r1"
>
What is this solving? This also would require polkit to have a
BBCLASSEXTEND with native.
Sau!
^ permalink raw reply [flat|nested] 17+ messages in thread
* Re: [oe-core 10/10] gconf: add polkit to DEPENDS
2011-11-29 20:25 ` Saul Wold
@ 2011-11-29 20:43 ` Martin Jansa
2011-11-29 20:49 ` Saul Wold
0 siblings, 1 reply; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 20:43 UTC (permalink / raw)
To: Saul Wold; +Cc: Patches and discussions about the oe-core layer
[-- Attachment #1: Type: text/plain, Size: 2320 bytes --]
On Tue, Nov 29, 2011 at 12:25:46PM -0800, Saul Wold wrote:
> On 11/29/2011 06:09 AM, Martin Jansa wrote:
> > Signed-off-by: Martin Jansa<Martin.Jansa@gmail.com>
> > ---
> > meta/recipes-gnome/gnome/gconf_3.2.3.bb | 2 +-
> > 1 files changed, 1 insertions(+), 1 deletions(-)
> >
> > diff --git a/meta/recipes-gnome/gnome/gconf_3.2.3.bb b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
> > index aa9da78..907f0ba 100644
> > --- a/meta/recipes-gnome/gnome/gconf_3.2.3.bb
> > +++ b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
> > @@ -3,7 +3,7 @@ SECTION = "x11/gnome"
> > LICENSE = "LGPLv2+"
> > LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605"
> >
> > -DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native"
> > +DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native polkit"
> >
> > PR = "r1"
> >
>
> What is this solving? This also would require polkit to have a
> BBCLASSEXTEND with native.
gconf-defaults.c:40:27: fatal error: polkit/polkit.h: No such file or directory
most people have polkit build in sysroot and then if you upgrade gconf
and polkit at the same time you can get it autodetected in
gconf's do_configure and later removed from sysroot while polkit itself
is being upgraded.
And we probably don't want to disable defaults_service for gconf to force polkit
dependency off.
HAVE_POLKIT=no
AC_ARG_ENABLE(defaults_service,
AS_HELP_STRING([--enable-defaults-service],
[build the defaults DBus service @<:@default=auto@:>@]),
, enable_defaults_service=auto)
if test "x$enable_defaults_service" != "xno" ; then
PKG_CHECK_MODULES(DEFAULTS, glib-2.0 gthread-2.0 gobject-2.0 dbus-1 dbus-glib-1 polkit-gobject-1, HAVE_POLKIT=yes, HAVE_POLKIT=no)
if test "x$HAVE_POLKIT" = "xno"; then
if test "x$enable_defaults_service" = "xyes" ; then
AC_MSG_ERROR([[
*** Could not find PolicyKit.]])
else
enable_defaults_service=no
fi
else
enable_defaults_service=yes
fi
fi
Weird it didn't fail for me without polkit-native (there isn't .bbappend in any of
my layers and I've even tested it in distro less oe-core), but you're right, we should
provide polkit-native or disable defaults_service for native gconf.
Cheers,
--
Martin 'JaMa' Jansa jabber: Martin.Jansa@gmail.com
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]
^ permalink raw reply [flat|nested] 17+ messages in thread* Re: [oe-core 10/10] gconf: add polkit to DEPENDS
2011-11-29 20:43 ` Martin Jansa
@ 2011-11-29 20:49 ` Saul Wold
2011-11-29 21:29 ` Martin Jansa
0 siblings, 1 reply; 17+ messages in thread
From: Saul Wold @ 2011-11-29 20:49 UTC (permalink / raw)
To: Martin Jansa; +Cc: Patches and discussions about the oe-core layer
On 11/29/2011 12:43 PM, Martin Jansa wrote:
> On Tue, Nov 29, 2011 at 12:25:46PM -0800, Saul Wold wrote:
>> On 11/29/2011 06:09 AM, Martin Jansa wrote:
>>> Signed-off-by: Martin Jansa<Martin.Jansa@gmail.com>
>>> ---
>>> meta/recipes-gnome/gnome/gconf_3.2.3.bb | 2 +-
>>> 1 files changed, 1 insertions(+), 1 deletions(-)
>>>
>>> diff --git a/meta/recipes-gnome/gnome/gconf_3.2.3.bb b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
>>> index aa9da78..907f0ba 100644
>>> --- a/meta/recipes-gnome/gnome/gconf_3.2.3.bb
>>> +++ b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
>>> @@ -3,7 +3,7 @@ SECTION = "x11/gnome"
>>> LICENSE = "LGPLv2+"
>>> LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605"
>>>
>>> -DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native"
>>> +DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native polkit"
>>>
>>> PR = "r1"
>>>
>>
>> What is this solving? This also would require polkit to have a
>> BBCLASSEXTEND with native.
>
> gconf-defaults.c:40:27: fatal error: polkit/polkit.h: No such file or directory
>
> most people have polkit build in sysroot and then if you upgrade gconf
> and polkit at the same time you can get it autodetected in
> gconf's do_configure and later removed from sysroot while polkit itself
> is being upgraded.
>
> And we probably don't want to disable defaults_service for gconf to force polkit
> dependency off.
>
> HAVE_POLKIT=no
> AC_ARG_ENABLE(defaults_service,
> AS_HELP_STRING([--enable-defaults-service],
> [build the defaults DBus service @<:@default=auto@:>@]),
> , enable_defaults_service=auto)
>
> if test "x$enable_defaults_service" != "xno" ; then
> PKG_CHECK_MODULES(DEFAULTS, glib-2.0 gthread-2.0 gobject-2.0 dbus-1 dbus-glib-1 polkit-gobject-1, HAVE_POLKIT=yes, HAVE_POLKIT=no)
> if test "x$HAVE_POLKIT" = "xno"; then
> if test "x$enable_defaults_service" = "xyes" ; then
> AC_MSG_ERROR([[
> *** Could not find PolicyKit.]])
> else
> enable_defaults_service=no
> fi
> else
> enable_defaults_service=yes
> fi
> fi
>
> Weird it didn't fail for me without polkit-native (there isn't .bbappend in any of
> my layers and I've even tested it in distro less oe-core), but you're right, we should
> provide polkit-native or disable defaults_service for native gconf.
>
I think it would be best to disable the default_services for native
gconf, a patch for that would be great, thanks
Sau!
> Cheers,
^ permalink raw reply [flat|nested] 17+ messages in thread
* Re: [oe-core 10/10] gconf: add polkit to DEPENDS
2011-11-29 20:49 ` Saul Wold
@ 2011-11-29 21:29 ` Martin Jansa
0 siblings, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 21:29 UTC (permalink / raw)
To: Saul Wold; +Cc: Patches and discussions about the oe-core layer
[-- Attachment #1: Type: text/plain, Size: 3015 bytes --]
On Tue, Nov 29, 2011 at 12:49:00PM -0800, Saul Wold wrote:
> On 11/29/2011 12:43 PM, Martin Jansa wrote:
> > On Tue, Nov 29, 2011 at 12:25:46PM -0800, Saul Wold wrote:
> >> On 11/29/2011 06:09 AM, Martin Jansa wrote:
> >>> Signed-off-by: Martin Jansa<Martin.Jansa@gmail.com>
> >>> ---
> >>> meta/recipes-gnome/gnome/gconf_3.2.3.bb | 2 +-
> >>> 1 files changed, 1 insertions(+), 1 deletions(-)
> >>>
> >>> diff --git a/meta/recipes-gnome/gnome/gconf_3.2.3.bb b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
> >>> index aa9da78..907f0ba 100644
> >>> --- a/meta/recipes-gnome/gnome/gconf_3.2.3.bb
> >>> +++ b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
> >>> @@ -3,7 +3,7 @@ SECTION = "x11/gnome"
> >>> LICENSE = "LGPLv2+"
> >>> LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605"
> >>>
> >>> -DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native"
> >>> +DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native polkit"
> >>>
> >>> PR = "r1"
> >>>
> >>
> >> What is this solving? This also would require polkit to have a
> >> BBCLASSEXTEND with native.
> >
> > gconf-defaults.c:40:27: fatal error: polkit/polkit.h: No such file or directory
> >
> > most people have polkit build in sysroot and then if you upgrade gconf
> > and polkit at the same time you can get it autodetected in
> > gconf's do_configure and later removed from sysroot while polkit itself
> > is being upgraded.
> >
> > And we probably don't want to disable defaults_service for gconf to force polkit
> > dependency off.
> >
> > HAVE_POLKIT=no
> > AC_ARG_ENABLE(defaults_service,
> > AS_HELP_STRING([--enable-defaults-service],
> > [build the defaults DBus service @<:@default=auto@:>@]),
> > , enable_defaults_service=auto)
> >
> > if test "x$enable_defaults_service" != "xno" ; then
> > PKG_CHECK_MODULES(DEFAULTS, glib-2.0 gthread-2.0 gobject-2.0 dbus-1 dbus-glib-1 polkit-gobject-1, HAVE_POLKIT=yes, HAVE_POLKIT=no)
> > if test "x$HAVE_POLKIT" = "xno"; then
> > if test "x$enable_defaults_service" = "xyes" ; then
> > AC_MSG_ERROR([[
> > *** Could not find PolicyKit.]])
> > else
> > enable_defaults_service=no
> > fi
> > else
> > enable_defaults_service=yes
> > fi
> > fi
> >
> > Weird it didn't fail for me without polkit-native (there isn't .bbappend in any of
> > my layers and I've even tested it in distro less oe-core), but you're right, we should
> > provide polkit-native or disable defaults_service for native gconf.
> >
> I think it would be best to disable the default_services for native
> gconf, a patch for that would be great, thanks
Ah, now I know why I haven't seen that in normal builds
/OE/shr-core/meta-openembedded/meta-gnome/recipes-gnome/gconf/gconf-native_2.6.1.bb
and nothing in my oe-core-only builds was depending on gconf-native
I'll send updated patch after few more tests..
Cheers,
--
Martin 'JaMa' Jansa jabber: Martin.Jansa@gmail.com
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]
^ permalink raw reply [flat|nested] 17+ messages in thread
* [PATCH] gconf: add polkit to DEPENDS only for target recipe and disable default-service for native
2011-11-29 14:09 ` [oe-core 10/10] gconf: add polkit to DEPENDS Martin Jansa
2011-11-29 20:25 ` Saul Wold
@ 2011-11-29 22:23 ` Martin Jansa
1 sibling, 0 replies; 17+ messages in thread
From: Martin Jansa @ 2011-11-29 22:23 UTC (permalink / raw)
To: openembedded-core
* gnome-common-native is needed because gnomebase.bbclass does only
DEPENDS += "gnome-common"
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
meta/recipes-gnome/gnome/gconf_3.2.3.bb | 10 +++++++---
1 files changed, 7 insertions(+), 3 deletions(-)
diff --git a/meta/recipes-gnome/gnome/gconf_3.2.3.bb b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
index aa9da78..cdc7a35 100644
--- a/meta/recipes-gnome/gnome/gconf_3.2.3.bb
+++ b/meta/recipes-gnome/gnome/gconf_3.2.3.bb
@@ -3,9 +3,10 @@ SECTION = "x11/gnome"
LICENSE = "LGPLv2+"
LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605"
-DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native"
+DEPENDS = "glib-2.0 dbus dbus-glib libxml2 intltool-native polkit"
+DEPENDS_virtclass-native = "glib-2.0-native dbus-native dbus-glib-native libxml2-native intltool-native gnome-common-native"
-PR = "r1"
+PR = "r2"
inherit gnomebase
@@ -18,7 +19,10 @@ SRC_URI[archive.sha256sum] = "52008a82a847527877d9e1e549a351c86cc53cada4733b8a70
S = "${WORKDIR}/GConf-${PV}"
-EXTRA_OECONF = "--disable-gtk-doc --disable-gtk --enable-shared --disable-static --enable-debug=yes --disable-introspection --disable-orbit --with-openldap=no"
+POLKIT_OECONF = "--enable-defaults-service"
+POLKIT_OECONF_virtclass-native = "--disable-defaults-service"
+EXTRA_OECONF = "--disable-gtk-doc --disable-gtk --enable-shared --disable-static --enable-debug=yes \
+ --disable-introspection --disable-orbit --with-openldap=no ${POLKIT_OECONF}"
do_configure_prepend () {
touch gtk-doc.make
--
1.7.8.rc4
^ permalink raw reply related [flat|nested] 17+ messages in thread
* Re: [oe-core 00/10] Small fixes
2011-11-29 6:55 [oe-core 00/10] Small fixes Martin Jansa
` (9 preceding siblings ...)
2011-11-29 14:09 ` [oe-core 10/10] gconf: add polkit to DEPENDS Martin Jansa
@ 2011-11-30 15:39 ` Richard Purdie
10 siblings, 0 replies; 17+ messages in thread
From: Richard Purdie @ 2011-11-30 15:39 UTC (permalink / raw)
To: Patches and discussions about the oe-core layer
On Tue, 2011-11-29 at 07:55 +0100, Martin Jansa wrote:
> The following changes since commit 2864ff6a4b3c3f9b3bbb6d2597243cc5d3715939:
>
> getVar/setVar cleanups (2011-11-26 22:42:00 +0000)
>
> are available in the git repository at:
> git://git.openembedded.org/openembedded-core-contrib jansa/pull2
> http://cgit.openembedded.org/cgit.cgi/openembedded-core-contrib/log/?h=jansa/pull2
>
> Denis 'GNUtoo' Carikli (1):
> libical: add version 0.47
>
> Martin Jansa (9):
> tinylogin: use u-a for getty so we can provide /sbin/getty from
> util-linux-agetty too
> util-linux: use u-a to provide /sbin/getty from util-linux-agetty
> mingetty: use u-a to provide /sbin/getty (also provided by
> util-linux-agetty and tinylogin)
> cronie: use useradd.bbclass instead of hardcoded groupadd calls
> ppp-dialin: use useradd.bbclass instead of hardcoded adduser/deluser
> calls
> libical: drop older version 0.46
> libid3tag: add gperf to DEPENDS
> gst-plugins-ugly: bump PR to rebuild after libid3tag fix
> gconf: add polkit to DEPENDS
I took these with the exception of the gconf change which I know there
is an updated patch for.
Cheers,
Richard
^ permalink raw reply [flat|nested] 17+ messages in thread