[PATCH 0/5] Add midori and dependencies

[PATCH 0/5] Add midori and dependencies

[Mihai Prica]

The Midori web-browser can be used to more easily test the functionality
of webkit-gtk.

* The midori and libnotify recipes are from meta-gnome.
* The python-docutils and vala recipes are from meta-oe.
* The midori and python-docutils packages have been updated to the latest
upstream version.

Midori also depends on ca-certificates. A patch set was sent by Christopher
Larson that adds the recipe in oe-core. This series depends on his addition.

The following changes since commit b467b99a5d25efe5eadfb07dbecba608575256ac:

  linux-yocto: switch genericx86 to use common-pc (2013-08-24 09:37:49 +0100)

are available in the git repository at:

  git://git.yoctoproject.org/poky-contrib mihaip/midori
  http://git.yoctoproject.org/cgit.cgi/poky-contrib/log/?h=mihaip/midori

Mihai Prica (5):
  python-docutils: add version 0.11 from meta-oe
  libnotify: add version 0.6.0 from meta-oe
  vala: add version 0.16 from meta-oe
  vala.bbclass: add class from meta-oe
  midori: add version 0.5.5 from meta-oe

 meta/classes/vala.bbclass                          |   18 +++++++
 .../python/python-docutils_0.11.bb                 |   18 +++++++
 ...-gen-don-t-append-dirty-if-we-re-not-in-g.patch |   53 ++++++++++++++++++++
 meta/recipes-devtools/vala/vala.inc                |   20 ++++++++
 meta/recipes-devtools/vala/vala_0.16.0.bb          |    8 +++
 meta/recipes-gnome/libnotify/libnotify_0.6.0.bb    |   17 +++++++
 meta/recipes-sato/midori/midori_0.5.5.bb           |   43 ++++++++++++++++
 7 files changed, 177 insertions(+)
 create mode 100644 meta/classes/vala.bbclass
 create mode 100644 meta/recipes-devtools/python/python-docutils_0.11.bb
 create mode 100644 meta/recipes-devtools/vala/vala-0.16.0/0001-git-version-gen-don-t-append-dirty-if-we-re-not-in-g.patch
 create mode 100644 meta/recipes-devtools/vala/vala.inc
 create mode 100644 meta/recipes-devtools/vala/vala_0.16.0.bb
 create mode 100644 meta/recipes-gnome/libnotify/libnotify_0.6.0.bb
 create mode 100644 meta/recipes-sato/midori/midori_0.5.5.bb

-- 
1.7.9.5

[PATCH 1/5] python-docutils: add version 0.11 from meta-oe

[Mihai Prica]

Docutils is a text processing system for processing plaintext
documentation into useful formats(HTML, XML, man-pages). This is
required by the Midori web-browser.

* Update 0.5 from meta-oe to 0.11.

Signed-off-by: Mihai Prica <mihai.prica@intel.com>
---
 .../python/python-docutils_0.11.bb                 |   18 ++++++++++++++++++
 1 file changed, 18 insertions(+)
 create mode 100644 meta/recipes-devtools/python/python-docutils_0.11.bb

diff --git a/meta/recipes-devtools/python/python-docutils_0.11.bb b/meta/recipes-devtools/python/python-docutils_0.11.bb
new file mode 100644
index 0000000..7987244
--- /dev/null
+++ b/meta/recipes-devtools/python/python-docutils_0.11.bb
@@ -0,0 +1,18 @@
+DESCRIPTION = "Text processing system"
+HOMEPAGE = "http://docutils.sourceforge.net"
+SECTION = "devel/python"
+LICENSE = "PSF & BSD-2-Clause & GPLv3"
+LIC_FILES_CHKSUM = "file://COPYING.txt;md5=da0d261d1db78ab21ce86c79364a4098"
+
+DEPENDS = "python"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/docutils/docutils-${PV}.tar.gz"
+SRC_URI[md5sum] = "20ac380a18b369824276864d98ec0ad6"
+SRC_URI[sha256sum] = "9af4166adf364447289c5c697bb83c52f1d6f57e77849abcccd6a4a18a5e7ec9"
+
+S = "${WORKDIR}/docutils-${PV}"
+
+inherit distutils
+
+BBCLASSEXTEND = "native"
+
-- 
1.7.9.5

