[meta-oe][PATCH v2 0/2] Import ckermit recipe

[meta-oe][PATCH v2 0/2] Import ckermit recipe

[Anders Darander]

Ckermit is useful, not least as an alternative to lrzsz for serial port
file-transfer (it has been a lot more robust in a number of cases).

This patch series imports the ckermit recipe from oe-dev. Thereafter, ckermit
gets updated to the latest version, which also has the licensed change to BSD
3-clause.

V2: * Rebasing on the latest OE-version
    * Make sure that the patch is a rename, not add/delete pair.

The following changes since commit 4edc680bfd93f9358f099e1513f916c46347f538:

  libx11: skip self if x11 not in DISTRO_FEATURES (2011-08-16 10:03:11 +0200)

are available in the git repository at:
  git://github.com/darander/meta-oe ckermit
  https://github.com/darander/meta-oe/tree/ckermit

Anders Darander (2):
  ckermit: import from OE rev 5350bbef01b8979617e3d0fd38939f94f1fa5315
  ckermit: update to version 9.0

 meta-oe/recipes-support/ckermit/ckermit_301.bb |   58 ++++++++++++++++++++++++
 1 files changed, 58 insertions(+), 0 deletions(-)
 create mode 100644 meta-oe/recipes-support/ckermit/ckermit_301.bb

-- 
1.7.5.4

[meta-oe][PATCH v2 1/2] ckermit: import from OE rev 5350bbef01b8979617e3d0fd38939f94f1fa5315

[Anders Darander]

Adding LIC_FILES_CHKSUM, otherwise it is identical to the oe version.

Build tested on a custom ARM9 platform.

Signed-off-by: Anders Darander <anders@chargestorm.se>
---
 meta-oe/recipes-support/ckermit/ckermit_211.bb |   98 ++++++++++++++++++++++++
 1 files changed, 98 insertions(+), 0 deletions(-)
 create mode 100644 meta-oe/recipes-support/ckermit/ckermit_211.bb

diff --git a/meta-oe/recipes-support/ckermit/ckermit_211.bb b/meta-oe/recipes-support/ckermit/ckermit_211.bb
new file mode 100644
index 0000000..88bc918
--- /dev/null
+++ b/meta-oe/recipes-support/ckermit/ckermit_211.bb
@@ -0,0 +1,98 @@
+DESCRIPTION = "C-Kermit is a combined serial and network communication \
+software package offering a consistent, medium-independent, \
+cross-platform approach to connection establishment, terminal \
+sessions, file transfer, character-set translation, and automation \
+of communication tasks."
+HOMEPAGE = "http://www.columbia.edu/kermit/"
+SECTION = "console/network"
+LICENSE = "Kermit"
+LIC_FILES_CHKSUM = "file://COPYING.TXT;md5=17dabbd2543933464b6d32083c3a3596"
+SRC_URI = "ftp://kermit.columbia.edu/kermit/archives/cku${PV}.tar.gz;subdir=${BPN}-${PV}"
+PR = "r3"
+
+#
+# From http://www.columbia.edu/kermit/ck80.html#license
+#
+#	"Free Unix Distributions: C-Kermit may be included in "free Unix"
+#	distributions such as GNU/Linux, FreeBSD, NetBSD, and OpenBSD. See the
+#	license for details."
+#
+# A distribution based on OpenEmbedded (OpenZaurus, OpenSimpad, etc.) is a
+# "free Unix" distribution, therefore we can include the package.
+#
+#
+# Please note that the license is not 100% free because it limits what you can
+# do:
+#
+#	"The C-Kermit source code may not be changed without the consent of
+#	the Kermit Project, which will not be unreasonably withheld (this is
+#	simply a matter of keeping a consistent and supportable code base)."
+#
+# But we don't change the source code in any way, so we comply to the license.
+# So, essentially for us C-Kermit is free as in beer, but not in freedom.
+#
+# That is true for other distros. C-Kkermit is distributed by:
+#
+#	Debian:	http://packages.debian.org/unstable/comm/ckermit
+#	Gentoo: http://mirror.pudas.net/gentoo-x86-portage/app-misc/ckermit/ckermit-8.0.211.ebuild
+#	SuSE: http://www.novell.com/products/linuxpackages/enterpriseserver/s390/ckermit.html
+#	Fedora Core: http://cvs.fedora.redhat.com/viewcvs/devel/ckermit/
+#	PLD: http://cvs.pld.org.pl/SPECS/ckermit.spec
+#
+# and, according to the Kermit website http://www.columbia.edu/kermit/ck80.html also with
+#
+#	Red Hat 9 (on earlier Red Hat's it was on the PowerTools CD)
+#	HP-UX
+#	FreeBSD
+#	NetBSD
+#	OpenBSD
+#
+# ... and probably other distros as well.
+#
+
+export CC2 = "${CC}"
+export BINDIR = "${bindir}"
+export MANDIR = "${mandir}/man1"
+export INFODIR = "${infodir}"
+
+# Additional flags. For uclibc we add -DNOARROWKEYS which stops ckermit
+# trying to look inside the stdio headers.
+CKERMIT_ADDITIONAL = ""
+CKERMIT_ADDITIONAL_libc-uclibc = "-DNOARROWKEYS"
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+
+do_compile () {
+	# The original makefile doesn't differentiate between CC and CC_FOR_BUILD,
+	# so we build wart manually. Note that you need a ckwart.o with the proper
+	# timestamp to make this hack work:
+	${BUILD_CC} -c ckwart.c
+	${BUILD_CC} -o wart ckwart.o
+	./wart ckcpro.w ckcpro.c
+
+	# read ${S}/ckccfg.txt to understand this :-)
+	oe_runmake wermit CFLAGS="${CFLAGS} -DLINUX -DCK_POSIX_SIG \
+		-DNOTCPOPTS -DLINUXFSSTND -DNOCOTFMC -DPOSIX -DUSE_STRERROR \
+		-DNOSYSLOG -DHAVE_PTMX -DNO_DNS_SRV -DNOGFTIMER \
+		-DNOB_50 -DNOB_75 -DNOB_134 -DNOB_150 -DNOB_200 \
+		-DNOB_1800 -DNOB_3600 -DNOB_7200 -DNOB_76K -DNOB_230K \
+		-DNOB_460K -DNOB_921K \
+		-DNOAPC -DNOCSETS -DNONET -DNOUNICODE -DNOHELP -DNODEBUG \
+		-DNOFRILLS -DNOFTP -DNODIAL -DNOPUSH -DNOIKSD -DNOHTTP -DNOFLOAT \
+		-DNOSERVER -DNOSEXP -DNORLOGIN -DNOOLDMODEMS -DNOSSH -DNOLISTEN \
+		-DNORESEND -DNOAUTODL -DNOSTREAMING -DNOHINTS -DNOCKXYZ -DNOLEARN \
+		-DNOMKDIR -DNOPERMS -DNOCKTIMERS -DNOCKREGEX -DNOREALPATH \
+		-DCK_SMALL -DNOLOGDIAL -DNORENAME -DNOWHATAMI \
+		${CKERMIT_ADDITIONAL}"
+}
+
+do_install () {
+	install -d ${D}${BINDIR} ${D}${MANDIR} ${D}${INFODIR}
+	oe_runmake 'DESTDIR=${D}' 'MANDIR=${D}${MANDIR}' install
+	# Fix up dangling symlink
+	rm ${D}${BINDIR}/kermit-sshsub
+	(cd ${D}${BINDIR} && ln -s ${BINDIR}/kermit kermit-sshusb)
+}
+
+SRC_URI[md5sum] = "5767ec5e6ff0857cbfe2d3ec1ee0e2bc"
+SRC_URI[sha256sum] = "39e7cd4892502344a635952843487d9b4bfa98e59d1e1acad5ef8aa969abba93"
-- 
1.7.5.4

[meta-oe][PATCH v2 2/2] ckermit: update to version 9.0

[Anders Darander]

The update changes the license from kermit to BSD.
Remove the NOAPCS compile flag to make the new version compile cleanly.

Signed-off-by: Anders Darander <anders@chargestorm.se>
---
 .../ckermit/{ckermit_211.bb => ckermit_301.bb}     |   56 +++-----------------
 1 files changed, 8 insertions(+), 48 deletions(-)
 rename meta-oe/recipes-support/ckermit/{ckermit_211.bb => ckermit_301.bb} (49%)

diff --git a/meta-oe/recipes-support/ckermit/ckermit_211.bb b/meta-oe/recipes-support/ckermit/ckermit_301.bb
similarity index 49%
rename from meta-oe/recipes-support/ckermit/ckermit_211.bb
rename to meta-oe/recipes-support/ckermit/ckermit_301.bb
index 88bc918..c789ea5 100644
--- a/meta-oe/recipes-support/ckermit/ckermit_211.bb
+++ b/meta-oe/recipes-support/ckermit/ckermit_301.bb
@@ -5,50 +5,10 @@ sessions, file transfer, character-set translation, and automation \
 of communication tasks."
 HOMEPAGE = "http://www.columbia.edu/kermit/"
 SECTION = "console/network"
-LICENSE = "Kermit"
-LIC_FILES_CHKSUM = "file://COPYING.TXT;md5=17dabbd2543933464b6d32083c3a3596"
-SRC_URI = "ftp://kermit.columbia.edu/kermit/archives/cku${PV}.tar.gz;subdir=${BPN}-${PV}"
-PR = "r3"
-
-#
-# From http://www.columbia.edu/kermit/ck80.html#license
-#
-#	"Free Unix Distributions: C-Kermit may be included in "free Unix"
-#	distributions such as GNU/Linux, FreeBSD, NetBSD, and OpenBSD. See the
-#	license for details."
-#
-# A distribution based on OpenEmbedded (OpenZaurus, OpenSimpad, etc.) is a
-# "free Unix" distribution, therefore we can include the package.
-#
-#
-# Please note that the license is not 100% free because it limits what you can
-# do:
-#
-#	"The C-Kermit source code may not be changed without the consent of
-#	the Kermit Project, which will not be unreasonably withheld (this is
-#	simply a matter of keeping a consistent and supportable code base)."
-#
-# But we don't change the source code in any way, so we comply to the license.
-# So, essentially for us C-Kermit is free as in beer, but not in freedom.
-#
-# That is true for other distros. C-Kkermit is distributed by:
-#
-#	Debian:	http://packages.debian.org/unstable/comm/ckermit
-#	Gentoo: http://mirror.pudas.net/gentoo-x86-portage/app-misc/ckermit/ckermit-8.0.211.ebuild
-#	SuSE: http://www.novell.com/products/linuxpackages/enterpriseserver/s390/ckermit.html
-#	Fedora Core: http://cvs.fedora.redhat.com/viewcvs/devel/ckermit/
-#	PLD: http://cvs.pld.org.pl/SPECS/ckermit.spec
-#
-# and, according to the Kermit website http://www.columbia.edu/kermit/ck80.html also with
-#
-#	Red Hat 9 (on earlier Red Hat's it was on the PowerTools CD)
-#	HP-UX
-#	FreeBSD
-#	NetBSD
-#	OpenBSD
-#
-# ... and probably other distros as well.
-#
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://COPYING.TXT;md5=932ca542d6c6cb8a59a0bcd76ab67cc3"
+SRC_URI = "ftp://www.columbia.edu/kermit/archives/cku${PV}.tar.gz;subdir=${BPN}-${PV}"
+PR = "r0"
 
 export CC2 = "${CC}"
 export BINDIR = "${bindir}"
@@ -77,7 +37,7 @@ do_compile () {
 		-DNOB_50 -DNOB_75 -DNOB_134 -DNOB_150 -DNOB_200 \
 		-DNOB_1800 -DNOB_3600 -DNOB_7200 -DNOB_76K -DNOB_230K \
 		-DNOB_460K -DNOB_921K \
-		-DNOAPC -DNOCSETS -DNONET -DNOUNICODE -DNOHELP -DNODEBUG \
+		-DNOCSETS -DNONET -DNOUNICODE -DNOHELP -DNODEBUG \
 		-DNOFRILLS -DNOFTP -DNODIAL -DNOPUSH -DNOIKSD -DNOHTTP -DNOFLOAT \
 		-DNOSERVER -DNOSEXP -DNORLOGIN -DNOOLDMODEMS -DNOSSH -DNOLISTEN \
 		-DNORESEND -DNOAUTODL -DNOSTREAMING -DNOHINTS -DNOCKXYZ -DNOLEARN \
@@ -88,11 +48,11 @@ do_compile () {
 
 do_install () {
 	install -d ${D}${BINDIR} ${D}${MANDIR} ${D}${INFODIR}
-	oe_runmake 'DESTDIR=${D}' 'MANDIR=${D}${MANDIR}' install
+	oe_runmake 'DESTDIR=${D}' install
 	# Fix up dangling symlink
 	rm ${D}${BINDIR}/kermit-sshsub
 	(cd ${D}${BINDIR} && ln -s ${BINDIR}/kermit kermit-sshusb)
 }
 
-SRC_URI[md5sum] = "5767ec5e6ff0857cbfe2d3ec1ee0e2bc"
-SRC_URI[sha256sum] = "39e7cd4892502344a635952843487d9b4bfa98e59d1e1acad5ef8aa969abba93"
+SRC_URI[md5sum] = "59e80f909edf305933af8e0348dcc5d7"
+SRC_URI[sha256sum] = "9793eb125f8936b079c6d7e5c3d2ff885cfedc07f9d2dd1e7db928e3029a211a"
-- 
1.7.5.4

Re: [meta-oe][PATCH v2 0/2] Import ckermit recipe

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

Op 16-08-11 14:05, Anders Darander schreef:
> 
> Ckermit is useful, not least as an alternative to lrzsz for serial port file-transfer (it has been a lot more robust in a number of cases).
> 
> This patch series imports the ckermit recipe from oe-dev. Thereafter, ckermit gets updated to the latest version, which also has the licensed change to BSD 3-clause.
> 
> V2: * Rebasing on the latest OE-version * Make sure that the patch is a rename, not add/delete pair.

Thanks, I q'd these after the binutils 2.20 patches, so they will go in after that completes its test build.
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)

iD8DBQFOSmb8MkyGM64RGpERAuPWAKCcgNTz/DvNGbx1DkFgs80sPLYwIwCeJ7OM
Ml3wIw3XHY9XLfdGJUdWA/I=
=kgBP
-----END PGP SIGNATURE-----

Re: [meta-oe][PATCH v2 1/2] ckermit: import from OE rev 5350bbef01b8979617e3d0fd38939f94f1fa5315

[Paul Menzel]

[-- Attachment #1: Type: text/plain, Size: 1500 bytes --]

Dear Anders, Koen,


Am Dienstag, den 16.08.2011, 14:05 +0200 schrieb Anders Darander:
> Adding LIC_FILES_CHKSUM, otherwise it is identical to the oe version.
> 
> Build tested on a custom ARM9 platform.
> 
> Signed-off-by: Anders Darander <anders@chargestorm.se>
> ---
>  meta-oe/recipes-support/ckermit/ckermit_211.bb |   98 ++++++++++++++++++++++++
>  1 files changed, 98 insertions(+), 0 deletions(-)
>  create mode 100644 meta-oe/recipes-support/ckermit/ckermit_211.bb
> 
> diff --git a/meta-oe/recipes-support/ckermit/ckermit_211.bb b/meta-oe/recipes-support/ckermit/ckermit_211.bb
> new file mode 100644
> index 0000000..88bc918
> --- /dev/null
> +++ b/meta-oe/recipes-support/ckermit/ckermit_211.bb
> @@ -0,0 +1,98 @@
> +DESCRIPTION = "C-Kermit is a combined serial and network communication \
> +software package offering a consistent, medium-independent, \
> +cross-platform approach to connection establishment, terminal \
> +sessions, file transfer, character-set translation, and automation \
> +of communication tasks."
> +HOMEPAGE = "http://www.columbia.edu/kermit/"
> +SECTION = "console/network"
> +LICENSE = "Kermit"
> +LIC_FILES_CHKSUM = "file://COPYING.TXT;md5=17dabbd2543933464b6d32083c3a3596"
> +SRC_URI = "ftp://kermit.columbia.edu/kermit/archives/cku${PV}.tar.gz;subdir=${BPN}-${PV}"
> +PR = "r3"

could you please edit this commit and make that `r0`.

[…]

Acked-by: Paul Menzel <paulepanter@users.sourceforge.net>


Thanks,

Paul

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

Re: [meta-oe][PATCH v2 1/2] ckermit: import from OE rev 5350bbef01b8979617e3d0fd38939f94f1fa5315

[Anders Darander]

* Paul Menzel <paulepanter@users.sourceforge.net> [110816 17:05]:
 
> Am Dienstag, den 16.08.2011, 14:05 +0200 schrieb Anders Darander:
> > +LICENSE = "Kermit"
> > +LIC_FILES_CHKSUM = "file://COPYING.TXT;md5=17dabbd2543933464b6d32083c3a3596"
> > +SRC_URI = "ftp://kermit.columbia.edu/kermit/archives/cku${PV}.tar.gz;subdir=${BPN}-${PV}"
> > +PR = "r3"

> could you please edit this commit and make that `r0`.

Sorry, I missed your previous comment on PR. Sure, I'll send an updated
patch shortly.

Cheers,
Anders

-- 
Anders Darander
ChargeStorm AB