* [PATCH V4 1/2] bluez5: new package for v5.7
2013-07-16 15:26 [PATCH V4 0/2] BlueZ 5 experimental recipes Cristian Iorga
@ 2013-07-16 15:26 ` Cristian Iorga
2013-07-16 15:26 ` [PATCH V4 2/2] bluez4: conflicts with bluez5 Cristian Iorga
` (3 subsequent siblings)
4 siblings, 0 replies; 6+ messages in thread
From: Cristian Iorga @ 2013-07-16 15:26 UTC (permalink / raw)
To: openembedded-core
- bluez5 does not replace bluez4
- bluez5 is integrated with systemd
- RCONFLICTS bluez4
- add readline dependency
Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
---
.../bluez5/bluez5-5.7/bluetooth.conf | 16 +++++
meta/recipes-connectivity/bluez5/bluez5.inc | 68 ++++++++++++++++++++
meta/recipes-connectivity/bluez5/bluez5_5.7.bb | 5 ++
3 files changed, 89 insertions(+)
create mode 100644 meta/recipes-connectivity/bluez5/bluez5-5.7/bluetooth.conf
create mode 100644 meta/recipes-connectivity/bluez5/bluez5.inc
create mode 100644 meta/recipes-connectivity/bluez5/bluez5_5.7.bb
diff --git a/meta/recipes-connectivity/bluez5/bluez5-5.7/bluetooth.conf b/meta/recipes-connectivity/bluez5/bluez5-5.7/bluetooth.conf
new file mode 100644
index 0000000..ca5e9e4
--- /dev/null
+++ b/meta/recipes-connectivity/bluez5/bluez5-5.7/bluetooth.conf
@@ -0,0 +1,16 @@
+<!-- This configuration file specifies the required security policies
+ for Bluetooth core daemon to work. -->
+
+<!DOCTYPE busconfig PUBLIC "-//freedesktop//DTD D-BUS Bus Configuration 1.0//EN"
+ "http://www.freedesktop.org/standards/dbus/1.0/busconfig.dtd">
+<busconfig>
+
+ <!-- ../system.conf have denied everything, so we just punch some holes -->
+
+ <policy context="default">
+ <allow own="org.bluez"/>
+ <allow send_destination="org.bluez"/>
+ <allow send_interface="org.bluez.Agent"/>
+ </policy>
+
+</busconfig>
diff --git a/meta/recipes-connectivity/bluez5/bluez5.inc b/meta/recipes-connectivity/bluez5/bluez5.inc
new file mode 100644
index 0000000..49113d7
--- /dev/null
+++ b/meta/recipes-connectivity/bluez5/bluez5.inc
@@ -0,0 +1,68 @@
+SUMMARY = "Linux Bluetooth Stack Userland V5"
+DESCRIPTION = "Linux Bluetooth stack V5 userland components. These include a system configurations, daemons, tools and system libraries."
+HOMEPAGE = "http://www.bluez.org"
+SECTION = "libs"
+LICENSE = "GPLv2+ & LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=12f884d2ae1ff87c09e5b7ccc2c4ca7e \
+ file://COPYING.LIB;md5=fb504b67c50331fc78734fed90fb0e09 \
+ file://src/main.c;beginline=1;endline=24;md5=9bc54b93cd7e17bf03f52513f39f926e"
+DEPENDS = "udev libusb dbus-glib glib-2.0 libcheck libical readline"
+
+RCONFLICTS_${PN} = "bluez4"
+
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)}"
+PACKAGECONFIG[alsa] = "--enable-alsa,--disable-alsa,alsa-lib"
+
+SRC_URI = "\
+ ${KERNELORG_MIRROR}/linux/bluetooth/bluez-${PV}.tar.gz \
+ file://bluetooth.conf \
+"
+S = "${WORKDIR}/bluez-${PV}"
+
+inherit autotools pkgconfig systemd
+
+EXTRA_OECONF = "\
+ --disable-gstreamer \
+ --enable-usb \
+ --enable-tools \
+ --enable-bccmd \
+ --enable-hid2hci \
+ --enable-dfutool \
+ --disable-hidd \
+ --disable-pand \
+ --disable-dund \
+ --disable-cups \
+ --enable-test \
+ --enable-datafiles \
+ ${@base_contains('DISTRO_FEATURES', 'systemd', '--with-systemdunitdir=${systemd_unitdir}/system/', '--disable-systemd', d)} \
+"
+
+do_install_append() {
+ install -d ${D}${sysconfdir}/bluetooth/
+ install -m 0644 ${S}/profiles/audio/audio.conf ${D}/${sysconfdir}/bluetooth/
+ install -m 0644 ${S}/profiles/network/network.conf ${D}/${sysconfdir}/bluetooth/
+ install -m 0644 ${S}/profiles/input/input.conf ${D}/${sysconfdir}/bluetooth/
+ # at_console doesn't really work with the current state of OE, so punch some more holes so people can actually use BT
+ install -m 0644 ${WORKDIR}/bluetooth.conf ${D}/${sysconfdir}/dbus-1/system.d/
+}
+
+ALLOW_EMPTY_libasound-module-bluez = "1"
+PACKAGES =+ "libasound-module-bluez ${PN}-test"
+
+FILES_libasound-module-bluez = "${libdir}/alsa-lib/lib*.so ${datadir}/alsa"
+FILES_${PN} += "${libdir}/bluetooth/plugins ${libdir}/bluetooth/plugins/*.so ${base_libdir}/udev/ ${nonarch_base_libdir}/udev/ ${systemd_unitdir}/ ${datadir}/dbus-1"
+FILES_${PN}-dev += "\
+ ${libdir}/bluetooth/plugins/*.la \
+ ${libdir}/alsa-lib/*.la \
+"
+
+FILES_${PN}-test = "${libdir}/bluez/test/*"
+
+FILES_${PN}-dbg += "\
+ ${libdir}/${PN}/bluetooth/.debug \
+ ${libdir}/bluetooth/plugins/.debug \
+ ${libdir}/*/.debug \
+ */udev/.debug \
+ "
+
+SYSTEMD_SERVICE_${PN} = "bluetooth.service"
diff --git a/meta/recipes-connectivity/bluez5/bluez5_5.7.bb b/meta/recipes-connectivity/bluez5/bluez5_5.7.bb
new file mode 100644
index 0000000..6e2850d
--- /dev/null
+++ b/meta/recipes-connectivity/bluez5/bluez5_5.7.bb
@@ -0,0 +1,5 @@
+require bluez5.inc
+
+SRC_URI[md5sum] = "ce0ef43938e8bfc230f3f06d6ad02d7e"
+SRC_URI[sha256sum] = "902299204b7139c913765603c7054a604570aea9e9fddb30454bd1b5e5997860"
+
--
1.7.10.4
^ permalink raw reply related [flat|nested] 6+ messages in thread* [PATCH V4 2/2] bluez4: conflicts with bluez5
2013-07-16 15:26 [PATCH V4 0/2] BlueZ 5 experimental recipes Cristian Iorga
2013-07-16 15:26 ` [PATCH V4 1/2] bluez5: new package for v5.7 Cristian Iorga
@ 2013-07-16 15:26 ` Cristian Iorga
2013-07-16 18:22 ` [PATCH V4 0/2] BlueZ 5 experimental recipes Burton, Ross
` (2 subsequent siblings)
4 siblings, 0 replies; 6+ messages in thread
From: Cristian Iorga @ 2013-07-16 15:26 UTC (permalink / raw)
To: openembedded-core
- RCONFLICTS bluez5
Signed-off-by: Cristian Iorga <cristian.iorga@intel.com>
---
meta/recipes-connectivity/bluez/bluez4_4.101.bb | 2 ++
1 file changed, 2 insertions(+)
diff --git a/meta/recipes-connectivity/bluez/bluez4_4.101.bb b/meta/recipes-connectivity/bluez/bluez4_4.101.bb
index f48adfd..7af1305 100644
--- a/meta/recipes-connectivity/bluez/bluez4_4.101.bb
+++ b/meta/recipes-connectivity/bluez/bluez4_4.101.bb
@@ -11,6 +11,8 @@ SRC_URI += "file://bluetooth.conf \
SRC_URI[md5sum] = "fb42cb7038c380eb0e2fa208987c96ad"
SRC_URI[sha256sum] = "59738410ade9f0e61a13c0f77d9aaffaafe49ba9418107e4ad75fe52846f7487"
+RCONFLICTS_${PN} = "bluez5"
+
do_install_append() {
install -m 0644 ${S}/audio/audio.conf ${D}/${sysconfdir}/bluetooth/
install -m 0644 ${S}/network/network.conf ${D}/${sysconfdir}/bluetooth/
--
1.7.10.4
^ permalink raw reply related [flat|nested] 6+ messages in thread* Re: [PATCH V4 0/2] BlueZ 5 experimental recipes
2013-07-16 15:26 [PATCH V4 0/2] BlueZ 5 experimental recipes Cristian Iorga
2013-07-16 15:26 ` [PATCH V4 1/2] bluez5: new package for v5.7 Cristian Iorga
2013-07-16 15:26 ` [PATCH V4 2/2] bluez4: conflicts with bluez5 Cristian Iorga
@ 2013-07-16 18:22 ` Burton, Ross
2013-07-17 22:29 ` Saul Wold
2013-07-18 6:08 ` Saul Wold
4 siblings, 0 replies; 6+ messages in thread
From: Burton, Ross @ 2013-07-16 18:22 UTC (permalink / raw)
To: Cristian Iorga; +Cc: openembedded-core
On 16 July 2013 16:26, Cristian Iorga <cristian.iorga@intel.com> wrote:
> This sets of patches adds bluez5 recipes as experimental packages.
> BlueZ 5.X is not an upgrade for Bluez 4.x, as such, no upgrade is
> provided/possible.
> The two versions of the BT stack also conflicts each other.
>
> In V4 RREPLACES is removed from the recipes.
>
> Cristian Iorga (2):
> bluez5: new package for v5.7
> bluez4: conflicts with bluez5
Looks good to me, thanks Cristian.
Ross
^ permalink raw reply [flat|nested] 6+ messages in thread
* Re: [PATCH V4 0/2] BlueZ 5 experimental recipes
2013-07-16 15:26 [PATCH V4 0/2] BlueZ 5 experimental recipes Cristian Iorga
` (2 preceding siblings ...)
2013-07-16 18:22 ` [PATCH V4 0/2] BlueZ 5 experimental recipes Burton, Ross
@ 2013-07-17 22:29 ` Saul Wold
2013-07-18 6:08 ` Saul Wold
4 siblings, 0 replies; 6+ messages in thread
From: Saul Wold @ 2013-07-17 22:29 UTC (permalink / raw)
To: Cristian Iorga; +Cc: openembedded-core
On 07/16/2013 08:26 AM, Cristian Iorga wrote:
> This sets of patches adds bluez5 recipes as experimental packages.
> BlueZ 5.X is not an upgrade for Bluez 4.x, as such, no upgrade is
> provided/possible.
> The two versions of the BT stack also conflicts each other.
>
> In V4 RREPLACES is removed from the recipes.
>
> Cristian Iorga (2):
> bluez5: new package for v5.7
> bluez4: conflicts with bluez5
>
> meta/recipes-connectivity/bluez/bluez4_4.101.bb | 2 +
> .../bluez5/bluez5-5.7/bluetooth.conf | 16 +++++
> meta/recipes-connectivity/bluez5/bluez5.inc | 68 ++++++++++++++++++++
> meta/recipes-connectivity/bluez5/bluez5_5.7.bb | 5 ++
> 4 files changed, 91 insertions(+)
> create mode 100644 meta/recipes-connectivity/bluez5/bluez5-5.7/bluetooth.conf
> create mode 100644 meta/recipes-connectivity/bluez5/bluez5.inc
> create mode 100644 meta/recipes-connectivity/bluez5/bluez5_5.7.bb
>
Have both recipes in a world build causes the following WARNING:
NOTE: multiple providers are available for runtime
libasound-module-bluez (bluez4, bluez5)
NOTE: consider defining a PREFERRED_PROVIDER entry to match
libasound-module-bluez
You can add a line in meta/conf/distro/include/default-providers.inc
Sau!
^ permalink raw reply [flat|nested] 6+ messages in thread* Re: [PATCH V4 0/2] BlueZ 5 experimental recipes
2013-07-16 15:26 [PATCH V4 0/2] BlueZ 5 experimental recipes Cristian Iorga
` (3 preceding siblings ...)
2013-07-17 22:29 ` Saul Wold
@ 2013-07-18 6:08 ` Saul Wold
4 siblings, 0 replies; 6+ messages in thread
From: Saul Wold @ 2013-07-18 6:08 UTC (permalink / raw)
To: Cristian Iorga; +Cc: openembedded-core
On 07/16/2013 08:26 AM, Cristian Iorga wrote:
> This sets of patches adds bluez5 recipes as experimental packages.
> BlueZ 5.X is not an upgrade for Bluez 4.x, as such, no upgrade is
> provided/possible.
> The two versions of the BT stack also conflicts each other.
>
> In V4 RREPLACES is removed from the recipes.
>
> Cristian Iorga (2):
> bluez5: new package for v5.7
> bluez4: conflicts with bluez5
>
> meta/recipes-connectivity/bluez/bluez4_4.101.bb | 2 +
> .../bluez5/bluez5-5.7/bluetooth.conf | 16 +++++
> meta/recipes-connectivity/bluez5/bluez5.inc | 68 ++++++++++++++++++++
> meta/recipes-connectivity/bluez5/bluez5_5.7.bb | 5 ++
> 4 files changed, 91 insertions(+)
> create mode 100644 meta/recipes-connectivity/bluez5/bluez5-5.7/bluetooth.conf
> create mode 100644 meta/recipes-connectivity/bluez5/bluez5.inc
> create mode 100644 meta/recipes-connectivity/bluez5/bluez5_5.7.bb
>
Looks like there is a world build failure also:
http://autobuilder.yoctoproject.org:8011/builders/nightly-world/builds/210/steps/Building%20Images/logs/stdio
Please investigate
Thanks
Sau!
^ permalink raw reply [flat|nested] 6+ messages in thread