[PATCH] waffle: new package, a GL deferred resolution library.

[PATCH] waffle: new package, a GL deferred resolution library.

[Ross Burton]

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 meta-oe/recipes-graphics/waffle/files/cflags.patch |   30 ++++++++++++++++++++
 meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb    |   21 ++++++++++++++
 2 files changed, 51 insertions(+)
 create mode 100644 meta-oe/recipes-graphics/waffle/files/cflags.patch
 create mode 100644 meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb

diff --git a/meta-oe/recipes-graphics/waffle/files/cflags.patch b/meta-oe/recipes-graphics/waffle/files/cflags.patch
new file mode 100644
index 0000000..34b9b7f
--- /dev/null
+++ b/meta-oe/recipes-graphics/waffle/files/cflags.patch
@@ -0,0 +1,30 @@
+Upstream-Status: Backport
+Signed-off-by: Ross Burton <ross.burton@intel.com>
+
+From 2abec1cb3c17fa5ec8d945d79acd74a39c38293a Mon Sep 17 00:00:00 2001
+From: Ross Burton <ross.burton@intel.com>
+Date: Wed, 12 Dec 2012 12:57:18 +0000
+Subject: cmake: respect existing CMAKE_C_FLAGS
+
+When cross-compiling it's not unusual to need specific arguments passed to gcc
+such as --sysroot.  Ensure that these are passed on from the toolchain file by
+appending to CMAKE_C_FLAGS instead of overwriting it.
+
+Signed-off-by: Ross Burton <ross.burton@intel.com>
+Signed-off-by: Chad Versace <chad.versace@linux.intel.com>
+---
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 3c9bb5d..5fc4467 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -211,7 +211,7 @@ endif()
+ # Compiler Flags
+ # ------------------------------------------------------------------------------
+ 
+-set(CMAKE_C_FLAGS "--std=c99 -Wall -Werror=implicit-function-declaration")
++set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} --std=c99 -Wall -Werror=implicit-function-declaration")
+ if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
+     # On MacOS, the SSE2 headers trigger this error.
+     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=missing-prototypes")
+--
+cgit v0.9.0.2-2-gbebe
diff --git a/meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb b/meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb
new file mode 100644
index 0000000..6bdeb1e
--- /dev/null
+++ b/meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb
@@ -0,0 +1,21 @@
+SUMMARY = "cross-platform C library to defer selection of GL API and of window system"
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=4c5154407c2490750dd461c50ad94797 \
+                    file://include/waffle/waffle.h;endline=24;md5=61dbf8697f61c78645e75a93c585b1bf"
+
+PR = "r0"
+
+SRC_URI = "http://people.freedesktop.org/~chadversary/waffle/files/release/${BPN}-${PV}/${BPN}-${PV}.tar.xz \
+           file://cflags.patch"
+
+SRC_URI[md5sum] = "fdd07cea7709422fbf72418ee63a285d"
+SRC_URI[sha256sum] = "7e342c859b58d4e051b347ef3d7740ed2f3b6c506b93daec272724afe7dd1311"
+
+inherit cmake
+
+DEPENDS = "virtual/libgl libxcb libx11"
+
+# TODO: add waffle_has_wayland, waffle_has_x11_egl, waffle_has_gbm depending on environment.
+EXTRA_OECMAKE = "-Dwaffle_has_glx=1"
+
+FILES_${PN}-dev += "${datadir}/cmake/Modules/FindWaffle.cmake"
-- 
1.7.10

Re: [PATCH] waffle: new package, a GL deferred resolution library.

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

Op 17-12-12 12:04, Ross Burton schreef:
> Signed-off-by: Ross Burton <ross.burton@intel.com>

> diff --git a/meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb
> b/meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb new file mode 100644 
> index 0000000..6bdeb1e --- /dev/null +++
> b/meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb @@ -0,0 +1,21 @@ 
> +SUMMARY = "cross-platform C library to defer selection of GL API and of
> window system" +LICENSE = "BSD-2-Clause" +LIC_FILES_CHKSUM =
> "file://LICENSE.txt;md5=4c5154407c2490750dd461c50ad94797 \ +
> file://include/waffle/waffle.h;endline=24;md5=61dbf8697f61c78645e75a93c585b1bf"
>
> 
+
> +PR = "r0"

*insert usual comment about PR=r0 being a nuisance*



-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
Comment: GPGTools - http://gpgtools.org

iD8DBQFQzxZaMkyGM64RGpERApjGAJ9UF7l5PcvEcKqHT6RW8JZ2uh5FEACgt1Eu
DTMV8WOs8cVWE2OCoUGmq/w=
=gawy
-----END PGP SIGNATURE-----

Re: [PATCH] waffle: new package, a GL deferred resolution library.

[Burton, Ross]

On 17 December 2012 12:55, Koen Kooi <koen@dominion.thruhere.net> wrote:
> *insert usual comment about PR=r0 being a nuisance*

I still find removing/adding PR lines more annoying than a redundant
r0, but we'll have to agree to disagree.  Alternatively meta-oe
embraces the PR service model as oe-core has, and I can drop them for
good.

Ross

Re: [PATCH] waffle: new package, a GL deferred resolution library.

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

Op 17-12-12 15:20, Burton, Ross schreef:
> On 17 December 2012 12:55, Koen Kooi <koen@dominion.thruhere.net> wrote:
>> *insert usual comment about PR=r0 being a nuisance*
> 
> I still find removing/adding PR lines more annoying than a redundant r0,
> but we'll have to agree to disagree.  Alternatively meta-oe embraces the
> PR service model as oe-core has, and I can drop them for good.

That's a DISTRO thing, not a layer thing to switch to PR service, but yes,
people should switch to PR service sooner than later (angstrom already has).

-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
Comment: GPGTools - http://gpgtools.org

iD8DBQFQzzCiMkyGM64RGpERAtJPAJ9W+ayP4j81+Rn/GqLuEWowm+uuSQCfd3BR
+oYyQvr39xiq3EtZ9nR6IB8=
=b11f
-----END PGP SIGNATURE-----

[PATCH] waffle: new package, a GL deferred resolution library.

[Ross Burton]

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 meta-oe/recipes-graphics/waffle/files/cflags.patch |   27 ++++++++++++++++
 meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb    |   34 ++++++++++++++++++++
 2 files changed, 61 insertions(+)
 create mode 100644 meta-oe/recipes-graphics/waffle/files/cflags.patch
 create mode 100644 meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb

diff --git a/meta-oe/recipes-graphics/waffle/files/cflags.patch b/meta-oe/recipes-graphics/waffle/files/cflags.patch
new file mode 100644
index 0000000..3819756
--- /dev/null
+++ b/meta-oe/recipes-graphics/waffle/files/cflags.patch
@@ -0,0 +1,27 @@
+Upstream-Status: Backport
+Signed-off-by: Ross Burton <ross.burton@intel.com>
+
+From 2abec1cb3c17fa5ec8d945d79acd74a39c38293a Mon Sep 17 00:00:00 2001
+From: Ross Burton <ross.burton@intel.com>
+Date: Wed, 12 Dec 2012 12:57:18 +0000
+Subject: cmake: respect existing CMAKE_C_FLAGS
+
+When cross-compiling it's not unusual to need specific arguments passed to gcc
+such as --sysroot.  Ensure that these are passed on from the toolchain file by
+appending to CMAKE_C_FLAGS instead of overwriting it.
+
+Signed-off-by: Ross Burton <ross.burton@intel.com>
+
+Index: waffle-1.2.2/CMakeLists.txt
+===================================================================
+--- waffle-1.2.2.orig/CMakeLists.txt	2012-11-28 00:43:40.000000000 +0000
++++ waffle-1.2.2/CMakeLists.txt	2013-02-13 11:34:02.476188233 +0000
+@@ -212,7 +212,7 @@
+ # ------------------------------------------------------------------------------
+ 
+ # FIXME: Only enable c99 if compiler supports it.
+-set(CMAKE_C_FLAGS "--std=c99 -Wall -Werror=implicit-function-declaration")
++set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} --std=c99 -Wall -Werror=implicit-function-declaration")
+ if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
+     # On MacOS, the SSE2 headers trigger this error.
+     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror=missing-prototypes")
diff --git a/meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb b/meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb
new file mode 100644
index 0000000..4f80191
--- /dev/null
+++ b/meta-oe/recipes-graphics/waffle/waffle_1.2.2.bb
@@ -0,0 +1,34 @@
+SUMMARY = "cross-platform C library to defer selection of GL API and of window system"
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=4c5154407c2490750dd461c50ad94797 \
+                    file://include/waffle/waffle.h;endline=24;md5=61dbf8697f61c78645e75a93c585b1bf"
+
+SRC_URI = "http://people.freedesktop.org/~chadversary/waffle/files/release/${BPN}-${PV}/${BPN}-${PV}.tar.xz \
+           file://cflags.patch"
+
+SRC_URI[md5sum] = "fdd07cea7709422fbf72418ee63a285d"
+SRC_URI[sha256sum] = "7e342c859b58d4e051b347ef3d7740ed2f3b6c506b93daec272724afe7dd1311"
+
+inherit cmake
+
+# This should be overridden per-machine to reflect the capabilities of the GL
+# stack.
+PACKAGECONFIG ??= "glx"
+
+# I say virtual/libgl, actually wants gl.pc
+PACKAGECONFIG[glx] = "-Dwaffle_has_glx=1,,virtual/libgl libx11"
+
+# I say virtual/libgl, actually wants wayland-egl.pc, egl.pc, and the wayland
+# DISTRO_FEATURE.
+PACKAGECONFIG[wayland] = "-Dwaffle_has_wayland=1,,virtual/libgl wayland"
+
+# I say virtual/libgl, actually wants gbm.pc egl.pc
+PACKAGECONFIG[gbm] = "-Dwaffle_has_wayland=1,,virtual/libgl udev"
+
+# I say virtual/libgl, actually wants egl.pc
+PACKAGECONFIG[x11-egl] = "-Dwaffle_has_x11_egl=1,,virtual/libgl libxcb"
+
+# Take the flags added by PACKAGECONFIG and pass them to cmake.
+EXTRA_OECMAKE = "${EXTRA_OECONF}"
+
+FILES_${PN}-dev += "${datadir}/cmake/Modules/FindWaffle.cmake"
-- 
1.7.10.4