* [PATCH 0/3] Upstream recipe for bootchart2 from WebOS (revised)
@ 2014-08-07 20:12 Max Eliaser
2014-08-07 20:12 ` [PATCH 1/3] python: python-pycairo: add python-pycairo-native Max Eliaser
` (2 more replies)
0 siblings, 3 replies; 4+ messages in thread
From: Max Eliaser @ 2014-08-07 20:12 UTC (permalink / raw)
To: openembedded-core
Hello list,
This series adds a recipe for the bootchart2 daemon (a fork of the original
bootchart.) It's based on a recipe from Meta-WebOS, but with extensive
modifications.
It is intended that bootchart2 will supersede the other bootchart daemons
kicking around in oe-core/meta-oe. See bug 5893. [1]
Regards,
-Max Eliaser
[1] https://bugzilla.yoctoproject.org/show_bug.cgi?id=5893
The following changes since commit 5452824960e8e77005a25ac11fd069d927523d3e:
default-distrovars.inc: Remove unused variable 'LIMIT_BUILT_LOCALES' (2014-06-13 13:08:44 +0100)
are available in the git repository at:
git://git.yoctoproject.org/poky-contrib meliaser/bootchart2-attempt2
http://git.yoctoproject.org/cgit.cgi/poky-contrib/log/?h=meliaser/bootchart2-attempt2
Max Eliaser (3):
python: python-pycairo: add python-pycairo-native
bootchart2: create recipe for bootchart2
ubootchart: delete ubootchart recipe
meta-yocto/conf/distro/include/distro_alias.inc | 1 -
meta-yocto/conf/distro/include/maintainers.inc | 1 -
meta-yocto/conf/distro/include/recipe_color.inc | 1 -
.../conf/distro/include/upstream_tracking.inc | 2 -
.../bootchart2/bootchart2/bootchartd_stop.sh | 18 +++
meta/recipes-devtools/bootchart2/bootchart2_git.bb | 148 +++++++++++++++++++++
.../python/python-pycairo_1.10.0.bb | 2 +
.../ubootchart/files/sysvinit.patch | 14 --
.../ubootchart/files/ubootchart-stop | 3 -
.../ubootchart/files/ubootchart.desktop | 6 -
meta/recipes-devtools/ubootchart/ubootchart_svn.bb | 39 ------
11 files changed, 168 insertions(+), 67 deletions(-)
create mode 100644 meta/recipes-devtools/bootchart2/bootchart2/bootchartd_stop.sh
create mode 100644 meta/recipes-devtools/bootchart2/bootchart2_git.bb
delete mode 100644 meta/recipes-devtools/ubootchart/files/sysvinit.patch
delete mode 100644 meta/recipes-devtools/ubootchart/files/ubootchart-stop
delete mode 100644 meta/recipes-devtools/ubootchart/files/ubootchart.desktop
delete mode 100644 meta/recipes-devtools/ubootchart/ubootchart_svn.bb
--
1.8.3.2
^ permalink raw reply [flat|nested] 4+ messages in thread
* [PATCH 1/3] python: python-pycairo: add python-pycairo-native
2014-08-07 20:12 [PATCH 0/3] Upstream recipe for bootchart2 from WebOS (revised) Max Eliaser
@ 2014-08-07 20:12 ` Max Eliaser
2014-08-07 20:12 ` [PATCH 2/3] bootchart2: create recipe for bootchart2 Max Eliaser
2014-08-07 20:12 ` [PATCH 3/3] ubootchart: delete ubootchart recipe Max Eliaser
2 siblings, 0 replies; 4+ messages in thread
From: Max Eliaser @ 2014-08-07 20:12 UTC (permalink / raw)
To: openembedded-core
A -native variant of python-pycairo will be necessary for running the native
version of pybootchartgui. It may also come in handy for running other Python
utilities from the native sysroot.
Signed-off-by: Max Eliaser <max.eliaser@intel.com>
---
meta/recipes-devtools/python/python-pycairo_1.10.0.bb | 2 ++
1 file changed, 2 insertions(+)
diff --git a/meta/recipes-devtools/python/python-pycairo_1.10.0.bb b/meta/recipes-devtools/python/python-pycairo_1.10.0.bb
index 5b59b6c..70fe25c 100644
--- a/meta/recipes-devtools/python/python-pycairo_1.10.0.bb
+++ b/meta/recipes-devtools/python/python-pycairo_1.10.0.bb
@@ -20,6 +20,8 @@ S = "${WORKDIR}/py2cairo-${PV}"
inherit distutils pkgconfig
+BBCLASSEXTEND = "native"
+
do_configure() {
BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} ./waf configure --prefix=${D}${prefix} --libdir=${D}${libdir}
}
--
1.8.3.2
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [PATCH 2/3] bootchart2: create recipe for bootchart2
2014-08-07 20:12 [PATCH 0/3] Upstream recipe for bootchart2 from WebOS (revised) Max Eliaser
2014-08-07 20:12 ` [PATCH 1/3] python: python-pycairo: add python-pycairo-native Max Eliaser
@ 2014-08-07 20:12 ` Max Eliaser
2014-08-07 20:12 ` [PATCH 3/3] ubootchart: delete ubootchart recipe Max Eliaser
2 siblings, 0 replies; 4+ messages in thread
From: Max Eliaser @ 2014-08-07 20:12 UTC (permalink / raw)
To: openembedded-core
This recipe creates packages for the bootchart2 system-wide profiler daemon
and related utilities. It fetches the Git revision immediately past the one
corresponding to the 0.14.6 release of bootchart2. (0.14.6 had a systemd-
related bug that was corrected right after it was tagged.)
The recipe contains three packages:
* bootchart2 - The daemon itself.
* pybootchartgui - Python program to visualize and display the data
collected by bootchart2 or compatible daemons such as the original
bootchart.
* bootchartd-stop-initscript - A SysV init script to stop data collection
when booting completes.
Depending on how you wish to use bootchart2, you may not end up having all
three of those packages installed on your image.
There is also a bootchart2-native variant, which is intended solely to provide
a native version of the pybootchartgui utility. The non-cross-compiled version
of the bootchart2 daemon has not been tested at all, don't use it.
The recipe is extensively documented. Read the comments at the beginning of
bootchart2_git.bb or else you'll have no idea how to use it.
This recipe is based on a recipe from meta-WebOS. The WebOS people had some
extra code (including patches against the bootchart2 code) to support the
Upstart init system. However, since upstream Poky does not support Upstart,
that stuff is being left behind. The WebOS people can write a bbappend to re-
add it.
Original recipe written by Wonhong Kwon of LG. Upstreamed as part of the
solution to [YOCTO #5893].
Signed-off-by: Max Eliaser <max.eliaser@intel.com>
---
.../bootchart2/bootchart2/bootchartd_stop.sh | 18 +++
meta/recipes-devtools/bootchart2/bootchart2_git.bb | 148 +++++++++++++++++++++
2 files changed, 166 insertions(+)
create mode 100644 meta/recipes-devtools/bootchart2/bootchart2/bootchartd_stop.sh
create mode 100644 meta/recipes-devtools/bootchart2/bootchart2_git.bb
diff --git a/meta/recipes-devtools/bootchart2/bootchart2/bootchartd_stop.sh b/meta/recipes-devtools/bootchart2/bootchart2/bootchartd_stop.sh
new file mode 100644
index 0000000..21a7887
--- /dev/null
+++ b/meta/recipes-devtools/bootchart2/bootchart2/bootchartd_stop.sh
@@ -0,0 +1,18 @@
+#!/bin/sh
+### BEGIN INIT INFO
+# Provides: bootchartd_stop
+# Required-Start: $remote_fs $all
+# Required-Stop:
+# Default-Start: 2 3 4 5
+# Default-Stop:
+# Short-Description: Stop bootchartd collection
+# Description: This script accompanies bootchartd from bootchart2.
+# bootchartd should stop detect the end of the boot process
+# automatically if a window manager is launched, but for
+# command-line only operating systems, this script should be
+# used instead.
+### END INIT INFO
+
+/sbin/bootchartd stop
+
+: exit 0
diff --git a/meta/recipes-devtools/bootchart2/bootchart2_git.bb b/meta/recipes-devtools/bootchart2/bootchart2_git.bb
new file mode 100644
index 0000000..e583852
--- /dev/null
+++ b/meta/recipes-devtools/bootchart2/bootchart2_git.bb
@@ -0,0 +1,148 @@
+# Copyright (c) 2013 LG Electronics, Inc.
+# Copyright (C) 2014 Intel Corp.
+
+# This recipe creates packages for the bootchart2 system-wide profiler daemon
+# and related utilities. Depending on the images you're building, additional
+# configuration may be needed in order to use it.
+#
+# Packages:
+# * bootchart2 - The daemon itself.
+# * pybootchartgui - Python program to visualize and display the data
+# collected by bootchart2 or compatible daemons such as the original
+# bootchart.
+# * bootchartd-stop-initscript - A SysV init script to stop data collection
+# when booting completes (see below for details.)
+#
+# While bootchart2 is designed to stop collecting data roughly when the boot
+# process completes, it is not exactly a stopwatch. It has a list of programs
+# which are supposed signify that the boot process has completed (for example,
+# openbox or gnome-shell,) but it waits a full 20 seconds after such a program
+# is launched before stopping itself, to collect additional data.
+#
+# If you are using a window manager or GUI which isn't included in bootchart2's
+# default configuration file, you should write bbappend file to amend
+# bootchartd.conf and add it to EXIT_PROC. An example of this is shown in this
+# recipe, where the Matchbox window manager (used by Sato) is added.
+#
+# If you want data collection to end at a certain point exactly, you should
+# arrange for the following command to be run:
+# bootchartd stop
+# You might set this command to be launched by the desktop environment shipped
+# on the image you're building after the other startup programs are complete.
+# This will not incur the 20 second wait period and will cause bootchart2 to
+# behave a bit more like a stopwatch. An example of this is shown in this
+# recipe, specifically the bootchartd-stop-initscript package, which stops data
+# collection as the last action when switching to runlevels 2 through 5. You can
+# add bootchartd-stop-initscript to IMAGE_INSTALL if you need to use it.
+#
+# Unless you're doing something special, if your image does not launch an X
+# window manager, you will need to add bootchartd-stop-initscript to your image.
+#
+# Bootchart2 can be started in two ways. Data collection can be initiated by
+# running the following command:
+# bootchartd start
+# However, for the most complete data, the bootchart2 developers recommend
+# running it as PID 1. This can be done by adding the following to the kernel
+# command line parameters in the bootloader setup:
+# init=/sbin/bootchartd
+# When invoked this way, bootchart2 will set itself up and then automatically
+# run /sbin/init. For example, when booting the default qemux86 image, one might
+# use a command like this:
+# runqemu qemux86 bootparams="initcall_debug printk.time=y quiet \
+# init=/sbin/bootchartd"
+#
+# Neither method is actually implemented here, choose what works for you.
+#
+# If you are building your image with systemd instead of SysV init, bootchart2
+# includes systemd service files to begin collection automatically at boot and
+# end collection automatically 20 seconds after the boot process has completed.
+# However, be aware that systemd tends to start bootchart2 relatively late into
+# the boot process, so it's highly recommended to use bootchart2 as PID 1. If
+# you're using systemd and you wish to use another method to stop data
+# collection at a time of your choosing, you may do so as long as you get to it
+# before the 20 second timeout of the systemd service files. Also, you may write
+# a bbappend to patch bootchart2-done.timer.in to increase or decrease the
+# timeout. Decreasing it to 0 will make it behave like
+# bootchartd-stop-initscript.
+#
+# By default, when data collection is stopped, a file named bootchart.tgz will
+# be created in /var/log. If pybootchartgui is included in your image,
+# bootchart.png will also be created at the same time. However, this results in
+# a noticeable hitch or pause at boot time, which may not be what you want on an
+# embedded device. So you may prefer to omit pybootchartgui from your image. In
+# that case, copy bootchart.tgz over to your development system and generate
+# bootchart.png there. To get pybootchartgui on your development system, you can
+# either install it directly from some other source, or build bootchart2-native
+# and find pybootchartgui in the native sysroot:
+# bitbake bootchart2-native
+# ./tmp/sysroots/x86_64-linux/usr/bin/pybootchartgui /path/to/bootchart.tgz
+# Note that, whether installed on your build system or on your image, the
+# pybootchartgui provided by this recipe does not support the -i option. You
+# will need to install pybootchartgui by other means in order to run it in
+# interactive mode.
+
+SUMMARY = "Booting sequence and CPU,I/O usage monitor"
+DESCRIPTION = "Monitors where the system spends its time at start, creating a graph of all processes, disk utilization, and wait time."
+AUTHOR = "Wonhong Kwon <wonhong.kwon@lge.com>"
+HOMEPAGE = "https://github.com/mmeeks/bootchart"
+LICENSE = "GPL-3.0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=44ac4678311254db62edf8fd39cb8124"
+
+# one commit beyond 1.14.6 for a systemd-related bugfix
+PV = "0.14.6+git${SRCPV}"
+
+SRC_URI = "git://github.com/mmeeks/bootchart.git"
+SRC_URI += "file://bootchartd_stop.sh"
+
+SRCREV = "b65ed43b0ae832080fb728245de9ef1a4b48d8b5"
+
+S = "${WORKDIR}/git"
+
+inherit systemd
+inherit update-rc.d
+inherit pythonnative
+
+# The only reason to build bootchart2-native is for a native pybootchartgui.
+BBCLASSEXTEND = "native"
+
+SYSTEMD_SERVICE_${PN} = "bootchart2.service bootchart2-done.service bootchart2-done.timer"
+
+UPDATERCPN = "bootchartd-stop-initscript"
+INITSCRIPT_NAME = "bootchartd_stop.sh"
+INITSCRIPT_PARAMS = "start 99 2 3 4 5 ."
+
+# We want native pybootchartgui to execute with the correct Python interpeter.
+do_compile_append_class-native () {
+ echo "#! ${PYTHON}" | cat - ${S}/pybootchartgui.py > ${WORKDIR}/temp_pybootchartgui
+ mv ${WORKDIR}/temp_pybootchartgui ${S}/pybootchartgui.py
+ chmod +x ${S}/pybootchartgui
+}
+
+do_install () {
+ install -d ${D}${sysconfdir} # needed for -native
+ export PY_LIBDIR="${libdir}/${PYTHON_DIR}"
+ export BINDIR="${bindir}"
+ export DESTDIR="${D}"
+
+ oe_runmake install
+ install -d ${D}${sysconfdir}/init.d
+ install -m 0755 ${WORKDIR}/bootchartd_stop.sh ${D}${sysconfdir}/init.d
+
+ echo 'EXIT_PROC="$EXIT_PROC matchbox-window-manager"' >> ${D}${sysconfdir}/bootchartd.conf
+}
+
+PACKAGES =+ "pybootchartgui"
+FILES_pybootchartgui += "${libdir}/python*/site-packages/pybootchartgui ${bindir}/pybootchartgui"
+RDEPENDS_pybootchartgui = "python-pycairo python-compression python-image python-textutils python-shell python-compression python-codecs"
+DEPENDS_append_class-native = " python-pycairo-native"
+
+PACKAGES =+ "bootchartd-stop-initscript"
+FILES_bootchartd-stop-initscript += "${sysconfdir}/init.d ${sysconfdir}/rc*.d"
+
+FILES_${PN} += "${base_libdir}/bootchart/bootchart-collector"
+FILES_${PN} += "${base_libdir}/bootchart/tmpfs"
+FILES_${PN} += "${libdir}"
+FILES_${PN}-dbg += "${base_libdir}/bootchart/.debug"
+FILES_${PN}-doc += "${datadir}/docs"
+
+RCONFLICTS_${PN} = "bootchart"
--
1.8.3.2
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [PATCH 3/3] ubootchart: delete ubootchart recipe
2014-08-07 20:12 [PATCH 0/3] Upstream recipe for bootchart2 from WebOS (revised) Max Eliaser
2014-08-07 20:12 ` [PATCH 1/3] python: python-pycairo: add python-pycairo-native Max Eliaser
2014-08-07 20:12 ` [PATCH 2/3] bootchart2: create recipe for bootchart2 Max Eliaser
@ 2014-08-07 20:12 ` Max Eliaser
2 siblings, 0 replies; 4+ messages in thread
From: Max Eliaser @ 2014-08-07 20:12 UTC (permalink / raw)
To: openembedded-core
The Ubootchart recipe had known issues. Ubootchart itself is no longer updated
upstream. Ubootchart is also now redundant with Bootchart2.
If people still want ubootchart around, it can be moved to meta-oe.
Ubootchart removed as part of the solution to [YOCTO #5893].
Signed-off-by: Max Eliaser <max.eliaser@intel.com>
---
meta-yocto/conf/distro/include/distro_alias.inc | 1 -
meta-yocto/conf/distro/include/maintainers.inc | 1 -
meta-yocto/conf/distro/include/recipe_color.inc | 1 -
.../conf/distro/include/upstream_tracking.inc | 2 --
.../ubootchart/files/sysvinit.patch | 14 --------
.../ubootchart/files/ubootchart-stop | 3 --
.../ubootchart/files/ubootchart.desktop | 6 ----
meta/recipes-devtools/ubootchart/ubootchart_svn.bb | 39 ----------------------
8 files changed, 67 deletions(-)
delete mode 100644 meta/recipes-devtools/ubootchart/files/sysvinit.patch
delete mode 100644 meta/recipes-devtools/ubootchart/files/ubootchart-stop
delete mode 100644 meta/recipes-devtools/ubootchart/files/ubootchart.desktop
delete mode 100644 meta/recipes-devtools/ubootchart/ubootchart_svn.bb
diff --git a/meta-yocto/conf/distro/include/distro_alias.inc b/meta-yocto/conf/distro/include/distro_alias.inc
index 48c1d92..5e2f214 100644
--- a/meta-yocto/conf/distro/include/distro_alias.inc
+++ b/meta-yocto/conf/distro/include/distro_alias.inc
@@ -435,7 +435,6 @@ DISTRO_PN_ALIAS_pn-tremor = "OSPDT upstream=http://www.xiph.org/vorbis/"
DISTRO_PN_ALIAS_pn-tslib = "Debian=tslib Ubuntu=tslib"
DISTRO_PN_ALIAS_pn-ttf-bitstream-vera = "Debian=ttf-bitstream-vera Ubuntu=ttf-bitstream-vera"
DISTRO_PN_ALIAS_pn-tzcode = "OSPDT"
-DISTRO_PN_ALIAS_pn-ubootchart = "OSPDT upstream=http://code.google.com/p/ubootchart"
DISTRO_PN_ALIAS_pn-u-boot-fw-utils = "Ubuntu=u-boot-tools Debian=u-boot-tools"
DISTRO_PN_ALIAS_pn-u-boot-mkimage = "Ubuntu=uboot-mkimage Debian=uboot-mkimage"
DISTRO_PN_ALIAS_pn-udev-extraconf = "OE-Core"
diff --git a/meta-yocto/conf/distro/include/maintainers.inc b/meta-yocto/conf/distro/include/maintainers.inc
index 7430c85..13e9209 100644
--- a/meta-yocto/conf/distro/include/maintainers.inc
+++ b/meta-yocto/conf/distro/include/maintainers.inc
@@ -646,7 +646,6 @@ RECIPE_MAINTAINER_pn-tslib = "Paul Eggleton <paul.eggleton@linux.intel.com>"
RECIPE_MAINTAINER_pn-ttf-bitstream-vera = "Valentin Popa <valentin.popa@intel.com>"
RECIPE_MAINTAINER_pn-tzcode-native = "Robert Yang <liezhi.yang@windriver.com>"
RECIPE_MAINTAINER_pn-tzdata = "Robert Yang <liezhi.yang@windriver.com>"
-RECIPE_MAINTAINER_pn-ubootchart = "Cristiana Voicu <cristiana.voicu@intel.com>"
RECIPE_MAINTAINER_pn-u-boot-fw-utils = "Cristiana Voicu <cristiana.voicu@intel.com>"
RECIPE_MAINTAINER_pn-u-boot-mkimage = "Cristiana Voicu <cristiana.voicu@intel.com>"
RECIPE_MAINTAINER_pn-udev-extraconf = "Cristiana Voicu <cristiana.voicu@intel.com>"
diff --git a/meta-yocto/conf/distro/include/recipe_color.inc b/meta-yocto/conf/distro/include/recipe_color.inc
index 7e50500..5474e83 100644
--- a/meta-yocto/conf/distro/include/recipe_color.inc
+++ b/meta-yocto/conf/distro/include/recipe_color.inc
@@ -383,7 +383,6 @@ RECIPE_COLOR_pn-trapproto = "yellow"
RECIPE_COLOR_pn-tslib = "yellow"
RECIPE_COLOR_pn-ttf-bitstream-vera = "yellow"
RECIPE_COLOR_pn-tzdata = "yellow"
-RECIPE_COLOR_pn-ubootchart = "red"
RECIPE_COLOR_pn-u-boot-mkimage = "red"
RECIPE_COLOR_pn-udev = "yellow"
RECIPE_COLOR_pn-udev-extraconf = "yellow"
diff --git a/meta-yocto/conf/distro/include/upstream_tracking.inc b/meta-yocto/conf/distro/include/upstream_tracking.inc
index d80ede4..714b692 100644
--- a/meta-yocto/conf/distro/include/upstream_tracking.inc
+++ b/meta-yocto/conf/distro/include/upstream_tracking.inc
@@ -207,8 +207,6 @@ RECIPE_UPSTREAM_VERSION_pn-tremor="20120122"
RECIPE_UPSTREAM_DATE_pn-tremor="Jan 22, 2012"
CHECK_DATE_pn-tremor = "Mar 11, 2013"
RECIPE_NO_UPDATE_REASON_pn-tremor = "Same revision on different SVN modules"
-RECIPE_UPSTREAM_VERSION_pn-ubootchart = "0.0+r12"
-CHECK_DATE_pn-ubootchart = "Sep 11, 2012"
RECIPE_UPSTREAM_DATE_pn-udev-extraconf = "n/a"
RECIPE_UPSTREAM_VERSION_pn-unifdef-native="2.6.18+git"
RECIPE_UPSTREAM_DATE_pn-unifdef-native = "Feb 05, 2011"
diff --git a/meta/recipes-devtools/ubootchart/files/sysvinit.patch b/meta/recipes-devtools/ubootchart/files/sysvinit.patch
deleted file mode 100644
index fc82ed8..0000000
--- a/meta/recipes-devtools/ubootchart/files/sysvinit.patch
+++ /dev/null
@@ -1,14 +0,0 @@
-Upstream-Status: Inappropriate [distribution]
-
-Index: ubootchart.conf
-===================================================================
---- ubootchart.conf (revision 9)
-+++ ubootchart.conf (working copy)
-@@ -1,6 +1,6 @@
-
- # If you want to chain on and run somthing other than /sbin/init...
--export init_prog=/sbin/init
-+export init_prog=/sbin/init.sysvinit
-
- # On startup ubootchart will mount a tmpfs filesystem at this
- # location and chdir here. This is only used for the logging of
diff --git a/meta/recipes-devtools/ubootchart/files/ubootchart-stop b/meta/recipes-devtools/ubootchart/files/ubootchart-stop
deleted file mode 100644
index 3444069..0000000
--- a/meta/recipes-devtools/ubootchart/files/ubootchart-stop
+++ /dev/null
@@ -1,3 +0,0 @@
-#! /bin/sh
-
-kill -USR1 $(pidof ubootchartd_bin)
diff --git a/meta/recipes-devtools/ubootchart/files/ubootchart.desktop b/meta/recipes-devtools/ubootchart/files/ubootchart.desktop
deleted file mode 100644
index 5552b3b..0000000
--- a/meta/recipes-devtools/ubootchart/files/ubootchart.desktop
+++ /dev/null
@@ -1,6 +0,0 @@
-[Desktop Entry]
-Encoding=UTF-8
-Exec=/sbin/ubootchart-stop
-Name=Stop Bootchart
-Type=Application
-Categories=Programming;
diff --git a/meta/recipes-devtools/ubootchart/ubootchart_svn.bb b/meta/recipes-devtools/ubootchart/ubootchart_svn.bb
deleted file mode 100644
index b13755e..0000000
--- a/meta/recipes-devtools/ubootchart/ubootchart_svn.bb
+++ /dev/null
@@ -1,39 +0,0 @@
-SUMMARY = "A boot profiling tool"
-HOMEPAGE = "http://code.google.com/p/ubootchart/"
-LICENSE = "GPLv3"
-LIC_FILES_CHKSUM = "file://COPYING;md5=8f0e2cd40e05189ec81232da84bd6e1a"
-SRCREV = "12"
-PV = "0.0+r${SRCPV}"
-PR = "r6"
-
-#RRECOMMENDS_${PN} = "acct"
-
-SRC_URI = "svn://ubootchart.googlecode.com/svn/;protocol=http;module=trunk \
- file://sysvinit.patch;striplevel=0 \
- file://ubootchart-stop \
- file://ubootchart.desktop"
-
-S = "${WORKDIR}/trunk"
-
-inherit update-alternatives
-
-ALTERNATIVE_${PN} = "init"
-ALTERNATIVE_TARGET[init] = "${base_sbindir}/ubootchartd"
-ALTERNATIVE_LINK_NAME[init] = "${base_sbindir}/init"
-ALTERNATIVE_PRIORITY = "70"
-
-do_compile() {
- ${CC} ${CFLAGS} ${LDFLAGS} ${LIBS} ${INCLUDES} ${S}/ubootchartd_bin.c -o ubootchartd_bin
-}
-
-do_install() {
- install -m 0755 -d ${D}${base_sbindir} ${D}${sysconfdir}/ubootchart ${D}${datadir}/applications
- install -m 0755 ${S}/ubootchartd_bin ${D}${base_sbindir}
- install -m 0755 ${S}/ubootchartd ${D}${base_sbindir}
- install -m 0644 ${S}/ubootchart.conf ${D}${sysconfdir}/ubootchart
- install -m 0755 ${S}/start.sh ${D}${sysconfdir}/ubootchart
- install -m 0755 ${S}/finish.sh ${D}${sysconfdir}/ubootchart
-
- install -m 0755 ${WORKDIR}/ubootchart-stop ${D}${base_sbindir}
- install -m 0644 ${WORKDIR}/ubootchart.desktop ${D}${datadir}/applications
-}
--
1.8.3.2
^ permalink raw reply related [flat|nested] 4+ messages in thread
end of thread, other threads:[~2014-08-07 20:15 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-08-07 20:12 [PATCH 0/3] Upstream recipe for bootchart2 from WebOS (revised) Max Eliaser
2014-08-07 20:12 ` [PATCH 1/3] python: python-pycairo: add python-pycairo-native Max Eliaser
2014-08-07 20:12 ` [PATCH 2/3] bootchart2: create recipe for bootchart2 Max Eliaser
2014-08-07 20:12 ` [PATCH 3/3] ubootchart: delete ubootchart recipe Max Eliaser
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox