[PATCH 0/7][python3] buildtools-tarball: replace python with python3

[PATCH 0/7][python3] buildtools-tarball: replace python with python3

[Robert Yang]

The following changes since commit 84b11bce72296d04a0e6bc9f18669284017c3704:

  pkgconfig: Update AM_GLIB_GNU_GETTEXT macro (2016-05-17 17:26:05 +0100)

are available in the git repository at:

  git://git.openembedded.org/openembedded-core-contrib rbt/btpy3
  http://cgit.openembedded.org/cgit.cgi/openembedded-core-contrib/log/?h=rbt/btpy3

Robert Yang (7):
  python3-smmap: add it for python3-gitdb
  python3-async: add it for python3-gitdb
  python3-gitdb: add it for python3-git
  python3-git: add it for buildtools-tarball
  buildtools-tarball: remove nativesdk-python-pexpect
  buildtools-tarball: replace nativesdk-python with nativesdk-python3
  buildtools-tarball: add nativesdk-locale-base-en-us

 meta/recipes-core/meta/buildtools-tarball.bb       | 12 ++++++------
 meta/recipes-devtools/python/python-async.inc      | 15 +++++++++++++++
 meta/recipes-devtools/python/python-async_0.6.2.bb | 16 +---------------
 meta/recipes-devtools/python/python-git.inc        | 21 +++++++++++++++++++++
 meta/recipes-devtools/python/python-git_1.0.2.bb   | 22 ++--------------------
 meta/recipes-devtools/python/python-gitdb.inc      | 16 ++++++++++++++++
 meta/recipes-devtools/python/python-gitdb_0.6.4.bb | 18 ++----------------
 meta/recipes-devtools/python/python-smmap.inc      | 19 +++++++++++++++++++
 meta/recipes-devtools/python/python-smmap_0.9.0.bb | 20 +-------------------
 .../recipes-devtools/python/python3-async_0.6.2.bb |  6 ++++++
 meta/recipes-devtools/python/python3-git_1.0.2.bb  |  7 +++++++
 .../recipes-devtools/python/python3-gitdb_0.6.4.bb |  7 +++++++
 .../recipes-devtools/python/python3-smmap_0.9.0.bb |  5 +++++
 13 files changed, 108 insertions(+), 76 deletions(-)
 create mode 100644 meta/recipes-devtools/python/python-async.inc
 create mode 100644 meta/recipes-devtools/python/python-git.inc
 create mode 100644 meta/recipes-devtools/python/python-gitdb.inc
 create mode 100644 meta/recipes-devtools/python/python-smmap.inc
 create mode 100644 meta/recipes-devtools/python/python3-async_0.6.2.bb
 create mode 100644 meta/recipes-devtools/python/python3-git_1.0.2.bb
 create mode 100644 meta/recipes-devtools/python/python3-gitdb_0.6.4.bb
 create mode 100644 meta/recipes-devtools/python/python3-smmap_0.9.0.bb

-- 
2.8.0

[PATCH 1/7] python3-smmap: add it for python3-gitdb

[Robert Yang]

Need add python3-git to buildtools-tarball for the py3 build, and the
dependencies chain is:

python3-git -> python3-gitdb -> python3-smmap

Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
---
 meta/recipes-devtools/python/python-smmap.inc       | 19 +++++++++++++++++++
 meta/recipes-devtools/python/python-smmap_0.9.0.bb  | 20 +-------------------
 meta/recipes-devtools/python/python3-smmap_0.9.0.bb |  5 +++++
 3 files changed, 25 insertions(+), 19 deletions(-)
 create mode 100644 meta/recipes-devtools/python/python-smmap.inc
 create mode 100644 meta/recipes-devtools/python/python3-smmap_0.9.0.bb

