[meta-oe][PATCHv2 1/3] libeigen: initial contribution required by opencv

[meta-oe][PATCHv2 1/3] libeigen: initial contribution required by opencv

[Lukas Bulwahn]

As opencv depends on libeigen, libeigen is added to the meta-oe
layer. This commit is derived from the work [1] by Kartik Mohta.

[1] https://github.com/kartikmohta/meta-km/tree/master/recipes-extended/eigen

Signed-off-by: Lukas Bulwahn <lukas.bulwahn@oss.bmw-carit.de>
---
 .../libeigen/libeigen/eigen-disable-tests.patch    |   75 ++++++++++++++++++++
 meta-oe/recipes-support/libeigen/libeigen_3.2.0.bb |   25 +++++++
 2 files changed, 100 insertions(+)
 create mode 100644 meta-oe/recipes-support/libeigen/libeigen/eigen-disable-tests.patch
 create mode 100644 meta-oe/recipes-support/libeigen/libeigen_3.2.0.bb

diff --git a/meta-oe/recipes-support/libeigen/libeigen/eigen-disable-tests.patch b/meta-oe/recipes-support/libeigen/libeigen/eigen-disable-tests.patch
new file mode 100644
index 0000000..b3dddbe
--- /dev/null
+++ b/meta-oe/recipes-support/libeigen/libeigen/eigen-disable-tests.patch
@@ -0,0 +1,75 @@
+libeigen: don't try building tests
+
+While configuring, if the tests are enabled, it checks some machine-specific
+settings which we don't want to do while cross-compiling.
+
+Upstream-Status: Inappropriate [configuration]
+
+Signed-off-by: Lukas Bulwahn <lukas.bulwahn@oss.bmw-carit.de>
+
+--- a/CMakeLists.txt~	2013-07-29 16:59:48.403504947 -0400
++++ b/CMakeLists.txt	2013-07-29 17:00:19.868020948 -0400
+@@ -346,25 +346,25 @@
+
+ add_subdirectory(doc EXCLUDE_FROM_ALL)
+
+-include(EigenConfigureTesting)
++#include(EigenConfigureTesting)
+
+ # fixme, not sure this line is still needed:
+-enable_testing() # must be called from the root CMakeLists, see man page
++#enable_testing() # must be called from the root CMakeLists, see man page
+
+
+-if(EIGEN_LEAVE_TEST_IN_ALL_TARGET)
+-  add_subdirectory(test) # can't do EXCLUDE_FROM_ALL here, breaks CTest
+-else()
+-  add_subdirectory(test EXCLUDE_FROM_ALL)
+-endif()
++#if(EIGEN_LEAVE_TEST_IN_ALL_TARGET)
++#  add_subdirectory(test) # can't do EXCLUDE_FROM_ALL here, breaks CTest
++#else()
++#  add_subdirectory(test EXCLUDE_FROM_ALL)
++#endif()
+
+-if(EIGEN_LEAVE_TEST_IN_ALL_TARGET)
+-  add_subdirectory(blas)
+-  add_subdirectory(lapack)
+-else()
+-  add_subdirectory(blas EXCLUDE_FROM_ALL)
+-  add_subdirectory(lapack EXCLUDE_FROM_ALL)
+-endif()
++#if(EIGEN_LEAVE_TEST_IN_ALL_TARGET)
++#  add_subdirectory(blas)
++#  add_subdirectory(lapack)
++#else()
++#  add_subdirectory(blas EXCLUDE_FROM_ALL)
++#  add_subdirectory(lapack EXCLUDE_FROM_ALL)
++#endif()
+
+ add_subdirectory(unsupported)
+
+@@ -384,7 +384,7 @@
+
+ configure_file(scripts/cdashtesting.cmake.in cdashtesting.cmake @ONLY)
+
+-ei_testing_print_summary()
++#ei_testing_print_summary()
+
+ message(STATUS "")
+ message(STATUS "Configured Eigen ${EIGEN_VERSION_NUMBER}")
+--- a/unsupported/CMakeLists.txt~	2013-07-29 16:59:54.091598607 -0400
++++ b/unsupported/CMakeLists.txt	2013-07-29 17:00:27.052139300 -0400
+@@ -1,7 +1,7 @@
+ add_subdirectory(Eigen)
+ add_subdirectory(doc EXCLUDE_FROM_ALL)
+-if(EIGEN_LEAVE_TEST_IN_ALL_TARGET)
+-  add_subdirectory(test) # can't do EXCLUDE_FROM_ALL here, breaks CTest
+-else()
+-  add_subdirectory(test EXCLUDE_FROM_ALL)
+-endif()
++#if(EIGEN_LEAVE_TEST_IN_ALL_TARGET)
++#  add_subdirectory(test) # can't do EXCLUDE_FROM_ALL here, breaks CTest
++#else()
++#  add_subdirectory(test EXCLUDE_FROM_ALL)
++#endif()
diff --git a/meta-oe/recipes-support/libeigen/libeigen_3.2.0.bb b/meta-oe/recipes-support/libeigen/libeigen_3.2.0.bb
new file mode 100644
index 0000000..4183f05
--- /dev/null
+++ b/meta-oe/recipes-support/libeigen/libeigen_3.2.0.bb
@@ -0,0 +1,25 @@
+DESCRIPTION = "Eigen is a C++ template library for linear algebra: matrices, vectors, numerical solvers, and related algorithms."
+AUTHOR = "Benoît Jacob and Gaël Guennebaud and others"
+HOMEPAGE = "http://eigen.tuxfamily.org/"
+LICENSE = "MPL-2.0"
+LIC_FILES_CHKSUM = "file://COPYING.MPL2;md5=815ca599c9df247a0c7f619bab123dad"
+
+SRC_URI = "http://bitbucket.org/eigen/eigen/get/${PV}.tar.bz2 \
+           file://eigen-disable-tests.patch"
+SRC_URI[md5sum] = "894381be5be65bb7099c6fd91d61b357"
+SRC_URI[sha256sum] = "011f78960d939227f9276173d0c4cc0053bb9e0a7356539a9a6c7c89d984fab6"
+
+S = "${WORKDIR}/eigen-eigen-ffa86ffb5570"
+
+inherit cmake
+
+OECMAKE_SOURCEPATH = ".."
+OECMAKE_BUILDPATH = "build"
+
+EXTRA_OECMAKE += "-Dpkg_config_libdir=${libdir}"
+
+FILES_${PN} = "${includedir} ${libdir}"
+
+# ${PN} is empty so we need to tweak -dev and -dbg package dependencies
+RDEPENDS_${PN}-dev = ""
+RRECOMMENDS_${PN}-dbg = "${PN}-dev (= ${EXTENDPKGV})"
-- 
1.7.10.4

[meta-oe][PATCHv2 2/3] opencv: adding libeigen dependency

[Lukas Bulwahn]

In the opencv's CMakeLists.txt under Optional 3rd party components,
the option "WITH_EIGEN" is by default ON. Hence, this commit adds
the libeigen dependency to opencv.

Signed-off-by: Lukas Bulwahn <lukas.bulwahn@oss.bmw-carit.de>
---
 meta-oe/recipes-support/opencv/opencv_2.4.3.bb |    2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta-oe/recipes-support/opencv/opencv_2.4.3.bb b/meta-oe/recipes-support/opencv/opencv_2.4.3.bb
index 39b608a..21a4f06 100644
--- a/meta-oe/recipes-support/opencv/opencv_2.4.3.bb
+++ b/meta-oe/recipes-support/opencv/opencv_2.4.3.bb
@@ -7,7 +7,7 @@ LIC_FILES_CHKSUM = "file://include/opencv2/opencv.hpp;endline=41;md5=6d690d8488a
 
 ARM_INSTRUCTION_SET = "arm"
 
-DEPENDS = "python-numpy v4l-utils libav gtk+ libtool swig swig-native python jpeg bzip2 zlib libpng tiff glib-2.0"
+DEPENDS = "python-numpy v4l-utils libav gtk+ libtool swig swig-native python jpeg bzip2 zlib libpng tiff glib-2.0 libeigen"
 
 SRC_URI = "${SOURCEFORGE_MIRROR}/opencvlibrary/opencv-unix/${PV}/OpenCV-${PV}.tar.bz2 \
            file://opencv-fix-pkgconfig-generation.patch \
-- 
1.7.10.4

[meta-oe][PATCHv2 3/3] opencv: adding PACKAGECONFIG for eigen gtk jpeg libav png tiff v4l

[Lukas Bulwahn]

Signed-off-by: Lukas Bulwahn <lukas.bulwahn@oss.bmw-carit.de>
---
 meta-oe/recipes-support/opencv/opencv_2.4.3.bb |   14 ++++++++++----
 1 file changed, 10 insertions(+), 4 deletions(-)

diff --git a/meta-oe/recipes-support/opencv/opencv_2.4.3.bb b/meta-oe/recipes-support/opencv/opencv_2.4.3.bb
index 21a4f06..a0adc32 100644
--- a/meta-oe/recipes-support/opencv/opencv_2.4.3.bb
+++ b/meta-oe/recipes-support/opencv/opencv_2.4.3.bb
@@ -7,7 +7,7 @@ LIC_FILES_CHKSUM = "file://include/opencv2/opencv.hpp;endline=41;md5=6d690d8488a
 
 ARM_INSTRUCTION_SET = "arm"
 
-DEPENDS = "python-numpy v4l-utils libav gtk+ libtool swig swig-native python jpeg bzip2 zlib libpng tiff glib-2.0 libeigen"
+DEPENDS = "python-numpy libtool swig swig-native python bzip2 zlib glib-2.0"
 
 SRC_URI = "${SOURCEFORGE_MIRROR}/opencvlibrary/opencv-unix/${PV}/OpenCV-${PV}.tar.bz2 \
            file://opencv-fix-pkgconfig-generation.patch \
@@ -26,14 +26,20 @@ OECMAKE_BUILDPATH = "${WORKDIR}/build-${TARGET_ARCH}"
 
 EXTRA_OECMAKE = "-DPYTHON_NUMPY_INCLUDE_DIR:PATH=${STAGING_LIBDIR}/${PYTHON_DIR}/site-packages/numpy/core/include \
                  -DBUILD_PYTHON_SUPPORT=ON \
-                 -DWITH_FFMPEG=ON \
                  -DWITH_GSTREAMER=OFF \
-                 -DWITH_V4L=ON \
-                 -DWITH_GTK=ON \
                  -DCMAKE_SKIP_RPATH=ON \
                  ${@bb.utils.contains("TARGET_CC_ARCH", "-msse3", "-DENABLE_SSE=1 -DENABLE_SSE2=1 -DENABLE_SSE3=1 -DENABLE_SSSE3=1", "", d)} \
 "
 
+PACKAGECONFIG ??= "eigen gtk jpeg libav png tiff v4l"
+PACKAGECONFIG[eigen] = "-DWITH_EIGEN=ON,-DWITH_EIGEN=OFF,libeigen,"
+PACKAGECONFIG[gtk] = "-DWITH_GTK=ON,-DWITH_GTK=OFF,gtk+,"
+PACKAGECONFIG[jpeg] = "-DWITH_JPEG=ON,-DWITH_JPEG=OFF,jpeg,"
+PACKAGECONFIG[libav] = "-DWITH_FFMPEG=ON,-DWITH_FFMPEG=OFF,libav,"
+PACKAGECONFIG[png] = "-DWITH_PNG=ON,-DWITH_PNG=OFF,libpng,"
+PACKAGECONFIG[tiff] = "-DWITH_TIFF=ON,-DWITH_TIFF=OFF,tiff,"
+PACKAGECONFIG[v4l] = "-DWITH_V4L=ON,-DWITH_V4L=OFF,v4l-utils,"
+
 inherit distutils-base pkgconfig cmake
 
 export BUILD_SYS
-- 
1.7.10.4

