[PATCH 0/3] Recipe for MuPDF

[PATCH 0/3] Recipe for MuPDF

[Dmitry Artamonow]

Hi!

Here's recipe for MuPDF (X11 pdf viewer and toolkit) and its dependencies.
Viewer doesn't have any fancy GUI - just a plain window with rendered PDF,
but it's a good thing on small screens embedded devices usually have,
as no screen space is wasted on buttons, etc. Viewer is perfectly
controllable from keyboard (and keyboardless devices like PDAs usually
have some joystick which is enough to navigate through pages, and other
tasks can be performed from on-screen keyboard). Also pdf contents is
scrollable by finger/stylus/mouse. And last, but not least - viewer is
VERY fast, much faster than poppler/xpdf-based solutions. I never thought
I can get such a speed of PDF-rendering on ARM-based machine.

Build tested for armv4(h3600), armv5(hx4700), armv7(beagleboard), x86(qemux86)
Run tested on armv5 machine (hx4700)

Dmitry Artamonow (3):
  openjpeg-1.3: new recipe
  jbig2dec-0.11: new recipe
  mupdf-0.6: new recipe

 recipes/jpeg/jbig2dec_0.11.bb                      |   19 ++++++
 recipes/jpeg/openjpeg-1.3/fix_installdir.patch     |   19 ++++++
 recipes/jpeg/openjpeg_1.3.bb                       |   24 ++++++++
 recipes/mupdf/mupdf-0.6/Makerules                  |    8 +++
 .../mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch  |   12 ++++
 recipes/mupdf/mupdf_0.6.bb                         |   59 ++++++++++++++++++++
 6 files changed, 141 insertions(+), 0 deletions(-)
 create mode 100644 recipes/jpeg/jbig2dec_0.11.bb
 create mode 100644 recipes/jpeg/openjpeg-1.3/fix_installdir.patch
 create mode 100644 recipes/jpeg/openjpeg_1.3.bb
 create mode 100644 recipes/mupdf/mupdf-0.6/Makerules
 create mode 100644 recipes/mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch
 create mode 100644 recipes/mupdf/mupdf_0.6.bb

[PATCH 1/3] openjpeg-1.3: new recipe

[Dmitry Artamonow]

The OpenJPEG library is an open-source JPEG 2000 codec written
in C language.

Signed-off-by: Dmitry Artamonow <mad_soft@inbox.ru>
---
 recipes/jpeg/openjpeg-1.3/fix_installdir.patch |   19 +++++++++++++++++++
 recipes/jpeg/openjpeg_1.3.bb                   |   24 ++++++++++++++++++++++++
 2 files changed, 43 insertions(+), 0 deletions(-)
 create mode 100644 recipes/jpeg/openjpeg-1.3/fix_installdir.patch
 create mode 100644 recipes/jpeg/openjpeg_1.3.bb

diff --git a/recipes/jpeg/openjpeg-1.3/fix_installdir.patch b/recipes/jpeg/openjpeg-1.3/fix_installdir.patch
new file mode 100644
index 0000000..f04a81e
--- /dev/null
+++ b/recipes/jpeg/openjpeg-1.3/fix_installdir.patch
@@ -0,0 +1,19 @@
+* status: pending
+* origin:
+  http://groups.google.com/group/openjpeg/browse_thread/thread/4cd7b53fbaab2822
+* comment: slightly modified patch by Patrick Reynolds, borrowed from
+  the thread above. Seems that it's not in upstream yet.
+  Had to modify header location from /usr/include/openjpeg/openjpeg.h to
+  /usr/include/openjpeg.h , as it's the only one header file anyway and
+  most of its users expect #include <openjpeg.h> to work.
+
+Index: libopenjpeg/CMakeLists.txt
+===================================================================
+--- a/libopenjpeg/CMakeLists.txt	(revision 541)
++++ b/libopenjpeg/CMakeLists.txt	(working copy)
+@@ -41,4 +41,4 @@
+ 
+ # Install includes files
+ INSTALL(FILES openjpeg.h
+-	DESTINATION ${INCLUDE_INSTALL_DIR}/openjpeg)
++	DESTINATION include)
diff --git a/recipes/jpeg/openjpeg_1.3.bb b/recipes/jpeg/openjpeg_1.3.bb
new file mode 100644
index 0000000..857c3dd
--- /dev/null
+++ b/recipes/jpeg/openjpeg_1.3.bb
@@ -0,0 +1,24 @@
+DESCRIPTION = "Open-source JPEG 2000 codec written in C language"
+HOMEPAGE = "http://www.openjpeg.org"
+SECTION = "libs"
+LICENSE = "BSD"
+PR = "r0"
+
+SRC_URI = "http://openjpeg.googlecode.com/files/openjpeg_v1_3.tar.gz \
+           file://fix_installdir.patch"
+
+S = "${WORKDIR}/OpenJPEG_v1_3"
+
+inherit cmake
+
+EXTRA_OECMAKE="-DBUILD_SHARED_LIBS:BOOL=ON"
+
+do_stage() {
+        autotools_stage_all
+}
+
+PACKAGES =+ "openjpeg-tools "
+FILES_openjpeg-tools = "${bindir}/*"
+
+SRC_URI[md5sum] = "f9a3ccfa91ac34b589e9bf7577ce8ff9"
+SRC_URI[sha256sum] = "3bca2e1e040f9dcbbcb1e0627f17a76eeb95e153bf663d082070c044a21202bd"
-- 
1.7.1

[PATCH 2/3] jbig2dec-0.11: new recipe

[Dmitry Artamonow]

jbig2dec is a decoder implementation of the JBIG2 image compression
format. JBIG2 is designed for lossy or lossless encoding of monochrome
images at moderately high resolution, in particular scanned paper documents.

Signed-off-by: Dmitry Artamonow <mad_soft@inbox.ru>
---
 recipes/jpeg/jbig2dec_0.11.bb |   19 +++++++++++++++++++
 1 files changed, 19 insertions(+), 0 deletions(-)
 create mode 100644 recipes/jpeg/jbig2dec_0.11.bb

diff --git a/recipes/jpeg/jbig2dec_0.11.bb b/recipes/jpeg/jbig2dec_0.11.bb
new file mode 100644
index 0000000..9bc7433
--- /dev/null
+++ b/recipes/jpeg/jbig2dec_0.11.bb
@@ -0,0 +1,19 @@
+DESCRIPTION = "Decoder implementation of the JBIG2 image compression format"
+HOMEPAGE = "http://jbig2dec.sourceforge.net/"
+SECTION = "libs"
+LICENSE = "GPL"
+PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/jbig2dec/${PN}-${PV}.tar.gz"
+
+inherit autotools
+
+do_stage() {
+        autotools_stage_all
+}
+
+PACKAGES =+ "jbig2dec-tools "
+FILES_jbig2dec-tools = "${bindir}/*"
+
+SRC_URI[md5sum] = "1f61e144852c86563fee6e5ddced63f1"
+SRC_URI[sha256sum] = "7e2d8330b36f2765da22043d174827bee0f30db8d78c330904f363275c7dd0b9"
-- 
1.7.1

Re: [PATCH 2/3] jbig2dec-0.11: new recipe

[Khem Raj]