diff --git a/meta/recipes-devtools/python/python-smmap.inc b/meta/recipes-devtools/python/python-smmap.inc
new file mode 100644
index 0000000..5b2ac74
--- /dev/null
+++ b/meta/recipes-devtools/python/python-smmap.inc
@@ -0,0 +1,19 @@
+SUMMARY = "Python implementation of a sliding window memory map manager"
+DESCRIPTION = "A pure Python implementation of a sliding memory map to \
+help unifying memory mapped access on 32 and 64 bit systems and to help \
+managing resources more efficiently."
+HOMEPAGE = "http://github.com/gitpython-developers/GitPython"
+SECTION = "devel/python"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://PKG-INFO;beginline=8;endline=8;md5=e910b35b0ef4e1f665b9a75d6afb7709"
+
+SRC_URI = "http://pypi.python.org/packages/source/s/smmap/smmap-${PV}.tar.gz"
+SRC_URI[md5sum] = "d7932d5ace206bf4ae15198cf36fb6ab"
+SRC_URI[sha256sum] = "0e2b62b497bd5f0afebc002eda4d90df9d209c30ef257e8673c90a6b5c119d62"
+
+UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/smmap/"
+UPSTREAM_CHECK_REGEX = "/smmap/(?P<pver>(\d+[\.\-_]*)+)"
+
+S = "${WORKDIR}/smmap-${PV}"
+
+BBCLASSEXTEND = "nativesdk"
diff --git a/meta/recipes-devtools/python/python-smmap_0.9.0.bb b/meta/recipes-devtools/python/python-smmap_0.9.0.bb
index 5f9cf45..c118dd8 100644
--- a/meta/recipes-devtools/python/python-smmap_0.9.0.bb
+++ b/meta/recipes-devtools/python/python-smmap_0.9.0.bb
@@ -1,23 +1,5 @@
-SUMMARY = "Python implementation of a sliding window memory map manager"
-DESCRIPTION = "A pure Python implementation of a sliding memory map to \
-help unifying memory mapped access on 32 and 64 bit systems and to help \
-managing resources more efficiently."
-HOMEPAGE = "http://github.com/gitpython-developers/GitPython"
-SECTION = "devel/python"
-LICENSE = "BSD"
-LIC_FILES_CHKSUM = "file://PKG-INFO;beginline=8;endline=8;md5=e910b35b0ef4e1f665b9a75d6afb7709"
-
-SRC_URI = "http://pypi.python.org/packages/source/s/smmap/smmap-${PV}.tar.gz"
-SRC_URI[md5sum] = "d7932d5ace206bf4ae15198cf36fb6ab"
-SRC_URI[sha256sum] = "0e2b62b497bd5f0afebc002eda4d90df9d209c30ef257e8673c90a6b5c119d62"
-
-UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/smmap/"
-UPSTREAM_CHECK_REGEX = "/smmap/(?P<pver>(\d+[\.\-_]*)+)"
-
-S = "${WORKDIR}/smmap-${PV}"
+require python-smmap.inc
 
 inherit setuptools
 
 RDEPENDS_${PN} += "python-codecs python-mmap python-lang"
-
-BBCLASSEXTEND = "nativesdk"
diff --git a/meta/recipes-devtools/python/python3-smmap_0.9.0.bb b/meta/recipes-devtools/python/python3-smmap_0.9.0.bb
new file mode 100644
index 0000000..9f8a26d
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-smmap_0.9.0.bb
@@ -0,0 +1,5 @@
+require python-smmap.inc
+
+inherit setuptools3
+
+RDEPENDS_${PN} += "python3-codecs python3-mmap python3-lang"
-- 
2.8.0

[PATCH 2/7] python3-async: add it for python3-gitdb

[Robert Yang]

Need add python3-git to buildtools-tarball for the py3 build, and the
dependencies chain is:

python3-git -> python3-gitdb -> python3-async

Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
---
 meta/recipes-devtools/python/python-async.inc       | 15 +++++++++++++++
 meta/recipes-devtools/python/python-async_0.6.2.bb  | 16 +---------------
 meta/recipes-devtools/python/python3-async_0.6.2.bb |  6 ++++++
 3 files changed, 22 insertions(+), 15 deletions(-)
 create mode 100644 meta/recipes-devtools/python/python-async.inc
 create mode 100644 meta/recipes-devtools/python/python3-async_0.6.2.bb

diff --git a/meta/recipes-devtools/python/python-async.inc b/meta/recipes-devtools/python/python-async.inc
new file mode 100644
index 0000000..d80606a
--- /dev/null
+++ b/meta/recipes-devtools/python/python-async.inc
@@ -0,0 +1,15 @@
+SUMMARY = "Python framework to process interdependent tasks in a pool of workers"
+HOMEPAGE = "http://github.com/gitpython-developers/async"
+SECTION = "devel/python"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://PKG-INFO;beginline=8;endline=8;md5=88df8e78b9edfd744953862179f2d14e"
+
+SRC_URI = "http://pypi.python.org/packages/source/a/async/async-${PV}.tar.gz"
+SRC_URI[md5sum] = "9b06b5997de2154f3bc0273f80bcef6b"
+SRC_URI[sha256sum] = "ac6894d876e45878faae493b0cf61d0e28ec417334448ac0a6ea2229d8343051"
+
+UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/async/"
+
+S = "${WORKDIR}/async-${PV}"
+
+BBCLASSEXTEND = "nativesdk"
diff --git a/meta/recipes-devtools/python/python-async_0.6.2.bb b/meta/recipes-devtools/python/python-async_0.6.2.bb
index ad0a617..d855e42 100644
--- a/meta/recipes-devtools/python/python-async_0.6.2.bb
+++ b/meta/recipes-devtools/python/python-async_0.6.2.bb
@@ -1,19 +1,5 @@
-SUMMARY = "Python framework to process interdependent tasks in a pool of workers"
-HOMEPAGE = "http://github.com/gitpython-developers/async"
-SECTION = "devel/python"
-LICENSE = "BSD"
-LIC_FILES_CHKSUM = "file://PKG-INFO;beginline=8;endline=8;md5=88df8e78b9edfd744953862179f2d14e"
-
-SRC_URI = "http://pypi.python.org/packages/source/a/async/async-${PV}.tar.gz"
-SRC_URI[md5sum] = "9b06b5997de2154f3bc0273f80bcef6b"
-SRC_URI[sha256sum] = "ac6894d876e45878faae493b0cf61d0e28ec417334448ac0a6ea2229d8343051"
-
-UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/async/"
-
-S = "${WORKDIR}/async-${PV}"
+require python-async.inc
 
 inherit setuptools
 
 RDEPENDS_${PN} += "python-threading python-lang"
-
-BBCLASSEXTEND = "nativesdk"
diff --git a/meta/recipes-devtools/python/python3-async_0.6.2.bb b/meta/recipes-devtools/python/python3-async_0.6.2.bb
new file mode 100644
index 0000000..54a30f5
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-async_0.6.2.bb
@@ -0,0 +1,6 @@
+require python-async.inc
+
+inherit setuptools3
+
+RDEPENDS_${PN} += "python3-threading python3-lang"
+
-- 
2.8.0

[PATCH 3/7] python3-gitdb: add it for python3-git

[Robert Yang]

Need add python3-git to buildtools-tarball for the py3 build, and the
dependencies chain is:

python3-git -> python3-gitdb

Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
---
 meta/recipes-devtools/python/python-gitdb.inc       | 16 ++++++++++++++++
 meta/recipes-devtools/python/python-gitdb_0.6.4.bb  | 18 ++----------------
 meta/recipes-devtools/python/python3-gitdb_0.6.4.bb |  7 +++++++
 3 files changed, 25 insertions(+), 16 deletions(-)
 create mode 100644 meta/recipes-devtools/python/python-gitdb.inc
 create mode 100644 meta/recipes-devtools/python/python3-gitdb_0.6.4.bb

diff --git a/meta/recipes-devtools/python/python-gitdb.inc b/meta/recipes-devtools/python/python-gitdb.inc
new file mode 100644
index 0000000..6467bd2
--- /dev/null
+++ b/meta/recipes-devtools/python/python-gitdb.inc
@@ -0,0 +1,16 @@
+SUMMARY = "A pure-Python git object database"
+HOMEPAGE = "http://github.com/gitpython-developers/gitdb"
+SECTION = "devel/python"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=59e5ecb13339a936eedf83282eaf4528"
+
+SRC_URI = "https://pypi.python.org/packages/source/g/gitdb/gitdb-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "44e4366b8bdfd306b075c3a52c96ae1a"
+SRC_URI[sha256sum] = "a3ebbc27be035a2e874ed904df516e35f4a29a778a764385de09de9e0f139658"
+
+UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/gitdb/"
+
+S = "${WORKDIR}/gitdb-${PV}"
+
+BBCLASSEXTEND = "nativesdk"
diff --git a/meta/recipes-devtools/python/python-gitdb_0.6.4.bb b/meta/recipes-devtools/python/python-gitdb_0.6.4.bb
index c82df1e..1777395 100644
--- a/meta/recipes-devtools/python/python-gitdb_0.6.4.bb
+++ b/meta/recipes-devtools/python/python-gitdb_0.6.4.bb
@@ -1,21 +1,7 @@
-SUMMARY = "A pure-Python git object database"
-HOMEPAGE = "http://github.com/gitpython-developers/gitdb"
-SECTION = "devel/python"
-LICENSE = "BSD-3-Clause"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=59e5ecb13339a936eedf83282eaf4528"
-DEPENDS = "python-async python-smmap"
-
-SRC_URI = "https://pypi.python.org/packages/source/g/gitdb/gitdb-${PV}.tar.gz"
-
-SRC_URI[md5sum] = "44e4366b8bdfd306b075c3a52c96ae1a"
-SRC_URI[sha256sum] = "a3ebbc27be035a2e874ed904df516e35f4a29a778a764385de09de9e0f139658"
+require python-gitdb.inc
 
-UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/gitdb/"
-
-S = "${WORKDIR}/gitdb-${PV}"
+DEPENDS = "python-async python-smmap"
 
 inherit distutils
 
 RDEPENDS_${PN} += "python-smmap python-async python-mmap python-lang python-zlib python-io python-shell"
-
-BBCLASSEXTEND = "nativesdk"
diff --git a/meta/recipes-devtools/python/python3-gitdb_0.6.4.bb b/meta/recipes-devtools/python/python3-gitdb_0.6.4.bb
new file mode 100644
index 0000000..9927658
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-gitdb_0.6.4.bb
@@ -0,0 +1,7 @@
+require python-gitdb.inc
+
+DEPENDS = "python3-async python3-smmap"
+
+inherit distutils3
+
+RDEPENDS_${PN} += "python3-smmap python3-async python3-mmap python3-lang python3-io python3-shell"
-- 
2.8.0

[PATCH 4/7] python3-git: add it for buildtools-tarball

[Robert Yang]

Need add python3-git to buildtools-tarball for the py3 build.

Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
---
 meta/recipes-devtools/python/python-git.inc       | 21 +++++++++++++++++++++
 meta/recipes-devtools/python/python-git_1.0.2.bb  | 22 ++--------------------
 meta/recipes-devtools/python/python3-git_1.0.2.bb |  7 +++++++
 3 files changed, 30 insertions(+), 20 deletions(-)
 create mode 100644 meta/recipes-devtools/python/python-git.inc
 create mode 100644 meta/recipes-devtools/python/python3-git_1.0.2.bb

diff --git a/meta/recipes-devtools/python/python-git.inc b/meta/recipes-devtools/python/python-git.inc
new file mode 100644
index 0000000..72632b7
--- /dev/null
+++ b/meta/recipes-devtools/python/python-git.inc
@@ -0,0 +1,21 @@
+SUMMARY = "Python library used to interact with Git repositories"
+DESCRIPTION = "GitPython provides object model read and write access to \
+a git repository. Access repository information conveniently, alter the \
+index directly, handle remotes, or go down to low-level object database \
+access with big-files support."
+HOMEPAGE = "http://github.com/gitpython-developers/GitPython"
+SECTION = "devel/python"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=8b8d26c37c1d5a04f9b0186edbebc183"
+
+SRC_URI = "http://pypi.python.org/packages/source/G/GitPython/GitPython-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "d92d96a8da0fc77cf141d3e16084e094"
+SRC_URI[sha256sum] = "85de72556781480a38897a77de5b458ae3838b0fd589593679a1b5f34d181d84"
+
+UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/GitPython/"
+UPSTREAM_CHECK_REGEX = "/GitPython/(?P<pver>(\d+[\.\-_]*)+)"
+
+S = "${WORKDIR}/GitPython-${PV}"
+
+BBCLASSEXTEND = "nativesdk"
diff --git a/meta/recipes-devtools/python/python-git_1.0.2.bb b/meta/recipes-devtools/python/python-git_1.0.2.bb
index f00f805..5ca7713 100644
--- a/meta/recipes-devtools/python/python-git_1.0.2.bb
+++ b/meta/recipes-devtools/python/python-git_1.0.2.bb
@@ -1,26 +1,8 @@
-SUMMARY = "Python library used to interact with Git repositories"
-DESCRIPTION = "GitPython provides object model read and write access to \
-a git repository. Access repository information conveniently, alter the \
-index directly, handle remotes, or go down to low-level object database \
-access with big-files support."
-HOMEPAGE = "http://github.com/gitpython-developers/GitPython"
-SECTION = "devel/python"
-LICENSE = "BSD-3-Clause"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=8b8d26c37c1d5a04f9b0186edbebc183"
-DEPENDS = "python-gitdb"
-
-SRC_URI = "http://pypi.python.org/packages/source/G/GitPython/GitPython-${PV}.tar.gz"
-
-SRC_URI[md5sum] = "d92d96a8da0fc77cf141d3e16084e094"
-SRC_URI[sha256sum] = "85de72556781480a38897a77de5b458ae3838b0fd589593679a1b5f34d181d84"
+require python-git.inc
 