Re: [meta-oe][PATCHv2 3/3] opencv: adding PACKAGECONFIG for eigen gtk jpeg libav png tiff v4l

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

Op 01-10-13 09:44, Lukas Bulwahn schreef:
> Signed-off-by: Lukas Bulwahn <lukas.bulwahn@oss.bmw-carit.de> --- 
> meta-oe/recipes-support/opencv/opencv_2.4.3.bb |   14 ++++++++++---- 1
> file changed, 10 insertions(+), 4 deletions(-)
> 
> diff --git a/meta-oe/recipes-support/opencv/opencv_2.4.3.bb
> b/meta-oe/recipes-support/opencv/opencv_2.4.3.bb index 21a4f06..a0adc32
> 100644 --- a/meta-oe/recipes-support/opencv/opencv_2.4.3.bb +++
> b/meta-oe/recipes-support/opencv/opencv_2.4.3.bb @@ -7,7 +7,7 @@
> LIC_FILES_CHKSUM =
> "file://include/opencv2/opencv.hpp;endline=41;md5=6d690d8488a
> 
> ARM_INSTRUCTION_SET = "arm"
> 
> -DEPENDS = "python-numpy v4l-utils libav gtk+ libtool swig swig-native
> python jpeg bzip2 zlib libpng tiff glib-2.0 libeigen" +DEPENDS =
> "python-numpy libtool swig swig-native python bzip2 zlib glib-2.0"
> 
> SRC_URI =
> "${SOURCEFORGE_MIRROR}/opencvlibrary/opencv-unix/${PV}/OpenCV-${PV}.tar.bz2
> \ file://opencv-fix-pkgconfig-generation.patch \ @@ -26,14 +26,20 @@
> OECMAKE_BUILDPATH = "${WORKDIR}/build-${TARGET_ARCH}"
> 
> EXTRA_OECMAKE =
> "-DPYTHON_NUMPY_INCLUDE_DIR:PATH=${STAGING_LIBDIR}/${PYTHON_DIR}/site-packages/numpy/core/include
> \ -DBUILD_PYTHON_SUPPORT=ON \ -                 -DWITH_FFMPEG=ON \ 
> -DWITH_GSTREAMER=OFF \ -                 -DWITH_V4L=ON \ -
> -DWITH_GTK=ON \ -DCMAKE_SKIP_RPATH=ON \ 
> ${@bb.utils.contains("TARGET_CC_ARCH", "-msse3", "-DENABLE_SSE=1
> -DENABLE_SSE2=1 -DENABLE_SSE3=1 -DENABLE_SSSE3=1", "", d)} \ "
> 
> +PACKAGECONFIG ??= "eigen gtk jpeg libav png tiff v4l" 
> +PACKAGECONFIG[eigen] = "-DWITH_EIGEN=ON,-DWITH_EIGEN=OFF,libeigen," 
> +PACKAGECONFIG[gtk] = "-DWITH_GTK=ON,-DWITH_GTK=OFF,gtk+," 
> +PACKAGECONFIG[jpeg] = "-DWITH_JPEG=ON,-DWITH_JPEG=OFF,jpeg," 
> +PACKAGECONFIG[libav] = "-DWITH_FFMPEG=ON,-DWITH_FFMPEG=OFF,libav," 
> +PACKAGECONFIG[png] = "-DWITH_PNG=ON,-DWITH_PNG=OFF,libpng," 
> +PACKAGECONFIG[tiff] = "-DWITH_TIFF=ON,-DWITH_TIFF=OFF,tiff," 
> +PACKAGECONFIG[v4l] = "-DWITH_V4L=ON,-DWITH_V4L=OFF,v4l-utils," +

Can you add one for gstreamer as well? In the past gst and libav were
mutually exclusive options for opencv, but I don't know if that's still the
case.

regards,

Koen

-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)
Comment: GPGTools - http://gpgtools.org

iD8DBQFSUmf7MkyGM64RGpERAuasAKCKq/PJt7dTmZVm/hf3biGNmWx6CQCgjwml
foAecPiAacNLzoy79SY0th4=
=Kcxg
-----END PGP SIGNATURE-----