[PATCH 2/5] libnotify: add version 0.6.0 from meta-oe

[Mihai Prica]

Libnotify is a library that can be used to send
desktop notifications to a daemon. It's required
by the Midori web-browser.

Signed-off-by: Mihai Prica <mihai.prica@intel.com>
---
 meta/recipes-gnome/libnotify/libnotify_0.6.0.bb |   17 +++++++++++++++++
 1 file changed, 17 insertions(+)
 create mode 100644 meta/recipes-gnome/libnotify/libnotify_0.6.0.bb

diff --git a/meta/recipes-gnome/libnotify/libnotify_0.6.0.bb b/meta/recipes-gnome/libnotify/libnotify_0.6.0.bb
new file mode 100644
index 0000000..0a590e3
--- /dev/null
+++ b/meta/recipes-gnome/libnotify/libnotify_0.6.0.bb
@@ -0,0 +1,17 @@
+DESCRIPTION = "Send desktop notifications to a notification daemon"
+SECTION = "libs"
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=7fbc338309ac38fefcd64b04bb903e34"
+
+PR = "r1"
+
+DEPENDS = "dbus gtk+"
+
+inherit gnome
+SRC_URI[archive.md5sum] = "732c9d2cd5eb6a9069264a319d330516"
+SRC_URI[archive.sha256sum] = "73b16a79bb2fed62dcf146b11c4405776cb96a09dce66379ca541da7dbd64210"
+
+do_configure_prepend() {
+    sed -i /GTK3/d configure.ac
+    sed -i -e /test-gtk3/d -e 's/test-xy-stress \\/test-xy-stress/' tests/Makefile.am
+}
-- 
1.7.9.5

[PATCH 3/5] vala: add version 0.16 from meta-oe

[Mihai Prica]

Vala is a C#-like language dedicated to ease GObject programming.
It is required by the Midori web-browser.

Signed-off-by: Mihai Prica <mihai.prica@intel.com>
---
 ...-gen-don-t-append-dirty-if-we-re-not-in-g.patch |   53 ++++++++++++++++++++
 meta/recipes-devtools/vala/vala.inc                |   20 ++++++++
 meta/recipes-devtools/vala/vala_0.16.0.bb          |    8 +++
 3 files changed, 81 insertions(+)
 create mode 100644 meta/recipes-devtools/vala/vala-0.16.0/0001-git-version-gen-don-t-append-dirty-if-we-re-not-in-g.patch
 create mode 100644 meta/recipes-devtools/vala/vala.inc
 create mode 100644 meta/recipes-devtools/vala/vala_0.16.0.bb

