[PATCHv2 1/5] ti-syslink: Add TI Syslink Common include file.

[PATCHv2 1/5] ti-syslink: Add TI Syslink Common include file.

[Siddharth Heroor]

From: Siddharth Heroor <heroor@ti.com>

* TI Syslink is an IPC layer for ARM-DSP Communication.
* Add a common include file for the different Syslink
  environment variables.

Signed-off-by: Siddharth Heroor <heroor@ti.com>
---
 recipes/ti/ti-syslink-common.inc |   25 +++++++++++++++++++++++++
 1 files changed, 25 insertions(+), 0 deletions(-)
 create mode 100644 recipes/ti/ti-syslink-common.inc

diff --git a/recipes/ti/ti-syslink-common.inc b/recipes/ti/ti-syslink-common.inc
new file mode 100644
index 0000000..584fe8e
--- /dev/null
+++ b/recipes/ti/ti-syslink-common.inc
@@ -0,0 +1,25 @@
+# Define all enviroment variables required by syslink.
+
+SYSLINK_ROOT           ?= "${WORKDIR}/syslink_${PV}"
+SYSLINKHLOSSAMPLES     ?= "procMgr frameq gateMP heapBufMP heapMemMP listMP messageQ notify ringIO ringIO_gpp sharedRegion"
+SYSLINKPLATFORM        ?= "TI81XX"
+SYSLINKSUFFIX          ?= "xe674"
+SYSLINKLOADER          ?= "ELF"
+
+SYSLINKVARIANT_ti816x   = "TI816X"
+SYSLINKVARIANT_ti814x   = "TI814X"
+SYSLINKVARIANT         ?= "<UNDEFINED_SYSLINKVARIANT>"
+
+XDCTARGETS             ?= "ti.targets.elf.C674"
+XDCPATH                ?= "${IPC_INSTALL_DIR}/packages;${SYSBIOS_INSTALL_DIR}/packages" 
+XDCBUILDCFG            ?= "${SYSLINK_ROOT}/config.bld"
+
+export SYSLINK_ROOT
+export SYSLINKHLOSSAMPLES
+export SYSLINKPLATFORM
+export SYSLINKSUFFIX
+export SYSLINKLOADER
+export SYSLINKVARIANT
+export XDCTARGETS
+export XDCPATH
+export XDCBUILDCFG
-- 
1.7.0.4

[PATCHv2 2/5] ti-syslink: Add include file for Syslink Module.

[Siddharth Heroor]

From: Siddharth Heroor <heroor@ti.com>

* Add Syslink Kernel Module include file for TI816x and TI814x
  device families.

Signed-off-by: Siddharth Heroor <heroor@ti.com>
---
 recipes/ti/ti-syslink-module.inc |   31 +++++++++++++++++++++++++++++++
 1 files changed, 31 insertions(+), 0 deletions(-)
 create mode 100644 recipes/ti/ti-syslink-module.inc

diff --git a/recipes/ti/ti-syslink-module.inc b/recipes/ti/ti-syslink-module.inc
new file mode 100644
index 0000000..10c2d6e
--- /dev/null
+++ b/recipes/ti/ti-syslink-module.inc
@@ -0,0 +1,31 @@
+DESCRIPTION = "SYSLINK Inter-Processor Communications (IPC) Kernel module for TI ARM/DSP processors"
+HOMEPAGE = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/syslink/index.html"
+SECTION = "devel"
+LICENSE = "BSD"
+
+COMPATIBLE_MACHINE = "(ti816x|ti814x)"
+
+require ti-paths.inc
+require ti-staging.inc
+require ti-syslink-common.inc
+
+inherit module
+
+S = "${WORKDIR}/syslink_${PV}/ti/syslink/utils/hlos/knl/Linux"
+
+SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/SysLink/${PV}/exports/syslink_${PV}.tar.gz;name=syslinktarball"
+
+DEPENDS =+ "ti-ipc"
+
+EXTRA_OEMAKE = "ARCH='${TARGET_ARCH}' \
+    CROSS_COMPILE='${TARGET_PREFIX}' \
+    SYSLINK_PLATFORM='${SYSLINKPLATFORM}' \
+    SYSLINK_VARIANT='${SYSLINKVARIANT}' \
+    SYSLINK_LOADER='${SYSLINKLOADER}' \
+    SYSLINK_PKGPATH='${IPC_INSTALL_DIR}/packages' \
+    KDIR='${STAGING_KERNEL_DIR}'"
+
+do_install () {
+    install -d ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp
+    install -m 0755 ${SYSLINK_ROOT}/ti/syslink/bin/${SYSLINKVARIANT}/syslink.ko ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/
+}
-- 
1.7.0.4

[PATCHv2 3/5] ti-syslink: Add include file for Syslink Libraries.

[Siddharth Heroor]

From: Siddharth Heroor <heroor@ti.com>

* Add Syslink libraries for TI816x and TI814x device families.
* Build and stage both Linux and DSP side library files.

Signed-off-by: Siddharth Heroor <heroor@ti.com>
---
 recipes/ti/ti-syslink-libs.inc |   45 ++++++++++++++++++++++++++++++++++++++++
 1 files changed, 45 insertions(+), 0 deletions(-)
 create mode 100644 recipes/ti/ti-syslink-libs.inc

diff --git a/recipes/ti/ti-syslink-libs.inc b/recipes/ti/ti-syslink-libs.inc
new file mode 100644
index 0000000..fff36b6
--- /dev/null
+++ b/recipes/ti/ti-syslink-libs.inc
@@ -0,0 +1,45 @@
+DESCRIPTION = "SYSLINK Inter-Processor Communications (IPC) libraries for TI ARM/DSP processors"
+HOMEPAGE = "http://software-dl.ti.com/dsps/dsps_public_sw/sdo_sb/targetcontent/syslink/index.html"
+SECTION = "devel"
+LICENSE = "BSD"
+
+COMPATIBLE_MACHINE = "(ti816x|ti814x)"
+
+require ti-paths.inc
+require ti-staging.inc
+require ti-syslink-common.inc
+
+S = "${WORKDIR}/syslink_${PV}"
+
+SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/SysLink/${PV}/exports/syslink_${PV}.tar.gz;name=syslinktarball"
+
+DEPENDS = "ti-sysbios ti-xdctools ti-cgt6x ti-ipc"
+
+EXTRA_OEMAKE = "ARCH='${TARGET_ARCH}' \
+    CROSS_COMPILE='${TARGET_PREFIX}' \
+    SYSLINK_PLATFORM='${SYSLINKPLATFORM}' \
+    SYSLINK_VARIANT='${SYSLINKVARIANT}' \
+    SYSLINK_LOADER='${SYSLINKLOADER}' \
+    SYSLINK_PKGPATH='${IPC_INSTALL_DIR}/packages' \
+    KDIR='${STAGING_KERNEL_DIR}'"
+
+do_compilexdc() {
+    cd ${S}/ti/syslink 
+    ${XDC_INSTALL_DIR}/xdc .make -PR .
+    ${XDC_INSTALL_DIR}/xdc clean -PR .
+    ${XDC_INSTALL_DIR}/xdc .interfaces -PR .
+    ${XDC_INSTALL_DIR}/xdc -PR . 
+}
+
+addtask compilexdc after do_configure before do_compile
+
+do_compile() {
+    cd ${S}/ti/syslink/utils/hlos/usr/Linux
+    oe_runmake
+}
+
+do_install () {
+    # Install/Stage the Source Tree
+    install -d ${D}${SYSLINK_INSTALL_DIR_RECIPE}
+    cp -pPrf ${S}/* ${D}${SYSLINK_INSTALL_DIR_RECIPE}
+}
-- 
1.7.0.4

[PATCHv2 4/5] ti-syslink-module: Add Syslink version 02.00.00.68 Beta2

[Siddharth Heroor]

From: Siddharth Heroor <heroor@ti.com>


Signed-off-by: Siddharth Heroor <heroor@ti.com>
---
 recipes/ti/ti-syslink-module_02.00.00.68.bb |   11 +++++++++++
 1 files changed, 11 insertions(+), 0 deletions(-)
 create mode 100644 recipes/ti/ti-syslink-module_02.00.00.68.bb

diff --git a/recipes/ti/ti-syslink-module_02.00.00.68.bb b/recipes/ti/ti-syslink-module_02.00.00.68.bb
new file mode 100644
index 0000000..f7bcb35
--- /dev/null
+++ b/recipes/ti/ti-syslink-module_02.00.00.68.bb
@@ -0,0 +1,11 @@
+require ti-syslink-module.inc
+
+PV = "02_00_00_68"
+PVExtra = "_beta1"
+
+S = "${WORKDIR}/syslink_${PV}${PVExtra}/ti/syslink/utils/hlos/knl/Linux"
+SYSLINK_ROOT = "${WORKDIR}/syslink_${PV}${PVExtra}"
+
+SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/SysLink/${PV}${PVExtra}/exports/syslink_${PV}${PVExtra}.tar.gz;name=syslinktarball"
+SRC_URI[syslinktarball.md5sum] = "468034372124f70f82b60cfb5f11c8e8"
+SRC_URI[syslinktarball.sha256sum] = "ed574dcb3a5477cfbc69a1c9e768d5197291cb057d19fd791e16e1c89af3e8e1"
-- 
1.7.0.4

Re: [PATCHv2 4/5] ti-syslink-module: Add Syslink version 02.00.00.68 Beta2

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

On 07-04-11 10:01, Siddharth Heroor wrote:
> From: Siddharth Heroor <heroor@ti.com>


> +PV = "02_00_00_68"
> +PVExtra = "_beta1"

Is this beta1 or beta2? And if it's really a beta please adhere to
http://wiki.openembedded.org/index.php/Versioning_Policy
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)

iD8DBQFNnYVEMkyGM64RGpERAgSKAJ9SQrp1wKUCBcffZhROtE2kuZnsagCeP2+E
7M1YG4CZDGQCFH4I1OmX0WU=
=b3C4
-----END PGP SIGNATURE-----

[PATCHv2 5/5] ti-syslink-libs: Add Syslink version 02.00.00.68 Beta2

[Siddharth Heroor]

From: Siddharth Heroor <heroor@ti.com>


Signed-off-by: Siddharth Heroor <heroor@ti.com>
---
 recipes/ti/ti-syslink-libs_02.00.00.68.bb |   24 ++++++++++++++++++++++++
 1 files changed, 24 insertions(+), 0 deletions(-)
 create mode 100644 recipes/ti/ti-syslink-libs_02.00.00.68.bb

diff --git a/recipes/ti/ti-syslink-libs_02.00.00.68.bb b/recipes/ti/ti-syslink-libs_02.00.00.68.bb
new file mode 100644
index 0000000..4a88f28
--- /dev/null
+++ b/recipes/ti/ti-syslink-libs_02.00.00.68.bb
@@ -0,0 +1,24 @@
+require ti-syslink-libs.inc
+
+PV = "02_00_00_68"
+PVExtra = "_beta1"
+
+S = "${WORKDIR}/syslink_${PV}${PVExtra}"
+SYSLINK_ROOT = "${WORKDIR}/syslink_${PV}${PVExtra}"
+
+SRC_URI = "http://software-dl.ti.com/dsps/dsps_public_sw/SysLink/${PV}${PVExtra}/exports/syslink_${PV}${PVExtra}.tar.gz;name=syslinktarball"
+SRC_URI[syslinktarball.md5sum] = "468034372124f70f82b60cfb5f11c8e8"
+SRC_URI[syslinktarball.sha256sum] = "ed574dcb3a5477cfbc69a1c9e768d5197291cb057d19fd791e16e1c89af3e8e1"
+
+do_configure() {
+    # Update config.bld
+    sed -i \
+        -e s:^C674_ELF.rootDir.*:C674_ELF.rootDir\ =\ \"${CODEGEN_INSTALL_DIR}\":g \
+        -e s:C64P_COFF,://C64P_COFF:g \
+        -e s:C64P_ELF,://C64P_ELF:g \
+        -e s:C674_COFF,://C674P_COFF:g \
+        -e s:M3_ELF,://M3_ELF:g \
+        -e s:A8_ELF$://A8_ELF:g \
+        ${S}/config.bld
+}
+
-- 
1.7.0.4