* [PATCH V2 1/7] opkg-arch-config: Renamed from opkg-config-base
2015-01-16 22:15 [PATCH V2 0/7] opkg refactoring Paul Barker
@ 2015-01-16 22:15 ` Paul Barker
2015-01-16 22:15 ` [PATCH V2 2/7] opkg-collateral: Simplify source files Paul Barker
` (6 subsequent siblings)
7 siblings, 0 replies; 15+ messages in thread
From: Paul Barker @ 2015-01-16 22:15 UTC (permalink / raw)
To: OE Core
The name 'opkg-arch-config' is much more descriptive.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/conf/layer.conf | 2 +-
.../opkg/{opkg-config-base_1.0.bb => opkg-arch-config_1.0.bb} | 5 ++++-
meta/recipes-devtools/opkg/opkg.inc | 2 +-
3 files changed, 6 insertions(+), 3 deletions(-)
rename meta/recipes-devtools/opkg/{opkg-config-base_1.0.bb => opkg-arch-config_1.0.bb} (79%)
diff --git a/meta/conf/layer.conf b/meta/conf/layer.conf
index de96548..4fd3a16 100644
--- a/meta/conf/layer.conf
+++ b/meta/conf/layer.conf
@@ -18,7 +18,7 @@ COREBASE = '${@os.path.normpath("${LAYERDIR}/../")}'
SIGGEN_EXCLUDERECIPES_ABISAFE += " \
sysvinit-inittab \
shadow-securetty \
- opkg-config-base \
+ opkg-arch-config \
netbase \
init-ifupdown \
connman-conf \
diff --git a/meta/recipes-devtools/opkg/opkg-config-base_1.0.bb b/meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
similarity index 79%
rename from meta/recipes-devtools/opkg/opkg-config-base_1.0.bb
rename to meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
index acbe129..4540de2 100644
--- a/meta/recipes-devtools/opkg/opkg-config-base_1.0.bb
+++ b/meta/recipes-devtools/opkg/opkg-arch-config_1.0.bb
@@ -1,4 +1,4 @@
-SUMMARY = "Base configuration files for opkg"
+SUMMARY = "Architecture-dependent configuration for opkg"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
PACKAGE_ARCH = "${MACHINE_ARCH}"
@@ -28,3 +28,6 @@ FILES_${PN} = "${sysconfdir}/opkg/ "
CONFFILES_${PN} += "${sysconfdir}/opkg/arch.conf"
+RREPLACES_${PN} = "opkg-config-base"
+RCONFLICTS_${PN} = "opkg-config-base"
+RPROVIDES_${PN} = "opkg-config-base"
diff --git a/meta/recipes-devtools/opkg/opkg.inc b/meta/recipes-devtools/opkg/opkg.inc
index 56c54b6..991c114 100644
--- a/meta/recipes-devtools/opkg/opkg.inc
+++ b/meta/recipes-devtools/opkg/opkg.inc
@@ -38,7 +38,7 @@ EXTRA_OECONF = "\
--with-opkglibdir=${OPKGLIBDIR} \
"
-RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-config-base run-postinsts"
+RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config run-postinsts"
RDEPENDS_${PN}_class-native = ""
RDEPENDS_${PN}_class-nativesdk = ""
RREPLACES_${PN} = "opkg-nogpg"
--
1.9.1
^ permalink raw reply related [flat|nested] 15+ messages in thread* [PATCH V2 2/7] opkg-collateral: Simplify source files
2015-01-16 22:15 [PATCH V2 0/7] opkg refactoring Paul Barker
2015-01-16 22:15 ` [PATCH V2 1/7] opkg-arch-config: Renamed from opkg-config-base Paul Barker
@ 2015-01-16 22:15 ` Paul Barker
2015-01-16 22:15 ` [PATCH V2 3/7] opkg: Merge opkg.inc into recipe and tidy up Paul Barker
` (5 subsequent siblings)
7 siblings, 0 replies; 15+ messages in thread
From: Paul Barker @ 2015-01-16 22:15 UTC (permalink / raw)
To: OE Core
Instead of having the source files 'opkg.conf.comments', 'dest' and 'src', we
simply have one 'opkg.conf' file containing all the necessary configuration.
This does mean that replacing 'src' in a bbappend to define distro-specific
package feeds is no longer supported, but these feed configurations should be
packaged separately from the rest of the opkg configuration anyway so that
things can be updated independently. The best recipe to use for managing feed
configs is currently distro-feed-config in the meta-oe layer.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/recipes-devtools/opkg/opkg-collateral.bb | 7 +------
meta/recipes-devtools/opkg/opkg-collateral/dest | 1 -
.../opkg/opkg-collateral/{opkg.conf.comments => opkg.conf} | 2 ++
meta/recipes-devtools/opkg/opkg-collateral/src | 0
4 files changed, 3 insertions(+), 7 deletions(-)
delete mode 100644 meta/recipes-devtools/opkg/opkg-collateral/dest
rename meta/recipes-devtools/opkg/opkg-collateral/{opkg.conf.comments => opkg.conf} (92%)
delete mode 100644 meta/recipes-devtools/opkg/opkg-collateral/src
diff --git a/meta/recipes-devtools/opkg/opkg-collateral.bb b/meta/recipes-devtools/opkg/opkg-collateral.bb
index 3825ffb..b16579c 100644
--- a/meta/recipes-devtools/opkg/opkg-collateral.bb
+++ b/meta/recipes-devtools/opkg/opkg-collateral.bb
@@ -4,15 +4,10 @@ LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
PR = "r2"
-SRC_URI = "file://opkg.conf.comments \
- file://dest \
- file://src "
+SRC_URI = "file://opkg.conf"
OPKGLIBDIR = "${localstatedir}/lib"
do_compile () {
- cat ${WORKDIR}/opkg.conf.comments >${WORKDIR}/opkg.conf
- cat ${WORKDIR}/src >>${WORKDIR}/opkg.conf
- cat ${WORKDIR}/dest >>${WORKDIR}/opkg.conf
echo "option lists_dir ${OPKGLIBDIR}/opkg" >>${WORKDIR}/opkg.conf
}
diff --git a/meta/recipes-devtools/opkg/opkg-collateral/dest b/meta/recipes-devtools/opkg/opkg-collateral/dest
deleted file mode 100644
index 088ca40..0000000
--- a/meta/recipes-devtools/opkg/opkg-collateral/dest
+++ /dev/null
@@ -1 +0,0 @@
-dest root /
diff --git a/meta/recipes-devtools/opkg/opkg-collateral/opkg.conf.comments b/meta/recipes-devtools/opkg/opkg-collateral/opkg.conf
similarity index 92%
rename from meta/recipes-devtools/opkg/opkg-collateral/opkg.conf.comments
rename to meta/recipes-devtools/opkg/opkg-collateral/opkg.conf
index e1fdada..c2e9e92 100644
--- a/meta/recipes-devtools/opkg/opkg-collateral/opkg.conf.comments
+++ b/meta/recipes-devtools/opkg/opkg-collateral/opkg.conf
@@ -24,3 +24,5 @@
# Offline mode (for use in constructing flash images offline)
#option offline_root target
+# Default destination for installed packages
+dest root /
diff --git a/meta/recipes-devtools/opkg/opkg-collateral/src b/meta/recipes-devtools/opkg/opkg-collateral/src
deleted file mode 100644
index e69de29..0000000
--
1.9.1
^ permalink raw reply related [flat|nested] 15+ messages in thread* [PATCH V2 3/7] opkg: Merge opkg.inc into recipe and tidy up
2015-01-16 22:15 [PATCH V2 0/7] opkg refactoring Paul Barker
2015-01-16 22:15 ` [PATCH V2 1/7] opkg-arch-config: Renamed from opkg-config-base Paul Barker
2015-01-16 22:15 ` [PATCH V2 2/7] opkg-collateral: Simplify source files Paul Barker
@ 2015-01-16 22:15 ` Paul Barker
2015-01-16 22:15 ` [PATCH V2 4/7] opkg: Merge in opkg-collateral Paul Barker
` (4 subsequent siblings)
7 siblings, 0 replies; 15+ messages in thread
From: Paul Barker @ 2015-01-16 22:15 UTC (permalink / raw)
To: OE Core
There is no benefit to having a separate .inc file when we only support one
version of opkg.
The .inc file had multiple do_install_append functions and several variables
were defined out of the usual order. This arrangement should be better.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/recipes-devtools/opkg/opkg.inc | 76 -------------------------------
meta/recipes-devtools/opkg/opkg_0.2.4.bb | 77 +++++++++++++++++++++++++++++++-
2 files changed, 75 insertions(+), 78 deletions(-)
delete mode 100644 meta/recipes-devtools/opkg/opkg.inc
diff --git a/meta/recipes-devtools/opkg/opkg.inc b/meta/recipes-devtools/opkg/opkg.inc
deleted file mode 100644
index 991c114..0000000
--- a/meta/recipes-devtools/opkg/opkg.inc
+++ /dev/null
@@ -1,76 +0,0 @@
-SUMMARY = "Open Package Manager"
-SUMMARY_libopkg = "Open Package Manager library"
-SECTION = "base"
-HOMEPAGE = "http://code.google.com/p/opkg/"
-BUGTRACKER = "http://code.google.com/p/opkg/issues/list"
-LICENSE = "GPLv2+"
-LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
- file://src/opkg-cl.c;beginline=1;endline=20;md5=321f658c3f6b6c832e25c8850b5dffba"
-
-PE = "1"
-
-# Werror gives all kinds bounds issuses with gcc 4.3.3
-do_configure_prepend() {
- sed -i -e s:-Werror::g ${S}/libopkg/Makefile.am
-}
-
-inherit autotools pkgconfig systemd
-
-python () {
- if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
- pn = d.getVar('PN', True)
- d.setVar('SYSTEMD_SERVICE_%s' % (pn), 'opkg-configure.service')
-}
-
-target_localstatedir := "${localstatedir}"
-OPKGLIBDIR = "${target_localstatedir}/lib"
-
-PACKAGECONFIG ??= ""
-
-PACKAGECONFIG[gpg] = "--enable-gpg,--disable-gpg,gpgme libgpg-error,gnupg"
-PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl"
-PACKAGECONFIG[ssl-curl] = "--enable-ssl-curl,--disable-ssl-curl,curl openssl"
-PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
-PACKAGECONFIG[sha256] = "--enable-sha256,--disable-sha256"
-PACKAGECONFIG[pathfinder] = "--enable-pathfinder,--disable-pathfinder,pathfinder"
-
-EXTRA_OECONF = "\
- --with-opkglibdir=${OPKGLIBDIR} \
-"
-
-RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config run-postinsts"
-RDEPENDS_${PN}_class-native = ""
-RDEPENDS_${PN}_class-nativesdk = ""
-RREPLACES_${PN} = "opkg-nogpg"
-
-PACKAGES =+ "libopkg-dev libopkg-staticdev libopkg"
-
-FILES_libopkg-dev = "${libdir}/*.la ${libdir}/*.so ${includedir}/libopkg"
-FILES_libopkg-staticdev = "${libdir}/*.a"
-FILES_libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/"
-FILES_${PN} += "${systemd_unitdir}/system/"
-
-do_install_append() {
- # We need to create the lock directory
- install -d ${D}${OPKGLIBDIR}/opkg
-
- if ${@bb.utils.contains('DISTRO_FEATURES','sysvinit','false','true',d)};then
- install -d ${D}${systemd_unitdir}/system
- install -m 0644 ${WORKDIR}/opkg-configure.service ${D}${systemd_unitdir}/system/
- sed -i -e 's,@BASE_BINDIR@,${base_bindir},g' \
- -e 's,@SYSCONFDIR@,${sysconfdir},g' \
- -e 's,@BINDIR@,${bindir},g' \
- -e 's,@SYSTEMD_UNITDIR@,${systemd_unitdir},g' \
- ${D}${systemd_unitdir}/system/opkg-configure.service
- fi
-
- # The installed binary is 'opkg-cl' but people and scripts often expect
- # it to just be 'opkg'
- ln -sf opkg-cl ${D}${bindir}/opkg
-}
-
-do_install_append() {
- rm ${D}${bindir}/update-alternatives
-}
-
-BBCLASSEXTEND = "native nativesdk"
diff --git a/meta/recipes-devtools/opkg/opkg_0.2.4.bb b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
index 2cca63c..573195a 100644
--- a/meta/recipes-devtools/opkg/opkg_0.2.4.bb
+++ b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
@@ -1,13 +1,86 @@
-require opkg.inc
+SUMMARY = "Open Package Manager"
+SUMMARY_libopkg = "Open Package Manager library"
+SECTION = "base"
+HOMEPAGE = "http://code.google.com/p/opkg/"
+BUGTRACKER = "http://code.google.com/p/opkg/issues/list"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+ file://src/opkg-cl.c;beginline=1;endline=20;md5=321f658c3f6b6c832e25c8850b5dffba"
+
+PE = "1"
SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz \
file://no-install-recommends.patch \
file://add-exclude.patch \
- file://opkg-configure.service \
file://libopkg-opkg_remove.c-avoid-remove-pkg-repeatly-with.patch \
+ file://opkg-configure.service \
"
S = "${WORKDIR}/${BPN}-${PV}"
SRC_URI[md5sum] = "40ed2aee15abc8d550539449630091bd"
SRC_URI[sha256sum] = "0f40c7e457d81edf9aedc07c778f4697111ab163a38ef95999faece015453086"
+
+inherit autotools pkgconfig systemd
+
+python () {
+ if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
+ pn = d.getVar('PN', True)
+ d.setVar('SYSTEMD_SERVICE_%s' % (pn), 'opkg-configure.service')
+}
+
+target_localstatedir := "${localstatedir}"
+OPKGLIBDIR = "${target_localstatedir}/lib"
+
+PACKAGECONFIG ??= ""
+
+PACKAGECONFIG[gpg] = "--enable-gpg,--disable-gpg,gpgme libgpg-error,gnupg"
+PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl"
+PACKAGECONFIG[ssl-curl] = "--enable-ssl-curl,--disable-ssl-curl,curl openssl"
+PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
+PACKAGECONFIG[sha256] = "--enable-sha256,--disable-sha256"
+PACKAGECONFIG[pathfinder] = "--enable-pathfinder,--disable-pathfinder,pathfinder"
+
+EXTRA_OECONF = "\
+ --with-opkglibdir=${OPKGLIBDIR} \
+"
+
+# Werror gives all kinds bounds issuses with gcc 4.3.3
+do_configure_prepend() {
+ sed -i -e s:-Werror::g ${S}/libopkg/Makefile.am
+}
+
+do_install_append () {
+ # We need to create the lock directory
+ install -d ${D}${OPKGLIBDIR}/opkg
+
+ if ${@bb.utils.contains('DISTRO_FEATURES','sysvinit','false','true',d)};then
+ install -d ${D}${systemd_unitdir}/system
+ install -m 0644 ${WORKDIR}/opkg-configure.service ${D}${systemd_unitdir}/system/
+ sed -i -e 's,@BASE_BINDIR@,${base_bindir},g' \
+ -e 's,@SYSCONFDIR@,${sysconfdir},g' \
+ -e 's,@BINDIR@,${bindir},g' \
+ -e 's,@SYSTEMD_UNITDIR@,${systemd_unitdir},g' \
+ ${D}${systemd_unitdir}/system/opkg-configure.service
+ fi
+
+ # The installed binary is 'opkg-cl' but people and scripts often expect
+ # it to just be 'opkg'
+ ln -sf opkg-cl ${D}${bindir}/opkg
+
+ rm ${D}${bindir}/update-alternatives
+}
+
+RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config run-postinsts"
+RDEPENDS_${PN}_class-native = ""
+RDEPENDS_${PN}_class-nativesdk = ""
+RREPLACES_${PN} = "opkg-nogpg"
+
+PACKAGES =+ "libopkg-dev libopkg-staticdev libopkg"
+
+FILES_libopkg-dev = "${libdir}/*.la ${libdir}/*.so ${includedir}/libopkg"
+FILES_libopkg-staticdev = "${libdir}/*.a"
+FILES_libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/"
+FILES_${PN} += "${systemd_unitdir}/system/"
+
+BBCLASSEXTEND = "native nativesdk"
--
1.9.1
^ permalink raw reply related [flat|nested] 15+ messages in thread* [PATCH V2 4/7] opkg: Merge in opkg-collateral
2015-01-16 22:15 [PATCH V2 0/7] opkg refactoring Paul Barker
` (2 preceding siblings ...)
2015-01-16 22:15 ` [PATCH V2 3/7] opkg: Merge opkg.inc into recipe and tidy up Paul Barker
@ 2015-01-16 22:15 ` Paul Barker
2015-01-16 22:15 ` [PATCH V2 5/7] poky-feed-config-opkg: Remove Paul Barker
` (3 subsequent siblings)
7 siblings, 0 replies; 15+ messages in thread
From: Paul Barker @ 2015-01-16 22:15 UTC (permalink / raw)
To: OE Core
All non-arch-specific and non-distro-specific configuration is now kept in the
main 'opkg' recipe and package.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/classes/rootfs_ipk.bbclass | 2 +-
meta/recipes-devtools/opkg/opkg-collateral.bb | 19 -------------------
.../opkg/{opkg-collateral => opkg}/opkg.conf | 0
meta/recipes-devtools/opkg/opkg_0.2.4.bb | 14 +++++++++++++-
4 files changed, 14 insertions(+), 21 deletions(-)
delete mode 100644 meta/recipes-devtools/opkg/opkg-collateral.bb
rename meta/recipes-devtools/opkg/{opkg-collateral => opkg}/opkg.conf (100%)
diff --git a/meta/classes/rootfs_ipk.bbclass b/meta/classes/rootfs_ipk.bbclass
index 6139cc7..dd144e4 100644
--- a/meta/classes/rootfs_ipk.bbclass
+++ b/meta/classes/rootfs_ipk.bbclass
@@ -6,7 +6,7 @@
#
EXTRAOPKGCONFIG ?= ""
-ROOTFS_PKGMANAGE = "opkg opkg-collateral ${EXTRAOPKGCONFIG}"
+ROOTFS_PKGMANAGE = "opkg ${EXTRAOPKGCONFIG}"
ROOTFS_PKGMANAGE_BOOTSTRAP = "run-postinsts"
do_rootfs[depends] += "opkg-native:do_populate_sysroot opkg-utils-native:do_populate_sysroot"
diff --git a/meta/recipes-devtools/opkg/opkg-collateral.bb b/meta/recipes-devtools/opkg/opkg-collateral.bb
deleted file mode 100644
index b16579c..0000000
--- a/meta/recipes-devtools/opkg/opkg-collateral.bb
+++ /dev/null
@@ -1,19 +0,0 @@
-SUMMARY = "Constructs the main configuration file for opkg"
-SECTION = "base"
-LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
-PR = "r2"
-
-SRC_URI = "file://opkg.conf"
-
-OPKGLIBDIR = "${localstatedir}/lib"
-do_compile () {
- echo "option lists_dir ${OPKGLIBDIR}/opkg" >>${WORKDIR}/opkg.conf
-}
-
-do_install () {
- install -d ${D}${sysconfdir}/opkg
- install -m 0644 ${WORKDIR}/opkg.conf ${D}${sysconfdir}/opkg/opkg.conf
-}
-
-CONFFILES_${PN} = "${sysconfdir}/opkg/opkg.conf"
diff --git a/meta/recipes-devtools/opkg/opkg-collateral/opkg.conf b/meta/recipes-devtools/opkg/opkg/opkg.conf
similarity index 100%
rename from meta/recipes-devtools/opkg/opkg-collateral/opkg.conf
rename to meta/recipes-devtools/opkg/opkg/opkg.conf
diff --git a/meta/recipes-devtools/opkg/opkg_0.2.4.bb b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
index 573195a..0369089 100644
--- a/meta/recipes-devtools/opkg/opkg_0.2.4.bb
+++ b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
@@ -14,6 +14,7 @@ SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz
file://add-exclude.patch \
file://libopkg-opkg_remove.c-avoid-remove-pkg-repeatly-with.patch \
file://opkg-configure.service \
+ file://opkg.conf \
"
S = "${WORKDIR}/${BPN}-${PV}"
@@ -50,7 +51,14 @@ do_configure_prepend() {
sed -i -e s:-Werror::g ${S}/libopkg/Makefile.am
}
+do_compile_append () {
+ echo "option lists_dir ${OPKGLIBDIR}/opkg" >>${WORKDIR}/opkg.conf
+}
+
do_install_append () {
+ install -d ${D}${sysconfdir}/opkg
+ install -m 0644 ${WORKDIR}/opkg.conf ${D}${sysconfdir}/opkg/opkg.conf
+
# We need to create the lock directory
install -d ${D}${OPKGLIBDIR}/opkg
@@ -74,7 +82,9 @@ do_install_append () {
RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config run-postinsts"
RDEPENDS_${PN}_class-native = ""
RDEPENDS_${PN}_class-nativesdk = ""
-RREPLACES_${PN} = "opkg-nogpg"
+RREPLACES_${PN} = "opkg-nogpg opkg-collateral"
+RCONFLICTS_${PN} = "opkg-collateral"
+RPROVIDES_${PN} = "opkg-collateral"
PACKAGES =+ "libopkg-dev libopkg-staticdev libopkg"
@@ -84,3 +94,5 @@ FILES_libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/"
FILES_${PN} += "${systemd_unitdir}/system/"
BBCLASSEXTEND = "native nativesdk"
+
+CONFFILES_${PN} = "${sysconfdir}/opkg/opkg.conf"
--
1.9.1
^ permalink raw reply related [flat|nested] 15+ messages in thread* [PATCH V2 5/7] poky-feed-config-opkg: Remove
2015-01-16 22:15 [PATCH V2 0/7] opkg refactoring Paul Barker
` (3 preceding siblings ...)
2015-01-16 22:15 ` [PATCH V2 4/7] opkg: Merge in opkg-collateral Paul Barker
@ 2015-01-16 22:15 ` Paul Barker
2015-01-16 22:15 ` [PATCH V2 6/7] opkg: Backport improvements to opkg-key Paul Barker
` (2 subsequent siblings)
7 siblings, 0 replies; 15+ messages in thread
From: Paul Barker @ 2015-01-16 22:15 UTC (permalink / raw)
To: OE Core
This recipe was not usable as-is. A much better way of configuring package feeds
for opkg is provided by the distro-feed-config recipe in meta-oe.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
.../feed-config/poky-feed-config-opkg_1.0.bb | 44 ----------------------
1 file changed, 44 deletions(-)
delete mode 100644 meta/recipes-core/feed-config/poky-feed-config-opkg_1.0.bb
diff --git a/meta/recipes-core/feed-config/poky-feed-config-opkg_1.0.bb b/meta/recipes-core/feed-config/poky-feed-config-opkg_1.0.bb
deleted file mode 100644
index fb312f8..0000000
--- a/meta/recipes-core/feed-config/poky-feed-config-opkg_1.0.bb
+++ /dev/null
@@ -1,44 +0,0 @@
-SUMMARY = "Poky example feed configuration"
-LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
-PR = "r2"
-PACKAGE_ARCH = "${MACHINE_ARCH}"
-INHIBIT_DEFAULT_DEPS = "1"
-
-#FEEDNAMEPREFIX ?= "INVALID"
-#FEEDURIPREFIX ?= "INVALID"
-
-do_compile() {
- mkdir -p ${S}/${sysconfdir}/opkg/
-
- archconf=${S}/${sysconfdir}/opkg/arch.conf
-
- rm -f $archconf
- ipkgarchs="${ALL_MULTILIB_PACKAGE_ARCHS}"
- priority=1
- for arch in $ipkgarchs; do
- echo "arch $arch $priority" >> $archconf
- priority=$(expr $priority + 5)
- done
-
- basefeedconf=${S}/${sysconfdir}/opkg/base-feeds.conf
-
- rm -f $basefeedconf
- touch $basefeedconf
-
- #for arch in $ipkgarchs; do
- # echo "src/gz ${FEEDNAMEPREFIX}-$arch http://pokylinux.org/${FEEDURIPREFIX}$arch" >> $basefeedconf
- #done
-}
-
-
-do_install () {
- install -d ${D}${sysconfdir}/opkg
- install -m 0644 ${S}/${sysconfdir}/opkg/* ${D}${sysconfdir}/opkg/
-}
-
-FILES_${PN} = "${sysconfdir}/opkg/ "
-
-CONFFILES_${PN} += "${sysconfdir}/opkg/base-feeds.conf \
- ${sysconfdir}/opkg/arch.conf"
-
--
1.9.1
^ permalink raw reply related [flat|nested] 15+ messages in thread* [PATCH V2 6/7] opkg: Backport improvements to opkg-key
2015-01-16 22:15 [PATCH V2 0/7] opkg refactoring Paul Barker
` (4 preceding siblings ...)
2015-01-16 22:15 ` [PATCH V2 5/7] poky-feed-config-opkg: Remove Paul Barker
@ 2015-01-16 22:15 ` Paul Barker
2015-01-16 22:15 ` [PATCH V2 7/7] opkg-keyrings: New recipe Paul Barker
2015-02-07 10:47 ` opkg refactoring Peter Urbanec
7 siblings, 0 replies; 15+ messages in thread
From: Paul Barker @ 2015-01-16 22:15 UTC (permalink / raw)
To: OE Core
The improvements to opkg-key made for v0.3.0 are backported. The rest of v0.3.0
needs further testing and bugfixing prior to release, but the improvements to
opkg-key have been tested and work well.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
.../opkg/0001-opkg-key-Backport-improvements.patch | 78 ++++++++++++++++++++++
meta/recipes-devtools/opkg/opkg_0.2.4.bb | 1 +
2 files changed, 79 insertions(+)
create mode 100644 meta/recipes-devtools/opkg/opkg/0001-opkg-key-Backport-improvements.patch
diff --git a/meta/recipes-devtools/opkg/opkg/0001-opkg-key-Backport-improvements.patch b/meta/recipes-devtools/opkg/opkg/0001-opkg-key-Backport-improvements.patch
new file mode 100644
index 0000000..ae319ce
--- /dev/null
+++ b/meta/recipes-devtools/opkg/opkg/0001-opkg-key-Backport-improvements.patch
@@ -0,0 +1,78 @@
+From 87bec8300a1122829b2ed565db7da5bacfa88919 Mon Sep 17 00:00:00 2001
+From: Paul Barker <paul@paulbarker.me.uk>
+Date: Sun, 12 Oct 2014 09:59:53 +0000
+Subject: [PATCH] opkg-key: Backport improvements
+
+The improvements to opkg-key made for v0.3.0 are backported. The rest of v0.3.0
+needs further testing and bugfixing prior to release, but the improvements to
+opkg-key have been tested and work well.
+
+ 1) opkg-key: Add 'reset' option
+
+ This option removes the keyrings used to verify package signatures,
+ effectively resetting opkg to the initial state where it recognises no
+ keys.
+
+ 2) opkg-key: Add 'populate' option
+
+ This option causes all keyrings in /usr/share/opkg/keyrings to be
+ imported. Thus distributions may install their keys into this directory
+ and use 'opkg-key populate' to ensure the correct keys are loaded.
+
+ 3) opkg-key: Improve usage output
+
+Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
+Upstream-status: Backport
+---
+ utils/opkg-key | 26 ++++++++++++++++++++++----
+ 1 file changed, 22 insertions(+), 4 deletions(-)
+
+diff --git a/utils/opkg-key b/utils/opkg-key
+index 266bb66..085f1e8 100755
+--- a/utils/opkg-key
++++ b/utils/opkg-key
+@@ -10,12 +10,17 @@ usage() {
+ echo
+ echo "Manage opkg's list of trusted keys"
+ echo
+- echo " opkg-key add <file> - add the key contained in <file> ('-' for stdin)"
+- echo " opkg-key del <keyid> - remove the key <keyid>"
+- echo " opkg-key list - list keys"
++ echo "Commands and arguments:"
++ echo " add <file> - Add the key contained in <file> ('-' for stdin)"
++ echo " del <keyid> - Remove the key <keyid>"
++ echo " list - List keys"
++ echo " fingerprint - List keys with fingerprints"
++ echo " reset - Remove all keys, resetting the keyring"
++ echo " populate - Import keys from /usr/share/opkg/keyrings"
++ echo " help - Print this usage message and exit"
+ echo
+ echo "Options:"
+- echo " -o <root> Use <root> as the offline root directory"
++ echo " -o <root> - Use <root> as the offline root directory"
+ echo
+ }
+
+@@ -64,6 +69,19 @@ case "$command" in
+ echo "Executing: $GPG $*"
+ $GPG $*
+ ;;
++ reset)
++ rm -f $ROOT/etc/opkg/trusted.gpg $ROOT/etc/opkg/trusted.gpg~
++ rm -f $ROOT/etc/opkg/secring.gpg $ROOT/etc/opkg/secring.gpg~
++ rm -f $ROOT/etc/opkg/trustdb.gpg $ROOT/etc/opkg/trustdb.gpg~
++ echo "OK"
++ ;;
++ populate)
++ for f in $ROOT/usr/share/opkg/keyrings/*.gpg; do
++ echo "Importing keys from '`basename $f`'..."
++ $GPG --quiet --batch --import "$f"
++ done
++ echo "OK"
++ ;;
+ help)
+ usage
+ ;;
+--
+1.9.1
+
diff --git a/meta/recipes-devtools/opkg/opkg_0.2.4.bb b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
index 0369089..f6a971b 100644
--- a/meta/recipes-devtools/opkg/opkg_0.2.4.bb
+++ b/meta/recipes-devtools/opkg/opkg_0.2.4.bb
@@ -15,6 +15,7 @@ SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz
file://libopkg-opkg_remove.c-avoid-remove-pkg-repeatly-with.patch \
file://opkg-configure.service \
file://opkg.conf \
+ file://0001-opkg-key-Backport-improvements.patch \
"
S = "${WORKDIR}/${BPN}-${PV}"
--
1.9.1
^ permalink raw reply related [flat|nested] 15+ messages in thread* [PATCH V2 7/7] opkg-keyrings: New recipe
2015-01-16 22:15 [PATCH V2 0/7] opkg refactoring Paul Barker
` (5 preceding siblings ...)
2015-01-16 22:15 ` [PATCH V2 6/7] opkg: Backport improvements to opkg-key Paul Barker
@ 2015-01-16 22:15 ` Paul Barker
2015-02-11 0:43 ` Richard Tollerton
2015-02-07 10:47 ` opkg refactoring Peter Urbanec
7 siblings, 1 reply; 15+ messages in thread
From: Paul Barker @ 2015-01-16 22:15 UTC (permalink / raw)
To: OE Core
This recipe wraps package and package feed verification keys into a package,
making the management and deployment of verification keys much easier. Comments
on how to select keys for inclusion in this package are provided in the recipe
file.
Signed-off-by: Paul Barker <paul@paulbarker.me.uk>
---
meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb | 48 +++++++++++++++++++++++++
1 file changed, 48 insertions(+)
create mode 100644 meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb
diff --git a/meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb b/meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb
new file mode 100644
index 0000000..18d6abd
--- /dev/null
+++ b/meta/recipes-devtools/opkg/opkg-keyrings_1.0.bb
@@ -0,0 +1,48 @@
+SUMMARY = "Keyrings for verifying opkg packages and feeds"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+# Distro-specific keys can be added to this package in two ways:
+#
+# 1) In a .bbappend, add .gpg and/or .asc files to SRC_URI and install them to
+# ${D}${datadir}/opkg/keyrings/ in a do_install_append function. These
+# files should not be named 'key-$name.gpg' to ensure they don't conflict
+# with keys exported as per (2).
+#
+# 2) In a .bbappend, distro config or local.conf, override the variable
+# OPKG_KEYRING_KEYS to contain a space-separated list of key names. For
+# each name, 'gpg --export $name' will be ran to export the public key to a
+# file named 'key-$name.gpg'. The public key must therefore be in the gpg
+# keyrings on the build machine.
+
+OPKG_KEYRING_KEYS ?= ""
+
+do_compile() {
+ for name in ${OPKG_KEYRING_KEYS}; do
+ gpg --export ${name} > ${B}/key-${name}.gpg
+ done
+}
+
+do_install () {
+ install -d ${D}${datadir}/opkg/keyrings/
+ for name in ${OPKG_KEYRING_KEYS}; do
+ install -m 0644 ${B}/key-${name}.gpg ${D}${datadir}/opkg/keyrings/
+ done
+}
+
+FILES_${PN} = "${datadir}/opkg/keyrings"
+
+# We need 'opkg-key' to run the postinst script
+RDEPENDS_${PN} = "opkg"
+
+pkg_postinst_${PN} () {
+#! /bin/sh
+set -e
+
+if [ x"$D" = "x" ]; then
+ # On target
+ opkg-key populate
+else
+ exit 1
+fi
+}
--
1.9.1
^ permalink raw reply related [flat|nested] 15+ messages in thread* Re: [PATCH V2 7/7] opkg-keyrings: New recipe
2015-01-16 22:15 ` [PATCH V2 7/7] opkg-keyrings: New recipe Paul Barker
@ 2015-02-11 0:43 ` Richard Tollerton
2015-02-11 8:14 ` Paul Barker
0 siblings, 1 reply; 15+ messages in thread
From: Richard Tollerton @ 2015-02-11 0:43 UTC (permalink / raw)
To: Paul Barker; +Cc: OE Core
Paul Barker <paul@paulbarker.me.uk> writes:
> This recipe wraps package and package feed verification keys into a package,
> making the management and deployment of verification keys much easier. Comments
> on how to select keys for inclusion in this package are provided in the recipe
> file.
Would you be receptive to this package being extended to support OpenSSL
keys?
^ permalink raw reply [flat|nested] 15+ messages in thread
* Re: [PATCH V2 7/7] opkg-keyrings: New recipe
2015-02-11 0:43 ` Richard Tollerton
@ 2015-02-11 8:14 ` Paul Barker
2015-02-11 22:49 ` Richard Tollerton
0 siblings, 1 reply; 15+ messages in thread
From: Paul Barker @ 2015-02-11 8:14 UTC (permalink / raw)
To: Richard Tollerton; +Cc: OE Core
[-- Attachment #1: Type: text/plain, Size: 1017 bytes --]
On Tue, Feb 10, 2015 at 06:43:34PM -0600, Richard Tollerton wrote:
> Paul Barker <paul@paulbarker.me.uk> writes:
>
> > This recipe wraps package and package feed verification keys into a package,
> > making the management and deployment of verification keys much easier. Comments
> > on how to select keys for inclusion in this package are provided in the recipe
> > file.
>
> Would you be receptive to this package being extended to support OpenSSL
> keys?
I wouldn't advise it.
There is no 'OpenSSL exception' in the opkg license and so a few people have
been worried that shipping binaries of opkg linked against OpenSSL is a breach
of the respective licenses. IANAL, but people have been concerned.
OpenSSL support is probably less tested than gpg support as well.
However, if it's something you're already using, have tested and are comfortable
with the licensing implications then go for it.
Thanks,
--
Paul Barker
Email: paul@paulbarker.me.uk
http://www.paulbarker.me.uk
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 501 bytes --]
^ permalink raw reply [flat|nested] 15+ messages in thread
* Re: [PATCH V2 7/7] opkg-keyrings: New recipe
2015-02-11 8:14 ` Paul Barker
@ 2015-02-11 22:49 ` Richard Tollerton
0 siblings, 0 replies; 15+ messages in thread
From: Richard Tollerton @ 2015-02-11 22:49 UTC (permalink / raw)
To: Paul Barker; +Cc: OE Core
Paul Barker <paul@paulbarker.me.uk> writes:
> On Tue, Feb 10, 2015 at 06:43:34PM -0600, Richard Tollerton wrote:
>> Paul Barker <paul@paulbarker.me.uk> writes:
>>
>> > This recipe wraps package and package feed verification keys into a package,
>> > making the management and deployment of verification keys much easier. Comments
>> > on how to select keys for inclusion in this package are provided in the recipe
>> > file.
>>
>> Would you be receptive to this package being extended to support OpenSSL
>> keys?
>
> I wouldn't advise it.
>
> There is no 'OpenSSL exception' in the opkg license and so a few people have
> been worried that shipping binaries of opkg linked against OpenSSL is a breach
> of the respective licenses. IANAL, but people have been concerned.
Do you recall if this is specifically because OpenSSL is statically
linked into libopkg? (Why is that done, anyway?)
> OpenSSL support is probably less tested than gpg support as well.
>
> However, if it's something you're already using, have tested and are comfortable
> with the licensing implications then go for it.
Meh. We've got some existing OpenSSL infrastructure for other operating
systems, so we were kinda sliding into an OpenSSL-based opkg setup by
sheer inertia. But if gnupg is going to align better with everybody else
long term, it's not too late to change directions.
^ permalink raw reply [flat|nested] 15+ messages in thread
* Re: opkg refactoring
2015-01-16 22:15 [PATCH V2 0/7] opkg refactoring Paul Barker
` (6 preceding siblings ...)
2015-01-16 22:15 ` [PATCH V2 7/7] opkg-keyrings: New recipe Paul Barker
@ 2015-02-07 10:47 ` Peter Urbanec
2015-02-07 11:55 ` Paul Barker
7 siblings, 1 reply; 15+ messages in thread
From: Peter Urbanec @ 2015-02-07 10:47 UTC (permalink / raw)
To: Paul Barker, OE Core
On 17/01/15 09:15, Paul Barker wrote:
> All these changes work locally in qemuarm and the on-target upgrade path is
> mostly clean. opkg-collateral does get left behind on the target filesystem
> after an upgrade but it's effectively an empty package. I don't think this
> poses any problems.
>
> V2 changes:
> - Add RCONFLICTS and RPROVIDES where RREPLACES is specified
>
> - opkg-collateral is no longer left behind on the target filesystem after an
> upgrade.
I'm running into problems on a few thousand deployed systems where opkg upgrades are "stuck".
I see this:
root@beyonwizt4:~# opkg list-upgradable
opkg-collateral - 1.0-r2 - 1:0.2.4-r0
root@beyonwizt4:~# opkg upgrade
Multiple replacers for opkg-config-base, using first one (opkg-arch-config).
Multiple replacers for opkg-config-base, using first one (opkg-arch-config).
Package opkg is already installed on root.
root@beyonwizt4:~# opkg status opkg-config-base
root@beyonwizt4:~# opkg status opkg-arch-config
Package: opkg-arch-config
Version: 1.0-r1
Provides: opkg-config-base
Replaces: opkg-config-base
Conflicts: opkg-config-base
Status: install ok installed
Architecture: beyonwizt4
Conffiles:
/etc/opkg/arch.conf 913f790674d06e2bd0c2a45971fe7002
Installed-Time: 1423281805
root@beyonwizt4:~# opkg status opkg
Package: opkg
Version: 1:0.2.4-r0
Depends: opkg-config-base, update-alternatives-opkg, libopkg1 (>= 0.2.4), run-postinsts, libc6 (>= 2.20)
Provides: opkg-collateral
Replaces: opkg-nogpg
Conflicts: opkg-collateral
Status: install user installed
Architecture: mips32el
Installed-Time: 1422327765
Unfortunately the user visible interface to opkg is limited to an option that will run "opkg update ; opkg upgrade".
I know I can clean up manually by running "opkg remove opkg-collateral". Any ideas on how to get this cleaned up automatically?
Thanks,
Peter
^ permalink raw reply [flat|nested] 15+ messages in thread* Re: opkg refactoring
2015-02-07 10:47 ` opkg refactoring Peter Urbanec
@ 2015-02-07 11:55 ` Paul Barker
2015-02-07 14:10 ` Peter Urbanec
2015-02-08 16:14 ` Mike Looijmans
0 siblings, 2 replies; 15+ messages in thread
From: Paul Barker @ 2015-02-07 11:55 UTC (permalink / raw)
To: Peter Urbanec; +Cc: OE Core
[-- Attachment #1: Type: text/plain, Size: 3331 bytes --]
On Sat, Feb 07, 2015 at 09:47:32PM +1100, Peter Urbanec wrote:
> On 17/01/15 09:15, Paul Barker wrote:
> > All these changes work locally in qemuarm and the on-target upgrade path is
> > mostly clean. opkg-collateral does get left behind on the target filesystem
> > after an upgrade but it's effectively an empty package. I don't think this
> > poses any problems.
> >
> > V2 changes:
> > - Add RCONFLICTS and RPROVIDES where RREPLACES is specified
> >
> > - opkg-collateral is no longer left behind on the target filesystem after an
> > upgrade.
>
> I'm running into problems on a few thousand deployed systems where opkg upgrades are "stuck".
>
> I see this:
>
> root@beyonwizt4:~# opkg list-upgradable
> opkg-collateral - 1.0-r2 - 1:0.2.4-r0
>
> root@beyonwizt4:~# opkg upgrade
> Multiple replacers for opkg-config-base, using first one (opkg-arch-config).
> Multiple replacers for opkg-config-base, using first one (opkg-arch-config).
> Package opkg is already installed on root.
>
> root@beyonwizt4:~# opkg status opkg-config-base
>
> root@beyonwizt4:~# opkg status opkg-arch-config
> Package: opkg-arch-config
> Version: 1.0-r1
> Provides: opkg-config-base
> Replaces: opkg-config-base
> Conflicts: opkg-config-base
> Status: install ok installed
> Architecture: beyonwizt4
> Conffiles:
> /etc/opkg/arch.conf 913f790674d06e2bd0c2a45971fe7002
> Installed-Time: 1423281805
>
> root@beyonwizt4:~# opkg status opkg
> Package: opkg
> Version: 1:0.2.4-r0
> Depends: opkg-config-base, update-alternatives-opkg, libopkg1 (>= 0.2.4), run-postinsts, libc6 (>= 2.20)
> Provides: opkg-collateral
> Replaces: opkg-nogpg
> Conflicts: opkg-collateral
> Status: install user installed
> Architecture: mips32el
> Installed-Time: 1422327765
>
> Unfortunately the user visible interface to opkg is limited to an option that will run "opkg update ; opkg upgrade".
>
> I know I can clean up manually by running "opkg remove opkg-collateral". Any ideas on how to get this cleaned up automatically?
>
> Thanks,
>
> Peter
>
I didn't realise people were following oe-core master on deployments of a few
thousand systems! This is definitely a use-case for the stable branches.
Are you just seeing opkg-collateral left behind or are you seeing some other
upgrades "stuck"?
"opkg status opkg" should show that opkg now replaces opkg-collateral. As it is
it's only showing provides and conflicts. In commit e8879cd, RREPLACES is
modified to include opkg-collateral but that doesn't seem to have been
propagated to the opkg package on your devices. If we can fix this you should be
able to 'opkg upgrade' again and have the replacement properly handled.
Could you check whether "Replaces" for opkg includes opkg-collateral in your
"Packages" file? And could you also check whether RREPLACES in
"meta/recipes-devtools/opkg/opkg_0.2.4.bb" includes opkg-collateral? That should
narrow down where the error is introduced.
I'm also surprised your opkg version is "1:0.2.4-r0". Are you using the PR
Service to ensure that version numbers increase each time a package is rebuilt?
If not, this could contribute to the issue you're seeing.
Thanks,
--
Paul Barker
Email: paul@paulbarker.me.uk
http://www.paulbarker.me.uk
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 501 bytes --]
^ permalink raw reply [flat|nested] 15+ messages in thread
* Re: opkg refactoring
2015-02-07 11:55 ` Paul Barker
@ 2015-02-07 14:10 ` Peter Urbanec
2015-02-08 16:14 ` Mike Looijmans
1 sibling, 0 replies; 15+ messages in thread
From: Peter Urbanec @ 2015-02-07 14:10 UTC (permalink / raw)
To: Paul Barker; +Cc: OE Core
On 07/02/15 22:55, Paul Barker wrote:
> I didn't realise people were following oe-core master on deployments of a few
> thousand systems! This is definitely a use-case for the stable branches.
The deployed systems are currently on:
opkg mips32el 1:0.2.2-r0
opkg-collateral mips32el 1.0-r2
opkg-config-base beyonwizt4 1.0-r3
I'm currently testing a beta based on oe-core master. The info I have shown in the previous post is the state after I tried to apply my current beta release.
> Are you just seeing opkg-collateral left behind or are you seeing some other
> upgrades "stuck"?
So far I have only noticed this with the opkg packages.
> "opkg status opkg" should show that opkg now replaces opkg-collateral. As it is
> it's only showing provides and conflicts. In commit e8879cd, RREPLACES is
> modified to include opkg-collateral but that doesn't seem to have been
> propagated to the opkg package on your devices. If we can fix this you should be
> able to 'opkg upgrade' again and have the replacement properly handled.
The package on the test system does not have the correct replaces entries.
> Could you check whether "Replaces" for opkg includes opkg-collateral in your
> "Packages" file? And could you also check whether RREPLACES in
> "meta/recipes-devtools/opkg/opkg_0.2.4.bb" includes opkg-collateral? That should
> narrow down where the error is introduced.
The .bb file is correct, but I think you may have figured out the problem in the next paragraph.
> I'm also surprised your opkg version is "1:0.2.4-r0". Are you using the PR
> Service to ensure that version numbers increase each time a package is rebuilt?
> If not, this could contribute to the issue you're seeing.
I had PRSERV_HOST = "localhost:0" in the configuration, but it looks like a colleague has commented out that entry at some stage for some unknown reason. He also added some code to delete the manifests for images. :-( - I need to talk to him!
Maybe it would be helpful to enhance the PRServer check logic and not only print a NOTE: with the details when PRServer is started, but when there is no PRServer configured, print a *WARNING:* line to let the user know that they might run into all sorts of issues without PRServer.
In summary, it looks like the problem boils down to a stale package due to lack of PR service. I'll test that soon - I just have to rebuild everything.
Thanks very much for your help.
Peter
^ permalink raw reply [flat|nested] 15+ messages in thread
* Re: opkg refactoring
2015-02-07 11:55 ` Paul Barker
2015-02-07 14:10 ` Peter Urbanec
@ 2015-02-08 16:14 ` Mike Looijmans
1 sibling, 0 replies; 15+ messages in thread
From: Mike Looijmans @ 2015-02-08 16:14 UTC (permalink / raw)
To: openembedded-core
> I didn't realise people were following oe-core master on deployments of a few
> thousand systems! This is definitely a use-case for the stable branches.
In that case I have some interesting information for you. OpenPLi also
follows 'master' (because for many things we need the bleeding edge new
stuff). OpenPLi and its derivatives are being used on millions of settop
boxes. Just the "feed" servers consume about 4 terabytes of traffic each
month.
--
Mike Looijmans
^ permalink raw reply [flat|nested] 15+ messages in thread