[PATCH 0/3] Clean up fontconfig recipes

[PATCH 0/3] Clean up fontconfig recipes

[Ross Burton]

Hi,

The fontconfig recipes were showing their age with lots of cruft and plain odd
constructs.  Distressingly the majority of them were from myself with no clear
commit logs.  Thus I was guilt-tripped into cleaning the fontconfig recipes up.

Ross

The following changes since commit 00a2411470b989ca80bc2a6de08d105bc400dae5:

  libiconv: Remove RPATH from binaries (2013-02-11 15:41:20 +0000)

are available in the git repository at:

  git://git.yoctoproject.org/poky-contrib ross/fontconfig

for you to fetch changes up to 27fe822aa3e7bfc8523f9a074c623ee0270cbefa:

  fontconfig: rename the patches directory (2013-02-11 16:00:58 +0000)

----------------------------------------------------------------
Ross Burton (3):
      fontconfig: remove unexplainable and broken build tweaking
      fontconfig: drop explicit -native recipe
      fontconfig: rename the patches directory

 ...Add-sysroot-option-to-fc-cache-and-fc-cat.patch |    0
 .../fontconfig-2.10.2/fix-pkgconfig.patch          |   15 -------
 .../fontconfig/fontconfig-native_2.10.2.bb         |   14 ------
 .../fontconfig/fontconfig_2.10.2.bb                |   47 ++------------------
 4 files changed, 4 insertions(+), 72 deletions(-)
 rename meta/recipes-graphics/fontconfig/{fontconfig-2.10.2 => files}/Add-sysroot-option-to-fc-cache-and-fc-cat.patch (100%)
 delete mode 100644 meta/recipes-graphics/fontconfig/fontconfig-2.10.2/fix-pkgconfig.patch
 delete mode 100644 meta/recipes-graphics/fontconfig/fontconfig-native_2.10.2.bb

Ross Burton (3):
  fontconfig: remove unexplainable and broken build tweaking
  fontconfig: drop explicit -native recipe
  fontconfig: rename the patches directory

 ...Add-sysroot-option-to-fc-cache-and-fc-cat.patch |    0
 .../fontconfig-2.10.2/fix-pkgconfig.patch          |   15 -------
 .../fontconfig/fontconfig-native_2.10.2.bb         |   14 ------
 .../fontconfig/fontconfig_2.10.2.bb                |   47 ++------------------
 4 files changed, 4 insertions(+), 72 deletions(-)
 rename meta/recipes-graphics/fontconfig/{fontconfig-2.10.2 => files}/Add-sysroot-option-to-fc-cache-and-fc-cat.patch (100%)
 delete mode 100644 meta/recipes-graphics/fontconfig/fontconfig-2.10.2/fix-pkgconfig.patch
 delete mode 100644 meta/recipes-graphics/fontconfig/fontconfig-native_2.10.2.bb

-- 
1.7.10.4

[PATCH 1/3] fontconfig: remove unexplainable and broken build tweaking

[Ross Burton]

The build flag twiddling in do_configure_append was unexplainable and clearly
wrong (native flags for a cross build), remove it all.

Parallel make appears to be working now, so enable it.

The tarball doesn't contain read only sources, remove the unpack hacking.

The pkgconfig doesn't need patching as the freetype link lines are the same.

Don't need to specify where freetype is, it's found automatically.

Merge fontconfig-util-dbg into fontconfig-dbg.

Don't export HASDOCBOOK, --disable-docs is sufficient to turn off documentation
building.

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 .../fontconfig-2.10.2/fix-pkgconfig.patch          |   15 -------
 .../fontconfig/fontconfig_2.10.2.bb                |   47 ++------------------
 2 files changed, 3 insertions(+), 59 deletions(-)
 delete mode 100644 meta/recipes-graphics/fontconfig/fontconfig-2.10.2/fix-pkgconfig.patch

