[meta-multimedia PATCH V2 1/6] gssdp: add 0.12.2.1 and 0.13.2

[meta-multimedia PATCH V2 1/6] gssdp: add 0.12.2.1 and 0.13.2

[Ross Burton]

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 meta-multimedia/recipes-connectivity/gupnp/gssdp.inc |   18 ++++++++++++++++++
 .../recipes-connectivity/gupnp/gssdp_0.12.2.1.bb     |    5 +++++
 .../recipes-connectivity/gupnp/gssdp_0.13.2.bb       |    8 ++++++++
 .../recipes-connectivity/gupnp/no-vala.inc           |    5 +++++
 4 files changed, 36 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/no-vala.inc

diff --git a/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc b/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
new file mode 100644
index 0000000..ae965b9
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gssdp.inc
@@ -0,0 +1,18 @@
+SUMMARY = "Resource discovery and announcement over SSDP"
+DESCRIPTION = "GSSDP implements resource discovery and announcement over SSDP (Simpe Service Discovery Protocol)."
+LICENSE = "LGPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7"
+DEPENDS = "glib-2.0 libsoup-2.4 gobject-introspection-stub"
+
+inherit autotools pkgconfig
+
+require no-vala.inc
+
+EXTRA_OECONF = "--disable-introspection"
+
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'x11', 'gtk', '', d)}"
+PACKAGECONFIG[gtk] = "--with-gtk,--without-gtk,gtk+"
+
+PACKAGES =+ "gssdp-tools"
+
+FILES_gssdp-tools = "${bindir}/gssdp* ${datadir}/gssdp/*.glade"
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
new file mode 100644
index 0000000..29cc721
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.12.2.1.bb
@@ -0,0 +1,5 @@
+require gssdp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.12/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "8ac3a544ef0dcf8caaf7c249d2a50dc2"
+SRC_URI[sha256sum] = "928aa257815d044fdbfc740f5799530d41897947b5d7854173f636b36d728414"
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
new file mode 100644
index 0000000..c308fa0
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gssdp_0.13.2.bb
@@ -0,0 +1,8 @@
+require gssdp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.13/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "758ed423cdd258a9a22d59c321b535ed"
+SRC_URI[sha256sum] = "8f663f8a72b66254f5c20a3610ff853ac8d00bf6f253828e37e51579caa34dce"
+
+# This is a development release so don't prefer it
+DEFAULT_PREFERENCE = "-1"
diff --git a/meta-multimedia/recipes-connectivity/gupnp/no-vala.inc b/meta-multimedia/recipes-connectivity/gupnp/no-vala.inc
new file mode 100644
index 0000000..a4f3fb6
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/no-vala.inc
@@ -0,0 +1,5 @@
+do_configure_prepend () {
+	# Vala needs gobject-introspection so won't work. Instead of depending
+	# on vala-native just to run configure, comment out the Vala macro.
+	sed -i -e 's/\(^[ \t]*VALA_PROG_VAPIGEN\)/dnl \1/g' ${S}/configure.ac
+}
-- 
1.7.10

[meta-multimedia PATCH V2 2/6] gupnp: add 0.18.4 and 0.19.3

[Ross Burton]

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 .../recipes-connectivity/gupnp/gupnp.inc           |   21 ++++++++++++++++++++
 .../recipes-connectivity/gupnp/gupnp_0.18.4.bb     |    8 ++++++++
 .../recipes-connectivity/gupnp/gupnp_0.19.3.bb     |   10 ++++++++++
 3 files changed, 39 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp.inc
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp_0.18.4.bb
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp_0.19.3.bb

diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp.inc b/meta-multimedia/recipes-connectivity/gupnp/gupnp.inc
new file mode 100644
index 0000000..81db3ea
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp.inc
@@ -0,0 +1,21 @@
+SUMMARY = "UPnP framework"
+DESCRIPTION = "GUPnP is an elegant, object-oriented open source framework for creating UPnP  devices and control points, written in C using GObject and libsoup. The GUPnP API is intended to be easy to use, efficient and flexible. It provides the same set of features as libupnp, but shields the developer from most of UPnP's internals."
+LICENSE = "LGPLv2+"
+
+DEPENDS = "e2fsprogs gssdp libsoup-2.4 libxml2 gnome-icon-theme gobject-introspection-stub"
+
+require no-vala.inc
+
+EXTRA_OECONF = "--disable-introspection"
+
+inherit autotools pkgconfig
+
+FILES_${PN} = "${libdir}/*.so.*"
+FILES_${PN}-dev += "${bindir}/gupnp-binding-tool"
+
+SYSROOT_PREPROCESS_FUNCS += "gupnp_sysroot_preprocess"
+
+gupnp_sysroot_preprocess () {
+	install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
+	install -m 755 ${D}${bindir}/gupnp-binding-tool ${SYSROOT_DESTDIR}${bindir_crossscripts}/
+}
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.18.4.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.18.4.bb
new file mode 100644
index 0000000..4fb1d05
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.18.4.bb
@@ -0,0 +1,8 @@
+require gupnp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.18/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "0e15fa26be7b1a0255e6dec07c285527"
+SRC_URI[sha256sum] = "6b437d5711b212292c6080626b97480268310da636a6cf937ad6119291af78a1"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+                    file://libgupnp/gupnp.h;beginline=1;endline=20;md5=28c49b17d623afc3335efc2e511879e1"
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.19.3.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.19.3.bb
new file mode 100644
index 0000000..bab74b8
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp_0.19.3.bb
@@ -0,0 +1,10 @@
+require gupnp.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.19/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "8165c3ad3d16576a0a99250b75df23f8"
+SRC_URI[sha256sum] = "0d3097c419e1f8af0ff8ee91318d75e8896b3b92924cb1a5cf93010795a7118b"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+                    file://libgupnp/gupnp.h;beginline=1;endline=20;md5=d78a69d9b6e63ee2dc72e7b674d97520"
+
+DEFAULT_PREFERENCE = "-1"
-- 
1.7.10

[meta-multimedia PATCH V2 3/6] gupnp-av: add 0.10.3 and 0.11.6

[Ross Burton]

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc      |    8 ++++++++
 .../recipes-connectivity/gupnp/gupnp-av_0.10.3.bb            |    8 ++++++++
 .../recipes-connectivity/gupnp/gupnp-av_0.11.6.bb            |   10 ++++++++++
 3 files changed, 26 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.10.3.bb
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.11.6.bb

diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc
new file mode 100644
index 0000000..b076155
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av.inc
@@ -0,0 +1,8 @@
+SUMMARY = "Helpers for AV applications using UPnP"
+DESCRIPTION = "GUPnP-AV is a collection of helpers for building AV (audio/video) applications using GUPnP."
+LICENSE = "LGPLv2"
+DEPENDS = "gupnp"
+
+inherit autotools pkgconfig
+
+require no-vala.inc
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.10.3.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.10.3.bb
new file mode 100644
index 0000000..5f8e73a
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.10.3.bb
@@ -0,0 +1,8 @@
+require gupnp-av.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.10/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "2c57e56b201765b2297946d8d99bd01c"
+SRC_URI[sha256sum] = "d0dbb727d87bc9f2dc834455d14a30700b16b41a57e9dcde2e822b378ca8f1e2"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+                    file://libgupnp-av/gupnp-av.h;beginline=1;endline=22;md5=d344132a8766641fcb11213ff5982086"
diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.11.6.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.11.6.bb
new file mode 100644
index 0000000..b402dd8
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-av_0.11.6.bb
@@ -0,0 +1,10 @@
+require gupnp-av.inc
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.11/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "ee200393207323f0b594f11d6184556c"
+SRC_URI[sha256sum] = "401991336babb18c4ebed16e75e0b4d3e5848cff7bb878bbfd54a5d15203c4cc"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7 \
+                    file://libgupnp-av/gupnp-av.h;beginline=1;endline=22;md5=2b47b7b5f799d2ebabe62b895e848820"
+
+DEFAULT_PREFERENCE = "-1"
-- 
1.7.10

[meta-multimedia PATCH V2 4/6] gupnp-dlna: add 0.9.2

[Ross Burton]

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 .../recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb |   20 ++++++++++++++++++++
 1 file changed, 20 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb

diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb
new file mode 100644
index 0000000..b7e71cf
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-dlna_0.9.2.bb
@@ -0,0 +1,20 @@
+SUMMARY = "Helpers for AV applications using DLNA"
+LICENSE = "LGPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
+                    file://libgupnp-dlna/gupnp-dlna-profile.h;beginline=1;endline=22;md5=1b85459f65cb1e73a885ca137aab6274"
+
+DEPENDS = "libxml2 glib-2.0"
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.9/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "d972f9b03f0f3793cb895eb034ea314f"
+SRC_URI[sha256sum] = "c28d5650604c7da4f193e6b85049a4885f3a01f1996df768d55b5cb898a9fc53"
+
+inherit autotools pkgconfig
+
+require no-vala.inc
+
+# The GStreamer metadata backend requires GStreamer 1.0, so skip this until we
+# have that packaged.
+EXTRA_OECONF = "--disable-gstreamer-metadata-backend"
+
+FILES_${PN} += "${datadir}/gupnp-dlna-2.0/dlna-profiles"
-- 
1.7.10