diff --git a/meta/recipes-devtools/vala/vala-0.16.0/0001-git-version-gen-don-t-append-dirty-if-we-re-not-in-g.patch b/meta/recipes-devtools/vala/vala-0.16.0/0001-git-version-gen-don-t-append-dirty-if-we-re-not-in-g.patch
new file mode 100644
index 0000000..e6c7941
--- /dev/null
+++ b/meta/recipes-devtools/vala/vala-0.16.0/0001-git-version-gen-don-t-append-dirty-if-we-re-not-in-g.patch
@@ -0,0 +1,53 @@
+From 2460d7b79f7e90dcfeebde5e9c53d9b6798a1f3c Mon Sep 17 00:00:00 2001
+From: Martin Jansa <Martin.Jansa@gmail.com>
+Date: Tue, 21 Feb 2012 17:12:50 +0100
+Subject: [PATCH] git-version-gen: don't append -dirty if we're not in git
+ repo
+
+* for example if we have some dirty directory and we unpack clean vala tarball in it, then it will append -dirty
+
+Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
+---
+ build-aux/git-version-gen |   25 ++++++++++++++-----------
+ 1 files changed, 14 insertions(+), 11 deletions(-)
+
+diff --git a/build-aux/git-version-gen b/build-aux/git-version-gen
+index 0fa6faa..1d1f9d2 100755
+--- a/build-aux/git-version-gen
++++ b/build-aux/git-version-gen
+@@ -126,18 +126,21 @@ fi
+ 
+ v=`echo "$v" |sed 's/^v//'`
+ 
+-# Don't declare a version "dirty" merely because a time stamp has changed.
+-git status > /dev/null 2>&1
++if test -d .git
++then
++	# Don't declare a version "dirty" merely because a time stamp has changed.
++	git status > /dev/null 2>&1
+ 
+-dirty=`sh -c 'git diff-index --name-only HEAD' 2>/dev/null` || dirty=
+-case "$dirty" in
+-    '') ;;
+-    *) # Append the suffix only if there isn't one already.
+-	case $v in
+-	  *-dirty) ;;
+-	  *) v="$v-dirty" ;;
+-	esac ;;
+-esac
++	dirty=`sh -c 'git diff-index --name-only HEAD' 2>/dev/null` || dirty=
++	case "$dirty" in
++	    '') ;;
++	    *) # Append the suffix only if there isn't one already.
++		case $v in
++		  *-dirty) ;;
++		  *) v="$v-dirty" ;;
++		esac ;;
++	esac
++fi
+ 
+ # Omit the trailing newline, so that m4_esyscmd can use the result directly.
+ echo "$v" | tr -d '\012'
+-- 
+1.7.8.4
+
diff --git a/meta/recipes-devtools/vala/vala.inc b/meta/recipes-devtools/vala/vala.inc
new file mode 100644
index 0000000..6cdc605
--- /dev/null
+++ b/meta/recipes-devtools/vala/vala.inc
@@ -0,0 +1,20 @@
+DESCRIPTION = "Vala is a C#-like language dedicated to ease GObject programming. \
+Vala compiles to plain C and has no runtime environment nor penalities whatsoever."
+SECTION = "devel"
+DEPENDS = "glib-2.0 dbus gtk+"
+BBCLASSEXTEND = "native"
+DEPENDS_virtclass-native = "glib-2.0-native dbus-native"
+HOMEPAGE = "http://vala-project.org"
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
+INC_PR = "r1"
+
+SHRT_VER = "${@d.getVar('PV',1).split('.')[0]}.${@d.getVar('PV',1).split('.')[1]}"
+
+SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/${BPN}/${SHRT_VER}/${BP}.tar.xz"
+inherit autotools
+
+EXTRA_OECONF = "--disable-vapigen"
+
+FILES_${PN}-doc += "${datadir}/devhelp"
+FILES_${PN} += "${datadir}/${BPN}-${SHRT_VER}/vapi"
diff --git a/meta/recipes-devtools/vala/vala_0.16.0.bb b/meta/recipes-devtools/vala/vala_0.16.0.bb
new file mode 100644
index 0000000..92120b4
--- /dev/null
+++ b/meta/recipes-devtools/vala/vala_0.16.0.bb
@@ -0,0 +1,8 @@
+require ${BPN}.inc
+
+PR = "${INC_PR}.1"
+
+SRC_URI += " file://0001-git-version-gen-don-t-append-dirty-if-we-re-not-in-g.patch"
+
+SRC_URI[md5sum] = "84b742e9cca4c90fde3026c3793c03c1"
+SRC_URI[sha256sum] = "3adb37aa2b35e2e2daed47552e85dbcbf752c0f7768b269d856993620073a657"
-- 
1.7.9.5

[PATCH 4/5] vala.bbclass: add class from meta-oe

[Mihai Prica]

This can be used by packages written in vala.
It is required by the Midori web-browser.

Signed-off-by: Mihai Prica <mihai.prica@intel.com>
---
 meta/classes/vala.bbclass |   18 ++++++++++++++++++
 1 file changed, 18 insertions(+)
 create mode 100644 meta/classes/vala.bbclass