diff --git a/meta/recipes-graphics/fontconfig/fontconfig-2.10.2/fix-pkgconfig.patch b/meta/recipes-graphics/fontconfig/fontconfig-2.10.2/fix-pkgconfig.patch
deleted file mode 100644
index 6be04a1..0000000
--- a/meta/recipes-graphics/fontconfig/fontconfig-2.10.2/fix-pkgconfig.patch
+++ /dev/null
@@ -1,15 +0,0 @@
-Upstream-Status: Inappropriate [configuration]
-
----
- fontconfig.pc.in |    2 +-
- 1 file changed, 1 insertion(+), 1 deletion(-)
-
---- fontconfig-2.9.0.orig/fontconfig.pc.in
-+++ fontconfig-2.9.0/fontconfig.pc.in
-@@ -7,5 +7,5 @@
- Description: Font configuration and customization library
- Version: @VERSION@
- Libs: -L${libdir} -lfontconfig
--Libs.private: @LIBXML2_LIBS@ @EXPAT_LIBS@ @FREETYPE_LIBS@ @ICONV_LIBS@
-+Libs.private: @LIBXML2_LIBS@ @EXPAT_LIBS@ -L${libdir} -lfreetype @ICONV_LIBS@
- Cflags: -I${includedir}
diff --git a/meta/recipes-graphics/fontconfig/fontconfig_2.10.2.bb b/meta/recipes-graphics/fontconfig/fontconfig_2.10.2.bb
index 607cf9e..6f2456d 100644
--- a/meta/recipes-graphics/fontconfig/fontconfig_2.10.2.bb
+++ b/meta/recipes-graphics/fontconfig/fontconfig_2.10.2.bb
@@ -24,16 +24,14 @@ PR = "r1"
 
 SRC_URI = "http://fontconfig.org/release/fontconfig-${PV}.tar.gz \
            file://Add-sysroot-option-to-fc-cache-and-fc-cat.patch \
-           file://fix-pkgconfig.patch \
           "
 
 SRC_URI[md5sum] = "025e08b3d7fe45c433de5718e441ed15"
 SRC_URI[sha256sum] = "5c3bf994bb6d6303bbf1e641eaa4b431932138dc90de33642e5845e31e1fdfd6"
 
-PACKAGES =+ "fontconfig-utils-dbg fontconfig-utils "
-FILES_fontconfig-utils-dbg = "${bindir}/*.dbg"
-FILES_fontconfig-utils = "${bindir}/*"
+PACKAGES =+ "fontconfig-utils"
 FILES_${PN} =+ "${datadir}/xml/*"
+FILES_fontconfig-utils = "${bindir}/*"
 
 # Work around past breakage in debian.bbclass
 RPROVIDES_fontconfig-utils = "libfontconfig-utils"
@@ -41,45 +39,6 @@ RREPLACES_fontconfig-utils = "libfontconfig-utils"
 RCONFLICTS_fontconfig-utils = "libfontconfig-utils"
 DEBIAN_NOAUTONAME_fontconfig-utils = "1"
 
-PARALLEL_MAKE = ""
-
 inherit autotools pkgconfig
 
-export HASDOCBOOK="no"
-
-EXTRA_OECONF = " --disable-docs --with-arch=${HOST_ARCH} --with-default-fonts=${datadir}/fonts"
-EXTRA_OEMAKE = "FC_LANG=fc-lang FC_GLYPHNAME=fc-glyphname"
-
-# The tarball has some of the patched files as read only, which
-# patch doesn't like at all
-
-fontconfig_do_unpack() {
-       chmod -R u+rw ${S}
-}
-
-python do_unpack () {
-       bb.build.exec_func('base_do_unpack', d)
-       bb.build.exec_func('fontconfig_do_unpack', d)
-}
-
-BUILD_CFLAGS += " -I${STAGING_INCDIR}/freetype2"
-
-do_configure_append () {
-	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-case/Makefile
-	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-glyphname/Makefile
-	sed -i 's|LDFLAGS =.*|LDFLAGS =|' fc-lang/Makefile
-
-	sed -i 's|CFLAGS =.*|CFLAGS =${BUILD_CFLAGS}|' fc-case/Makefile
-	sed -i 's|CFLAGS =.*|CFLAGS =${BUILD_CFLAGS}|' fc-glyphname/Makefile
-	sed -i 's|CFLAGS =.*|CFLAGS =${BUILD_CFLAGS}|' fc-lang/Makefile
-
-	sed -i 's|CPPFLAGS =.*|CPPFLAGS =${BUILD_CPPFLAGS}|' fc-case/Makefile
-	sed -i 's|CPPFLAGS =.*|CPPFLAGS =${BUILD_CPPFLAGS}|' fc-glyphname/Makefile
-	sed -i 's|CPPFLAGS =.*|CPPFLAGS =${BUILD_CPPFLAGS}|' fc-lang/Makefile
-
-	sed -i 's|CXXFLAGS =.*|CFLAGS =${BUILD_CXXFLAGS}|' fc-case/Makefile
-	sed -i 's|CXXFLAGS =.*|CFLAGS =${BUILD_CXXFLAGS}|' fc-glyphname/Makefile
-	sed -i 's|CXXFLAGS =.*|CFLAGS =${BUILD_CXXFLAGS}|' fc-lang/Makefile
-
-}
-
+EXTRA_OECONF = " --disable-docs --with-default-fonts=${datadir}/fonts"
-- 
1.7.10.4