[meta-multimedia PATCH V2 5/6] gupnp-igd: add 0.2.2

[Ross Burton]

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 .../recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb        |   14 ++++++++++++++
 1 file changed, 14 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb

diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb
new file mode 100644
index 0000000..112bc4b
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-igd_0.2.2.bb
@@ -0,0 +1,14 @@
+SUMMARY = "Helpers for interacting with Internet Gateway Devices over UPnP"
+LICENSE = "LGPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
+                    file://libgupnp-igd/gupnp-simple-igd.c;beginline=1;endline=21;md5=aa292c0d9390463a6e1055dc5fc68e80"
+
+DEPENDS = "glib-2.0 gupnp"
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.2/${BPN}-${PV}.tar.xz"
+SRC_URI[md5sum] = "f881323304185c02634034e3bda714ba"
+SRC_URI[sha256sum] = "73b6a98a0f13b29b34c3bfc07f99f78b1319211cb95a8585752873af2b9067d3"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--disable-introspection --disable-python"
-- 
1.7.10

[meta-multimedia PATCH V2 6/6] gupnp-tools: add 0.8.1

[Ross Burton]

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 .../recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb         |   11 +++++++++++
 1 file changed, 11 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb

diff --git a/meta-multimedia/recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb b/meta-multimedia/recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb
new file mode 100644
index 0000000..7a26453
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/gupnp/gupnp-tools_0.8.1.bb
@@ -0,0 +1,11 @@
+DESCRIPTION = "Tools for GUPnP"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
+                    file://src/network-light/main.c;beginline=1;endline=21;md5=033bf37c030780c5a72165846b3003f6"
+DEPENDS = "gupnp gupnp-av gtk+ gnome-icon-theme"
+
+SRC_URI = "http://download.gnome.org/sources/${BPN}/0.8/${BPN}-${PV}.tar.bz2"
+SRC_URI[md5sum] = "cafc2a4f2d1a91a8c1228799073d1d7d"
+SRC_URI[sha256sum] = "57d5ca899f8da7e4ae69e5f98d75d1603aa7f388022f9ccb357f90abb22b75b6"
+
+inherit autotools pkgconfig
-- 
1.7.10

Re: [meta-multimedia PATCH V2 1/6] gssdp: add 0.12.2.1 and 0.13.2

[Paul Eggleton]

On Friday 21 December 2012 13:43:37 Ross Burton wrote:
> Signed-off-by: Ross Burton <ross.burton@intel.com>

Why both versions?

Cheers,
Paul

-- 

Paul Eggleton
Intel Open Source Technology Centre

Re: [meta-multimedia PATCH V2 1/6] gssdp: add 0.12.2.1 and 0.13.2

[Burton, Ross]

On 23 December 2012 19:44, Paul Eggleton <paul.eggleton@linux.intel.com> wrote:
> On Friday 21 December 2012 13:43:37 Ross Burton wrote:
>> Signed-off-by: Ross Burton <ross.burton@intel.com>
>
> Why both versions?

GUPnP uses the GNOME-style stable/development even/odd versioning so
there's value in having both.  Specifically, dLeyna requires the
current development releases as that's where several critical bug
fixes have landed (ideally those fixes would be pushed to the stable
series, but I'm not in a position to suggest that anymore).

Ross

Re: [meta-multimedia PATCH V2 1/6] gssdp: add 0.12.2.1 and 0.13.2

[Paul Eggleton]

On Thursday 03 January 2013 10:26:35 Burton, Ross wrote:
> On 23 December 2012 19:44, Paul Eggleton <paul.eggleton@linux.intel.com> 
wrote:
> > On Friday 21 December 2012 13:43:37 Ross Burton wrote:
> >> Signed-off-by: Ross Burton <ross.burton@intel.com>
> > 
> > Why both versions?
> 
> GUPnP uses the GNOME-style stable/development even/odd versioning so
> there's value in having both.  Specifically, dLeyna requires the
> current development releases as that's where several critical bug
> fixes have landed (ideally those fixes would be pushed to the stable
> series, but I'm not in a position to suggest that anymore).

OK, I would definitely recommend noting that in the commit message in that 
case.

Cheers,
Paul

-- 

Paul Eggleton
Intel Open Source Technology Centre