diff --git a/meta/classes/vala.bbclass b/meta/classes/vala.bbclass
new file mode 100644
index 0000000..c7db08c
--- /dev/null
+++ b/meta/classes/vala.bbclass
@@ -0,0 +1,18 @@
+# Vala has problems with multiple concurrent invocations
+PARALLEL_MAKE = ""
+
+# Vala needs vala-native
+DEPENDS += "vala-native"
+DEPENDS_virtclass-native += "vala-native"
+
+# Our patched version of Vala looks in STAGING_DATADIR for .vapi files
+export STAGING_DATADIR
+# Upstream Vala >= 0.11 looks in XDG_DATA_DIRS for .vapi files
+export XDG_DATA_DIRS = "${STAGING_DATADIR}"
+
+# Package additional files
+FILES_${PN}-dev += "\
+    ${datadir}/vala/vapi/*.vapi \
+    ${datadir}/vala/vapi/*.deps \
+    ${datadir}/gir-1.0 \
+"
-- 
1.7.9.5

[PATCH 5/5] midori: add version 0.5.5 from meta-oe

[Mihai Prica]

Midori is a lightweight web browser that uses the WebKit
rendering engine and the GTK interface. This allows a more
easy testing of the functionality of webkit-gtk component
that is already in oe-core.

Signed-off-by: Mihai Prica <mihai.prica@intel.com>
---
 meta/recipes-sato/midori/midori_0.5.5.bb |   43 ++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 meta/recipes-sato/midori/midori_0.5.5.bb

diff --git a/meta/recipes-sato/midori/midori_0.5.5.bb b/meta/recipes-sato/midori/midori_0.5.5.bb
new file mode 100644
index 0000000..e545753
--- /dev/null
+++ b/meta/recipes-sato/midori/midori_0.5.5.bb
@@ -0,0 +1,43 @@
+DESCRIPTION = "Midori is a lightweight web browser."
+HOMEPAGE = "http://www.twotoasts.de/index.php?/pages/midori_summary.html"
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
+DEPENDS = "webkit-gtk libsoup-2.4 openssl python-native python-docutils-native librsvg-native libnotify libunique"
+
+SRC_URI = "http://www.midori-browser.org/downloads/${PN}_${PV}_all_.tar.bz2 \
+"
+
+SRC_URI[md5sum] = "b99e87d4b73a4732ed1c1e591f0242ac"
+SRC_URI[sha256sum] = "ca69382a285222a86028abebd73fed1976735883027ff0adc094b627789bbd62"
+
+inherit gtk-icon-cache pkgconfig vala pythonnative
+
+do_configure() {
+    sed -i -e 's:, shell=False::g' -e s:/usr/X11R6/include::g -e s:/usr/X11R6/lib::g wscript
+    ./configure \
+            --prefix=${prefix} \
+            --bindir=${bindir} \
+            --sbindir=${sbindir} \
+            --libexecdir=${libexecdir} \
+            --datadir=${datadir} \
+            --sysconfdir=${sysconfdir} \
+            --sharedstatedir=${sharedstatedir} \
+            --localstatedir=${localstatedir} \
+            --libdir=${libdir} \
+            --includedir=${includedir} \
+            --infodir=${infodir} \
+            --mandir=${mandir} \
+            --disable-gtk3 \
+            --disable-zeitgeist \
+}
+
+PARALLEL_MAKE = ""
+TARGET_CC_ARCH += "${LDFLAGS}"
+
+do_install() {
+    oe_runmake DESTDIR=${D} install
+}
+
+RRECOMMENDS_${PN} += "glib-networking ca-certificates gnome-icon-theme"
+
+FILES_${PN}-dev += "${datadir}/vala/vapi"
-- 
1.7.9.5

Re: [PATCH 0/5] Add midori and dependencies

[Paul Eggleton]

Hi Mihai,

On Tuesday 27 August 2013 17:59:34 Mihai Prica wrote:
> The Midori web-browser can be used to more easily test the functionality
> of webkit-gtk.
> 
> * The midori and libnotify recipes are from meta-gnome.

Can you please correct the commit messages on your branch to reflect this?

Thanks,
Paul

-- 

Paul Eggleton
Intel Open Source Technology Centre

Re: [PATCH 0/5] Add midori and dependencies

[Martin Jansa]

[-- Attachment #1: Type: text/plain, Size: 2573 bytes --]

On Tue, Aug 27, 2013 at 05:59:34PM +0300, Mihai Prica wrote:
> The Midori web-browser can be used to more easily test the functionality
> of webkit-gtk.
> 
> * The midori and libnotify recipes are from meta-gnome.
> * The python-docutils and vala recipes are from meta-oe.
> * The midori and python-docutils packages have been updated to the latest
> upstream version.
> 
> Midori also depends on ca-certificates. A patch set was sent by Christopher
> Larson that adds the recipe in oe-core. This series depends on his addition.

Are you going to send patches to oe-devel to remove moved
recipes/bbclasses ?

> The following changes since commit b467b99a5d25efe5eadfb07dbecba608575256ac:
> 
>   linux-yocto: switch genericx86 to use common-pc (2013-08-24 09:37:49 +0100)
> 
> are available in the git repository at:
> 
>   git://git.yoctoproject.org/poky-contrib mihaip/midori
>   http://git.yoctoproject.org/cgit.cgi/poky-contrib/log/?h=mihaip/midori
> 
> Mihai Prica (5):
>   python-docutils: add version 0.11 from meta-oe
>   libnotify: add version 0.6.0 from meta-oe
>   vala: add version 0.16 from meta-oe
>   vala.bbclass: add class from meta-oe
>   midori: add version 0.5.5 from meta-oe
> 
>  meta/classes/vala.bbclass                          |   18 +++++++
>  .../python/python-docutils_0.11.bb                 |   18 +++++++
>  ...-gen-don-t-append-dirty-if-we-re-not-in-g.patch |   53 ++++++++++++++++++++
>  meta/recipes-devtools/vala/vala.inc                |   20 ++++++++
>  meta/recipes-devtools/vala/vala_0.16.0.bb          |    8 +++
>  meta/recipes-gnome/libnotify/libnotify_0.6.0.bb    |   17 +++++++
>  meta/recipes-sato/midori/midori_0.5.5.bb           |   43 ++++++++++++++++
>  7 files changed, 177 insertions(+)
>  create mode 100644 meta/classes/vala.bbclass
>  create mode 100644 meta/recipes-devtools/python/python-docutils_0.11.bb
>  create mode 100644 meta/recipes-devtools/vala/vala-0.16.0/0001-git-version-gen-don-t-append-dirty-if-we-re-not-in-g.patch
>  create mode 100644 meta/recipes-devtools/vala/vala.inc
>  create mode 100644 meta/recipes-devtools/vala/vala_0.16.0.bb
>  create mode 100644 meta/recipes-gnome/libnotify/libnotify_0.6.0.bb
>  create mode 100644 meta/recipes-sato/midori/midori_0.5.5.bb
> 
> -- 
> 1.7.9.5
> 
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

Re: [PATCH 0/5] Add midori and dependencies

[Paul Eggleton]

On Wednesday 28 August 2013 10:18:15 Martin Jansa wrote:
> On Tue, Aug 27, 2013 at 05:59:34PM +0300, Mihai Prica wrote:
> > The Midori web-browser can be used to more easily test the functionality
> > of webkit-gtk.
> > 
> > * The midori and libnotify recipes are from meta-gnome.
> > * The python-docutils and vala recipes are from meta-oe.
> > * The midori and python-docutils packages have been updated to the latest
> > upstream version.
> > 
> > Midori also depends on ca-certificates. A patch set was sent by
> > Christopher
> > Larson that adds the recipe in oe-core. This series depends on his
> > addition.
>
> Are you going to send patches to oe-devel to remove moved
> recipes/bbclasses ?

I'll take care of this along with ca-certificates.

Cheers,
Paul

-- 

Paul Eggleton
Intel Open Source Technology Centre