[PATCH 2/3] fontconfig: drop explicit -native recipe

[Ross Burton]

Instead, use BBCLASSEXTEND=native in fontconfig.

We can drop the installation of fc-lang/fc-glyphname, they are not used by
fontconfig's build anymore as it ships the generated files in the tarball.

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 .../fontconfig/fontconfig-native_2.10.2.bb               |   14 --------------
 meta/recipes-graphics/fontconfig/fontconfig_2.10.2.bb    |    2 ++
 2 files changed, 2 insertions(+), 14 deletions(-)
 delete mode 100644 meta/recipes-graphics/fontconfig/fontconfig-native_2.10.2.bb

diff --git a/meta/recipes-graphics/fontconfig/fontconfig-native_2.10.2.bb b/meta/recipes-graphics/fontconfig/fontconfig-native_2.10.2.bb
deleted file mode 100644
index cee94de..0000000
--- a/meta/recipes-graphics/fontconfig/fontconfig-native_2.10.2.bb
+++ /dev/null
@@ -1,14 +0,0 @@
-require fontconfig_${PV}.bb
-inherit native
-DEPENDS = "freetype-native expat-native zlib-native"
-
-EXTRA_OEMAKE = ""
-EXTRA_OECONF = "${@[' --disable-docs',' --disable-docs --with-freetype-config=%s/freetype-config' % d.getVar('STAGING_BINDIR', True)][os.path.isfile('%s/freetype-config' % d.getVar('STAGING_BINDIR', True))]}"
-
-FILESEXTRAPATHS_prepend := "${THISDIR}/${BPN}-${PV}:"
-
-do_install_append () {
-	install -d ${D}${bindir}/
-	install fc-lang/fc-lang ${D}${bindir}/
-	install fc-glyphname/fc-glyphname ${D}${bindir}/
-}
diff --git a/meta/recipes-graphics/fontconfig/fontconfig_2.10.2.bb b/meta/recipes-graphics/fontconfig/fontconfig_2.10.2.bb
index 6f2456d..45631ed 100644
--- a/meta/recipes-graphics/fontconfig/fontconfig_2.10.2.bb
+++ b/meta/recipes-graphics/fontconfig/fontconfig_2.10.2.bb
@@ -42,3 +42,5 @@ DEBIAN_NOAUTONAME_fontconfig-utils = "1"
 inherit autotools pkgconfig
 
 EXTRA_OECONF = " --disable-docs --with-default-fonts=${datadir}/fonts"
+
+BBCLASSEXTEND = "native"
-- 
1.7.10.4

[PATCH 3/3] fontconfig: rename the patches directory

[Ross Burton]

Rename the patches directory to files as we only have one version of fontconfig,
so the hassle of moving these files every upgrade can be avoided.

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 .../Add-sysroot-option-to-fc-cache-and-fc-cat.patch                    |    0
 1 file changed, 0 insertions(+), 0 deletions(-)
 rename meta/recipes-graphics/fontconfig/{fontconfig-2.10.2 => files}/Add-sysroot-option-to-fc-cache-and-fc-cat.patch (100%)

diff --git a/meta/recipes-graphics/fontconfig/fontconfig-2.10.2/Add-sysroot-option-to-fc-cache-and-fc-cat.patch b/meta/recipes-graphics/fontconfig/files/Add-sysroot-option-to-fc-cache-and-fc-cat.patch
similarity index 100%
rename from meta/recipes-graphics/fontconfig/fontconfig-2.10.2/Add-sysroot-option-to-fc-cache-and-fc-cat.patch
rename to meta/recipes-graphics/fontconfig/files/Add-sysroot-option-to-fc-cache-and-fc-cat.patch
-- 
1.7.10.4