* [PATCH 0/2] Build and package dbus-tests - separate recipe
@ 2012-08-17 13:02 Andrei Gherzan
2012-08-17 13:02 ` [PATCH 2/2] dbus-tests: Add separate recipe for building dbus-tests Andrei Gherzan
2012-08-17 13:05 ` [PATCH 1/2] python-dbus: Native dbus python module needed for dbus tests Andrei Gherzan
0 siblings, 2 replies; 7+ messages in thread
From: Andrei Gherzan @ 2012-08-17 13:02 UTC (permalink / raw)
To: openembedded-core; +Cc: Andrei Gherzan
While compiling dbus with tests, dbus and dbus-glib are needed. To
compile dbus-glib, dbus is needed (obviously). The only solution (to
compile dbus with tests) that i found, is to create a new recipe named
dbus-tests where to compile dbus with --enable-tests
--enable-embedded-tests, skip write to sysroot (noexec) and just
package dbus-tests.
I included a wrapper to run all tests.
As discussed on mailing list, tests location is: libdir/BPN
Tested on all qemu machines with dbus 1.4.20 and with the comming
1.6.4
The following changes since commit bddd8300325267253941e7ce656ce2cf86a8a4a4:
apr-util: fix the rules.mk with path to sysroot instead of the workdir of apr (2012-08-17 13:10:08 +0100)
are available in the git repository at:
git://git.yoctoproject.org/poky-contrib ag/dbus-tests
http://git.yoctoproject.org/cgit.cgi/poky-contrib/log/?h=ag/dbus-tests
Andrei Gherzan (2):
python-dbus: Native dbus python module needed for dbus tests
dbus-tests: Add separate recipe for building dbus-tests
meta/recipes-core/dbus/dbus-tests/run_test.sh | 22 +++++++
meta/recipes-core/dbus/dbus-tests_1.4.20.bb | 64 +++++++++++++++++++++
meta/recipes-devtools/python/python-dbus_1.1.1.bb | 5 +-
3 files changed, 90 insertions(+), 1 deletions(-)
create mode 100755 meta/recipes-core/dbus/dbus-tests/run_test.sh
create mode 100644 meta/recipes-core/dbus/dbus-tests_1.4.20.bb
--
1.7.5.4
^ permalink raw reply [flat|nested] 7+ messages in thread
* [PATCH 2/2] dbus-tests: Add separate recipe for building dbus-tests
2012-08-17 13:02 [PATCH 0/2] Build and package dbus-tests - separate recipe Andrei Gherzan
@ 2012-08-17 13:02 ` Andrei Gherzan
2012-08-17 13:44 ` Radu Moisan
2012-08-17 13:05 ` [PATCH 1/2] python-dbus: Native dbus python module needed for dbus tests Andrei Gherzan
1 sibling, 1 reply; 7+ messages in thread
From: Andrei Gherzan @ 2012-08-17 13:02 UTC (permalink / raw)
To: openembedded-core; +Cc: Andrei Gherzan
While compiling dbus with tests, dbus and dbus-glib are needed.
To compile dbus-glib, dbus is needed (obviously). The only solution
(to compile dbus with tests) is to create a new recipe where to
compile dbus with --enable-tests --enable-embedded-tests, skip write
to sysroot (noexec) and just package dbus-tests.
A bash wrapper to run all tests is included.
Signed-off-by: Andrei Gherzan <andrei.gherzan@windriver.com>
---
meta/recipes-core/dbus/dbus-tests/run_test.sh | 22 +++++++++
meta/recipes-core/dbus/dbus-tests_1.4.20.bb | 64 +++++++++++++++++++++++++
2 files changed, 86 insertions(+), 0 deletions(-)
create mode 100755 meta/recipes-core/dbus/dbus-tests/run_test.sh
create mode 100644 meta/recipes-core/dbus/dbus-tests_1.4.20.bb
diff --git a/meta/recipes-core/dbus/dbus-tests/run_test.sh b/meta/recipes-core/dbus/dbus-tests/run_test.sh
new file mode 100755
index 0000000..90abad2
--- /dev/null
+++ b/meta/recipes-core/dbus/dbus-tests/run_test.sh
@@ -0,0 +1,22 @@
+#!/bin/sh
+
+# Tests location
+export DBUS_TEST_HOMEDIR=/usr/lib/dbus-tests
+# Tests data location
+export DBUS_TEST_DATA=${DBUS_TEST_HOMEDIR}/test/data
+
+TESTS=" \
+ bus/bus-test \
+ bus/bus-test-system \
+ dbus/dbus-test \
+ bus/bus-test-launch-helper \
+ test/shell-test \
+ test/test-corrupt \
+ test/test-dbus-daemon \
+ test/test-loopback \
+ test/test-marshal \
+ test/test-relay \
+ test/test-syslog \
+ test/test-refs"
+
+${DBUS_TEST_HOMEDIR}/test/dbus-test-runner ${DBUS_TEST_HOMEDIR} ${TESTS}
diff --git a/meta/recipes-core/dbus/dbus-tests_1.4.20.bb b/meta/recipes-core/dbus/dbus-tests_1.4.20.bb
new file mode 100644
index 0000000..0e7d272
--- /dev/null
+++ b/meta/recipes-core/dbus/dbus-tests_1.4.20.bb
@@ -0,0 +1,64 @@
+FILESEXTRAPATHS_append := "${THISDIR}/dbus-${PV}"
+include recipes-core/dbus/dbus.inc
+
+PR = "${INC_PR}.0"
+
+SRC_URI[md5sum] = "79eca2f2c1894ac347acce128314428b"
+SRC_URI[sha256sum] = "103bdcd261a13140730b5fa69f56a98ab5c89ba3f0116ea62fcfd639520d5aaf"
+
+DEPENDS += "python-pygobject-native python-dbus-native dbus-glib dbus"
+RDEPENDS_${PN} = "dbus-x11"
+RPROVIDES_${PN} = ""
+
+TEST_PATH = "${libdir}/${BPN}"
+
+EXTRA_OECONF += "--enable-tests --enable-embedded-tests --enable-verbose-mode --with-dbus-test-dir=${TEST_PATH}"
+
+export DBUS_GLIB_CFLAGS="-I${STAGING_DIR_HOST}${includedir}/dbus-1.0"
+export DBUS_GLIB_LIBS="-ldbus-glib-1"
+
+S = "${WORKDIR}/dbus-${PV}"
+
+# Add test wrapper
+SRC_URI += "file://run_test.sh"
+
+# We don't want to overwrite dbus in sysroot. Just want to package the tests
+do_populate_sysroot[noexec] = "1"
+
+PACKAGES = "${PN}-dbg ${PN}"
+
+FILES_${PN} = "${TEST_PATH}"
+FILES_${PN}-dbg = "${TEST_PATH}/bus/.debug \
+ ${TEST_PATH}/dbus/.debug \
+ ${TEST_PATH}/test/.debug \
+ /usr/src/debug"
+
+BUS_TESTS = "bus-test bus-test-system bus-test-launch-helper dbus-daemon-launch-helper-test"
+DBUS_TESTS = "dbus-test"
+TEST = "dbus-test-runner spawn-test .libs/test-dbus-daemon .libs/test-loopback test-sleep-forever \
+ test-segfault shell-test test-exit .libs/test-marshal test-refs test-shell-service \
+ .libs/test-corrupt test-syslog test-names .libs/test-relay test-service"
+
+do_install () {
+ install -d ${D}/${TEST_PATH}/test/data
+ install -d ${D}/${TEST_PATH}/dbus
+ install -d ${D}/${TEST_PATH}/bus
+
+ cp -r ${S}/test/data/* ${D}/${TEST_PATH}/test/data
+
+ for file in ${BUS_TESTS}; do
+ install -m 766 ${S}/bus/${file} ${D}/${TEST_PATH}/bus
+ done
+
+ for file in ${DBUS_TESTS}; do
+ install -m 766 ${S}/dbus/${file} ${D}/${TEST_PATH}/dbus
+ done
+
+ for file in ${TEST}; do
+ install -m 766 ${S}/test/${file} ${D}/${TEST_PATH}/test
+ done
+
+ install -m 766 ${WORKDIR}/run_test.sh ${D}/${TEST_PATH}
+}
+
+BBCLASSEXTEND = ""
--
1.7.5.4
^ permalink raw reply related [flat|nested] 7+ messages in thread
* [PATCH 1/2] python-dbus: Native dbus python module needed for dbus tests
2012-08-17 13:02 [PATCH 0/2] Build and package dbus-tests - separate recipe Andrei Gherzan
2012-08-17 13:02 ` [PATCH 2/2] dbus-tests: Add separate recipe for building dbus-tests Andrei Gherzan
@ 2012-08-17 13:05 ` Andrei Gherzan
2012-08-17 13:09 ` Martin Jansa
1 sibling, 1 reply; 7+ messages in thread
From: Andrei Gherzan @ 2012-08-17 13:05 UTC (permalink / raw)
To: openembedded-core; +Cc: Andrei Gherzan
Signed-off-by: Andrei Gherzan <andrei.gherzan@windriver.com>
---
meta/recipes-devtools/python/python-dbus_1.1.1.bb | 5 ++++-
1 files changed, 4 insertions(+), 1 deletions(-)
diff --git a/meta/recipes-devtools/python/python-dbus_1.1.1.bb b/meta/recipes-devtools/python/python-dbus_1.1.1.bb
index 51d5bc2..35149a0 100644
--- a/meta/recipes-devtools/python/python-dbus_1.1.1.bb
+++ b/meta/recipes-devtools/python/python-dbus_1.1.1.bb
@@ -4,7 +4,7 @@ HOMEPAGE = "http://www.freedesktop.org/Software/dbus"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://COPYING;md5=f5612614133e9a2f2dad527d97554670"
DEPENDS = "expat dbus dbus-glib virtual/libintl python-pyrex-native"
-PR = "r0"
+PR = "r1"
SRC_URI = "http://dbus.freedesktop.org/releases/dbus-python/dbus-python-${PV}.tar.gz"
@@ -23,3 +23,6 @@ export STAGING_INCDIR
RDEPENDS_${PN} = "python-io python-logging python-stringold python-threading python-xml"
FILES_${PN}-dev += "${libdir}/pkgconfig"
+
+RDEPENDS_${PN}_virtclass-native = "python"
+BBCLASSEXTEND = "native"
--
1.7.5.4
^ permalink raw reply related [flat|nested] 7+ messages in thread
* Re: [PATCH 1/2] python-dbus: Native dbus python module needed for dbus tests
2012-08-17 13:05 ` [PATCH 1/2] python-dbus: Native dbus python module needed for dbus tests Andrei Gherzan
@ 2012-08-17 13:09 ` Martin Jansa
2012-08-17 13:55 ` Andrei Gherzan
0 siblings, 1 reply; 7+ messages in thread
From: Martin Jansa @ 2012-08-17 13:09 UTC (permalink / raw)
To: Patches and discussions about the oe-core layer; +Cc: Andrei Gherzan
[-- Attachment #1: Type: text/plain, Size: 1704 bytes --]
On Fri, Aug 17, 2012 at 04:05:00PM +0300, Andrei Gherzan wrote:
> Signed-off-by: Andrei Gherzan <andrei.gherzan@windriver.com>
> ---
> meta/recipes-devtools/python/python-dbus_1.1.1.bb | 5 ++++-
> 1 files changed, 4 insertions(+), 1 deletions(-)
>
> diff --git a/meta/recipes-devtools/python/python-dbus_1.1.1.bb b/meta/recipes-devtools/python/python-dbus_1.1.1.bb
> index 51d5bc2..35149a0 100644
> --- a/meta/recipes-devtools/python/python-dbus_1.1.1.bb
> +++ b/meta/recipes-devtools/python/python-dbus_1.1.1.bb
> @@ -4,7 +4,7 @@ HOMEPAGE = "http://www.freedesktop.org/Software/dbus"
> LICENSE = "MIT"
> LIC_FILES_CHKSUM = "file://COPYING;md5=f5612614133e9a2f2dad527d97554670"
> DEPENDS = "expat dbus dbus-glib virtual/libintl python-pyrex-native"
> -PR = "r0"
> +PR = "r1"
>
> SRC_URI = "http://dbus.freedesktop.org/releases/dbus-python/dbus-python-${PV}.tar.gz"
>
> @@ -23,3 +23,6 @@ export STAGING_INCDIR
> RDEPENDS_${PN} = "python-io python-logging python-stringold python-threading python-xml"
>
> FILES_${PN}-dev += "${libdir}/pkgconfig"
> +
> +RDEPENDS_${PN}_virtclass-native = "python"
Does RDEPENDS_${PN} work for native recipes? I thought that R* vars are
for runtime packages and native builds doesn't provide them imho.
And if they do, why not explicitly ask for python-native, because target python wont help I guess.
> +BBCLASSEXTEND = "native"
> --
> 1.7.5.4
>
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core
--
Martin 'JaMa' Jansa jabber: Martin.Jansa@gmail.com
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]
^ permalink raw reply [flat|nested] 7+ messages in thread
* Re: [PATCH 2/2] dbus-tests: Add separate recipe for building dbus-tests
2012-08-17 13:44 ` Radu Moisan
@ 2012-08-17 13:43 ` Andrei Gherzan
0 siblings, 0 replies; 7+ messages in thread
From: Andrei Gherzan @ 2012-08-17 13:43 UTC (permalink / raw)
To: Patches and discussions about the oe-core layer
[-- Attachment #1: Type: text/plain, Size: 2581 bytes --]
On Fri, Aug 17, 2012 at 4:44 PM, Radu Moisan <radu.moisan@intel.com> wrote:
>
> On 08/17/2012 04:02 PM, Andrei Gherzan wrote:
>
> While compiling dbus with tests, dbus and dbus-glib are needed.
> To compile dbus-glib, dbus is needed (obviously). The only solution
> (to compile dbus with tests) is to create a new recipe where to
> compile dbus with --enable-tests --enable-embedded-tests, skip write
> to sysroot (noexec) and just package dbus-tests.
> A bash wrapper to run all tests is included.
>
> Signed-off-by: Andrei Gherzan <andrei.gherzan@windriver.com> <andrei.gherzan@windriver.com>
> ---
> meta/recipes-core/dbus/dbus-tests/run_test.sh | 22 +++++++++
> meta/recipes-core/dbus/dbus-tests_1.4.20.bb | 64 +++++++++++++++++++++++++
> 2 files changed, 86 insertions(+), 0 deletions(-)
> create mode 100755 meta/recipes-core/dbus/dbus-tests/run_test.sh
> create mode 100644 meta/recipes-core/dbus/dbus-tests_1.4.20.bb
>
> diff --git a/meta/recipes-core/dbus/dbus-tests/run_test.sh b/meta/recipes-core/dbus/dbus-tests/run_test.sh
> new file mode 100755
> index 0000000..90abad2
> --- /dev/null
> +++ b/meta/recipes-core/dbus/dbus-tests/run_test.sh
> @@ -0,0 +1,22 @@
> +#!/bin/sh
> +
> +# Tests location
> +export DBUS_TEST_HOMEDIR=/usr/lib/dbus-tests
> +# Tests data location
> +export DBUS_TEST_DATA=${DBUS_TEST_HOMEDIR}/test/data
> +
> +TESTS=" \
> + bus/bus-test \
> + bus/bus-test-system \
> + dbus/dbus-test \
> + bus/bus-test-launch-helper \
> + test/shell-test \
> + test/test-corrupt \
> + test/test-dbus-daemon \
> + test/test-loopback \
> + test/test-marshal \
> + test/test-relay \
> + test/test-syslog \
> + test/test-refs"
> +
> +${DBUS_TEST_HOMEDIR}/test/dbus-test-runner ${DBUS_TEST_HOMEDIR} ${TESTS}
> diff --git a/meta/recipes-core/dbus/dbus-tests_1.4.20.bb b/meta/recipes-core/dbus/dbus-tests_1.4.20.bb
> new file mode 100644
> index 0000000..0e7d272
> --- /dev/null
> +++ b/meta/recipes-core/dbus/dbus-tests_1.4.20.bb
> @@ -0,0 +1,64 @@
> +FILESEXTRAPATHS_append := "${THISDIR}/dbus-${PV}"
> +include recipes-core/dbus/dbus.inc
> +
> +PR = "${INC_PR}.0"
> +
> +SRC_URI[md5sum] = "79eca2f2c1894ac347acce128314428b"
> +SRC_URI[sha256sum] = "103bdcd261a13140730b5fa69f56a98ab5c89ba3f0116ea62fcfd639520d5aaf"
> +
> +DEPENDS += "python-pygobject-native python-dbus-native dbus-glib dbus"
> +RDEPENDS_${PN} = "dbus-x11"
>
> wouldn't RDEPENDS_${PN} = "dbus" be a better choice since dbus-x11 is
> RPROVIDED only for compatibility reasons?
>
>
Yes. Forgot about that. Thanks.
ag
[-- Attachment #2: Type: text/html, Size: 3538 bytes --]
^ permalink raw reply [flat|nested] 7+ messages in thread
* Re: [PATCH 2/2] dbus-tests: Add separate recipe for building dbus-tests
2012-08-17 13:02 ` [PATCH 2/2] dbus-tests: Add separate recipe for building dbus-tests Andrei Gherzan
@ 2012-08-17 13:44 ` Radu Moisan
2012-08-17 13:43 ` Andrei Gherzan
0 siblings, 1 reply; 7+ messages in thread
From: Radu Moisan @ 2012-08-17 13:44 UTC (permalink / raw)
To: openembedded-core
[-- Attachment #1: Type: text/plain, Size: 2428 bytes --]
On 08/17/2012 04:02 PM, Andrei Gherzan wrote:
> While compiling dbus with tests, dbus and dbus-glib are needed.
> To compile dbus-glib, dbus is needed (obviously). The only solution
> (to compile dbus with tests) is to create a new recipe where to
> compile dbus with --enable-tests --enable-embedded-tests, skip write
> to sysroot (noexec) and just package dbus-tests.
> A bash wrapper to run all tests is included.
>
> Signed-off-by: Andrei Gherzan <andrei.gherzan@windriver.com>
> ---
> meta/recipes-core/dbus/dbus-tests/run_test.sh | 22 +++++++++
> meta/recipes-core/dbus/dbus-tests_1.4.20.bb | 64 +++++++++++++++++++++++++
> 2 files changed, 86 insertions(+), 0 deletions(-)
> create mode 100755 meta/recipes-core/dbus/dbus-tests/run_test.sh
> create mode 100644 meta/recipes-core/dbus/dbus-tests_1.4.20.bb
>
> diff --git a/meta/recipes-core/dbus/dbus-tests/run_test.sh b/meta/recipes-core/dbus/dbus-tests/run_test.sh
> new file mode 100755
> index 0000000..90abad2
> --- /dev/null
> +++ b/meta/recipes-core/dbus/dbus-tests/run_test.sh
> @@ -0,0 +1,22 @@
> +#!/bin/sh
> +
> +# Tests location
> +export DBUS_TEST_HOMEDIR=/usr/lib/dbus-tests
> +# Tests data location
> +export DBUS_TEST_DATA=${DBUS_TEST_HOMEDIR}/test/data
> +
> +TESTS=" \
> + bus/bus-test \
> + bus/bus-test-system \
> + dbus/dbus-test \
> + bus/bus-test-launch-helper \
> + test/shell-test \
> + test/test-corrupt \
> + test/test-dbus-daemon \
> + test/test-loopback \
> + test/test-marshal \
> + test/test-relay \
> + test/test-syslog \
> + test/test-refs"
> +
> +${DBUS_TEST_HOMEDIR}/test/dbus-test-runner ${DBUS_TEST_HOMEDIR} ${TESTS}
> diff --git a/meta/recipes-core/dbus/dbus-tests_1.4.20.bb b/meta/recipes-core/dbus/dbus-tests_1.4.20.bb
> new file mode 100644
> index 0000000..0e7d272
> --- /dev/null
> +++ b/meta/recipes-core/dbus/dbus-tests_1.4.20.bb
> @@ -0,0 +1,64 @@
> +FILESEXTRAPATHS_append := "${THISDIR}/dbus-${PV}"
> +include recipes-core/dbus/dbus.inc
> +
> +PR = "${INC_PR}.0"
> +
> +SRC_URI[md5sum] = "79eca2f2c1894ac347acce128314428b"
> +SRC_URI[sha256sum] = "103bdcd261a13140730b5fa69f56a98ab5c89ba3f0116ea62fcfd639520d5aaf"
> +
> +DEPENDS += "python-pygobject-native python-dbus-native dbus-glib dbus"
> +RDEPENDS_${PN} = "dbus-x11"
wouldn't RDEPENDS_${PN} = "dbus" be a better choice since dbus-x11 is
RPROVIDED only for compatibility reasons?
radu
[-- Attachment #2: Type: text/html, Size: 2976 bytes --]
^ permalink raw reply [flat|nested] 7+ messages in thread
* Re: [PATCH 1/2] python-dbus: Native dbus python module needed for dbus tests
2012-08-17 13:09 ` Martin Jansa
@ 2012-08-17 13:55 ` Andrei Gherzan
0 siblings, 0 replies; 7+ messages in thread
From: Andrei Gherzan @ 2012-08-17 13:55 UTC (permalink / raw)
To: Patches and discussions about the oe-core layer
[-- Attachment #1: Type: text/plain, Size: 2460 bytes --]
On Fri, Aug 17, 2012 at 4:09 PM, Martin Jansa <martin.jansa@gmail.com>wrote:
> On Fri, Aug 17, 2012 at 04:05:00PM +0300, Andrei Gherzan wrote:
> > Signed-off-by: Andrei Gherzan <andrei.gherzan@windriver.com>
> > ---
> > meta/recipes-devtools/python/python-dbus_1.1.1.bb | 5 ++++-
> > 1 files changed, 4 insertions(+), 1 deletions(-)
> >
> > diff --git a/meta/recipes-devtools/python/python-dbus_1.1.1.bbb/meta/recipes-devtools/python/
> python-dbus_1.1.1.bb
> > index 51d5bc2..35149a0 100644
> > --- a/meta/recipes-devtools/python/python-dbus_1.1.1.bb
> > +++ b/meta/recipes-devtools/python/python-dbus_1.1.1.bb
> > @@ -4,7 +4,7 @@ HOMEPAGE = "http://www.freedesktop.org/Software/dbus"
> > LICENSE = "MIT"
> > LIC_FILES_CHKSUM = "file://COPYING;md5=f5612614133e9a2f2dad527d97554670"
> > DEPENDS = "expat dbus dbus-glib virtual/libintl python-pyrex-native"
> > -PR = "r0"
> > +PR = "r1"
> >
> > SRC_URI = "
> http://dbus.freedesktop.org/releases/dbus-python/dbus-python-${PV}.tar.gz"
> >
> > @@ -23,3 +23,6 @@ export STAGING_INCDIR
> > RDEPENDS_${PN} = "python-io python-logging python-stringold
> python-threading python-xml"
> >
> > FILES_${PN}-dev += "${libdir}/pkgconfig"
> > +
> > +RDEPENDS_${PN}_virtclass-native = "python"
>
> Does RDEPENDS_${PN} work for native recipes? I thought that R* vars are
> for runtime packages and native builds doesn't provide them imho.
>
> And if they do, why not explicitly ask for python-native, because target
> python wont help I guess.
>
>
The idea here was that rdepends should be overwritten as - python-io
python-logging python-stringold python-threading python-xml - are not
native packages. While compiling (python-dbus-native) build-system is
looking for python-io-native for example which wrong and fails:
ERROR: Nothing RPROVIDES 'python-io-native'
Do you think of a better solution?
Thank you
> > +BBCLASSEXTEND = "native"
> > --
> > 1.7.5.4
> >
> >
> > _______________________________________________
> > Openembedded-core mailing list
> > Openembedded-core@lists.openembedded.org
> > http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core
>
> --
> Martin 'JaMa' Jansa jabber: Martin.Jansa@gmail.com
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core
>
>
[-- Attachment #2: Type: text/html, Size: 4279 bytes --]
^ permalink raw reply [flat|nested] 7+ messages in thread
end of thread, other threads:[~2012-08-17 14:07 UTC | newest]
Thread overview: 7+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-08-17 13:02 [PATCH 0/2] Build and package dbus-tests - separate recipe Andrei Gherzan
2012-08-17 13:02 ` [PATCH 2/2] dbus-tests: Add separate recipe for building dbus-tests Andrei Gherzan
2012-08-17 13:44 ` Radu Moisan
2012-08-17 13:43 ` Andrei Gherzan
2012-08-17 13:05 ` [PATCH 1/2] python-dbus: Native dbus python module needed for dbus tests Andrei Gherzan
2012-08-17 13:09 ` Martin Jansa
2012-08-17 13:55 ` Andrei Gherzan
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox