[meta-oe][PATCH 01/11] lcdproc5: add PACKAGECONFIG for libftdi, libusb

[meta-oe][PATCH 01/11] lcdproc5: add PACKAGECONFIG for libftdi, libusb

[Martin Jansa]

* drivers for lis, ula200 and i2500vfd weren't deterministicly enabled

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-oe/recipes-extended/lcdproc/lcdproc5.inc | 8 ++++++--
 1 file changed, 6 insertions(+), 2 deletions(-)

diff --git a/meta-oe/recipes-extended/lcdproc/lcdproc5.inc b/meta-oe/recipes-extended/lcdproc/lcdproc5.inc
index f5a1f3c..d1a45ca 100644
--- a/meta-oe/recipes-extended/lcdproc/lcdproc5.inc
+++ b/meta-oe/recipes-extended/lcdproc/lcdproc5.inc
@@ -4,7 +4,7 @@ SUMMARY = "Drivers for character-based LCD displays"
 HOMEPAGE = "http://lcdproc.org"
 SECTION = "utils"
 LICENSE = "GPLv2+"
-DEPENDS = "virtual/libusb0 ncurses"
+DEPENDS = "ncurses"
 
 LIC_FILES_CHKSUM = "file://COPYING;md5=18810669f13b87348459e611d31ab760 \
                     file://README;beginline=60;md5=637e042cdd3671ba00e78b58ede45d3b"
@@ -16,7 +16,11 @@ inherit autotools update-rc.d
 LCD_DRIVERS ?= "all"
 LCD_DEFAULT_DRIVER ?= "curses"
 
-EXTRA_OECONF = "--enable-drivers=${LCD_DRIVERS} --enable-libusb"
+PACKAGECONFIG ??= "usb"
+PACKAGECONFIG[usb] = "--enable-libusb,--disable-libusb,virtual/libusb0"
+PACKAGECONFIG[ftdi] = "--enable-libftdi,--disable-libftdi,libftdi"
+
+EXTRA_OECONF = "--enable-drivers=${LCD_DRIVERS}"
 
 do_install () {
     # binaries
-- 
1.8.3.2

[meta-oe][PATCH 02/11] openldap: convert to PACKAGECONFIGs, explicitly disable openssl

[Martin Jansa]

* some options like ldbm weren't supported by current version
* when gnutls and openssl were both available it was picking openssl
  because default --with-tls is auto

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 .../recipes-support/openldap/openldap_2.4.23.bb    | 136 +++++++--------------
 1 file changed, 43 insertions(+), 93 deletions(-)

diff --git a/meta-oe/recipes-support/openldap/openldap_2.4.23.bb b/meta-oe/recipes-support/openldap/openldap_2.4.23.bb
index c545b5c..1121008 100644
--- a/meta-oe/recipes-support/openldap/openldap_2.4.23.bb
+++ b/meta-oe/recipes-support/openldap/openldap_2.4.23.bb
@@ -28,16 +28,6 @@ SRC_URI += "file://install-strip.patch"
 
 inherit autotools
 
-# OPTIONS
-# The following two variables can be set in a distro or local.conf
-# to switch features on.  Each feature foo defines OPENLDAP_OPTION_foo
-# and OPENLDAP_DEPENDS_foo in this file - to include feature foo add
-# the two variables into the setting of the options below (please use
-# += because that means this can be done in *both* distro.conf and
-# local.conf!
-OPENLDAP_OPTIONS ?= ""
-OPENLDAP_DEPENDS ?= ""
-
 # CV SETTINGS
 # Required to work round AC_FUNC_MEMCMP which gets the wrong answer
 # when cross compiling (should be in site?)
@@ -50,33 +40,21 @@ EXTRA_OECONF += "ac_cv_func_memcmp_working=yes"
 EXTRA_OECONF += "--with-yielding-select=yes"
 # Shared libraries are nice...
 EXTRA_OECONF += "--enable-dynamic"
-#
-# Disable TLS to remove the need for openssl/libcrypto
-OPENLDAP_OPTION_tls  ?= "--with-tls"
-# set the following to "openssl" to build tls support
-OPENLDAP_DEPENDS_tls ?= "gnutls"
-EXTRA_OECONF += "${OPENLDAP_OPTION_tls}"
-DEPENDS += "${OPENLDAP_DEPENDS_tls}"
-#
-# Disable Cyrus SASL, which may or may not be working at present...
-OPENLDAP_OPTION_sasl  ?= "--without-cyrus-sasl"
-# set the following to "cyrus-sasl" to build SASL support
-OPENLDAP_DEPENDS_sasl ?= ""
-EXTRA_OECONF += "${OPENLDAP_OPTION_sasl}"
-DEPENDS += "${OPENLDAP_DEPENDS_sasl}"
+
+PACKAGECONFIG ??= "gnutls modules \
+                   ldap meta monitor null passwd shell proxycache dnssrv \
+"
+#--with-tls              with TLS/SSL support auto|openssl|gnutls [auto]
+PACKAGECONFIG[gnutls] = "--with-tls=gnutls,,gnutls"
+PACKAGECONFIG[openssl] = "--with-tls=openssl,,openssl"
+
+PACKAGECONFIG[sasl] = "--with-cyrus-sasl,--without-cyrus-sasl,cyrus-sasl"
+PACKAGECONFIG[modules] = "lt_cv_dlopen_self=yes --enable-modules,--disable-modules,libtool"
 
 # SLAPD options
 #
 # UNIX crypt(3) passwd support:
 EXTRA_OECONF += "--enable-crypt"
-#
-# Enable dynamic module loading.  If this is *disabled* the
-# dependency on libtool is removed (to disable set the following
-# to variables to "" in a .conf file).
-OPENLDAP_OPTION_modules += "lt_cv_dlopen_self=yes --enable-modules"
-OPENLDAP_DEPENDS_modules += "libtool"
-EXTRA_OECONF += " ${OPENLDAP_OPTION_modules}"
-DEPENDS += "${OPENLDAP_DEPENDS_modules}"
 
 # SLAPD BACKEND
 #
@@ -99,92 +77,64 @@ md = "${libexecdir}/openldap"
 #--enable-bdb          enable Berkeley DB backend no|yes|mod yes
 # The Berkely DB is the standard choice.  This version of OpenLDAP requires
 # the version 4 implementation or better.
-# To disable this set all three of the following variables to <empty> in
-# a .conf file (this will allow ldbm to be build with gdbm).
-#OPENLDAP_OPTION_bdb   ?= "--enable-bdb=mod"
-OPENLDAP_DEPENDS_bdb  ?= "db"
-EXTRA_OECONF += "${OPENLDAP_OPTION_bdb}"
-DEPENDS += "${OPENLDAP_DEPENDS_bdb}"
-#
+PACKAGECONFIG[bdb] = "--enable-bdb=mod,--enable-bdb=no,db"
+
 #--enable-dnssrv       enable dnssrv backend no|yes|mod no
-# This has no dependencies.
-EXTRA_OECONF += "--enable-dnssrv=mod"
-#
+PACKAGECONFIG[dnssrv] = "--enable-dnssrv=mod,--enable-dnssrv=no"
+
 #--enable-hdb          enable Hierarchical DB backend no|yes|mod no
 # This forces ldbm to use Berkeley too, remove to use gdbm
-#OPENLDAP_OPTION_hdb   ?= "--enable-hdb=mod"
-OPENLDAP_DEPENDS_hdb  ?= "db"
-OPENLDAP_PACKAGE_hdb  ?= "${PN}-backend-hdb"
-EXTRA_OECONF += "${OPENLDAP_OPTION_hdb}"
-DEPENDS += "${OPENLDAP_DEPENDS_hdb}"
-#
+PACKAGECONFIG[hdb] = "--enable-hdb=mod,--enable-hdb=no,db"
+
 #--enable-ldap         enable ldap backend no|yes|mod no
-# This has no dependencies
-EXTRA_OECONF += "--enable-ldap=mod"
-#
+PACKAGECONFIG[ldap] = "--enable-ldap=mod,--enable-ldap=no,"
+
 #--enable-ldbm         enable ldbm backend no|yes|mod no
 # ldbm requires further specification of the underlying database API, because
 # bdb is enabled above this must be set to berkeley, however the config
 # defaults this correctly so --with-ldbm-api is *not* set.  The build will
-# fail if bdb is removed (above) but not database is built to provide the
-# support for ldbm (because the 'DEPENDS_ldbm' is empty below.)
-#
-# So to use gdbm set:
-OPENLDAP_OPTION_ldbm = "--enable-ldbm=mod --with-ldbm-api=gdbm"
-OPENLDAP_DEPENDS_ldbm = "gdbm"
-# And clear the bdb and hdb settings.
-OPENLDAP_OPTION_ldbm ?= "--enable-ldbm=mod"
-OPENLDAP_DEPENDS_ldbm ?= ""
-EXTRA_OECONF += "${OPENLDAP_OPTION_ldbm}"
-DEPENDS += "${OPENLDAP_DEPENDS_ldbm}"
-#
+# fail if bdb is removed, but no database is built to provide the
+# support for ldbm
+# guide.html:<P>back-ldbm was both slow and unreliable. Its byzantine indexing code was prone to spontaneous corruption, as were the underlying database libraries that were commonly used (e.g. GDBM or NDBM). back-bdb and back-hdb are superior in every aspect, with simplified indexing to avoid index corruption, fine-grained locking for greater concurrency, hierarchical caching for greater performance, streamlined on-disk format for greater efficiency and portability, and full transaction support for greater reliability.</P>
+# configure: WARNING: unrecognized options: --disable-silent-rules, --enable-ldbm, --with-ldbm-api
+#PACKAGECONFIG[ldbm] = "--enable-ldbm=mod --with-ldbm-api=gdbm,--enable-ldbm-no,gdbm"
+
 #--enable-meta         enable metadirectory backend no|yes|mod no
-# No dependencies
-EXTRA_OECONF += "--enable-meta=mod"
-#
+PACKAGECONFIG[meta] = "--enable-meta=mod,--enable-meta=no,"
+
 #--enable-monitor      enable monitor backend no|yes|mod yes
-EXTRA_OECONF += "--enable-monitor=mod"
-#
+PACKAGECONFIG[monitor] = "--enable-monitor=mod,--enable-monitor=no,"
+
 #--enable-null         enable null backend no|yes|mod no
-EXTRA_OECONF += "--enable-null=mod"
-#
+PACKAGECONFIG[null] = "--enable-null=mod,--enable-null=no,"
+
 #--enable-passwd       enable passwd backend no|yes|mod no
-EXTRA_OECONF += " --enable-passwd=mod"
-#
+PACKAGECONFIG[passwd] = "--enable-passwd=mod,--enable-passwd=no,"
+
 #--enable-perl         enable perl backend no|yes|mod no
 #  This requires a loadable perl dynamic library, if enabled without
 #  doing something appropriate (building perl?) the build will pick
-#  up the build machine perl - not good.
-OPENLDAP_OPTION_perl ?= "--enable-perl=mod"
-OPENLDAP_DEPENDS_perl ?= "perl"
-#EXTRA_OECONF += "${OPENLDAP_OPTION_perl}"
-#DEPENDS += "${OPENLDAP_DEPENDS_perl}"
-#
+#  up the build machine perl - not good (inherit perlnative?)
+PACKAGECONFIG[perl] = "--enable-perl=mod,--enable-perl=no,perl"
+
 #--enable-shell        enable shell backend no|yes|mod no
-EXTRA_OECONF += "--enable-shell=mod"
-#
+# configure: WARNING: Use of --without-threads is recommended with back-shell
+PACKAGECONFIG[shell] = "--enable-shell=mod --without-threads,--enable-shell=no,"
+
 #--enable-sql          enable sql backend no|yes|mod no
 # sql requires some sql backend which provides sql.h, sqlite* provides
 # sqlite.h (which may be compatible but hasn't been tried.)
-OPENLDAP_OPTION_sql ?= "--enable-sql=mod"
-OPENLDAP_DEPENDS_sql ?= "sql"
-#EXTRA_OECONF += "${OPENLDAP_OPTION_sql}"
-#DEPENDS += "${OPENLDAP_DEPENDS_sql}"
-#
+PACKAGECONFIG[sql] = "--enable-sql=mod,--enable-sql=no,sqlite3"
+
 #--enable-dyngroup     Dynamic Group overlay no|yes|mod no
 #  This is a demo, Proxy Cache defines init_module which conflicts with the
 #  same symbol in dyngroup
-#EXTRA_OECONF += "--enable-dyngroup=mod"
-#
+PACKAGECONFIG[dyngroup] = "--enable-dyngroup=mod,--enable-dyngroup=no,"
+
 #--enable-proxycache   Proxy Cache overlay no|yes|mod no
-EXTRA_OECONF += "--enable-proxycache=mod"
+PACKAGECONFIG[proxycache] = "--enable-proxycache=mod,--enable-proxycache=no,"
 FILES_${PN}-overlay-proxycache = "${md}/pcache-*.so.*"
 PACKAGES += "${PN}-overlay-proxycache"
-#
-# LOCAL OPTION OVERRIDES
-# The distro/lcoal options must be added in *last*
-EXTRA_OECONF += "${OPENLDAP_OPTIONS}"
-DEPENDS      += "${OPENLDAP_DEPENDS}"
 
 CPPFLAGS_append = " -D_GNU_SOURCE"
 
-- 
1.8.3.2

[meta-oe][PATCH 03/11] samba: use more specific LICENSE

[Martin Jansa]

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-oe/recipes-connectivity/samba/samba.inc | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-oe/recipes-connectivity/samba/samba.inc b/meta-oe/recipes-connectivity/samba/samba.inc
index 6092226..e7defaa 100644
--- a/meta-oe/recipes-connectivity/samba/samba.inc
+++ b/meta-oe/recipes-connectivity/samba/samba.inc
@@ -1,5 +1,5 @@
 SECTION = "console/network"
-LICENSE = "GPL"
+LICENSE = "GPL-3.0"
 DEPENDS = "readline virtual/libiconv talloc"
 
 SRC_URI = "http://samba.org/samba/ftp/stable/samba-${PV}.tar.gz \
-- 
1.8.3.2

[meta-oe][PATCH 04/11] samba: add dependency on zlib popt, PACKAGECONFIG for pam

[Martin Jansa]

* zlib, popt are autodetected or used in bundled versions
* pam is autodetected if available

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-oe/recipes-connectivity/samba/samba.inc | 7 ++++++-
 1 file changed, 6 insertions(+), 1 deletion(-)

diff --git a/meta-oe/recipes-connectivity/samba/samba.inc b/meta-oe/recipes-connectivity/samba/samba.inc
index e7defaa..df8ed68 100644
--- a/meta-oe/recipes-connectivity/samba/samba.inc
+++ b/meta-oe/recipes-connectivity/samba/samba.inc
@@ -1,6 +1,6 @@
 SECTION = "console/network"
 LICENSE = "GPL-3.0"
-DEPENDS = "readline virtual/libiconv talloc"
+DEPENDS = "readline virtual/libiconv talloc zlib popt"
 
 SRC_URI = "http://samba.org/samba/ftp/stable/samba-${PV}.tar.gz \
            file://volatiles.03_samba \
@@ -33,12 +33,17 @@ EXTRA_OECONF='--disable-cups \
               --with-mandir=${mandir} \
               --with-swatdir=${datadir}/swat \
               --with-aio-support \
+              --with-winbind \
+              --with-wbclient \
               --without-libtalloc \
               --without-acl-support \
               --disable-avahi \
               samba_cv_struct_timespec=yes \
               libreplace_cv_HAVE_MMAP=${SAMBAMMAP}'
 
+PACKAGECONFIG = "${@base_contains('DISTRO_FEATURES', 'pam', 'pam', '', d)}"
+PACKAGECONFIG[pam] = "--with-pam,--without-pam,libpam"
+
 INITSCRIPT_PACKAGES = "samba winbind"
 INITSCRIPT_NAME_samba = "samba"
 INITSCRIPT_NAME_winbind = "winbind"
-- 
1.8.3.2

[meta-oe][PATCH 05/11] libgphoto2: add configure option for gd and add PACKAGECONFIG

[Martin Jansa]

* it's autodetected and pulls couple of other dependencies
  freetype gd libpng lockdev zlib

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 .../libgphoto2-2.4.11/allow.to.disable.gd.patch    | 33 ++++++++++++++++++++++
 .../recipes-graphics/gphoto2/libgphoto2_2.4.11.bb  |  6 +++-
 2 files changed, 38 insertions(+), 1 deletion(-)
 create mode 100644 meta-oe/recipes-graphics/gphoto2/libgphoto2-2.4.11/allow.to.disable.gd.patch

diff --git a/meta-oe/recipes-graphics/gphoto2/libgphoto2-2.4.11/allow.to.disable.gd.patch b/meta-oe/recipes-graphics/gphoto2/libgphoto2-2.4.11/allow.to.disable.gd.patch
new file mode 100644
index 0000000..aa1a124
--- /dev/null
+++ b/meta-oe/recipes-graphics/gphoto2/libgphoto2-2.4.11/allow.to.disable.gd.patch
@@ -0,0 +1,33 @@
+--- libgphoto2-2.4.11.orig/configure.ac	2013-07-19 21:59:10.857223729 +0200
++++ libgphoto2-2.4.11/configure.ac	2013-07-19 22:06:13.873233928 +0200
+@@ -270,15 +270,21 @@
+ dnl ---------------------------------------------------------------------------
+ dnl check for libgd
+ dnl ---------------------------------------------------------------------------
+-LIBGD=""
+-libgd_msg="no"
+-AC_SUBST(LIBGD)
+-AC_CHECK_LIB(gd,gdImageCreateTrueColor,[
+-	AC_CHECK_HEADER(gd.h,[
+-		AC_DEFINE(HAVE_GD,1,[define if we have LIBGD and its headers])
+-		LIBGD="-lgd"
+-		libgd_msg="yes"
+-	])
++AC_ARG_ENABLE([gd],
++[AS_HELP_STRING([--enable-gd],
++                [enable gd support])],[
++        LIBGD=""
++        libgd_msg="no"
++        AC_SUBST(LIBGD)
++        if test "x$enableval" != "xno"; then
++                AC_CHECK_LIB(gd,gdImageCreateTrueColor,[
++                        AC_CHECK_HEADER(gd.h,[
++                                AC_DEFINE(HAVE_GD,1,[define if we have LIBGD and its headers])
++                                LIBGD="-lgd"
++                                libgd_msg="yes"
++                        ])
++                ])
++        fi
+ ])
+ GP_CONFIG_MSG([GD conversion support],[${libgd_msg}])
+ 
diff --git a/meta-oe/recipes-graphics/gphoto2/libgphoto2_2.4.11.bb b/meta-oe/recipes-graphics/gphoto2/libgphoto2_2.4.11.bb
index fd547d9..ae783b8 100644
--- a/meta-oe/recipes-graphics/gphoto2/libgphoto2_2.4.11.bb
+++ b/meta-oe/recipes-graphics/gphoto2/libgphoto2_2.4.11.bb
@@ -16,6 +16,7 @@ SRC_URI = "${SOURCEFORGE_MIRROR}/gphoto/libgphoto2-${PV}.tar.bz2;name=libgphoto2
            file://10-camera-libgphoto2.fdi \
            file://40-libgphoto2.rules \
            file://0001-configure.ac-remove-AM_PO_SUBDIRS.patch \
+           file://allow.to.disable.gd.patch \
 "
 
 SRC_URI[libgphoto2.md5sum] = "16a22b9739e45a95980ed62705fe7333"
@@ -25,6 +26,9 @@ inherit autotools pkgconfig gettext lib_package
 
 EXTRA_OECONF = " --with-drivers=all udevscriptdir=/lib/udev ac_cv_lib_ltdl_lt_dlcaller_register=yes"
 
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[gd] = "--enable-gd,--disable-gd,gd"
+
 do_configure_append() {
     cp ${STAGING_DATADIR}/gettext/po/Makefile.in.in ${S}/libgphoto2_port/po/
     cd ${S}/libgphoto2_port/
@@ -44,7 +48,7 @@ PACKAGES =+ "libgphotoport libgphoto2-camlibs"
 FILES_libgphoto2-camlibs = "${libdir}/libgphoto2*/*/*.so*"
 RRECOMMENDS_${PN} = "libgphoto2-camlibs"
 
-FILES_libgphotoport = "${libdir}/libgphoto2_port.so.*" 
+FILES_libgphotoport = "${libdir}/libgphoto2_port.so.*"
 
 FILES_${PN} += "${base_libdir}/udev/* ${datadir}/hal"
 FILES_${PN}-dbg += "${libdir}/*/*/.debug"
-- 
1.8.3.2

[meta-oe][PATCH 06/11] jack: add dependency on libsaplerate0 and readline

[Martin Jansa]

* they are autodetected from sysroot and configure doesn't have option
  to explicitly disable them, so PACKAGECONFIG won't work without improving
  configure

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-oe/recipes-multimedia/jack/jack_0.121.0.bb | 3 +--
 1 file changed, 1 insertion(+), 2 deletions(-)

diff --git a/meta-oe/recipes-multimedia/jack/jack_0.121.0.bb b/meta-oe/recipes-multimedia/jack/jack_0.121.0.bb
index e3d5e7e..b255cef 100644
--- a/meta-oe/recipes-multimedia/jack/jack_0.121.0.bb
+++ b/meta-oe/recipes-multimedia/jack/jack_0.121.0.bb
@@ -10,8 +10,7 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=c030468238b2cf89925a57f2780396a7 \
                     file://COPYING.LGPL;md5=e77fe93202736b47c07035910f47974a \
 "
 
-
-DEPENDS = "alsa-lib"
+DEPENDS = "alsa-lib libsamplerate0 readline"
 
 SVNPV = "${@'${PV}'.replace('.', '_')}"
 SRCREV = "4484"
-- 
1.8.3.2

[meta-oe][PATCH 07/11] glog: add dependency on libunwind

[Martin Jansa]

* it's autodetected from sysroot and configure doesn't have parameter to explicitly
  disable it so PACKAGECONFIG won't work OOTB

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-oe/recipes-support/glog/glog.inc | 2 ++
 1 file changed, 2 insertions(+)

diff --git a/meta-oe/recipes-support/glog/glog.inc b/meta-oe/recipes-support/glog/glog.inc
index 97f3728..8a1fb42 100644
--- a/meta-oe/recipes-support/glog/glog.inc
+++ b/meta-oe/recipes-support/glog/glog.inc
@@ -6,4 +6,6 @@ HOMEPAGE = "https://code.google.com/p/google-glog/"
 LICENSE = "BSD"
 LIC_FILES_CHKSUM = "file://COPYING;md5=dc9db360e0bbd4e46672f3fd91dd6c4b"
 
+DEPENDS = "libunwind"
+
 inherit autotools pkgconfig
-- 
1.8.3.2

[meta-oe][PATCH 00/11] autodetected dependencies

[Martin Jansa]

The following changes since commit 41748a4afc494b714315ba529f138214f80d41b9:

  licences: Add iozone3, SMAIL_GPL (2013-07-20 17:03:29 +0200)

are available in the git repository at:

  git://git.openembedded.org/meta-openembedded-contrib jansa/deps
  http://cgit.openembedded.org/cgit.cgi/meta-openembedded-contrib/log/?h=jansa/deps

Martin Jansa (11):
  lcdproc5: add PACKAGECONFIG for libftdi, libusb
  openldap: convert to PACKAGECONFIGs, explicitly disable openssl
  samba: use more specific LICENSE
  samba: add dependency on zlib popt, PACKAGECONFIG for pam
  libgphoto2: add configure option for gd and add PACKAGECONFIG
  jack: add dependency on libsaplerate0 and readline
  glog: add dependency on libunwind
  lvm2: add PACKAGECONFIG for readline
  libunwind: add PACKAGECONFIG for lzma
  ntp: add PACKAGECONFIG for libcap and readline
  vim: add PACKAGECONFIG for acl

 meta-networking/recipes-support/ntp/ntp.inc        |   2 +
 meta-oe/recipes-connectivity/samba/samba.inc       |   9 +-
 meta-oe/recipes-extended/lcdproc/lcdproc5.inc      |   8 +-
 .../libgphoto2-2.4.11/allow.to.disable.gd.patch    |  33 +++++
 .../recipes-graphics/gphoto2/libgphoto2_2.4.11.bb  |   6 +-
 meta-oe/recipes-multimedia/jack/jack_0.121.0.bb    |   3 +-
 meta-oe/recipes-support/glog/glog.inc              |   2 +
 meta-oe/recipes-support/libunwind/libunwind.inc    |   4 +
 meta-oe/recipes-support/lvm2/lvm2.inc              |   3 +
 .../recipes-support/openldap/openldap_2.4.23.bb    | 136 +++++++--------------
 meta-oe/recipes-support/vim/vim.inc                |   1 +
 11 files changed, 107 insertions(+), 100 deletions(-)
 create mode 100644 meta-oe/recipes-graphics/gphoto2/libgphoto2-2.4.11/allow.to.disable.gd.patch

-- 
1.8.3.2

[meta-oe][PATCH 08/11] lvm2: add PACKAGECONFIG for readline

[Martin Jansa]

* it's autodetected from sysroot

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-oe/recipes-support/lvm2/lvm2.inc | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/meta-oe/recipes-support/lvm2/lvm2.inc b/meta-oe/recipes-support/lvm2/lvm2.inc
index 5de1e3f..1f3b62e 100644
--- a/meta-oe/recipes-support/lvm2/lvm2.inc
+++ b/meta-oe/recipes-support/lvm2/lvm2.inc
@@ -11,6 +11,9 @@ S = "${WORKDIR}/LVM2.${PV}"
 SRC_URI = "ftp://sources.redhat.com/pub/lvm2/old/LVM2.${PV}.tgz \
            file://lvm.conf"
 
+PACKAGECONFIG ??= "readline"
+PACKAGECONFIG[readline] = "--enable-readline,--disable-readline,readline"
+
 # Unset user/group to unbreak install.
 EXTRA_OECONF = "--with-user= \
                 --with-group= \
-- 
1.8.3.2

[meta-oe][PATCH 09/11] libunwind: add PACKAGECONFIG for lzma

[Martin Jansa]

* it's autodetected from sysroot

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-oe/recipes-support/libunwind/libunwind.inc | 4 ++++
 1 file changed, 4 insertions(+)

diff --git a/meta-oe/recipes-support/libunwind/libunwind.inc b/meta-oe/recipes-support/libunwind/libunwind.inc
index 2e1504e..a5b7482 100644
--- a/meta-oe/recipes-support/libunwind/libunwind.inc
+++ b/meta-oe/recipes-support/libunwind/libunwind.inc
@@ -6,6 +6,10 @@ LIC_FILES_CHKSUM = "file://LICENSE;md5=3fced11d6df719b47505837a51c16ae5"
 SRC_URI = "http://download.savannah.nongnu.org/releases/${BPN}/${BPN}-${PV}.tar.gz"
 
 inherit autotools
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[lzma] = "--enable-minidebuginfo,--disable-minidebuginfo,lzma"
+
 EXTRA_OECONF_arm = "--enable-debug-frame"
 
 CFLAGS += "${ATOMICOPS}"
-- 
1.8.3.2

[meta-oe][PATCH 10/11] ntp: add PACKAGECONFIG for libcap and readline

[Martin Jansa]

* it's autodetected from sysroot

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-networking/recipes-support/ntp/ntp.inc | 2 ++
 1 file changed, 2 insertions(+)

diff --git a/meta-networking/recipes-support/ntp/ntp.inc b/meta-networking/recipes-support/ntp/ntp.inc
index 79e7401..9367d41 100644
--- a/meta-networking/recipes-support/ntp/ntp.inc
+++ b/meta-networking/recipes-support/ntp/ntp.inc
@@ -37,6 +37,8 @@ PACKAGECONFIG[openssl] = "--with-openssl-libdir=${STAGING_LIBDIR} \
                           --with-crypto, \
                           --without-openssl --without-crypto, \
                           openssl"
+PACKAGECONFIG[cap] = "--enable-linuxcaps,--disable-linuxcaps,libcap"
+PACKAGECONFIG[readline] = "--with-lineeditlibs,--without-lineeditlibs,readline"
 
 do_install_append() {
     install -d ${D}${sysconfdir}/init.d
-- 
1.8.3.2

[meta-oe][PATCH 11/11] vim: add PACKAGECONFIG for acl

[Martin Jansa]

* it's autodetected from sysroot

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-oe/recipes-support/vim/vim.inc | 1 +
 1 file changed, 1 insertion(+)

diff --git a/meta-oe/recipes-support/vim/vim.inc b/meta-oe/recipes-support/vim/vim.inc
index 12e8c1e..d7336c2 100644
--- a/meta-oe/recipes-support/vim/vim.inc
+++ b/meta-oe/recipes-support/vim/vim.inc
@@ -32,6 +32,7 @@ do_configure () {
 PACKAGECONFIG ??= ""
 
 PACKAGECONFIG[gtkgui] = "--enable-gtk2-test --enable-gui=gtk2,--enable-gui=no,gtk+,"
+PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
 PACKAGECONFIG[x11] = "--with-x,--without-x,xt,"
 PACKAGECONFIG[tiny] = "--with-features=tiny,--with-features=big,,"
 
-- 
1.8.3.2