-UPSTREAM_CHECK_URI = "https://pypi.python.org/pypi/GitPython/"
-UPSTREAM_CHECK_REGEX = "/GitPython/(?P<pver>(\d+[\.\-_]*)+)"
-
-S = "${WORKDIR}/GitPython-${PV}"
+DEPENDS = "python-gitdb"
 
 inherit setuptools
 
 RDEPENDS_${PN} += "python-gitdb python-lang python-io python-shell python-math python-re python-subprocess python-stringold python-unixadmin"
 
-BBCLASSEXTEND = "nativesdk"
diff --git a/meta/recipes-devtools/python/python3-git_1.0.2.bb b/meta/recipes-devtools/python/python3-git_1.0.2.bb
new file mode 100644
index 0000000..6620444
--- /dev/null
+++ b/meta/recipes-devtools/python/python3-git_1.0.2.bb
@@ -0,0 +1,7 @@
+require python-git.inc
+
+DEPENDS = "python3-gitdb"
+
+inherit setuptools3
+
+RDEPENDS_${PN} += "python3-gitdb python3-lang python3-io python3-shell python3-math python3-re python3-subprocess python3-stringold python3-unixadmin"
-- 
2.8.0

[PATCH 5/7] buildtools-tarball: remove nativesdk-python-pexpect

[Robert Yang]

It was added for testing, and not needed any more after:
4a8a74c62836a20610daf029d4cec0b3087758b2
Author: Robert Yang <liezhi.yang@windriver.com>
Date:   Mon Mar 21 02:25:50 2016 -0700

    gpg_sign.py: get rid of pexpect

So remove it.

Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
---
 meta/recipes-core/meta/buildtools-tarball.bb | 1 -
 1 file changed, 1 deletion(-)

diff --git a/meta/recipes-core/meta/buildtools-tarball.bb b/meta/recipes-core/meta/buildtools-tarball.bb
index e9578ca..dd28b96 100644
--- a/meta/recipes-core/meta/buildtools-tarball.bb
+++ b/meta/recipes-core/meta/buildtools-tarball.bb
@@ -12,7 +12,6 @@ TOOLCHAIN_HOST_TASK ?= "\
     nativesdk-python-modules \
     nativesdk-python-misc \
     nativesdk-python-git \
-    nativesdk-python-pexpect \
     nativesdk-ncurses-terminfo-base \
     nativesdk-chrpath \
     nativesdk-tar \
-- 
2.8.0

[PATCH 6/7] buildtools-tarball: replace nativesdk-python with nativesdk-python3

[Robert Yang]

Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
---
 meta/recipes-core/meta/buildtools-tarball.bb | 10 +++++-----
 1 file changed, 5 insertions(+), 5 deletions(-)

diff --git a/meta/recipes-core/meta/buildtools-tarball.bb b/meta/recipes-core/meta/buildtools-tarball.bb
index dd28b96..f45e781 100644
--- a/meta/recipes-core/meta/buildtools-tarball.bb
+++ b/meta/recipes-core/meta/buildtools-tarball.bb
@@ -1,4 +1,4 @@
-DESCRIPTION = "SDK type target for building a standalone tarball containing python, chrpath, make, git and tar. The \
+DESCRIPTION = "SDK type target for building a standalone tarball containing python3, chrpath, make, git and tar. The \
                tarball can be used to run bitbake builds on systems which don't meet the usual version requirements."
 SUMMARY = "Standalone tarball for running builds on systems with inadequate software"
 LICENSE = "MIT"
