[PATCH 0/5] tuning support for 1st and 2nd generation Intel Atom CPUs

[PATCH 0/5] tuning support for 1st and 2nd generation Intel Atom CPUs

[Andre McCurdy]

Andre McCurdy (5):
  tune-corei7.inc: fix PACKAGE_EXTRA_ARCHS_tune-corei7-32 typo
  tune-bonnell.inc: support for first generation Intel Atom CPUs
  tune-silvermont.inc: support for second generation Intel Atom CPUs
  tune-atom.inc: include tune-bonnell.inc instead of tune-core2.inc
  tune-corei7.inc: update comments regarding Silvermont support

 meta/conf/machine/include/tune-atom.inc       |  4 +--
 meta/conf/machine/include/tune-bonnell.inc    | 35 ++++++++++++++++++++++++++
 meta/conf/machine/include/tune-corei7.inc     |  6 ++---
 meta/conf/machine/include/tune-silvermont.inc | 36 +++++++++++++++++++++++++++
 4 files changed, 76 insertions(+), 5 deletions(-)
 create mode 100644 meta/conf/machine/include/tune-bonnell.inc
 create mode 100644 meta/conf/machine/include/tune-silvermont.inc

-- 
1.9.1

[PATCH 1/5] tune-corei7.inc: fix PACKAGE_EXTRA_ARCHS_tune-corei7-32 typo

[Andre McCurdy]

Signed-off-by: Andre McCurdy <armccurdy@gmail.com>
---
 meta/conf/machine/include/tune-corei7.inc | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/conf/machine/include/tune-corei7.inc b/meta/conf/machine/include/tune-corei7.inc
index 42cf932..bea652f 100644
--- a/meta/conf/machine/include/tune-corei7.inc
+++ b/meta/conf/machine/include/tune-corei7.inc
@@ -20,7 +20,7 @@ AVAILTUNES += "corei7-32"
 TUNE_FEATURES_tune-corei7-32 = "${TUNE_FEATURES_tune-x86} corei7"
 BASE_LIB_tune-corei7-32 = "lib"
 TUNE_PKGARCH_tune-corei7-32 = "corei7-32"
-PACKAGE_EXTRA_ARCHS_tune-corei7-32 = "${PACKAGE_EXTRA_ARCHS_tune-core2} corei7-32"
+PACKAGE_EXTRA_ARCHS_tune-corei7-32 = "${PACKAGE_EXTRA_ARCHS_tune-core2-32} corei7-32"
 
 AVAILTUNES += "corei7-64"
 TUNE_FEATURES_tune-corei7-64 = "${TUNE_FEATURES_tune-x86-64} corei7"
-- 
1.9.1

[PATCH 2/5] tune-bonnell.inc: support for first generation Intel Atom CPUs

[Andre McCurdy]

Signed-off-by: Andre McCurdy <armccurdy@gmail.com>
---
 meta/conf/machine/include/tune-bonnell.inc | 35 ++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)
 create mode 100644 meta/conf/machine/include/tune-bonnell.inc

diff --git a/meta/conf/machine/include/tune-bonnell.inc b/meta/conf/machine/include/tune-bonnell.inc
new file mode 100644
index 0000000..f6d92dc
--- /dev/null
+++ b/meta/conf/machine/include/tune-bonnell.inc
@@ -0,0 +1,35 @@
+# Settings for the GCC(1) cpu-type "bonnell":
+#
+#      Intel Bonnell CPU with 64-bit extensions, MOVBE, MMX, SSE, SSE2, SSE3
+#      and SSSE3 instruction set support. 
+#
+# This tune is recommended for the processors based on the first generation
+# Bonnell (45nm) and Saltwell (32nm) Intel Atom CPUs.
+#
+DEFAULTTUNE ?= "bonnell-32"
+
+# Include the previous tune to pull in PACKAGE_EXTRA_ARCHS
+require conf/machine/include/tune-core2.inc
+
+# Extra tune features
+TUNEVALID[bonnell] = "Enable bonnell specific processor optimizations"
+TUNE_CCARGS .= "${@bb.utils.contains("TUNE_FEATURES", "bonnell", " -march=bonnell -mtune=bonnell -msse3 -mfpmath=sse", "", d)}"
+
+# Extra tune selections
+AVAILTUNES += "bonnell-32"
+TUNE_FEATURES_tune-bonnell-32 = "${TUNE_FEATURES_tune-x86} bonnell"
+BASE_LIB_tune-bonnell-32 = "lib"
+TUNE_PKGARCH_tune-bonnell-32 = "bonnell-32"
+PACKAGE_EXTRA_ARCHS_tune-bonnell-32 = "${PACKAGE_EXTRA_ARCHS_tune-core2-32} bonnell-32"
+
+AVAILTUNES += "bonnell-64"
+TUNE_FEATURES_tune-bonnell-64 = "${TUNE_FEATURES_tune-x86-64} bonnell"
+BASE_LIB_tune-bonnell-64 = "lib64"
+TUNE_PKGARCH_tune-bonnell-64 = "bonnell-64"
+PACKAGE_EXTRA_ARCHS_tune-bonnell-64 = "${PACKAGE_EXTRA_ARCHS_tune-core2-64} bonnell-64"
+
+AVAILTUNES += "bonnell-64-x32"
+TUNE_FEATURES_tune-bonnell-64-x32 = "${TUNE_FEATURES_tune-x86-64-x32} bonnell"
+BASE_LIB_tune-bonnell-64-x32 = "libx32"
+TUNE_PKGARCH_tune-bonnell-64-x32 = "bonnell-64-x32"
+PACKAGE_EXTRA_ARCHS_tune-bonnell-64-x32 = "${PACKAGE_EXTRA_ARCHS_tune-core2-64-x32} bonnell-64-x32"
-- 
1.9.1

[PATCH 3/5] tune-silvermont.inc: support for second generation Intel Atom CPUs

[Andre McCurdy]

Signed-off-by: Andre McCurdy <armccurdy@gmail.com>
---
 meta/conf/machine/include/tune-silvermont.inc | 36 +++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)
 create mode 100644 meta/conf/machine/include/tune-silvermont.inc

diff --git a/meta/conf/machine/include/tune-silvermont.inc b/meta/conf/machine/include/tune-silvermont.inc
new file mode 100644
index 0000000..19bff65
--- /dev/null
+++ b/meta/conf/machine/include/tune-silvermont.inc
@@ -0,0 +1,36 @@
+# Settings for the GCC(1) cpu-type "silvermont":
+#
+#      Intel Silvermont CPU with 64-bit extensions, MOVBE, MMX, SSE, SSE2, SSE3,
+#      SSSE3, SSE4.1, SSE4.2, POPCNT, AES, PCLMUL and RDRND instruction set
+#      support. 
+#
+# This tune is recommended for the processors based on the second generation
+# Silvermont (22nm) Intel Atom CPUs.
+#
+DEFAULTTUNE ?= "silvermont-32"
+
+# Include the previous tune to pull in PACKAGE_EXTRA_ARCHS
+require conf/machine/include/tune-bonnell.inc
+
+# Extra tune features
+TUNEVALID[silvermont] = "Enable silvermont specific processor optimizations"
+TUNE_CCARGS .= "${@bb.utils.contains("TUNE_FEATURES", "silvermont", " -march=silvermont -mtune=silvermont -msse4.2 -mfpmath=sse", "", d)}"
+
+# Extra tune selections
+AVAILTUNES += "silvermont-32"
+TUNE_FEATURES_tune-silvermont-32 = "${TUNE_FEATURES_tune-x86} silvermont"
+BASE_LIB_tune-silvermont-32 = "lib"
+TUNE_PKGARCH_tune-silvermont-32 = "silvermont-32"
+PACKAGE_EXTRA_ARCHS_tune-silvermont-32 = "${PACKAGE_EXTRA_ARCHS_tune-bonnell-32} silvermont-32"
+
+AVAILTUNES += "silvermont-64"
+TUNE_FEATURES_tune-silvermont-64 = "${TUNE_FEATURES_tune-x86-64} silvermont"
+BASE_LIB_tune-silvermont-64 = "lib64"
+TUNE_PKGARCH_tune-silvermont-64 = "silvermont-64"
+PACKAGE_EXTRA_ARCHS_tune-silvermont-64 = "${PACKAGE_EXTRA_ARCHS_tune-bonnell-64} silvermont-64"
+
+AVAILTUNES += "silvermont-64-x32"
+TUNE_FEATURES_tune-silvermont-64-x32 = "${TUNE_FEATURES_tune-x86-64-x32} silvermont"
+BASE_LIB_tune-silvermont-64-x32 = "libx32"
+TUNE_PKGARCH_tune-silvermont-64-x32 = "silvermont-64-x32"
+PACKAGE_EXTRA_ARCHS_tune-silvermont-64-x32 = "${PACKAGE_EXTRA_ARCHS_tune-bonnell-64-x32} silvermont-64-x32"
-- 
1.9.1

[PATCH 4/5] tune-atom.inc: include tune-bonnell.inc instead of tune-core2.inc

[Andre McCurdy]

Use 'atom' as an alias for the first generation Intel Atom CPUs.
---
 meta/conf/machine/include/tune-atom.inc | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta/conf/machine/include/tune-atom.inc b/meta/conf/machine/include/tune-atom.inc
index 5e1bb74..24cd676 100644
--- a/meta/conf/machine/include/tune-atom.inc
+++ b/meta/conf/machine/include/tune-atom.inc
@@ -1,2 +1,2 @@
-# Atom tunings are the same as core2 for now...
-require conf/machine/include/tune-core2.inc
+# Alias for the first generation of Intel Atom CPUs.
+require conf/machine/include/tune-bonnell.inc
-- 
1.9.1

Re: [PATCH 4/5] tune-atom.inc: include tune-bonnell.inc instead of tune-core2.inc

[Khem Raj]

[-- Attachment #1: Type: text/plain, Size: 972 bytes --]

What do we get with this change
On Oct 19, 2015 12:00 PM, "Andre McCurdy" <armccurdy@gmail.com> wrote:

> Use 'atom' as an alias for the first generation Intel Atom CPUs.
> ---
>  meta/conf/machine/include/tune-atom.inc | 4 ++--
>  1 file changed, 2 insertions(+), 2 deletions(-)
>
> diff --git a/meta/conf/machine/include/tune-atom.inc
> b/meta/conf/machine/include/tune-atom.inc
> index 5e1bb74..24cd676 100644
> --- a/meta/conf/machine/include/tune-atom.inc
> +++ b/meta/conf/machine/include/tune-atom.inc
> @@ -1,2 +1,2 @@
> -# Atom tunings are the same as core2 for now...
> -require conf/machine/include/tune-core2.inc
> +# Alias for the first generation of Intel Atom CPUs.
> +require conf/machine/include/tune-bonnell.inc
> --
> 1.9.1
>
> --
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core
>

[-- Attachment #2: Type: text/html, Size: 1437 bytes --]

Re: [PATCH 4/5] tune-atom.inc: include tune-bonnell.inc instead of tune-core2.inc

[Andre McCurdy]

On Mon, Oct 19, 2015 at 12:37 PM, Khem Raj <raj.khem@gmail.com> wrote:
> What do we get with this change

It's mainly just a convenience for anyone with an existing machine
config using "tune-atom.inc". They would get atom specific tuning
without needing to update their machine configs.


> On Oct 19, 2015 12:00 PM, "Andre McCurdy" <armccurdy@gmail.com> wrote:
>>
>> Use 'atom' as an alias for the first generation Intel Atom CPUs.
>> ---
>>  meta/conf/machine/include/tune-atom.inc | 4 ++--
>>  1 file changed, 2 insertions(+), 2 deletions(-)
>>
>> diff --git a/meta/conf/machine/include/tune-atom.inc
>> b/meta/conf/machine/include/tune-atom.inc
>> index 5e1bb74..24cd676 100644
>> --- a/meta/conf/machine/include/tune-atom.inc
>> +++ b/meta/conf/machine/include/tune-atom.inc
>> @@ -1,2 +1,2 @@
>> -# Atom tunings are the same as core2 for now...
>> -require conf/machine/include/tune-core2.inc
>> +# Alias for the first generation of Intel Atom CPUs.
>> +require conf/machine/include/tune-bonnell.inc
>> --
>> 1.9.1
>>
>> --
>> _______________________________________________
>> Openembedded-core mailing list
>> Openembedded-core@lists.openembedded.org
>> http://lists.openembedded.org/mailman/listinfo/openembedded-core

Re: [PATCH 4/5] tune-atom.inc: include tune-bonnell.inc instead of tune-core2.inc

[Richard Purdie]

On Mon, 2015-10-19 at 11:59 -0700, Andre McCurdy wrote:
> Use 'atom' as an alias for the first generation Intel Atom CPUs.
> ---
>  meta/conf/machine/include/tune-atom.inc | 4 ++--
>  1 file changed, 2 insertions(+), 2 deletions(-)
> 
> diff --git a/meta/conf/machine/include/tune-atom.inc b/meta/conf/machine/include/tune-atom.inc
> index 5e1bb74..24cd676 100644
> --- a/meta/conf/machine/include/tune-atom.inc
> +++ b/meta/conf/machine/include/tune-atom.inc
> @@ -1,2 +1,2 @@
> -# Atom tunings are the same as core2 for now...
> -require conf/machine/include/tune-core2.inc
> +# Alias for the first generation of Intel Atom CPUs.
> +require conf/machine/include/tune-bonnell.inc

This is actually pretty nasty to anyone who uses package feeds or
packages since all of a sudden, the system rebuilds with a completely
different package architecture. Not sure we can take this change for
that reason.

I'd also like to understand how much of a difference these specific
tunes actually give. I know the Intel people have been trying to focus
on a smaller number of tunes that work well on the majority of platforms
rather than micro optimising the tunes.

Are there some benchmark numbers or other analysis which shows these
tunes as being more effective?

Cheers,

Richard

Re: [PATCH 4/5] tune-atom.inc: include tune-bonnell.inc instead of tune-core2.inc

[Andre McCurdy]

On Tue, Oct 20, 2015 at 2:16 AM, Richard Purdie
<richard.purdie@linuxfoundation.org> wrote:
> On Mon, 2015-10-19 at 11:59 -0700, Andre McCurdy wrote:
>> Use 'atom' as an alias for the first generation Intel Atom CPUs.
>> ---
>>  meta/conf/machine/include/tune-atom.inc | 4 ++--
>>  1 file changed, 2 insertions(+), 2 deletions(-)
>>
>> diff --git a/meta/conf/machine/include/tune-atom.inc b/meta/conf/machine/include/tune-atom.inc
>> index 5e1bb74..24cd676 100644
>> --- a/meta/conf/machine/include/tune-atom.inc
>> +++ b/meta/conf/machine/include/tune-atom.inc
>> @@ -1,2 +1,2 @@
>> -# Atom tunings are the same as core2 for now...
>> -require conf/machine/include/tune-core2.inc
>> +# Alias for the first generation of Intel Atom CPUs.
>> +require conf/machine/include/tune-bonnell.inc
>
> This is actually pretty nasty to anyone who uses package feeds or
> packages since all of a sudden, the system rebuilds with a completely
> different package architecture. Not sure we can take this change for
> that reason.

OK. I was thinking the comment in tune-atom.inc "Atom tunings are the
same as core2 FOR NOW..." gave people fair warning that tune-atom.inc
might not remain an alias for tune-core2.inc forever, but no problem
to drop this patch.

Another approach might be to drop tune-atom.inc altogether. Atom is
now ambiguous in terms of defining a CPU architecture and it hasn't
been a documented gcc x86 tuning option since gcc 4.8

  https://gcc.gnu.org/onlinedocs/gcc-4.8.5/gcc/i386-and-x86-64-Options.html#i386-and-x86-64-Options
  https://gcc.gnu.org/onlinedocs/gcc-4.9.3/gcc/i386-and-x86-64-Options.html#i386-and-x86-64-Options
  https://gcc.gnu.org/onlinedocs/gcc-5.2.0/gcc/x86-Options.html#x86-Options

> I'd also like to understand how much of a difference these specific
> tunes actually give. I know the Intel people have been trying to focus
> on a smaller number of tunes that work well on the majority of platforms
> rather than micro optimising the tunes.
>
> Are there some benchmark numbers or other analysis which shows these
> tunes as being more effective?

Not that I'm aware of. My own tests suggest that the benefits of
bonnell -vs- core2 tuning on a first generation Atom are pretty
unspectacular (maybe ~0 to 5 % performance increase and ~5% increase
in code size). I don't have a Silvermont board. This patch set was
more about enabling further experiments though, so if solid benchmark
improvements are a prerequisite then this patch set isn't ready to
merge.

>
> Cheers,
>
> Richard
>
>
>

[PATCH 5/5] tune-corei7.inc: update comments regarding Silvermont support

[Andre McCurdy]

Although still compatible, tune-corei7.inc is no longer the recommended
way to tune for Silvermont (which now has its own dedicated .inc file).

Signed-off-by: Andre McCurdy <armccurdy@gmail.com>
---
 meta/conf/machine/include/tune-corei7.inc | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta/conf/machine/include/tune-corei7.inc b/meta/conf/machine/include/tune-corei7.inc
index bea652f..13da46b 100644
--- a/meta/conf/machine/include/tune-corei7.inc
+++ b/meta/conf/machine/include/tune-corei7.inc
@@ -3,8 +3,8 @@
 #     Intel Core i7 CPU with 64-bit extensions, MMX, SSE, SSE2, SSE3, SSSE3, SSE4.1
 #     and SSE4.2 instruction set support.
 #
-# This tune is recommended for Intel Nehalem and Silvermont (e.g. Bay Trail) CPUs
-# (and beyond).
+# This tune is recommended for Intel Nehalem CPUs and beyond.
+# It is also compatible with second generation Silvermont Intel Atom CPUs.
 #
 DEFAULTTUNE ?= "corei7-64"
 
-- 
1.9.1

Re: [PATCH 0/5] tuning support for 1st and 2nd generation Intel Atom CPUs

[Saul Wold]

Hi Andre,


On 10/19/2015 11:59 AM, Andre McCurdy wrote:
> Andre McCurdy (5):
>    tune-corei7.inc: fix PACKAGE_EXTRA_ARCHS_tune-corei7-32 typo

This change makes sense and addresses an issue.

>    tune-bonnell.inc: support for first generation Intel Atom CPUs
>    tune-silvermont.inc: support for second generation Intel Atom CPUs
>    tune-atom.inc: include tune-bonnell.inc instead of tune-core2.inc
>    tune-corei7.inc: update comments regarding Silvermont support
>
I am not sure these make sense, it adds additional complexity to an 
already complex testing matrix.

Both the bonnell and silvermont tunes are fully part of their respective 
core* tune settings, there is no real need to become more specific. We 
know that newer code is starting to use intrinsics that can determine 
the correct extensions based on the CPU type.

I know you replied partly to RP's query, but is there something specific 
your trying to accomplish with these additional .incs that we don't 
already do and if so what?

Sau!
meta-intel maintainer

>   meta/conf/machine/include/tune-atom.inc       |  4 +--
>   meta/conf/machine/include/tune-bonnell.inc    | 35 ++++++++++++++++++++++++++
>   meta/conf/machine/include/tune-corei7.inc     |  6 ++---
>   meta/conf/machine/include/tune-silvermont.inc | 36 +++++++++++++++++++++++++++
>   4 files changed, 76 insertions(+), 5 deletions(-)
>   create mode 100644 meta/conf/machine/include/tune-bonnell.inc
>   create mode 100644 meta/conf/machine/include/tune-silvermont.inc
>

Re: [PATCH 0/5] tuning support for 1st and 2nd generation Intel Atom CPUs

[Saul Wold]

On 10/19/2015 11:59 AM, Andre McCurdy wrote:
> Andre McCurdy (5):
>    tune-corei7.inc: fix PACKAGE_EXTRA_ARCHS_tune-corei7-32 typo

This change makes sense

>    tune-bonnell.inc: support for first generation Intel Atom CPUs
>    tune-silvermont.inc: support for second generation Intel Atom CPUs
>    tune-atom.inc: include tune-bonnell.inc instead of tune-core2.inc
>    tune-corei7.inc: update comments regarding Silvermont support
>
I am not sure these make sense, it adds additional complexity to an 
already complex testing matrix.

Both the bonnell and silvermont tunes are fully part of their respective 
core* tune settings, there is no real need to become more specific. We 
know that newer code is starting to use intrinsics that can determine 
the correct extensions based on the CPU type.

I know you replied partly to RP's query, but is there something specific 
your trying to accomplish with these additional .incs that we don't 
already do and if so what?

Sau!
meta-intel maintainer

>   meta/conf/machine/include/tune-atom.inc       |  4 +--
>   meta/conf/machine/include/tune-bonnell.inc    | 35 ++++++++++++++++++++++++++
>   meta/conf/machine/include/tune-corei7.inc     |  6 ++---
>   meta/conf/machine/include/tune-silvermont.inc | 36 +++++++++++++++++++++++++++
>   4 files changed, 76 insertions(+), 5 deletions(-)
>   create mode 100644 meta/conf/machine/include/tune-bonnell.inc
>   create mode 100644 meta/conf/machine/include/tune-silvermont.inc
>