Re: [OE-core] [PATCH 1/6] libseccomp: move recipe from meta-security to core

["Armin Kuster" <akuster808@gmail.com>]

On 4/24/21 9:19 AM, Khem Raj wrote:
> On Sat, Apr 24, 2021 at 8:56 AM Armin Kuster <akuster808@gmail.com> wrote:
>> ptest results:
>> Regression Test Summary
>>  tests run: 1404
>>  tests skipped: 369
>>  tests passed: 1402
>>  tests failed: 2
>>  tests errored: 154
>>
>> Add feature_check so that the other recipes who can take
>> advantage of this funtionality can enable it.
>>
>> Signed-off-by: Armin Kuster <akuster808@gmail.com>
>> ---
>>  .../libseccomp/files/run-ptest                |  4 ++
>>  .../libseccomp/libseccomp_2.5.1.bb            | 49 +++++++++++++++++++
>>  2 files changed, 53 insertions(+)
>>  create mode 100644 meta/recipes-support/libseccomp/files/run-ptest
>>  create mode 100644 meta/recipes-support/libseccomp/libseccomp_2.5.1.bb
>>
>> diff --git a/meta/recipes-support/libseccomp/files/run-ptest b/meta/recipes-support/libseccomp/files/run-ptest
>> new file mode 100644
>> index 00000000000..54b4a63cd2c
>> --- /dev/null
>> +++ b/meta/recipes-support/libseccomp/files/run-ptest
>> @@ -0,0 +1,4 @@
>> +#!/bin/sh
>> +
>> +cd tests
>> +./regression -a
>> diff --git a/meta/recipes-support/libseccomp/libseccomp_2.5.1.bb b/meta/recipes-support/libseccomp/libseccomp_2.5.1.bb
>> new file mode 100644
>> index 00000000000..667d5da8242
>> --- /dev/null
>> +++ b/meta/recipes-support/libseccomp/libseccomp_2.5.1.bb
>> @@ -0,0 +1,49 @@
>> +SUMMARY = "interface to seccomp filtering mechanism"
>> +DESCRIPTION = "The libseccomp library provides and easy to use, platform independent,interface to the Linux Kernel's syscall filtering mechanism: seccomp."
>> +SECTION = "security"
>> +LICENSE = "LGPL-2.1"
>> +LIC_FILES_CHKSUM = "file://LICENSE;beginline=0;endline=1;md5=8eac08d22113880357ceb8e7c37f989f"
>> +
>> +DEPENDS += "gperf-native"
>> +
>> +SRCREV = "4bf70431a339a2886ab8c82e9a45378f30c6e6c7"
>> +
>> +SRC_URI = "git://github.com/seccomp/libseccomp.git;branch=release-2.5 \
>> +           file://run-ptest \
>> +           "
>> +
>> +COMPATIBLE_HOST_riscv32 = "null"
>> +
>> +S = "${WORKDIR}/git"
>> +
>> +inherit autotools-brokensep pkgconfig ptest features_check
>> +
>> +REQUIRED_DISTRO_FEATURES = "seccomp"
>> +
>> +PACKAGECONFIG ??= ""
>> +PACKAGECONFIG[python] = "--enable-python, --disable-python, python3"
>> +
>> +DISABLE_STATIC = ""
> do we need apps to use some static libs ? if so which library is it,
> Or is it all internal?

The commit that added that:

commit 2153c59b429293120095a2bd4562f4f7553c1ae7
Author: Stefan Agner <stefan.agner@toradex.com>
Date:   Sun Sep 1 21:48:13 2019 +0200

    libseccomp: build static library always
   
    Always build static library. This is required e.g. for runc from
    meta-virtualization in its default configuration.

Meta-virt is one of the reasons I am this patch set.

-armin
>
>> +
>> +do_compile_ptest() {
>> +    oe_runmake -C tests check-build
>> +}
>> +
>> +do_install_ptest() {
>> +    install -d ${D}${PTEST_PATH}/tests
>> +    install -d ${D}${PTEST_PATH}/tools
>> +    for file in $(find tests/* -executable -type f); do
>> +        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
>> +    done
>> +    for file in $(find tests/*.tests -type f); do
>> +        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
>> +    done
>> +    for file in $(find tools/* -executable -type f); do
>> +        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tools
>> +    done
>> +}
>> +
>> +FILES_${PN} = "${bindir} ${libdir}/${BPN}.so*"
>> +FILES_${PN}-dbg += "${libdir}/${PN}/tests/.debug/* ${libdir}/${PN}/tools/.debug"
>> +
>> +RDEPENDS_${PN}-ptest = "coreutils bash"
>> --
>> 2.25.1
>>
>>
>> 
>>