@@ -8,10 +8,10 @@ LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=4d92cd373abda3937c2bc47fbc49d
 TOOLCHAIN_TARGET_TASK ?= ""
 
 TOOLCHAIN_HOST_TASK ?= "\
-    nativesdk-python-core \
-    nativesdk-python-modules \
-    nativesdk-python-misc \
-    nativesdk-python-git \
+    nativesdk-python3-core \
+    nativesdk-python3-modules \
+    nativesdk-python3-misc \
+    nativesdk-python3-git \
     nativesdk-ncurses-terminfo-base \
     nativesdk-chrpath \
     nativesdk-tar \
-- 
2.8.0

[PATCH 7/7] buildtools-tarball: add nativesdk-locale-base-en-us

[Robert Yang]

It is required by python3's bitbake.

Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
---
 meta/recipes-core/meta/buildtools-tarball.bb | 1 +
 1 file changed, 1 insertion(+)

diff --git a/meta/recipes-core/meta/buildtools-tarball.bb b/meta/recipes-core/meta/buildtools-tarball.bb
index f45e781..34df531 100644
--- a/meta/recipes-core/meta/buildtools-tarball.bb
+++ b/meta/recipes-core/meta/buildtools-tarball.bb
@@ -23,6 +23,7 @@ TOOLCHAIN_HOST_TASK ?= "\
     nativesdk-wget \
     nativesdk-ca-certificates \
     nativesdk-texinfo \
+    nativesdk-locale-base-en-us \
     "
 
 SDK_PACKAGE_ARCHS += "buildtools-dummy-${SDKPKGSUFFIX}"
-- 
2.8.0

Re: [PATCH 0/7][python3] buildtools-tarball: replace python with python3

[Alexander Kanavin]

On 05/18/2016 10:43 AM, Robert Yang wrote:

> Robert Yang (7):
>    python3-smmap: add it for python3-gitdb
>    python3-async: add it for python3-gitdb
>    python3-gitdb: add it for python3-git
>    python3-git: add it for buildtools-tarball

You can remove the Python 2 versions at the same time. Nothing is 
requiring them in oe-core or meta-oe.

Alex

Re: [PATCH 5/7] buildtools-tarball: remove nativesdk-python-pexpect

[Alexander Kanavin]

On 05/18/2016 10:43 AM, Robert Yang wrote:
> It was added for testing, and not needed any more after:

>   meta/recipes-core/meta/buildtools-tarball.bb | 1 -
>   1 file changed, 1 deletion(-)

Same thing: if the pexpect recipe is not needed by anything, then remove it.

Alex

Re: [PATCH 0/7][python3] buildtools-tarball: replace python with python3

[Alexander Kanavin]

On 05/19/2016 03:19 PM, Alexander Kanavin wrote:
> On 05/18/2016 10:43 AM, Robert Yang wrote:
>
>> Robert Yang (7):
>>    python3-smmap: add it for python3-gitdb
>>    python3-async: add it for python3-gitdb
>>    python3-gitdb: add it for python3-git
>>    python3-git: add it for buildtools-tarball
>
> You can remove the Python 2 versions at the same time. Nothing is
> requiring them in oe-core or meta-oe.

Nevermind; I just noticed that packagegroup-self-hosted refers to 
python-git, so it can be removed only after bitbake's python3 support is 
merged.

Alex

Re: [PATCH 0/7][python3] buildtools-tarball: replace python with python3

[Robert Yang]

On 05/19/2016 08:41 PM, Alexander Kanavin wrote:
> On 05/19/2016 03:19 PM, Alexander Kanavin wrote:
>> On 05/18/2016 10:43 AM, Robert Yang wrote:
>>
>>> Robert Yang (7):
>>>    python3-smmap: add it for python3-gitdb
>>>    python3-async: add it for python3-gitdb
>>>    python3-gitdb: add it for python3-git
>>>    python3-git: add it for buildtools-tarball
>>
>> You can remove the Python 2 versions at the same time. Nothing is
>> requiring them in oe-core or meta-oe.
>
> Nevermind; I just noticed that packagegroup-self-hosted refers to python-git, so
> it can be removed only after bitbake's python3 support is merged.

Thanks, I will remove them in another patch.

// Robert

>
> Alex
>