On (09/06/10 11:33), Dmitry Artamonow wrote:
> jbig2dec is a decoder implementation of the JBIG2 image compression
> format. JBIG2 is designed for lossy or lossless encoding of monochrome
> images at moderately high resolution, in particular scanned paper documents.
> 
> Signed-off-by: Dmitry Artamonow <mad_soft@inbox.ru>
> ---
>  recipes/jpeg/jbig2dec_0.11.bb |   19 +++++++++++++++++++
>  1 files changed, 19 insertions(+), 0 deletions(-)
>  create mode 100644 recipes/jpeg/jbig2dec_0.11.bb
> 
> diff --git a/recipes/jpeg/jbig2dec_0.11.bb b/recipes/jpeg/jbig2dec_0.11.bb
> new file mode 100644
> index 0000000..9bc7433
> --- /dev/null
> +++ b/recipes/jpeg/jbig2dec_0.11.bb
> @@ -0,0 +1,19 @@
> +DESCRIPTION = "Decoder implementation of the JBIG2 image compression format"
> +HOMEPAGE = "http://jbig2dec.sourceforge.net/"
> +SECTION = "libs"
> +LICENSE = "GPL"
> +PR = "r0"
> +
> +SRC_URI = "${SOURCEFORGE_MIRROR}/jbig2dec/${PN}-${PV}.tar.gz"
> +
> +inherit autotools
> +
> +do_stage() {
> +        autotools_stage_all
> +}

do_stage is not needed for new staging.


> +
> +PACKAGES =+ "jbig2dec-tools "
> +FILES_jbig2dec-tools = "${bindir}/*"
> +
> +SRC_URI[md5sum] = "1f61e144852c86563fee6e5ddced63f1"
> +SRC_URI[sha256sum] = "7e2d8330b36f2765da22043d174827bee0f30db8d78c330904f363275c7dd0b9"
> -- 
> 1.7.1
> 
> 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-devel

Re: [PATCH 2/3] jbig2dec-0.11: new recipe

[Dmitry Artamonow]

On 06:31 Wed 09 Jun     , Khem Raj wrote:
> On (09/06/10 11:33), Dmitry Artamonow wrote:
> > +inherit autotools
> > +
> > +do_stage() {
> > +        autotools_stage_all
> > +}
> 
> do_stage is not needed for new staging.

So I can drop this "autotools_stage_all" hack entirely and it will do
the right thing? Nice! Ok, will redo both openjpeg and jbig2dec recipes,
test them and resubmit.

BTW, it would be nice to have this thing removed from other existing recipes
tree-wide, so it won't be tempting to "copy-paste" it, as I did :)

-- 
Best regards,
Dmitry "MAD" Artamonow

[PATCH 3/3] mupdf-0.6: new recipe

[Dmitry Artamonow]

MuPDF is a slim and fast PDF viewer/toolkit.

Signed-off-by: Dmitry Artamonow <mad_soft@inbox.ru>
---
 recipes/mupdf/mupdf-0.6/Makerules                  |    8 +++
 .../mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch  |   12 ++++
 recipes/mupdf/mupdf_0.6.bb                         |   59 ++++++++++++++++++++
 3 files changed, 79 insertions(+), 0 deletions(-)
 create mode 100644 recipes/mupdf/mupdf-0.6/Makerules
 create mode 100644 recipes/mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch
 create mode 100644 recipes/mupdf/mupdf_0.6.bb

diff --git a/recipes/mupdf/mupdf-0.6/Makerules b/recipes/mupdf/mupdf-0.6/Makerules
new file mode 100644
index 0000000..5f3d4e2
--- /dev/null
+++ b/recipes/mupdf/mupdf-0.6/Makerules
@@ -0,0 +1,8 @@
+# Configuration for the Makefile
+LIBS := -ljbig2dec -lopenjpeg -ljpeg -lz -lm
+CFLAGS := -Wall --std=gnu99 -Ifitz -Imupdf $(THIRD_INCS)
+
+CFLAGS += `pkg-config --cflags freetype2`
+LDFLAGS += `pkg-config --libs freetype2`
+X11LIBS = -lX11 -lXext
+PDFVIEW_EXE = $(X11VIEW_EXE)
diff --git a/recipes/mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch b/recipes/mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch
new file mode 100644
index 0000000..fdc0b74
--- /dev/null
+++ b/recipes/mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch
@@ -0,0 +1,12 @@
+* upstream: http://bugs.ghostscript.com/show_bug.cgi?id=690932
+
+--- mupdf/apps/x11_image.c.orig	2010-06-06 19:42:46.000000000 +0400
++++ mupdf/apps/x11_image.c	2010-06-06 20:32:35.000000000 +0400
+@@ -14,6 +14,7 @@
+ 
+ #include <X11/Xlib.h>
+ #include <X11/Xutil.h>
++#include <X11/Xarch.h>
+ #include <sys/ipc.h>
+ #include <sys/shm.h>
+ #include <X11/extensions/XShm.h>
diff --git a/recipes/mupdf/mupdf_0.6.bb b/recipes/mupdf/mupdf_0.6.bb
new file mode 100644
index 0000000..e9cb0b1
--- /dev/null
+++ b/recipes/mupdf/mupdf_0.6.bb
@@ -0,0 +1,59 @@
+DESCRIPTION = "A lightweight PDF viewer and toolkit written in portable C."
+HOMEPAGE = "http://www.mupdf.com"
+SECTION = "x11/applications"
+LICENSE = "GPLv3"
+PR = "r0"
+
+DEPENDS = "openjpeg jbig2dec jpeg zlib virtual/libx11 libxext freetype"
+
+SRC_URI = "http://mupdf.com/download/source/${PN}-${PV}-source.tar.gz \
+           file://mupdf_fix_16bit_display.patch \
+           file://Makerules"
+
+S = "${WORKDIR}/mupdf"
+
+PACKAGES =+ "${PN}-tools ${PN}-tools-doc "
+FILES_${PN}-tools = "${bindir}/pdfclean ${bindir}/pdfdraw ${bindir}/pdfshow \
+                     ${bindir}/pdfextract ${bindir}/pdfinfo"
+FILES_${PN}-tools-doc = "${mandir}/man1/pdfclean.1 ${mandir}/man1/pdfdraw.1 \
+                         ${mandir}/man1/pdfshow.1"
+
+# mupdf crashes (at least on arm) when built with high level of optimization
+FULL_OPTIMIZATION = "-O2"
+
+do_configure() {
+    cp ${WORKDIR}/Makerules ${S}/Makerules
+
+    # we don't include CJK fonts to make binary more slim
+    # comment out following two lines if you need support for CJK
+    sed -i 's:^\t\$.GENDIR./font_cjk.c::g' ${S}/Makefile
+    echo "CFLAGS += -DNOCJK" >> ${S}/Makerules
+}
+
+do_compile() {
+    # mupdf uses couple of tools for code generation during build process
+    # so we need to compile them first with host compiler
+    unset CFLAGS LDFLAGS
+    oe_runmake build/debug
+    oe_runmake build/debug/cmapdump LD=${BUILD_CC} CC=${BUILD_CC}
+    oe_runmake build/debug/fontdump LD=${BUILD_CC} CC=${BUILD_CC}
+
+    # ...and then we fire 'make', feeding proper
+    # cross-compilation flags through Makerules file
+    echo "CFLAGS += ${CFLAGS}" >> ${S}/Makerules
+    echo "LDFLAGS += ${LDFLAGS}" >> ${S}/Makerules
+    oe_runmake LD="${CC}"
+}
+
+do_install() {
+    oe_runmake install prefix="${D}/usr"
+    install -d ${D}/${datadir}/applications
+    install -d ${D}/${datadir}/pixmaps
+    install -d ${D}/${mandir}/man1
+    install -m 0644 ${S}/debian/mupdf.xpm ${D}/${datadir}/pixmaps/
+    install -m 0644 ${S}/debian/mupdf.desktop ${D}/${datadir}/applications/
+    install -m 0644 ${S}/debian/*.1 ${D}/${mandir}/man1/
+}
+
+SRC_URI[md5sum] = "d1e1a1df8fb3e4d1c601506797b75036"
+SRC_URI[sha256sum] = "6f87c4f113ee9e0f4bdfd3a316ef44052edc4febc8f7b531c4a3f44ffe149605"
-- 
1.7.1

Re: [PATCH 3/3] mupdf-0.6: new recipe

[Khem Raj]

On (09/06/10 11:33), Dmitry Artamonow wrote:
> MuPDF is a slim and fast PDF viewer/toolkit.
> 
> Signed-off-by: Dmitry Artamonow <mad_soft@inbox.ru>
> ---
>  recipes/mupdf/mupdf-0.6/Makerules                  |    8 +++
>  .../mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch  |   12 ++++
>  recipes/mupdf/mupdf_0.6.bb                         |   59 ++++++++++++++++++++
>  3 files changed, 79 insertions(+), 0 deletions(-)
>  create mode 100644 recipes/mupdf/mupdf-0.6/Makerules
>  create mode 100644 recipes/mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch
>  create mode 100644 recipes/mupdf/mupdf_0.6.bb
> 
> diff --git a/recipes/mupdf/mupdf-0.6/Makerules b/recipes/mupdf/mupdf-0.6/Makerules
> new file mode 100644
> index 0000000..5f3d4e2
> --- /dev/null
> +++ b/recipes/mupdf/mupdf-0.6/Makerules
> @@ -0,0 +1,8 @@
> +# Configuration for the Makefile
> +LIBS := -ljbig2dec -lopenjpeg -ljpeg -lz -lm
> +CFLAGS := -Wall --std=gnu99 -Ifitz -Imupdf $(THIRD_INCS)
> +
> +CFLAGS += `pkg-config --cflags freetype2`
> +LDFLAGS += `pkg-config --libs freetype2`
> +X11LIBS = -lX11 -lXext
> +PDFVIEW_EXE = $(X11VIEW_EXE)
> diff --git a/recipes/mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch b/recipes/mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch
> new file mode 100644
> index 0000000..fdc0b74
> --- /dev/null
> +++ b/recipes/mupdf/mupdf-0.6/mupdf_fix_16bit_display.patch
> @@ -0,0 +1,12 @@
> +* upstream: http://bugs.ghostscript.com/show_bug.cgi?id=690932
> +
> +--- mupdf/apps/x11_image.c.orig	2010-06-06 19:42:46.000000000 +0400
> ++++ mupdf/apps/x11_image.c	2010-06-06 20:32:35.000000000 +0400
> +@@ -14,6 +14,7 @@
> + 
> + #include <X11/Xlib.h>
> + #include <X11/Xutil.h>
> ++#include <X11/Xarch.h>
> + #include <sys/ipc.h>
> + #include <sys/shm.h>
> + #include <X11/extensions/XShm.h>
> diff --git a/recipes/mupdf/mupdf_0.6.bb b/recipes/mupdf/mupdf_0.6.bb
> new file mode 100644
> index 0000000..e9cb0b1
> --- /dev/null
> +++ b/recipes/mupdf/mupdf_0.6.bb
> @@ -0,0 +1,59 @@
> +DESCRIPTION = "A lightweight PDF viewer and toolkit written in portable C."
> +HOMEPAGE = "http://www.mupdf.com"
> +SECTION = "x11/applications"
> +LICENSE = "GPLv3"
> +PR = "r0"
> +
> +DEPENDS = "openjpeg jbig2dec jpeg zlib virtual/libx11 libxext freetype"
> +
> +SRC_URI = "http://mupdf.com/download/source/${PN}-${PV}-source.tar.gz \
> +           file://mupdf_fix_16bit_display.patch \
> +           file://Makerules"
> +
> +S = "${WORKDIR}/mupdf"
> +
> +PACKAGES =+ "${PN}-tools ${PN}-tools-doc "
> +FILES_${PN}-tools = "${bindir}/pdfclean ${bindir}/pdfdraw ${bindir}/pdfshow \
> +                     ${bindir}/pdfextract ${bindir}/pdfinfo"
> +FILES_${PN}-tools-doc = "${mandir}/man1/pdfclean.1 ${mandir}/man1/pdfdraw.1 \
> +                         ${mandir}/man1/pdfshow.1"
> +
> +# mupdf crashes (at least on arm) when built with high level of optimization
> +FULL_OPTIMIZATION = "-O2"

the commend does not go with the code. O2 is high enough optimization.
be more specific what does not work and by default OE uses -Os + some 
specific opt passes.

> +
> +do_configure() {
> +    cp ${WORKDIR}/Makerules ${S}/Makerules
> +

Why not create a patch for Makerules instread of creating a file and then
copying. It will help upgrades the patch will get refreshed for any changes
but this will overwrite those changes.

> +    # we don't include CJK fonts to make binary more slim
> +    # comment out following two lines if you need support for CJK
> +    sed -i 's:^\t\$.GENDIR./font_cjk.c::g' ${S}/Makefile
> +    echo "CFLAGS += -DNOCJK" >> ${S}/Makerules
> +}
> +
> +do_compile() {
> +    # mupdf uses couple of tools for code generation during build process
> +    # so we need to compile them first with host compiler
> +    unset CFLAGS LDFLAGS
> +    oe_runmake build/debug
> +    oe_runmake build/debug/cmapdump LD=${BUILD_CC} CC=${BUILD_CC}
> +    oe_runmake build/debug/fontdump LD=${BUILD_CC} CC=${BUILD_CC}
> +
> +    # ...and then we fire 'make', feeding proper
> +    # cross-compilation flags through Makerules file
> +    echo "CFLAGS += ${CFLAGS}" >> ${S}/Makerules
> +    echo "LDFLAGS += ${LDFLAGS}" >> ${S}/Makerules
> +    oe_runmake LD="${CC}"
> +}
> +
> +do_install() {
> +    oe_runmake install prefix="${D}/usr"
> +    install -d ${D}/${datadir}/applications
> +    install -d ${D}/${datadir}/pixmaps
> +    install -d ${D}/${mandir}/man1
> +    install -m 0644 ${S}/debian/mupdf.xpm ${D}/${datadir}/pixmaps/
> +    install -m 0644 ${S}/debian/mupdf.desktop ${D}/${datadir}/applications/
> +    install -m 0644 ${S}/debian/*.1 ${D}/${mandir}/man1/
> +}
> +
> +SRC_URI[md5sum] = "d1e1a1df8fb3e4d1c601506797b75036"
> +SRC_URI[sha256sum] = "6f87c4f113ee9e0f4bdfd3a316ef44052edc4febc8f7b531c4a3f44ffe149605"
> -- 
> 1.7.1
> 
> 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-devel

Re: [PATCH 3/3] mupdf-0.6: new recipe

[Dmitry Artamonow]

On 06:36 Wed 09 Jun     , Khem Raj wrote:
> On (09/06/10 11:33), Dmitry Artamonow wrote:
> > +# mupdf crashes (at least on arm) when built with high level of optimization
> > +FULL_OPTIMIZATION = "-O2"
> 
> the commend does not go with the code. O2 is high enough optimization.
> be more specific what does not work and by default OE uses -Os + some 
> specific opt passes.
I think optimization options vary depending on distro. Anyway, I had runtime
crashes on armv5 (hx4700) when mupdf is built with Angstrom's default
optimization flags:
-fexpensive-optimizations -frename-registers -fomit-frame-pointer -Os -ggdb3
Didn't investigate which exactly option leads to fault, but changing CFLAGS to
simple "-O2" produced working build ("-Os" without other flags probably
also does the trick, need to recheck).

So would it be better to add some more text in comment to prevent ambiguity -
something like this?
# mupdf crashes (at least on arm) when built with high level of optimization
# so we need to provide some safe settings


> > +
> > +do_configure() {
> > +    cp ${WORKDIR}/Makerules ${S}/Makerules
> > +
> 
> Why not create a patch for Makerules instread of creating a file and then
> copying. It will help upgrades the patch will get refreshed for any changes
> but this will overwrite those changes.

Well, as far as I can understand, Makerules was designed just to keep
CFLAGS and other host-specific tunings separate from main Makefile.
Currently, Makerules in original tarball contains some host-detecting
logic and corresponding sections with CFLAGS, LDFLAGS, etc. for each
host OS: Linux, Darwin, MinGW and build type - debug or release.
As there's really nothing to reuse for cross-compiling, I decided that
it's better to rewrite this file, than patching it. Patch would be
almost as big as original Makerules (as it would throw almost
everything from it), hard to maintain, and absolutely no help in
upgrades.

-- 
Best regards,
Dmitry "MAD" Artamonow

Re: [PATCH 3/3] mupdf-0.6: new recipe

[Martin Jansa]

On Wed, Jun 09, 2010 at 06:36:18AM -0700, Khem Raj wrote:
> On (09/06/10 11:33), Dmitry Artamonow wrote:
> > +do_configure() {
> > +    cp ${WORKDIR}/Makerules ${S}/Makerules
> > +
> 
> Why not create a patch for Makerules instread of creating a file and then
> copying. It will help upgrades the patch will get refreshed for any changes
> but this will overwrite those changes.

This Makerules doesn't work very well for me

    oe_runmake build/debug/cmapdump LD=${BUILD_CC} CC=${BUILD_CC}
    oe_runmake build/debug/fontdump LD=${BUILD_CC} CC=${BUILD_CC}

needs couple of -native stuff missing in DEPENDS and then pkg-config
doesn't find ie freetype, because my host system doesn't have freetype
etc.

Any advice? (using pkg-config from armv4 staging dir returns right
freetype for non-native build, but injects the same libs to
cmapdump/fontdump which of course fails.

Regards,
-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

Re: [PATCH 0/3] Recipe for MuPDF

[Martin Jansa]

On Wed, Jun 09, 2010 at 11:32:59AM +0400, Dmitry Artamonow wrote:
> Hi!
> 
> Here's recipe for MuPDF (X11 pdf viewer and toolkit) and its dependencies.
> Viewer doesn't have any fancy GUI - just a plain window with rendered PDF,
> but it's a good thing on small screens embedded devices usually have,
> as no screen space is wasted on buttons, etc. Viewer is perfectly
> controllable from keyboard (and keyboardless devices like PDAs usually
> have some joystick which is enough to navigate through pages, and other
> tasks can be performed from on-screen keyboard). Also pdf contents is
> scrollable by finger/stylus/mouse. And last, but not least - viewer is
> VERY fast, much faster than poppler/xpdf-based solutions. I never thought
> I can get such a speed of PDF-rendering on ARM-based machine.
> 
> Build tested for armv4(h3600), armv5(hx4700), armv7(beagleboard), x86(qemux86)
> Run tested on armv5 machine (hx4700)

Hi, is there PATCHv2 series with Khem's suggestions fixed?

Would be nice to have it in oe.dev.

Thanks!

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

Re: [PATCH 0/3] Recipe for MuPDF

[Martin Jansa]

On Sun, Jul 18, 2010 at 09:56:38AM +0200, Martin Jansa wrote:
> On Wed, Jun 09, 2010 at 11:32:59AM +0400, Dmitry Artamonow wrote:
> > Hi!
> > 
> > Here's recipe for MuPDF (X11 pdf viewer and toolkit) and its dependencies.
> > Viewer doesn't have any fancy GUI - just a plain window with rendered PDF,
> > but it's a good thing on small screens embedded devices usually have,
> > as no screen space is wasted on buttons, etc. Viewer is perfectly
> > controllable from keyboard (and keyboardless devices like PDAs usually
> > have some joystick which is enough to navigate through pages, and other
> > tasks can be performed from on-screen keyboard). Also pdf contents is
> > scrollable by finger/stylus/mouse. And last, but not least - viewer is
> > VERY fast, much faster than poppler/xpdf-based solutions. I never thought
> > I can get such a speed of PDF-rendering on ARM-based machine.
> > 
> > Build tested for armv4(h3600), armv5(hx4700), armv7(beagleboard), x86(qemux86)
> > Run tested on armv5 machine (hx4700)
> 
> Hi, is there PATCHv2 series with Khem's suggestions fixed?
> 
> Would be nice to have it in oe.dev.

Please....

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa@gmail.com

[PATCH v2 0/3] Recipe for MuPDF

[Dmitry Artamonow]

As there's no more comments on original patch series[1], guess it's time
to send v2. Do whatever you like with these patches :-)

[1] http://patchwork.openembedded.org/bundle/mad_soft/mupdf-0.6-v1/

Changelog v1 => v2:

* removed autotools_stage_all from openjpeg and jbig2dec recipes,
  as suggested by Khem Raj
* used upstream patch fixing endianness issues on 16-bit displays
  instead of custom hack (upstream has been very kind to fix this
  bug so quickly)
* more verbose comment about why we need -O2

Dmitry Artamonow (3):
  openjpeg-1.3: new recipe
  jbig2dec-0.11: new recipe
  mupdf-0.6: new recipe

 recipes/jpeg/jbig2dec_0.11.bb                      |   15 +++
 recipes/jpeg/openjpeg-1.3/fix_installdir.patch     |   19 ++++
 recipes/jpeg/openjpeg_1.3.bb                       |   20 +++++
 recipes/mupdf/mupdf-0.6/Makerules                  |    8 ++
 recipes/mupdf/mupdf-0.6/mupdf_fix_endianness.patch |   90 ++++++++++++++++++++
 recipes/mupdf/mupdf_0.6.bb                         |   60 +++++++++++++
 6 files changed, 212 insertions(+), 0 deletions(-)
 create mode 100644 recipes/jpeg/jbig2dec_0.11.bb
 create mode 100644 recipes/jpeg/openjpeg-1.3/fix_installdir.patch
 create mode 100644 recipes/jpeg/openjpeg_1.3.bb
 create mode 100644 recipes/mupdf/mupdf-0.6/Makerules
 create mode 100644 recipes/mupdf/mupdf-0.6/mupdf_fix_endianness.patch
 create mode 100644 recipes/mupdf/mupdf_0.6.bb

[PATCH 2/3] jbig2dec-0.11: new recipe

[Dmitry Artamonow]

jbig2dec is a decoder implementation of the JBIG2 image compression
format. JBIG2 is designed for lossy or lossless encoding of monochrome
images at moderately high resolution, in particular scanned paper documents.

Signed-off-by: Dmitry Artamonow <mad_soft@inbox.ru>
---
 recipes/jpeg/jbig2dec_0.11.bb |   15 +++++++++++++++
 1 files changed, 15 insertions(+), 0 deletions(-)
 create mode 100644 recipes/jpeg/jbig2dec_0.11.bb

diff --git a/recipes/jpeg/jbig2dec_0.11.bb b/recipes/jpeg/jbig2dec_0.11.bb
new file mode 100644
index 0000000..ccdeedd
--- /dev/null
+++ b/recipes/jpeg/jbig2dec_0.11.bb
@@ -0,0 +1,15 @@
+DESCRIPTION = "Decoder implementation of the JBIG2 image compression format"
+HOMEPAGE = "http://jbig2dec.sourceforge.net/"
+SECTION = "libs"
+LICENSE = "GPL"
+PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/jbig2dec/${PN}-${PV}.tar.gz"
+
+inherit autotools
+
+PACKAGES =+ "jbig2dec-tools "
+FILES_jbig2dec-tools = "${bindir}/*"
+
+SRC_URI[md5sum] = "1f61e144852c86563fee6e5ddced63f1"
+SRC_URI[sha256sum] = "7e2d8330b36f2765da22043d174827bee0f30db8d78c330904f363275c7dd0b9"
-- 
1.7.1